追随者转职BUG如何解决

fantacyfish

下了一个补丁，实现了[wiki]追随者[/wiki]经验和[wiki]转职[/wiki]，但是在防守战中，无发通过右键防守图标改变攻击模式。请问有解决办法么？？

原来下载的补丁：http://bbs.h3wog.com/viewthread. ... p;extra=&page=1

poet

这个是[wiki]WoG[/wiki]的bug，与追随者完全没有关系。

你用任何版本的WoG开一副随机图，防守时也不可能切换攻击方式的。

[wiki]TDS[/wiki]中是手工增加了这个功能而已，虽然实现得有点奇怪。

[ 本帖最后由 poet 于 2009-8-13 13:01 编辑 ]

yunings

Poet，能废了这个Bug么？

fantacyfish

只是奇怪，不打补丁之前可以右键，为啥打了就不行，难道真的是鱼和熊掌的关系么

szx_9933

你去问fly123吧，他的新图“安姆的阴影”里防守时可以选择攻击方式。

poet

原帖由 yunings 于 2009-8-13 13:16 发表
Poet，能废了这个Bug么？

写个 erm 实现防守时右键既可，貌似不会太难。以前想过这个问题，不过一直没有做，主要是考虑战场中的具体某个兵好像没有可以用于存放变量的地点。

不过TDS貌似实现了这个功能，yunings不妨说说这个功能在哪一天的事件中，我们挖出来就可以了。

shenbing

ZVSE
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except [wiki]ERM[/wiki]_S for making any kind of changes!
ERMS_ScriptDate=28.5(May).2006
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
ERMS_Script by woodmelon
**Ver 2.0
**攻击返回+射击修正脚本
**作为防御方时右键点击防御图标触发
**v5100-v5140

**生物之周怪物修正脚本
**FU25012

*******************************************************************
                    攻击后返回/射击修正脚本
*******************************************************************

!?BA52;
!!VRv5100:C-1/-1/-1/-1/-1/-1/-1/-1/-1/-1;
!!VRv5110:C-1/-1/-1/-1/-1/-1/-1/-1/-1/-1;
!!VRv5120:C-1/-1/-1/-1/-1/-1/-1/-1/-1/-1;
!!VRv5130:C-1/-1/-1/-1/-1/-1/-1/-1/-1/-1;

!?CM4;
!!CM:I?y10 S?y11;
!!FU|y10<>2010/y11<>14:E;
!!BH1:N?y10;
!!FU&y10<0:E;
!!BG:Q?y11 H?y12;
!!FU&y10<>y12:E;
!!BG:N?y10;
!!BMy10:F?y11;
!!VRy11:&4;
!!VRy12:Sy10 +1 *-1;
!!EAy12:F102/98/?y13 F0/?y16;

!!VRy14:Sy10 +5079;
!!VRy15:Sy10 +5099;

!!IF:V2/0;
!!IF&y11>0:V2/1;
!!IF&vy14>0/y14<5120:V2/1;
!!IF&y13<y16:V2/1;
!!IF&y13>5/y16=-1:V2/1;
!!IF&vy15>0/y15>=5120:V2/1;
!!FU&-2:E;
!!CM:R0;

!!VRz1:S^远程和攻击后返回修正脚本
仅对防御方有效,对暗黑龙和鹰身女妖无效
Script by woodmelon  2006.5.2^;
!!VRz2:S^^;
!!VRz3:S^^;
!!VRz4:S^^;
!!VRz5:S^^;
!!VRz2&vy14>0:S^射击^;
!!VRz3&y11=4:S^近身^;
!!VRz4&vy15>0/y15>=5120:S^攻击后返回^;
!!VRz5&y13<y16/y15>=5120:S^攻击不返回^;
!!VRz5&y13>5/y16=-1/y15>=5120:S^攻击不返回^;
!!VRz6:S^取消^;
!!IF:G1/1/16/1/2/3/4/5/6;
!!FU&v1=16:E;

!!BMy10&v1=1:Fd4 U3/vy14;
!!VRvy14&v1=1:S-1;
!!BMy10&v1=2:U3/?vy14;
!!BMy10&v1=2:Fd-4;

!!EAy12&v1=4:Bvy15/1/102/98/d/d/d/d/d/d/d/d/d/d/d;
!!VRvy15&v1=4:S-1;
!!EAy12&v1=8:By13/0/102/98/d/d/d/d/d/d/d/d/d/d/d;
!!VRvy15&v1=8:Sy13;

*******************************************************************
                   生物/资源之周修正脚本
*******************************************************************

!?PI;
!!UN:U54/-1/?v4;
!!DO25012/1/v4/1&v4>0:P54;     生物之周

!!UN:U79/-1/?v4;
!!DO25012/1/v4/1&v4>0:P79;     资源之周

!?FU25012;
!!VRv1&x16=1:S-1;
!!UN&x16<v4:Ux1/-1/-1/1;       最后一个时阻止脚本继续执行
!!UN&x16=v4:Ux1/-1/v4/1;       最后一个直接读取索引执行
!!PO1:V1/128;


!?CM0;
!!CM:S?y20 I?y21;
!!FU|y20<>14/y21<>37:E;
!!CM:P?v1/?v2/?v3;
!!OBv1/v2/v3:T?y20;
!!VRy21:S128;
!!PO1|y20=54/y20=79:V1/?y21;
!!FU&y21=128:E;
!!VRz1&y20=54:S^生物^;
!!VRz1&y20=79:S^资源^;
!!VRz1:S^该%Z1好像是%Z1之周产生的,是否将其移至异次元空间?^;
!!IF:D90///1////////////;
!!IF:F90/////1;
!!IF:E4/90;
!!UN&v4=5:Ov1/v2/v3;
!!CM&v4=5:R0;