地图中可用的中文ERM收集专帖

暗黑龙守护神

1、可用于地图事件中的第二追随者ERM汉化版。
2、可用于地图事件中的秘银ERM汉化版。
3、可用于地图事件中的追随者ERM汉化版。
4、老实猪版的加强一追

补充一个Yunings整理内置脚本集（有时间会逐一汉化）：经过验证的标准内置脚本，助你编制100%纯粹WoG地图（版本1.4）

[ 本帖最后由 暗黑龙守护神 于 2009-6-26 12:47 编辑 ]

暗黑龙守护神

隐藏技能

ZVSE
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
ERMS_ScriptDate=22.5(May).2005
!?HL-1;
!!FU710:P;

!?FU707;
!!HE-1:Sx16/?y1; [check for presence of skill]
!!VRv549&y1>0:+1; [count it]

!?FU710;
!!VRv549:S0; [count of skills for this hero]
!!DO707/0/27/1:P; [count the skills, return in v549]

!!FU|v549<8/v549>12:E; // exit if hero has not enough or to much skills

!!VRy1:S0 R27; [pick a random skill to offer]
!!VRy1&y1=4:+1;
!!VRy1&y1=11:+2;
!!VRy1&y1=12:+1;
!!VRy1&y1>13/y1<19:+5;
!!HE-1:Sy1/?y2; [check for presence of random skill]
!!HE-1:B0/?z352; [get hero name]
!!UN:N4/353/y1; [get skill name]
!!HE-1:R2/?y3; [get hero sex]
!!VRz354&y3=0:S^他^;
!!VRz354&y3=1:S^她^;
!!VRy4:Sy1 *3 +3; [get picture of skill]
!!IF:V2/0; [assume won't learn skill]
!!IF&1000/y2=0/v549>=8/v549<=11:Q2/20/y4/2^%Z352可以学到一个秘术，%Z353。%Z354想不想学习这个秘术呢？^;
!!IF&-1000/y2=0/v549>=8/v549<=11:V2/1; [AI always learns it]
!!HE-1&2:Sy1/1; [give skill]

** end of function

********************************************************************************
Display Hidden Skills
********************************************************************************

[To view all skills (text list), Left-Click on the Experience icon]

Temporary Variables: v1-v4, z1-z3
Functions: FU14802-FU14806

[Hero screen trigger]
!?CM2;
!!UN:P182/?y-1; [Check if script is enabled: y-1]
!!VRy-1:S1;
!!FU&y-1<>1:E; [Exit if script isn't enabled]
!!CM:I?v1 S?v2 F?v4; [Location clicked: v1 (119=Experience Icon), Type of click: v2 (12=left), Flags: v4]

!!FU|v1<>119/v2<>12/v4>4:E; [Exit if Experience icon isn't left-clicked]

!!VRv3&v4=1:S0; [Initialize v3 to 0 for skill shifting: v3]

!!DO14804/1/8/1&v4=1:P; [Shift displayed skills, part 1 (store skills)]
!!DO14805/1/v3/1&v4=1/v3>1:P; [Shift displayed skills, part 2 (remove skills)]
!!DO14806/1/v3/1&v4=1/v3>1:P; [Shift displayed skills, part 3 (redisplay skills)]
!!UN&v4=1/v3>1:R3/-1; [Redraw hero screen]

!!VRv3&v4=4:S1; [Initialize v3 to 1 for skill swapping: v3]
!!DO14803/0/27/1&v4=4:P; [Skill display swapping: hidden skills with displayed skills]
!!IF&v4=4/y-60=0:M^{替换隐藏/显示技能}

(无隐藏技能交换)^;
!!CM&v4>0:R0; [Cancel normal click message]

!!FU&v4>0:E; [Exit if Experience icon shift or ctrl-clicked (Hidden skill display swapping)]

[Initialize z1, z4, v3 and y-1..y-27]
!!VRv3:S0;
!!HE-1:B0/?z3; [Hero's name: z3]
!!VRz1:S^{%Z3的隐藏技能}^;
!!VRz4:S^^;

!!DO14802/0/27/1:P; [Loop through all skills and add hidden skills to z1 list]

[Prepare dialogue for display of hidden skills]
!!VRy-29&v3>=9/v3<=16:S2; [Total number of skill pages: y-29]
!!VRy-29&v3>=17/v3<=24:S3; [Total number of skill pages: y-29]
!!VRy-29&v3>=25:S4; [Total number of skill pages: y-29]
!!IF&v3>=1:Ny-31/y-1/y-32/y-2/y-33/y-3/y-34/y-4/y-35/y-5/y-36/y-6/y-37/y-7/y-38/y-8;
!!VRz4&v3<=8:S^%Z1^;
!!VRz4&v3>=9:S^%Z1

(Page 1 of %Y-29)^;
!!IF&v3>=1:N^%Z4^; [Display 1-8 hidden skill pictures]
!!IF&v3>=9:Ny-39/y-9/y-40/y-10/y-41/y-11/y-42/y-12/y-43/y-13/y-44/y-14/y-45/y-15/y-46/y-16;
!!VRz4&v3>=9:S^%Z1

(Page 2 of %Y-29)^;
!!IF&v3>=9:N^%Z4^; [Display 9-16 hidden skill pictures]
!!IF&v3>=17:Ny-47/y-17/y-48/y-18/y-49/y-19/y-50/y-20/y-51/y-21/y-52/y-22/y-53/y-23/y-54/y-24;
!!VRz4&v3>=17:S^%Z1

(Page 3 of %Y-29)^;
!!IF&v3>=17:N^%Z4^; [Display 17-24 hidden skill pictures]
!!IF&v3>=25:Ny-55/y-25/y-56/y-26/y-57/y-27/y-58/y-28;
!!VRz4&v3>=25:S^%Z1

(Page 4 of %Y-29)^;
!!IF&v3>=25:N^%Z4^; [Display 25-28 hidden skill pictures]

!!IF&v3=0:M^%Z1

(无)^; [If no skills hidden skills, display this string]
!!CM:R0; [Disable standard mouse click message]

------------------------------------------------------------------------------------------------------------------

[Loop through all skills and store hidden skill picture numbers to y- variables]

!?FU14802;
!!HE-1:Sx16/?y1; [Skill Level in skill x16: y1]
!!HE-1:S?y2/x16/1; [Show slot for skill x16: y2 (0=not shown)]
!!VRv3&y1>0/y2=0:+1; [Increment v3 skill counter]
!!VRy3&y1>0/y2=0:Sv3 *-1; [Negative of skill counter: y3]
!!VRy7&y1>0/y2=0:Sy3 -30; [Negative of skill counter -30: y7]

[Store hidden skill number in yy3 (y-1..y-28)]
!!VRy5:Sx16 +1 *-1; [-1..-28: y5]
!!VRy6:Sy5 -30; [-31..-58: y6]
!!VRyy5:S-1; [Initialize y-1..y-28 to -1]
!!VRyy6:S-1; [Initialize y-31..y-58 to -1]
!!VRy4&y1>0/y2=0:Sx16 +1 *3 +y1 -1; [Calculate skill picture number: y4]
!!VRyy3&y1>0/y2=0:Sy4; [Store hidden skill picture number]
!!VRyy7&y1>0/y2=0:S20; [Store 20 for each hidden skill]

------------------------------------------------------------------------------------------------------------------

[Loop through all skills and allow hidden skills to be swapped with non-hidden]

!?FU14803;
!!HE-1:Sx16/?y1; [Skill Level in skill x16: y1 (0=no skill)]
!!HE-1:S?y2/x16/1; [Check display slot for skill x16: y2 (0=not shown)]
!!FU|y1=0/y2<>0/v3>8:E; [Exit if not a hidden skill or if v3>8]

!!UN:P193/?y11; [See if Warfare Option is enabled: y11=1 if yes]
!!VRy12:S0; [Initialize y12 to 0]
!!VRy19:S0; [Initialize y19 to 0]
!!VRy12|x16=10/x16=20/x16=27:S1; [Set y12 to 1 if this hidden skill is a Warfare Skill]
!!HE-1:S10/?y13; [Skill Level in Ballistics: y13 (0=no skill)]
!!HE-1:S?y14/10/1; [Check display slot for Ballistics: y14 (0=not shown)]
!!VRy19&y13>0/y14>0:S1; [Set y19 to 1 if Ballistics skill know and shown: y19]
!!HE-1:S20/?y15; [Skill Level in Artillery: y15 (0=no skill)]
!!HE-1:S?y16/20/1; [Check display slot for Artillery: y16 (0=not shown)]
!!VRy19&y15>0/y16>0:S1; [Set y19 to 1 if Artillery skill know and shown: y19]
!!HE-1:S27/?y17; [Skill Level in First Aid: y17 (0=no skill)]
!!HE-1:S?y18/27/1; [Check display slot for First Aid: y18 (0=not shown)]
!!VRy19&y17>0/y18>0:S1; [Set y19 to 1 if First Aid skill know and shown: y19]
!!VRy12|y11=0/y19=0:S0; [Reset y12 if Warfare not enabled, or no non-hidden Warfare Skill known]
!!FU&y12=1:E; [Exit if Hidden skill is a Warfare skill and another is known and shown]

!!VRy-60:S1; [Set y-60 to 1 if any hidden skill found: y-60]
!!VRy4:Sx16 +1 *3 +y1 -1; [Calculate hidden skill picture number: y4]

!!HE-1:S?y8; [Check number of displayed skills: y8]
!!VRy9|y8=0/y8=8:Sv3; [If 0 or 8 skills are displayed, used v3 for display slot: y9]
!!VRy9&y8>0/y8<8:Sy8 +1; [If more than 0 but fewer than 8 skills, use number displayed +1: y9]

!!HE-1:Sy9/?y5/1; [Skill number of skill in display slot #y9 (1..8): y5]
!!VRy6:S0; [Initialize y6 to 0]
!!HE-1&y5>=0:Sy5/?y6; [Hero's Skill Level of skill in slot v3: y6]

!!VRy7&y6>0:Sy5 +1 *3 +y6 -1; [Calculate displayed skill picture number: y7]

!!UN:N4/-1/x16; [Skill name of Hidden skill: z-1]
!!UN&y6>0:N4/-2/y5; [Skill name of Display skill: z-2]

!!IF:V2/0 V3/0; [Initialize Flags 2 and 3 to False]

!!IF&y6>0:Q2/20/y4/20/y7/2^{交换隐藏/显示技能}

你是否想把 %Z-1 技能和 %Z-2 技能交换？^;

!!HE-1&2:Sv3/x16/1; [Set hidden skill to display slot v3]

!!IF&y6<1:Q3/20/y4/2^{交换隐藏/显示技能}

你是否想把 %Z-1 放到空技能槽 #%Y9 里？^;

!!HE-1&3:Sx16/0; [Remove hidden skill]
!!HE-1&3:Sx16/y1; [Give hidden skill]

!!FU&-2/-3:E; [If no change, exit]

!!UN:R3/-1; [Redraw hero screen]
!!VRv3&y9=v3:+1; [Increment v3 display slot counter if y9=v3: v3]

------------------------------------------------------------------------------------------------------------------

[Loop through all displayed skills and store their number and level]

!?FU14804;
!!HE-1:Sx16/?y1/1; [Skill number of skill in display slot #x16 (1..8): y1]
!!FU&y1<0:E; [Skip if no skill there]
!!HE-1:Sy1/?y2; [Hero's Skill Level of skill in slot y1: y2]

!!VRv3:+1; [Increment v3]
!!VRy3:S70 +v3 *-1; [Index: Store skill number in y-71..y-78]
!!VRyy3:Sy1; [Store skill number: yy3]
!!VRy4:S80 +v3 *-1; [Index: Store skill level in y-81..y-88]
!!VRyy4:Sy2; [Store skill level: yy4]

------------------------------------------------------------------------------------------------------------------

[Remove all displayed skills]

!?FU14805;
!!VRy1:S70 +x16 *-1; [Index for stored skill number in y-71..y-78: y1]
!!HE-1:Syy1/0; [Delete skill: yy1]

------------------------------------------------------------------------------------------------------------------

[Redisplay redordered skills]

!?FU14806;
!!VRy1&x16=1:S70 +v3 *-1; [Index for last skill number: y1]
!!VRy2&x16=1:S80 +v3 *-1; [Index for last skill level: y2]

!!VRy1&x16>1:S70 +x16 -1 *-1; [Index for next skill number: y1]
!!VRy2&x16>1:S80 +x16 -1 *-1; [Index for next skill level: y2]

!!HE-1:Syy1/yy2; [Give skill to hero]

------------------------------------------------------------------------------------------------------------------

[End of Display Hidden Skills]

秘银矿（就是那个带个无色旗子的大锅）

ZVSE

*Mithril Smelter
*Uses vars v1800-v1807
*Uses functions FU1800-FU1802
!#TM83:S2/999/7/255;Gives resource on day 2 every week,set up timer for 7 daily,replace 7 with 1 for daily,with 2 for two daily and so on...
!#VRz100:S^秘银熔炉^;
!#HT63/27:T100;
!#VRv1800:S0; player 0
!#VRv1801:S0; player 1
!#VRv1802:S0; player 2
!#VRv1803:S0; player 3
!#VRv1804:S0; player 4
!#VRv1805:S0; player 5
!#VRv1806:S0; player 6
!#VRv1807:S0; player 7

!?OB63/27;                    If visited
!!PO998:O?i;                  get owner
!!HE-1:O?j;                   get hero owner
!!FU1800&i<>j:Pi/j;           if not owner then change owner

!?FU1800;
!!PO998:Ox2;                  set new owner
!!IF&1000:Q1/7/-1/1^{秘银熔炉}

你控制了一口秘银熔炉，它将每天向你提供1秘银。^;
!!FU1801:Pj;                   hint text
!!VRy1:S8;                     default is no owner(y1=8)
!!VRy1&x1>-1/x1<8:S1800 +x1;   if previous owner was a player then index to his var is y1
!!VRy2:S1800 +x2;              index to visiting hero's var is y2
!!VRvy1&y1<>8:-1;              decrease previous owner's var
!!VRvy2:+1;                    increase visitor's var

!?FU1801;
!!VRz100:S^秘银熔炉 ^; calc hint text into z100
!!VRz100&x1=0:+^红色玩家占有。(秘银)^;
!!VRz100&x1=1:+^蓝色玩家占有。(秘银)^;
!!VRz100&x1=2:+^褐色玩家占有。(秘银)^;
!!VRz100&x1=3:+^绿色玩家占有。(秘银)^;
!!VRz100&x1=4:+^橙色玩家占有。(秘银)^;
!!VRz100&x1=5:+^紫色玩家占有。(秘银)^;
!!VRz100&x1=6:+^青色玩家占有。(秘银)^;
!!VRz100&x1=7:+^粉色玩家占有。(秘银)^;
!!OB998:H100;    set hint text

!?TM83;                       timer trigger
!!DO1802/0/1/10:P;            give mithril

!?FU1802;
!!VRi:Sx16;                   calc index
!!VRi:+1800;                  calc index
!!VRj:Svi;                    store in j for easier reference
!!OW:Rx16/7/dj;               give mithril
*!OW:Rx16/7/?k;               ? current mithril
*!VRk:+j;                     ? new mithril
*!OW:Rx16/7/j;                store new mithril

移动步数显示（Ctrl+左键点击英雄界面中英雄头像）

1. ZVSE
   
2. _WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
   
3. ERMS_ScriptName=Movement Display
   
4. ERMS_ScriptAuthor=?
   
5. ERMS_ScriptVersion=1.0.0
   
6. ERMS_ScriptDate=3.July.2006
   
7. ERMS_ScriptERMVersion=2.X
   
8. ERMS_ScriptLanguage=英语(美国) or 中文(简体) (native)
   
9. 
   
10. !?CM2;
    
11. !!CM:I?y-1 F?y-2 S?y-3;
    
12. !!FU|y-1<>45/y-2<>4/y-3<>12:E;
    
13. !!HE-1:W?v568 B0/?z982 W?v684;
    
14. !!VRv684::103;
    
15. !!IF:M^{%Z982的移动点}
    
16. 
    
17. %Z982有%V568移动点(还可以走%V684步)。^;
    
18. !!UN:R3/-1;
    
19. 
    
20. **end of function

复制代码

死亡之屋

ZVSE
ERMS_ScriptDate=18.8(August).2004
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
***DEATH CHAMBER 9.0**** (by Rich Reed a.k.a. "Space8999")

***UPDATED: August 18, 2004


**This script allows for heroes to visit the new WoG structure in the Castle
**Objects in the Map Editor that resembles a pile of skulls (it is the 7th
**object in the very first column underneath the CASTLE town). When a hero
**visits it, he/she has a choice of fighting an "Undead King", which is a stack
**of Power Liches. Dread Knights, Wraiths, and Ghosts are
**also summoned onto the battlefield to aid the King in battle.

**Upon defeating the King, the hero is awarded lots of gold, Mithril,
**and Ghosts attempt to join the hero's army.

**This structure works similar to the other creature banks, such as the Medusa Stores,
**Imp Cache, Transylvanian Tavern, Naga Bank, Cyclops Stockpile, etc.

*!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
*MAJOR THANKS TO TIM PULVER (a.k.a. "Fnord"), STEVE HANNA, ARSTAHD, AND TO ANYONE ELSE
*WHO HELPED ME IN MAKING THIS SCRIPT POSSIBLE!
*!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!


**========================================
**FLAGS AND VARIABLES USED IN THIS SCRIPT
**========================================

**Flags
*-------------------------------------------------------------------------------
*FLAG 3 is used to ask the player if he/she wants to fight the Death Chamber
*FLAGS 800 and 801 are used solely for the Death Chamber battles
*-------------------------------------------------------------------------------

**Variables
**------------------------------------------------------------------------------
*z890 and z891 keeps the hint text for the Death Chamber structures
*z849 gets the name of the hero fighting the Power Liches
*z850 allows "Power Lich King" to be displayed when "Death Ripple" is cast
*v805 keeps the value of the visited Death Chamber's square
*v806 is used to store whether the script is enabled or not
*v807, v808, v809, v810, v811, v812 used for Power Lich King's spellcasting
*v820 used for summoning of Wraiths
**------------------------------------------------------------------------------

**Set up Death Chamber structure

!#UN:P70/?v806; ** Store 1 in v806 if script enabled, 0 if disabled

!#VRv805&v806=1:S0; **Store 0 in the variable v805

!#VRz890&v806=1:Sz170000;
!#HT63/15&v806=1:P0/890;

!#VRz891&v806=1:Sz170001;
!#HT63/15&v806=1:P1/891;

**------------------------------------------------------------------------------

!?OB63/15&1000/v806=1; *Triggers when any "Death Chamber" is visited

!!PO998:N?v805; **Check PO:N value of Death Chamber square
!!IF&v805=1:M1/z170002;


!?OB63/15&v805=0/1000/v806=1; *Triggers when any "Death Chamber" is visited
!!IF:Q3/21/65/2/z170003;

!!IF&3:V800/1; **Sets FLAG 800 to TRUE if OK is pressed

!!HE-1&3/v805=0:Tv998/v999/v1000/65/1; **Trigger battle with the Lich King

*===============================================================================
**Set up the special "Death Chamber" battlefields and Power Liches
*===============================================================================
!?BA0&800/v806=1;
!!BA:B20; **Evil Fog

!?BF&800/v806=1; **Sets up special battlefield
!!BF:C; **Clear the battlefield

!!BFO65/59; **Place 4 huge Crypts onto center of battlefield
!!BFO65/127;
!!BFO65/89;
!!BFO65/97;

!!BFO34/3; **Place spooky trees onto top and bottom of battlefield
!!BFO34/5;
!!BFO34/7;
!!BFO34/9;
!!BFO34/11;
!!BFO34/13;
!!BFO34/173;
!!BFO34/175;
!!BFO34/177;
!!BFO34/179;
!!BFO34/181;
!!BFO34/183;

!!BFO62/21; **Place 8 Gravemarkers and 2 crosses onto the battlefield
!!BFO62/24;
!!BFO62/26;
!!BFO62/27;
!!BFO62/30;
!!BFO62/157;
!!BFO62/160;
!!BFO62/162;
!!BFO62/163;
!!BFO62/166;

**Place 4 tombstones to close up area in middle of battlefield

!!BFO61/75;
!!BFO61/79;
!!BFO61/109;
!!BFO61/113;


**Code for attributes for the Lich King stacks

!!BM21:S50; **Lich King has 50 speed for duration of combat

!!BM21&v998<36:H600; **Lich King has 600 health if "x" position on map is less than 36
!!BM21&v998>35/v998<72:H800; **Lich King has 800 health if "x" position on map is between 36 and 71
!!BM21&v998>71/v998<108:H1000; **Lich King has 1000 health if "x" position on map is between 72 and 107
!!BM21&v998>107:H1200; **Lich King has 1200 health if "x" position on map is greater than 107

!!BM21:R5000; **Lich King has endless retaliations each round

!!MA:X65/?i;
!!VRi:+32768;
!!BM21:Fi;

!?BG&800/v806=1;
!!BU:G4; **Evil Fog effect

*===================================================================================
**Begin In-battle code for battle with Power Lich King
*===================================================================================
!?BR&800/v806=1;

!!VRz850:Sz170004;

!!BG&v997>0:N?v807; **Get current stack number into "v807"
!!BMv807&v997>0:P?i; **Get position of current stack number into "i"

!!HE-1:B0/?z849; **Get name of the hero
!!HE-1&v807<21:B0/z850; **Change hero's name to "Lich King" temporarily each round

!!BM21&v997>0/v807<21/v998<36:C24/i/1/1/0; **Power Lich King casts "Death Ripple"

!!BM21&v997>0/v807<21/v998>35/v998<72:C24/i/1/1/0;
!!BM21&v997>0/v807<21/v998>35/v998<72:C24/i/2/2/0; **Power Lich King casts "Death Ripple" twice

!!BM21&v997>0/v807<21/v998>71/v998<108:C24/i/1/1/0;
!!BM21&v997>0/v807<21/v998>71/v998<108:C24/i/2/2/0;
!!BM21&v997>0/v807<21/v998>71/v998<108:C24/i/2/2/0; **Power Lich King casts "Death Ripple" three times

!!BM21&v997>0/v807<21/v998>107:C24/i/1/1/0;
!!BM21&v997>0/v807<21/v998>107:C24/i/2/2/0;
!!BM21&v997>0/v807<21/v998>107:C24/i/1/1/0;
!!BM21&v997>0/v807<21/v998>107:C24/i/2/2/0; **Power Lich King casts "Death Ripple" four times

**Lich King removes the 4 huge Crypts closing up the battlefield
!!BM21&v997=1:C64/59/3/3/0;
!!BM21&v997=1:C64/127/3/3/0;
!!BM21&v997=1:C64/89/3/3/0;
!!BM21&v997=1:C64/97/3/3/0;

!!HE-1:B0/z849; **Reset name of the hero

**Code to summon additional Lich stacks onto battlefield during second round
!!VRk:S1 T10;
!!BU&v997=1:S64/k/59/1/-1/1;
!!BU&v997=1:S64/k/127/1/-1/1;
!!BU&v997=1:S64/k/89/1/-1/1;
!!BU&v997=1:S64/k/97/1/-1/1;

**The "Age" spell applied to hero's troops during THIRD ROUND of combat and beyond
!!BM0&v997>=2:M75/5/3;
!!BM1&v997>=2:M75/5/3;
!!BM2&v997>=2:M75/5/3;
!!BM3&v997>=2:M75/5/3;
!!BM4&v997>=2:M75/5/3;
!!BM5&v997>=2:M75/5/3;
!!BM6&v997>=2:M75/5/3;
!!BM7&v997>=2:M75/5/3;
!!BM8&v997>=2:M75/5/3;
!!BM9&v997>=2:M75/5/3;
!!BM10&v997>=2:M75/5/3;
!!BM11&v997>=2:M75/5/3;
!!BM12&v997>=2:M75/5/3;
!!BM13&v997>=2:M75/5/3;
!!BM14&v997>=2:M75/5/3;
!!BM15&v997>=2:M75/5/3;
!!BM16&v997>=2:M75/5/3;
!!BM17&v997>=2:M75/5/3;
!!BM18&v997>=2:M75/5/3;
!!BM19&v997>=2:M75/5/3;
!!BM20&v997>=2:M75/5/3;

*===============================================================================
**Code to summon Dread Knights onto battlefield at beginning of combat

!!VRv817&v998<36:S2;
*2 Dread Knights per stack summoned if x position of Death Chamber is less than 36
!!VRv817&v998>35/v998<72:S3;
*3 Dread Knights per stack summoned if x position of Death Chamber is between 35 and 72
!!VRv817&v998>71/v998<108:S4;
*4 Dread Knights per stack summoned if x position of Death Chamber is between 71 and 108
!!VRv817&v998>107:S5;
*5 Dread Knights per stack summoned if x position of Death Chamber is greater than 108

!!BU&v997=0:S67/v817/41/1/-1/0;
!!BU&v997=0:S67/v817/47/1/-1/0;
!!BU&v997=0:S67/v817/143/1/-1/0;
!!BU&v997=0:S67/v817/149/1/-1/0;

*==================================================================================

***********************************************************************************
*3 Wraiths per stack summoned if x position less than 36
!!BU&v997=0/v998<36:S61/3/6/1/-1/0;
!!BU&v997=0/v998<36:S61/3/8/1/-1/0;
!!BU&v997=0/v998<36:S61/3/10/1/-1/0;
!!BU&v997=0/v998<36:S61/3/176/1/-1/0;
!!BU&v997=0/v998<36:S61/3/178/1/-1/0;
!!BU&v997=0/v998<36:S61/3/180/1/-1/0;

*5 Wraiths per stack summoned if x position greater than 107
!!BU&v997=0/v998>107:S61/5/6/1/-1/0;
!!BU&v997=0/v998>107:S61/5/8/1/-1/0;
!!BU&v997=0/v998>107:S61/5/10/1/-1/0;
!!BU&v997=0/v998>107:S61/5/176/1/-1/0;
!!BU&v997=0/v998>107:S61/5/178/1/-1/0;
!!BU&v997=0/v998>107:S61/5/180/1/-1/0;

*7 Wraiths per stack summoned if x position of Death Chamber is between 36 and 72
!!BU&v997=0/v998>35/v998<72:S61/7/6/1/-1/0;
!!BU&v997=0/v998>35/v998<72:S61/7/8/1/-1/0;
!!BU&v997=0/v998>35/v998<72:S61/7/10/1/-1/0;
!!BU&v997=0/v998>35/v998<72:S61/7/176/1/-1/0;
!!BU&v997=0/v998>35/v998<72:S61/7/178/1/-1/0;
!!BU&v997=0/v998>35/v998<72:S61/7/180/1/-1/0;

*9 Wraiths per stack summoned if x position of Death Chamber is between 72 and 108
!!BU&v997=0/v998>71/v998<108:S61/9/6/1/-1/0;
!!BU&v997=0/v998>71/v998<108:S61/9/8/1/-1/0;
!!BU&v997=0/v998>71/v998<108:S61/9/10/1/-1/0;
!!BU&v997=0/v998>71/v998<108:S61/9/176/1/-1/0;
!!BU&v997=0/v998>71/v998<108:S61/9/178/1/-1/0;
!!BU&v997=0/v998>71/v998<108:S61/9/180/1/-1/0;

************************************************************************************

**Additional Lich stack summoned between the crypts depending upon x position
!!BU&v997=0/v998<36:S64/10/94/1/-1/0;
!!BU&v997=0/v998>35/v998<72:S64/20/94/1/-1/0;
!!BU&v997=0/v998>71/v998<108:S64/30/94/1/-1/0;
!!BU&v997=0/v998>107:S64/40/94/1/-1/0;

************************************************************************************

**Ghosts now summoned inbetween trees during the third round and beyond!

!!HE-1:E?p/?q; **Get hero's current level into "q"

!!VRr&v998<36:Sq*8; **Summon 8x hero level of ghosts per stack
!!VRr&v998<36:+v997; **Add ghosts depending upon round number

!!VRr&v998>35/v998<72:Sq*12; **Summon 12x hero level of ghosts per stack
!!VRr&v998>35/v998<72:+v997; **Add ghosts depending upon round number

!!VRr&v998>71/v998<108:Sq*16; **Summon 16x hero level of ghosts per stack
!!VRr&v998>71/v998<108:+v997; **Add ghosts depending upon round number

!!VRr&v998>107:Sq*24; **Summon 24x hero level of ghosts per stack
!!VRr&v998>107:+v997; **Add ghosts depending upon round number

**Ghosts summoned inbetween trees
!!BU&v997>=2/v998<36:S159/r/4/1/-1/1;
!!BU&v997>=2/v998<36:S159/r/12/1/-1/1;
!!BU&v997>=2/v998<36:S159/r/174/1/-1/1;
!!BU&v997>=2/v998<36:S159/r/182/1/-1/1;

!!BU&v997>=2/v998>35/v998<72:S159/r/4/1/-1/1;
!!BU&v997>=2/v998>35/v998<72:S159/r/12/1/-1/1;
!!BU&v997>=2/v998>35/v998<72:S159/r/174/1/-1/1;
!!BU&v997>=2/v998>35/v998<72:S159/r/182/1/-1/1;

!!BU&v997>=2/v998>71/v998<108:S159/r/4/1/-1/1;
!!BU&v997>=2/v998>71/v998<108:S159/r/12/1/-1/1;
!!BU&v997>=2/v998>71/v998<108:S159/r/174/1/-1/1;
!!BU&v997>=2/v998>71/v998<108:S159/r/182/1/-1/1;

!!BU&v997>=2/v998>107:S159/r/4/1/-1/1;
!!BU&v997>=2/v998>107:S159/r/12/1/-1/1;
!!BU&v997>=2/v998>107:S159/r/174/1/-1/1;
!!BU&v997>=2/v998>107:S159/r/182/1/-1/1;

*========================================================================================
**Triggers for Power Lich King's spellcasting

!?BG&800/v806=1;

!?BG&800/v806=1;
!!BG&v997=1:N?v808 Q?v812; **Get current stack number and attacking side
!!BMv808&v997>=0:G29/?v810/?v811; **Get FIRE SHIELD info from current stack
!!BMv808&v997>=0:P?j; **Get position of current stack number into "j"
!!BM21&v997>=0/v808>=21/v810=0/v812=1:C29/j/1/1/0;**Power Lich King casts BASIC FIRE SHIELD

!!BG&v997=1:N?v808 Q?v812; **Get current stack number and attacking side
!!BMv808&v997>=0:G58/?v810/?v811; **Get COUNTERSTRIKE info from current stack
!!BMv808&v997>=0:P?j; **Get position of current stack number into "j"
!!BM21&v997>=0/v808>=21/v810=0/v812=1:C58/j/1/1/0;**Power Lich King casts BASIC COUNTERSTRIKE

*-------------------------------------------------------------------------------------------------------

!?BG&800/v998<36/v806=1;
!!BG&v997=1:N?v807 Q?v812; **Get current stack number and attacking side
!!BMv808&v997=1:G21/?v810/?v811; **Get MISFORTUNE info from current stack
!!BMv808&v997=1:P?j; **Get position of current stack number into "j"
!!BM21&v997=1/v807<21/v810=0/v812=0:C52/j/1/1/0;**Power Lich King casts BASIC MISFORTUNE

!?BG&800/v998>35/v998<72/v806=1;
!!BG&v997=1:N?v807 Q?v812; **Get current stack number and attacking side
!!BMv808&v997=1:G21/?v810/?v811; **Get DISRUPTING RAY info from current stack
!!BMv808&v997=1:P?j; **Get position of current stack number into "j"
!!BM21&v997=1/v807<21/v810=0/v812=0:C47/j/1/1/0;**Power Lich King casts BASIC DISRUPTING RAY

!?BG&800/v998>71/v998<108/v806=1;
!!BG&v997=1:N?v807 Q?v812; **Get current stack number and attacking side
!!BMv808&v997=1:G45/?v810/?v811; **Get WEAKNESS info from current stack
!!BMv808&v997=1:P?j; **Get position of current stack number into "j"
!!BM21&v997=1/v807<21/v810=0/v812=0:C45/j/1/1/0; **Power Lich King casts BASIC WEAKNESS

!?BG&800/v998>107/v806=1;
!!BG&v997=1:N?v807 Q?v812; **Get current stack number and attacking side
!!BMv808&v997=1:G22/?v810/?v811; **Get SORROW info from current stack
!!BMv808&v997=1:P?j; **Get position of current stack number into "j"
!!BM21&v997=1/v807<21/v810=0/v812=0:C50/j/1/1/0; **Power Lich King casts BASIC SORROW

!?BG&800/v806=1;
!!BG&v997=1:N?v807 Q?v812; **Get current stack number and attacking side
!!BMv808&v997=1:G21/?v810/?v811; **Get FIREBALL info from current stack
!!BMv808&v997=1:P?j; **Get position of current stack number into "j"
!!BM21&v997=1/v807<21/v810=0/v812=0:C21/j/1/1/0; **Power Lich King casts BASIC FIREBALL



**==============================================================================
**BEGIN THE POST-BATTLE TRIGGER AND COMMANDS (Power Liches)
**==============================================================================

**Post-battle trigger

!?BA1&800/v806=1; **Do the following while FLAG 800 is still TRUE

!!HE-1:O?t;

!!IF&t>=0/v998<38:Q3/6/8000/7/4/21/159/1/z170005;
!!IF&t>=0/v998>37/v998<72:Q3/6/10000/7/6/21/159/1/z170006;
!!IF&t>=0/v998>71/v998<108:Q3/6/12000/7/8/21/159/1/z170007;
!!IF&t>=0/v998>107:Q3/6/16000/7/10/21/159/1/z170008;

!!OW&t>=0/v998<36:R-1/6/d800000; **Give 800000 gold to current player
!!OW&t>=0/v998<36:R-1/7/d400; **Give 400 Mithril to current player
!!HE-1&t>=0/v998<36:C2/159/3000/1; **Give 3000 Ghosts to current hero

!!OW&t>=0/v998>35/v998<72:R-1/6/d1000000; **Give 1000000 gold to current player
!!OW&t>=0/v998>35/v998<72:R-1/7/d600; **Give 600 Mithril to current player
!!HE-1&t>=0/v998>35/v998<72:C2/159/4000/1; **Give 4000 Ghosts to current hero

!!OW&t>=0/v998>71/v998<108:R-1/6/d1200000; **Give 1200000 gold to current player
!!OW&t>=0/v998>71/v998<108:R-1/7/d800; **Give 800 Mithril to current player
!!HE-1&t>=0/v998>71/v998<108:C2/159/5000/1; **Give 5000 Ghosts to current hero

!!OW&t>=0/v998>107:R-1/6/d1600000; **Give 1600000 gold to current player
!!OW&t>=0/v998>107:R-1/7/d1000; **Give 1000 Mithril to current player
!!HE-1&t>=0/v998>107:C2/159/6000/1; **Give 6000 Ghosts to current hero

!!PO998&t>=0:N1; **If hero is owned, value of Death Chamber position square is 1

!!IF:V800/0; **Clear FLAG 800

!!PO998&t=-1:N0;
**If hero is unowned, value of Death Chamber position is 0 and another hero
**can visit the structure

**Variables cleared
!!VRv805:S0;
!!VRv807:S0;
!!VRv808:S0;
!!VRv809:S0;
!!VRv810:S0;
!!VRv811:S0;
!!VRv812:S0;
!!VRv820:S0;

**End post-battle trigger

*Object trigger when any "Death Chamber" that HASN'T been defeated is visited

!?OB63/15&v805=0/1000/v806=1;

!!VRj:S0;

!!POv998/v999/v1000:B0/?j; **Read PO:B0 value into j
!!POv998/v999/v1000:H?k; **Read PO:H value into k

!!VRv1176:+v1179; **Add current value in "v1179" weekly counter into "v1176"

**Store values from "j" into "v1176" to determine number of Lich Guards and Ghosts summoned
!!VRv1176&j=0:+2;
!!VRv1176&j=1:+4;
!!VRv1176&j=2:+6;
!!VRv1176&j=3:+8;
!!VRv1176&j>=4:+10;

**Store values from "j" into "v1177" to determine Lich King's stats
!!VRv1177&j=0:S2;
!!VRv1177&j=1:S4;
!!VRv1177&j=2:S6;
!!VRv1177&j=3:S8;
!!VRv1177&j>=4:S10;

**Store values from "k" into "v1173" to determine type of guards summoned with the Ghosts
!!VRv1173&k=0:S0;
!!VRv1173&k=1:S1;
!!VRv1173&k=2:S2;
!!VRv1173&k>=3:S3;

**Store values from v1173 into "m" temporarily to show monsters in dialogue box
!!VRm:S0;
!!VRm&v1173=0:S68;
!!VRm&v1173=1:S141;
!!VRm&v1173=2:S172;
!!VRm&v1173=3:S195;

**Store names into "z3" to give hints to the player as to the amount of guards inside the chamber
!!VRz3:S^^;
!!VRz3&v1177=2:Sz170003;
!!VRz3&v1177=4:Sz170004;
!!VRz3&v1177=6:Sz170005;
!!VRz3&v1177=8:Sz170006;
!!VRz3&v1177>=10:Sz170007;

**Random numbers from 0-5 determines what the Lich King says in his speech
!!VRn:S0 T4;
!!VRo:S0 T4;
!!VRq:S0 T4;
!!VRr:S0 T4;
!!VRs:S0 T4;
!!VRt:S0 T4;

**Store names into "z4" to describe the Death Chamber structure
!!VRz4:S^^;
!!VRz4&n=0:Sz170008;
!!VRz4&n=1:Sz170009;
!!VRz4&n=2:Sz170010;
!!VRz4&n=3:Sz170011;
!!VRz4&n=4:Sz170012;

**Store names into "z5" to describe the Lich King
!!VRz5:S^^;
!!VRz5&o=0:Sz170013;
!!VRz5&o=1:Sz170014;
!!VRz5&o=2:Sz170015;
!!VRz5&o=3:Sz170016;
!!VRz5&o=4:Sz170017;

**Prepare to change the Power Liches name temporarily
!!VRz6:S^^;
!!VRz6:Sz170018;
!!UN:G1/65/1/z6; **Change Power Liches name to temporarily

**Store names into "z7" to describe Lich King's voice
!!VRz7:S^^;
!!VRz7&q=0:Sz170019;
!!VRz7&q=1:Sz170020;
!!VRz7&q=2:Sz170021;
!!VRz7&q=3:Sz170022;
!!VRz7&q=4:Sz170023;

**Store names into "z8" to describe Lich King's treasures
!!VRz8:S^^;
!!VRz8&r=0:Sz170024;
!!VRz8&r=1:Sz170025;
!!VRz8&r=2:Sz170026;
!!VRz8&r=3:Sz170027;
!!VRz8&r=4:Sz170028;

**Store names into "z9" to describe Lich King's threat
!!VRz9:S^^;
!!VRz9&s=0:Sz170029;
!!VRz9&s=1:Sz170030;
!!VRz9&s=2:Sz170031;
!!VRz9&s=3:Sz170032;
!!VRz9&s=4:Sz170033;

**Store names into "z10" to describe Lich King's threat
!!VRz10:S^^;
!!VRz10&t=0:Sz170034;
!!VRz10&t=1:Sz170035;
!!VRz10&t=2:Sz170036;
!!VRz10&t=3:Sz170037;
!!VRz10&t=4:Sz170038;

!!IF:Q3/21/65/21/159/21/m/2/z170039;

**Clear "z" variables
!!VRz3:S^^;
!!VRz4:S^^;
!!VRz5:S^^;
!!VRz6:S^^;
!!VRz7:S^^;
!!VRz8:S^^;
!!VRz9:S^^;
!!VRz10:S^^;


**end of function

[/free]

[ 本帖最后由 暗黑龙守护神 于 2009-6-25 22:09 编辑 ]

songfx

非常有用

另外,我把yunings整理的那些脚本也加进来了.

shenbing100

楼主不厚道。既然知道yunings那有个合集，怎么又搞一个合集呢。

暗黑龙守护神

哈哈。抱歉了。标题没说清楚。其实我开这个贴是专门想把汉化过的ERM收集在一起的。不小心弄错了。附的那四个都是纯中文的。

老虎

最好能把所有常用的erm都弄成事件版。
时不时的见有人找。

szx_9933

支持楼主!正在收集呢。

szx_9933

楼主不更新了？

pxc04l7

不踩一下再走还真过意不去呵......

szx_9933

原帖由 pxc04l7 于 2009-9-24 17:01 发表
不踩一下再走还真过意不去呵......

LS的是嘎嘎新的新人啊，还是谁的马甲？

DKmlws5

楼主啊，那个秘银熔炉除了占领的第一天外就不再给秘银了啊~

剑舞苍澜

好东西……
尤其是那个一追……
我找了好久……