【已解决】如何让电脑从7级兵升级到8级兵也要扣减资源？

水流行险

以下是33wog城镇升级脚本的电脑从7级兵升级到8级兵的脚本，可是电脑的8八级兵太多了，动不动就几十。如何让电脑从7级兵升级到8级兵也要扣减资源？
请版主和高手指点！@Archer30 @XEricSin

********************** AI直接升级生物 **********************
*Fu99868-Fu99869
!?OB98&v9428=1/-1000;
!!FU99868:P;

!?FU99868;
!!CA998:O?y1;
!!OW:C?y2;
!!FU&y1<>y2:E;
!!CA998:T?y3;
;v2=生物1，v3=升级生物1,v4=生物2,v5=升级生物2,v6=建筑标志1,v7=资源类型1
!!VRv2&y3=0:C7/144/13/150/40/5;      7十字军-144恶鬼 13大天使-150至高大天使 40-5
!!VRv2&y3=1:C19/170/27/151/39/4;     以下是个种族的八级兵
!!VRv2&y3=2:C33/116/41/152/39/5;
!!VRv2&y3=3:C51/195/55/153/41/1;
!!VRv2&y3=4:C59/141/69/154/38/1;
!!VRv2&y3=5:C77/192/83/155/40/3;
!!VRv2&y3=6:C87/142/97/156/38/4;
!!VRv2&y3=7:C99/194/111/157/37/1;
!!VRv2&y3=8:C129/164/131/158/40/1;
!!UN:J2/?y4;   检测难度等级
!!VRy5&y4<3:S90;  130%-80%      AI升级时间限制  90
!!VRy5&y4=3:S60;  160%                          60
!!VRy5&y4=4:S30;  200%                          30
!!VRy6:Sc;
!!FU&y6<y5:E;  游戏天数低于设定数值禁止AI升级特殊兵种跟8级生物
!!HE-1:N?y7;
!!DO99869/0/6/1:Py7/v2/v3/v4/v5/v6/43;  检测当前英雄身上的部队

!?FU99869;
!!HEx1:C0/x16/?y1/?y2;
!!FU|y1<0/y2=0:E;
!!CA998:B3/9;     检测城堡是否建造
!!FU&-1:E;
!!if&y1=x2:;
!!CA998:B3/x6;  建造4级高级巢穴
!!HEx1&1:C0/x16/x3/y2;  自动升级特殊进阶兵种
!!el:;
!!if&y1=x4:;
!!CA998:B3/x7; 建造7级高级巢穴   -------------------------------------------这里插入检查该势力的资源，和升级所需的资源，要扣减
!!HEx1&1:C0/x16/x5/y2;  自动升级8级兵   改变怪物的位置、类型、数量
!!el:;
!!en:;

Archer30

1. ********************** AI直接升级生物 **********************
   
2. *Fu99868-Fu99869
   
3. !?OB98&v9428=1/-1000;
   
4. !!FU99868:P;
   
5. 
   
6. !?FU99868;
   
7. !!CA998:O?y1;
   
8. !!OW:C?y2;
   
9. !!FU&y1<>y2:E;
   
10. 
    
11. !!CA998:B3/9;     检测城堡是否建造
    
12. !!FU&-1:E;
    
13. 
    
14. !!UN:J2/?y4;   检测难度等级
    
15. !!VRy5&y4<3:S90;  130%-80%      AI升级时间限制  90
    
16. !!VRy5&y4=3:S60;  160%                          60
    
17. !!VRy5&y4=4:S30;  200%                          30
    
18. !!VRy6:Sc;
    
19. !!FU&y6<y5:E;  游戏天数低于设定数值禁止AI升级特殊兵种跟8级生物
    
20. 
    
21. !!CA998:T?y3;[注意！！所有的默认值（50、2000、2）都要修改为实际的资源消耗数值]
    
22. ;v2=生物1，v3=升级生物1，v4=生物2，v5=升级生物2，v6=4级巢穴，v7=生物1升级需要的金币（默认50）v8=生物2升级需要的金币（默认2000），v9=生物2升级需要的额外资源类型，v10=生物2升级需要的额外资源数量（默认2）
    
23. !!VRv2&y3=0:C7/144/13/150/40/50/2000/5/2;      7十字军-144恶鬼 13大天使-150至高大天使 40-5
    
24. !!VRv2&y3=1:C19/170/27/151/39/50/2000/4/2;     以下是各个种族的八级兵
    
25. !!VRv2&y3=2:C33/116/41/152/39/50/2000/5/2;
    
26. !!VRv2&y3=3:C51/195/55/153/41/50/2000/1/2;
    
27. !!VRv2&y3=4:C59/141/69/154/38/50/2000/1/2;
    
28. !!VRv2&y3=5:C77/192/83/155/40/50/2000/3/2;
    
29. !!VRv2&y3=6:C87/142/97/156/38/50/2000/4/2;
    
30. !!VRv2&y3=7:C99/194/111/157/37/50/2000/3/2;
    
31. !!VRv2&y3=8:C129/164/131/158/40/50/2000/1/2;
    
32. 
    
33. !!HE-1:N?y7;
    
34. !!DO99869/0/6/1:Py7/v2/v3/v4/v5/v6/43/v7/v8/v9/v10/y2;  检测当前英雄身上的部队
    
35. 
    
36. !?FU99869;
    
37. ; x1=当前英雄
    
38. ; x2=生物1 x3=升级生物1 x4=生物2 x5=升级生物2
    
39. ; x6=4级巢穴，x7=升级7级建筑
    
40. ; x8=生物1升级金币 x9=生物2升级金币 x10=生物2升级资源类型 x11=生物2升级资源数量
    
41. ; x12=当前玩家
    
42. ; 金币资源类型=6
    
43. !!HEx1:C0/x16/?y1/?y2;
    
44. !!FU|y1<0/y2=0:E;
    
45. 
    
46. !!if&y1=x2:;
    
47.   !!CA998:B3/x6;  检查是否建造4级高级巢穴
    
48. 
    
49.   !!FU&-1:E;  未建造则退出
    
50. 
    
51.   !!OW:Rx12/6/?y30; 计算玩家拥有的金币 y30
    
52.   !!VRy31:Sy30 :x8; 计算现有的金币可以升级多少生物1 y31
    
53. 
    
54.   !!if&y31>=y2:; 如果金币满足升级本槽位所有生物的需求（承担不起费用则不升级）
    
55.     !!HEx1:C0/x16/x3/y2;  自动升级特殊进阶兵种
    
56.     !!VRy32:Sy2 *x8;  计算升级需要的金币
    
57.     !!OW:Rx12/6/dy32; 扣除金币
    
58.   !!en:;
    
59. !!en:;
    
60. 
    
61. !!if&y1=x4:;
    
62.   !!CA998:B3/x7; 检查是否建造7级高级巢穴
    
63. 
    
64.   !!FU&-1:E;  未建造则退出
    
65.   
    
66.   !!OW:Rx12/6/?y30; 计算玩家拥有的金币 y30
    
67.   !!VRy31:Sy30 :x9; 计算现有的金币可以升级多少生物2 y31
    
68.   !!OW:Rx12/x10/?y32; 计算玩家现有的特殊资源x10 y32
    
69.   !!VRy33:Sy33 :x11; 计算现有的特殊资源可以升级多少生物2 y33
    
70. 
    
71.   !!if&y31>=y2/y33>=y2:;  如果金币和特殊资源满足升级本槽位所有生物的需求（承担不起费用则不升级）
    
72.     !!HEx1:C0/x16/x5/y2;  自动升级8级兵
    
73.     !!VRy34:Sy2 *x9;  计算升级需要的金币
    
74.     !!OW:Rx12/6/dy34; 扣除金币
    
75.     !!VRy35:Sy2 *x11; 计算升级需要的特殊资源
    
76.     !!OW:Rx12/x10/dy35; 扣除特殊资源
    
77.   !!en:;
    
78. !!en:;

复制代码

贤知有您

楼主为啥不自己试一下,写一写.
你已经知道在哪里改了.
还差一些脚本,不妨试试看.遇到不懂的可以继续提问.
检查两种兵种的价格差(包括特殊资源)
检查玩家是否拥有足够多的资源.
对比扣减,然后升级.

lima133

城镇第八生物能否也有进阶三阶的升级？
直接在 城堡招募界面如三阶一样升级？

lima133

贤知有您 发表于 2021-6-11 16:55
楼主为啥不自己试一下,写一写.
你已经知道在哪里改了.
还差一些脚本,不妨试试看.遇到不懂的可以继续提问. ...

请求增加第8生物的三阶升级脚本。

babyandy

好多大神                     

水流行险

lima133 发表于 2021-6-11 18:36
城镇第八生物能否也有进阶三阶的升级？
直接在 城堡招募界面如三阶一样升级？

模仿也很辛苦，搞不定啊！快帮我矫正！@XEricSin @Archer30

********************** AI直接升级生物 **********************
*Fu99868-Fu99869
!?OB98&v9428=1/-1000;
!!FU99868:P;

!?FU99868;
!!CA998:O?y1;
!!OW:C?y2;
!!FU&y1<>y2:E;
!!CA998:T?y3;
;v2=生物1，v3=升级生物1,v4=生物2,v5=升级生物2,v6=建筑标志1,v7=资源类型1
!!VRv2&y3=0:C7/144/13/150/40/5;      7十字军-144恶鬼 13大天使-150至高大天使 40-5
!!VRv2&y3=1:C19/170/27/151/39/4;     以下是个种族的八级兵
!!VRv2&y3=2:C33/116/41/152/39/5;
!!VRv2&y3=3:C51/195/55/153/41/1;
!!VRv2&y3=4:C59/141/69/154/38/1;
!!VRv2&y3=5:C77/192/83/155/40/3;
!!VRv2&y3=6:C87/142/97/156/38/4;
!!VRv2&y3=7:C99/194/111/157/37/1;
!!VRv2&y3=8:C129/164/131/158/40/1;
!!UN:J2/?y4;   检测难度等级
!!VRy5&y4<3:S90;  130%-80%      AI升级时间限制  90
!!VRy5&y4=3:S60;  160%                          60
!!VRy5&y4=4:S30;  200%                          30
!!VRy6:Sc;
!!FU&y6<y5:E;  游戏天数低于设定数值禁止AI升级特殊兵种跟8级生物
!!HE-1:N?y7;
!!DO99869/0/6/1:Py7/v2/v3/v4/v5/v6/43;  检测当前英雄身上的部队

!?FU99869;
!!HEx1:C0/x16/?y1/?y2;
!!FU|y1<0/y2=0:E;
!!CA998:B3/9;     检测城堡是否建造
!!FU&-1:E;
!!if&y1=x2:;
!!CA998:B3/x6;  建造4级高级巢穴
!!HEx1&1:C0/x16/x3/y2;  自动升级特殊进阶兵种
!!el:;
!!if&y1=x4:;
!!CA998:B3/x7; 建造7级高级巢穴

!!VRy1:Sx4 +1;
!!VRy1&x4=7:S144;
!!VRy1&x4=13:S150; 至高大天使
!!VRy1&x4=19:S170;
!!VRy1&x4=27:S151;
!!VRy1&x4=33:S116;
!!VRy1&x4=41:S152;
!!VRy1&x4=51:S195;
!!VRy1&x4=55:S153;
!!VRy1&x4=59:S141;
!!VRy1&x4=69:S154;
!!VRy1&x4=77:S192;
!!VRy1&x4=83:S155;
!!VRy1&x4=87:S142;
!!VRy1&x4=97:S156;
!!VRy1&x4=99:S194;
!!VRy1&x4=111:S157;  地狱九头怪
!!VRy1&x4=129:S164;   烈火元素-火元素使者
!!VRy1&x4=127:S166;   雷元素-气元素使者
!!VRy1&x4=125:S165;   石元素-土元素使者
!!VRy1&x4=123:S167;   冰元素-水元素使者
!!VRy1&x4=131:S158;   神圣凤凰


!!UN:N3/-2/x4/1 N3/-3/y1/1;获取怪物编号
!!MA:Cx4/?y2 Cx4/6/?y3 Cx4/1/?y4 Cx4/3/?y5 Cx4/4/?y6 Cx4/5/?y7;   获取怪物的所需资源
!!MA:Cy1/?y12 Cy1/6/?y13 Cy1/1/?y14 Cy1/3/?y15 Cy1/4/?y16 Cy1/5/?y17;  获取怪物的所需资源
!!OW:R-1/6/?y22 R-1/1/?y23 R-1/3/?y24 R-1/4/?y25 R-1/5/?y26;    获取势力的资源数
!!VRy30:Sy2*x5:y12;   两种怪物的资源差
!!FU&y30<1:E;         资源不够就结束


!!VRy31:Sy13-y3*2*y30;         黄金
!!FU&y22<y31:E;
!!VRy32:Sy14-y4*y30;           水银
!!FU&y14>0/y23<y32:E;
!!VRy33:Sy15-y5*y30;           硫磺
!!FU&y15>0/y24<y33:E;
!!VRy34:Sy16-y6*y30;           水晶
!!FU&y16>0/y25<y34:E;
!!VRy35:Sy17-y7*y30;           宝石
!!FU&y17>0/y26<y35:E;


!!VRy40:Sy22-y31;            如果够用就扣去
!!VRy41:Sy23-y32;
!!VRy42:Sy24-y33;
!!VRy43:Sy25-y34;
!!VRy44:Sy26-y35;
!!OW:R-1/6/y40;
!!OW&y14>0:R-1/1/y41;
!!OW&y15>0:R-1/3/y42;
!!OW&y16>0:R-1/4/y43;
!!OW&y17>0:R-1/5/y44;

!!HEx1&1:C0/x16/x5/y2;  自动升级8级兵   改变怪物的位置、类型、数量
!!el:;
!!en:;

Parry

请求增加第8生物的三阶升级脚本。

裂空之冰

不懂帮顶

老鹰怕睡觉

天底下没有免费的午餐，如果能有，早就横扫一切了。

水流行险

贤知有您 发表于 2021-6-11 16:55
楼主为啥不自己试一下,写一写.
你已经知道在哪里改了.
还差一些脚本,不妨试试看.遇到不懂的可以继续提问. ...

快来救救命啊，搞不定！@Archer30 @XEricSin

Archer30

没空，只写了一些（没啥用的一些）

1. !?FU(OnAfterErmInstructions);
   
2. !!FU(arch_CalculUpgLv7toLv8Res):P;
   
3. 
   
4. !?FU(arch_CalculUpgLv7toLv8Res);
   
5. !!VR(upgLv7Mons[9]:y):C(MON_ARCHANGEL)/(MON_GOLD_DRAGON)/(MON_TITAN)/(MON_ARCH_DEVIL)/(MON_GHOST_DRAGON)/(MON_BLACK_DRAGON)/(MON_ANCIENT_BEHEMOTH)/(MON_CHAOS_HYDRA)/(MON_PHOENIX);
   
6. !!VR(lv8Mons[9]:y):C(MON_SUPREME_ARCHANGEL)/(MON_DIAMOND_DRAGON)/(MON_LORD_OF_THUNDER)/(MON_ANTICHRIST)/(MON_BLOOD_DRAGON)/(MON_DARKNESS_DRAGON)/(MON_GHOST_BEHEMOTH)/(MON_HELL_HYDRA)/(MON_SACRED_PHOENIX);
   
7. !!VR(extRes[9]:y):C(RES_GEMS)/(RES_CRYSTAL)/(RES_GEMS)/(RES_MERCURY)/(RES_MERCURY)/(RES_SULFUR)/(RES_CRYSTAL)/(RES_SULFUR)/(RES_MERCURY);
   
8. 
   
9. !!re i/(TOWN_FIRST)/(TOWN_LAST_WOG);
   
10.   !!MA:C(upgLv7Mons[i])/(RES_GOLD)/?(goldUpgLv7:y) C(upgLv7Mons[i])/(extRes[i])/?(extResUpgLv7:y);
    
11.   !!MA:C(lv8Mons[i])/(RES_GOLD)/?(goldLv8:y) C(lv8Mons[i])/(extRes[i])/?(extResLv8:y);
    
12. 
    
13.   !!VRi^arch_lv7to8GoldDif_%i(upgLv7Mons[i])^:S(goldLv8) -(goldUpgLv7);
    
14.   !!VRi^arch_lv7to8ExtResDif_%i(upgLv7Mons[i])^:S(extResLv8) -(extResUpgLv7);
    
15. !!en;

复制代码

这段计算升级7级兵到8级兵的差异，并把值存储在i^arch_lv7to8GoldDif_升级7级兵序号^和i^arch_lv7to8ExtResDif_升级7级兵序号^中

还缺啥呢？
每天遍历电脑玩家所有英雄的兵
判断升级7级兵的种类和数量
通过7级兵的种类判断额外资源（extRes）的种类
然后扣除电脑玩家 升级7级兵 * 数量的资源

水流行险

Archer30 发表于 2021-6-13 15:32
没空，只写了一些（没啥用的一些）
这段计算升级7级兵到8级兵的差异，并把值存储在i^arch_lv7to8GoldDif_ ...

哈哈哈，有希望了！

ioppp789

不清楚，了解一下！！

水流行险

Archer30 发表于 2021-6-13 15:32
没空，只写了一些（没啥用的一些）
这段计算升级7级兵到8级兵的差异，并把值存储在i^arch_lv7to8GoldDif_ ...

老板，我搞不定啊！ERA3连中文教程都没有！

水流行险

Archer30 发表于 2021-6-13 15:32
没空，只写了一些（没啥用的一些）
这段计算升级7级兵到8级兵的差异，并把值存储在i^arch_lv7to8GoldDif_ ...

帮我多加一点补全它吧？

水流行险

Archer30 发表于 2021-6-13 15:32
没空，只写了一些（没啥用的一些）
这段计算升级7级兵到8级兵的差异，并把值存储在i^arch_lv7to8GoldDif_ ...

现在新的ERA3搞定了，可以有空帮我加两行代码完成这个了吗？

Archer30

1. ZVSE2
   
2. ; Author:   Archer30
   
3. ; Engine:   ERM 2.0+
   
4. ; Requires: ERA 3.3+, Era Erm Framework, 77 wog - map rules
   
5. 
   
6. ; Hero's upgraded level 7 monsters become level 8 now costs resources from AI players.
   
7. 
   
8. 
   
9. !?FU(OnStartOrLoad);
   
10. !!FU(costupg_CalcUpgCost):P;
    
11. 
    
12. !?FU(OnEveryDay)&i^timerIsAi^;
    
13. !!FU(costupg_LoopAiArmies):P;
    
14. 
    
15. !?FU(costupg_CalcUpgCost);
    
16. ; Check if auto upgrading Upgraded Lv 7 to Lv 8 is enabeld. Exit if negative.
    
17. !!UN:P125/?(autoUpgOn:y);
    
18. !!FU&(autoUpgOn)<>(TRUE):E;
    
19. 
    
20. ; Create arrays for Upgraded Lv 7, Lv 8 creatures and additional resources required for them
    
21. !!FU(NewIntArray):P8/?i^costupg_upgLv7Array^/(M_TEMP); [array of upgraded lv 7 creaturers (only 8 IDs)]
    
22. !!FU(Array_Fill):Pi^costupg_upgLv7Array^/(MON_ARCHANGEL)/14; [fill in the array with a number sequence, starts from Archangel, step 14]
    
23. !!FU(Array_Push):Pi^costupg_upgLv7Array^/(MON_PHOENIX); [push the last creature id as it's not in the number sequence]
    
24. 
    
25. !!FU(NewIntArray):P9/?(lv8MonArray:y);
    
26. !!FU(Array_Fill):P(lv8MonArray)/(MON_SUPREME_ARCHANGEL)/1;
    
27. 
    
28. !!FU(NewIntArray):P?i^costupg_extResArray^/(M_TEMP);
    
29. !!FU(Array_Push):Pi^costupg_extResArray^/(RES_GEMS)/(RES_CRYSTAL)/(RES_GEMS)/(RES_MERCURY)/(RES_MERCURY)/(RES_SULFUR)/(RES_CRYSTAL)/(RES_SULFUR)/(RES_MERCURY);
    
30. 
    
31. ; Create arrays for the difference of gold and additoinal resrouces of Upgraded Lv 7 to Lv 8
    
32. !!FU(NewIntArray):P?i^costupg_goldDiffArray^/(M_TEMP);
    
33. 
    
34. !!FU(NewIntArray):P?i^costupg_extResDiffArray^/(M_TEMP);
    
35. 
    
36. ; Calculate the gold and resources difference for all 9 factions
    
37. !!re i/(TOWN_FIRST)/(TOWN_LAST_WOG);
    
38.   !!SN:Mi^costupg_upgLv7Array^/i/?(upgLv7Mon:y);
    
39.   !!SN:M(lv8MonArray)/i/?(lv8Mon:y);
    
40.   !!SN:Mi^costupg_extResArray^/i/?(extRes:y);
    
41. 
    
42.   !!MA:C(upgLv7Mon)/(RES_GOLD)/?(goldUpgLv7:y);
    
43.   !!MA:C(upgLv7Mon)/(extRes)/?(extResUpgLv7:y);
    
44.   !!MA:C(lv8Mon)/(RES_GOLD)/?(goldLv8:y);
    
45.   !!MA:C(lv8Mon)/(extRes)/?(extResLv8:y);
    
46. 
    
47.   !!VR(goldDiff:y):S(goldLv8) -(goldUpgLv7);
    
48.   !!VR(extResDiff:y):S(extResLv8) -(extResUpgLv7);
    
49. 
    
50.   !!FU(Array_Push):Pi^costupg_goldDiffArray^/(goldDiff);
    
51.   !!FU(Array_Push):Pi^costupg_extResDiffArray^/(extResDiff);
    
52. !!en;
    
53. 
    
54. !?FU(costupg_LoopAiArmies);
    
55. ; Check if auto upgrading upgraded Lv 7 to Lv 8 is enabeld. Exit if negative.
    
56. !!UN:P125/?(autoUpgOn:y);
    
57. !!FU&(autoUpgOn)<>(TRUE):E;
    
58. 
    
59. !!OW:C?(player:y);
    
60. 
    
61. ; Loops through all slots of all heroes of current player
    
62. !!re (hero:y)/(HERO_FIRST)/(HERO_LAST_WOG);
    
63.   !!HE(hero):O?(owner:y);
    
64. 
    
65.   !!re (slot:y)/(ARMY_SLOT_FIRST)/(ARMY_SLOT_LAST)&(player)=(owner);
    
66.     !!HE(hero):C0/(slot)/?(mon:y)/?(qty:y);
    
67. 
    
68.     ; Check if any slot has an upgraded Lv 7 creature
    
69.     !!re (town:y)/(TOWN_FIRST)/(TOWN_LAST_WOG);
    
70.       !!SN:Mi^costupg_upgLv7Array^/(town)/?(upgLv7Mon:y);
    
71. 
    
72.       !!br&(mon)=(upgLv7Mon);
    
73.     !!en;
    
74. 
    
75.     ; Reduce resource if upgraded Lv 7 is found
    
76.     !!if&(town)<=(TOWN_LAST_WOG);
    
77.       ; Get the gold/additional resources difference and resoruces type for upgrades
    
78.       !!SN:Mi^costupg_extResArray^/(town)/?(extRes:y);
    
79.       !!SN:Mi^costupg_goldDiffArray^/(town)/?(goldDiff:y);
    
80.       !!SN:Mi^costupg_extResDiffArray^/(town)/?(extResDiff:y);
    
81. 
    
82.       ; Get the total amout of gold and additional resources difference of the slot
    
83.       !!VR(goldDiffSum:y):S(qty) *(goldDiff);
    
84.       !!VR(extResDiffSum:y):S(qty) *(extResDiff);
    
85. 
    
86.       ; Reduce resource for the total difference of the slot, make sure everything's not negative
    
87.       !!OW:R(player)/(RES_GOLD)/d-(goldDiffSum);
    
88.       !!OW:R(player)/(RES_GOLD)/?(goldNew:y);
    
89.       !!OW&(goldNew)<0:R(player)/(RES_GOLD)/0;
    
90.       !!OW:R(player)/(extRes)/d-(extResDiffSum);
    
91.       !!OW:R(player)/(extRes)/?(extResNew:y);
    
92.       !!OW&(extResNew)<0:R(player)/(extRes)/0;
    
93.     !!en;
    
94.   !!en;
    
95. !!en;

复制代码

Archer30

等一下。我发现审错题目了。写了一篇论文，然后发现我写的是“英雄带领的升级7级生物自动升级为8级”AI消耗资源的脚本。不是楼主需求的部分

水流行险

Archer30 发表于 2021-7-20 22:23
等一下。我发现审错题目了。写了一篇论文，然后发现我写的是“英雄带领的升级7级生物自动升级为8级”A ...

没关系，有人关心就很幸福了。

我的意图很简单，就是把城镇升级脚本的电脑AI的八级兵也要受资源限制。毕竟，英雄无敌离开了资源就没有玩头了。 用资源支撑的兵种和宝物来源是最大的乐趣。

Archer30

能不能说一下FU99869里被传入的x6和x7什么作用？（也就是FU99868的v6和43）

主楼是原本的脚本吗？我只在主楼的基础上修改就行？