远程招募野外生物巢穴部队

琭琭有彧 · 发表于 2022-2-2 21:37:30

本帖最后由琭琭有彧于 2022-2-5 16:46 编辑

改编自封神的代码，分享一下

ZVSE
;v1.0
;改编自封神2.21
;鼠标右键 + ctrl
*************点击物体触发*************
;处理远程招募生物巢穴部队
!?FU(OnAdventureMapRightMouseClick)&i^key_ctrl^;
!!CM:P?y8/?y9/?y10;
!!OBy8/y9/y10:T?y11;
!!FU|y11<17/y11>20:E;
!!CM:R0;
!!OW:A-1/?y1; y1英雄编号
!!FU&y1<0:E;
!!CM:I?y2 F?y18;
!!FU|y2<>37/y18<>512:E;
!!HEy1:P?y3/?y4/?y5 O?y6 R7/?y7;
!!IF:Wy1;
!!VRy7:&262144;
! !CM:P?y8/?y9/?y10;
!!FU|y5<>y10/y7=262144:E;
! !OBy8/y9/y10:T?y11;
!!FU&y11<>17:E;
!!DWy8/y9/y10:O?y12 M0/?y13/?y14;
!!FU|y6<>y12/y13=-1/y14<1:E;
**UN:X?y15/?y16;
!!VRy15:Sy3-y8;
!!VRy15&y15<0:*-1;
!!VRy16:Sy4-y9;
!!VRy16&y16<0:*-1;
!!VRy17&y15<=y16:Sy16; 距离
!!VRy17&y15>y16:Sy15;
!!if&y17>=20:;
!!VRz1:S^当前距离为:%Y17，太远了不能招募！^;
!!IF:M0/4/1;
!!en:;
!!FU&y17>=20:E;
!!MA:Ly13/?y20; 巢穴等级
!!UN:N3/4/y13/1;
!!if&y20=0:; 一级兵
!!IF:Q2/21/y13/2^是否从这个巢穴招募并运输%Y14个%Z4？^;
!!if&2:;
!!VRz9:S^BUILDTWN.wav^;
!!SN:Pz9;
!!HEy1:C2/y13/y14/1;
!!DWy8/y9/y10:M0/y13/0;
!!UN:R1 R2;
!!en:;
!!en:;
!!FU&y20=0:E;
!!MA:Cy13/6/?y21 Cy13/1/?y22 Cy13/3/?y23 Cy13/4/?y24 Cy13/5/?y25;
!!OW:Ry6/6/?y26 Ry6/1/?y27 Ry6/3/?y28 Ry6/4/?y29 Ry6/5/?y30;
!!VRy31:Sy26 :y21;
!!VRy31&y31>y14:Sy14;
!!FU&y31<1:E;
!!VRy40:Sy31;
!!if&y22>0:; 处理水银
!!VRy32:Sy27 :y22;
!!VRy40&y32>y31:Sy31;
!!VRy40&y31>y32:Sy32;
!!VRy41:Sy40 *y22;
!!FU&y32<1:E;
!!en:;
!!if&y23>0:; 处理硫磺
!!VRy33:Sy28 :y23;
!!VRy40&y33>y31:Sy31;
!!VRy40&y31>y33:Sy33;
!!VRy42:Sy40 *y23;
!!FU&y33<1:E;
!!en:;
!!if&y24>0:; 处理水晶
!!VRy34:Sy29 :y24;
!!VRy40&y34>y31:Sy31;
!!VRy40&y31>y34:Sy34;
!!VRy43:Sy40 *y24;
!!FU&y34<1:E;
!!en:;
!!if&y25>0:; 处理宝石
!!VRy35:Sy30 :y25;
!!VRy40&y35>y31:Sy31;
!!VRy40&y31>y35:Sy35;
!!VRy44:Sy40 *y25;
!!FU&y35<1:E;
!!en:;
!!VRy45:Sy40 *y21;
!-!VRy45&y1=9::2; //特殊英雄：阿德拉招募费用减半
!!IF&y22=0/y23=0/y24=0/y25=0:Q2/21/y13/6/y45/2^是否从这个巢穴招募并运输%Y40个%Z4？^;
!!IF&y22>0:Q2/21/y13/6/y45/1/y41/2^是否从这个巢穴招募并运输%Y40个%Z4？^;
!!IF&y23>0:Q2/21/y13/6/y45/3/y42/2^是否从这个巢穴招募并运输%Y40个%Z4？^;
!!IF&y24>0:Q2/21/y13/6/y45/4/y43/2^是否从这个巢穴招募并运输%Y40个%Z4？^;
!!IF&y25>0:Q2/21/y13/6/y45/5/y44/2^是否从这个巢穴招募并运输%Y40个%Z4？^;
!!FU&-2:E;
!!VRz9:S^BUILDTWN.wav^;
!!SN:Pz9;
!!HEy1:C2/y13/y40/1;
!!VRy41&y22>0:*-1;
!!VRy42&y23>0:*-1;
!!VRy43&y24>0:*-1;
!!VRy44&y25>0:*-1;
!!VRy45:*-1;
!!VRy46:Sy14 -y40;
!!OW:Ry6/6/dy45;
!!OW&y22>0:Ry6/1/dy41;
!!OW&y23>0:Ry6/3/dy42;
!!OW&y24>0:Ry6/4/dy43;
!!OW&y25>0:Ry6/5/dy44;
!!DWy8/y9/y10:M0/y13/y46;
!!CM:R0;
!!UN:R1 R2;

复制代码

chaoticorder · 发表于 2022-2-3 08:53:37

这个好，省着没事老去跑巢穴

cs48129813 · 发表于 2022-2-3 10:36:19

小白多问一嘴，这个怎么用？

琭琭有彧 · 发表于 2022-2-3 11:23:14

放入Mods/任意启用mod/Data/s文件夹下，鼠标右键+Ctrl 点击野外生物巢穴

闲云碎梦 · 发表于 2022-2-3 13:25:35

战马不是本身有这个功能么

琭琭有彧 · 发表于 2022-2-3 15:51:56

闲云碎梦发表于 2022-2-3 13:25
战马不是本身有这个功能么

有，这个是方便非封神、封魔玩家的通用脚本。

噬魂恶魔 · 发表于 2022-2-5 17:00:42

建议加上版本号，方便区别更新

账号		自动登录	找回密码
密码			英雄注册\|Register

远程招募野外生物巢穴部队

评分

相关帖子

点评

社区QQ达人

退役版主