【招内测】颠覆你想象的mod地图：守卫家园

gsczwzzzzz · 发表于 2020-10-22 09:43:04

照例更新一波，昨天花了3个小时改了一个bug，超级坑= =，分享一下。
截图202010220938403314..png

这是最新的事件图，我在刷怪脚本里面使用的是！？GE来触发后续命令的，这个指令接收的时间事件之前不能有普通事件
截图202010220940323103..png

比如上图这种情况如果点击确定的话，创建了第2天触发的这个时间事件，游戏会在加载过程崩溃。不要问我怎么知道都是血泪史~查了3小时bug才试出来= =
解决方法就是删掉这个事件或者在收到资源前随便写点数字满足GE可以判定的要求。

gsczwzzzzz · 发表于 2020-10-22 09:54:46

再分享一下版本适配功能，我打算针对不同的版本适配不同的wog设定，趋向于让不同版本的难度体验大致一致。

!!VRz-10:S^选择打开本地图的游戏版本^;
!!VRz-1:S^魔力觉醒（推荐这个打开）^;
!!VRz-2:S^封魔（未测试）^;
!!VRz-3:S^封神（未测试）^;
!!VRz-4:S^普通wog（未测试）^;
!!IF:G1/1/1/-10/-1/-2/-3/-4;
!!SN:W^GameVer^/v1;
!!SN:W^GameVer^/?y3; 读取GameVer值到y3
!!if&y3=1:;
!#UN:P702/1;启用10倍伤害
!#UN:P703/1;启用h5非线性减伤计算
!#UN:P709/0;关闭英雄12技能
!#UN:P715/1;启用英雄14技能
!#UN:P714/1;启用3技能选择
!#UN:P716/0;关闭空地造东西
!#UN:P713/1;启用组合装备只占一格子
!#UN:P242/0;关闭无城市不失败
!#UN:P777/1;启用新招魂
!#UN:P756/1;启用新增隐藏装备
!#UN:P775/1;启用新魔法伤害结算
!#UN:P761/1;启用生物宝物
!#UN:P757/1;启用新魔法
!#UN:P53/1;启用新龙国
!#UN:P40/0;关闭开局给钱
!#UN:P142/0;关闭打怪给宝物
!#UN:P171/1;风车产秘银
!#UN:P149/1;秘银显示
!#UN:P36/1;秘银用途开
!#UN:P45/1;城镇升级
!#UN:P46/1;城镇升级辅助
!#UN:P231/1;野兵经验
!#UN:P135/0;禁止静止怪物
!#UN:P136/0;禁止游荡怪物
!!IF:M^魔力觉醒设置完成^;
!!en:;

复制代码

目前就针对魔力觉醒有专门设定，后续计划先封魔再封神和普通wog添加。
效果就是如下图多了一个选择版本的对话
截图202010220954416727..png

gsczwzzzzz · 发表于 2020-10-22 10:00:35

接下来要更新一个重点内容，副本功能的实现。尽情期待哈。
第一个副本叫树木花园，故事背景就不提了，反正要木头来这里就没错了。矿材场我打算起一个矿材副本，这里不放。
功能就是，第一鼠标右键显示这个副本的更新日期，以及副本简介。英雄交互后传入副本，cd期间副本被锁住无法访问。副本出来要收取1000元过路费（其实是偷懒直接放一个回城建筑而已）。踏入副本瞬间小怪刷新，并且告知杀怪奖励。

飞跃长江 · 发表于 2020-10-22 11:25:18

感谢，期待成品出来

阿么 · 发表于 2020-10-22 11:36:24

哦豁，有点厉害了，我以后可以说我是看着他一点点长大的

blackye · 发表于 2020-10-22 12:07:03

厉害了啊，期待楼主完成的作品

gsczwzzzzz · 发表于 2020-10-22 14:53:35

又来更新了，现在在做副本功能，脚本预留了副本刷怪的模块还没有写，目前完成了副本右键介绍、副本传送、副本cd功能，直接展示成果，代码最后给
截图202010221440467489..png

截图的时候鼠标会消失，鼠标位置在那颗树上面（那颗树就是副本入口）
截图202010221441383616..png

上面这事右键效果，直接访问试试
截图202010221442193046..png

直接访问就进入副本了，这个时候回来右键那个副本
截图202010221443074063..png

会显示副本cd时间

旁边的树桩我也做了一个副本，进入后
截图202010221445055312..png

回头右击这个树桩

现在试试过天后文本是否会刷新
截图202010221447504787..png

这个效果没问题了，雇一个英雄看能不能进
截图202010221449171166..png

成功，最后等2天看能不能再进
截图202010221450412776..png

上面2个图是第4天2个副本的情况，第一个副本已经又可以进了
截图202010221452247819..png

果然第3个英雄可以进，然后第一个副本又进入了cd。
最后把代码黏上~~~

ZVSE
*****树木花园 FB001
!#VRz125:S^副本^;
!#SN:W^FB001X^/88;入口坐标x（需要输入）
!#SN:W^FB001Y^/216;入口坐标y（需要输入）
!#SN:W^FB001Z^/1;入口坐标z（需要输入）
!#SN:W^FB001Timer^/1;计天器
!#SN:W^FB001CD^/3;副本cd多少（需要输入）
!#SN:W^FB001Trigger^/0; 定义为0则未触发，定义为1则触发
!#SN:W^FB001X^/?y11;
!#SN:W^FB001Y^/?y12;
!#SN:W^FB001Z^/?y13;
!#TRy11/y12/y13:P1;
!#TRy11/y12/y13:E0;所在区域为黄色可触发区
!#OBy11/y12/y13:T49;让这个变成魔法井
!#OBy11/y12/y13:S; 禁止此物体的一般属性
!#OBy11/y12/y13:H125;
!?OB88/216/1; 需要输入副本坐标
!!SN:W^FB001Trigger^/?y1;
!!if&y1=1:; 如果在cd
!!VRy22:Sc;
!!SN:W^FB001Timer^/?y23;
!!SN:W^FB001CD^/?y24;
!!VRy31:Sy22-y23;
!!VRy32:Sy24-1;
!!if&y31>y32:; 如果超出cd天数则把trigger改为0
!!SN:W^FB001Trigger^/0;
!!en:;
!!en:;
!!SN:W^FB001Trigger^/?y1; 重新获取一遍trigger
!!if&y1=0:; 如果不在cd
!!IF:M^你的英雄进入了树木花园^;
!!HE-1:P2/2/1/1; 副本传送位置（需要输入）前3个数字
!!SN:W^FB001Trigger^/1; 触发成功
!!VRy22:Sc;
!!SN:W^FB001Timer^/y22;计天器
--这里写刷新的怪
--
!!el:; 如果在cd
!!IF:M^该副本还在cd中，请稍后再来^;
!!en:;
!?CM0;
!!CM:P?y2/?y3/?y4; 获取大地图位置
!!if&y2=88/y3=216/y4=1:; 需要输入改的坐标
!!CM:R0;禁用原来的鼠标右键事件。
!!SN:W^FB001Trigger^/?y1;
!!if&y1=1:; 如果在cd
!!VRy22:Sc;
!!SN:W^FB001Timer^/?y23;
!!SN:W^FB001CD^/?y24;
!!VRy31:Sy22-y23;
!!VRy32:Sy24-1;
!!if&y31>y32:; 如果超出cd天数则把trigger改为0
!!SN:W^FB001Trigger^/0;
!!en:;
!!en:;
!!SN:W^FB001Trigger^/?y1; 重新获取
!!if&y1=0:; 如果不在cd
!!IF:M^树木花园，副本难度1，出产木头和一些宝物^;
!!el:; 如果在cd
!!SN:W^FB001CD^/?y6;
!!SN:W^FB001Timer^/?y7;
!!VRy8:Sc;
!!VRy5:Sy6+y7-y8;
!!IF:M^树木花园，副本难度1，出产木头和一些宝物，还在刷新中，还剩下%y5天开启^;
!!en:;
!!en:;
******副本2 枯树森林 FB002
!#VRz125:S^副本^;
!#SN:W^FB002X^/82;入口坐标x（需要输入）
!#SN:W^FB002Y^/216;入口坐标y（需要输入）
!#SN:W^FB002Z^/1;入口坐标z（需要输入）
!#SN:W^FB002Timer^/1;
!#SN:W^FB002CD^/5;副本cd多少（需要输入）
!#SN:W^FB002Trigger^/0;
!#SN:W^FB002X^/?y11;
!#SN:W^FB002Y^/?y12;
!#SN:W^FB002Z^/?y13;
!#TRy11/y12/y13:P1;
!#TRy11/y12/y13:E0;
!#OBy11/y12/y13:T49;
!#OBy11/y12/y13:S;
!#OBy11/y12/y13:H125;
!?OB82/216/1; 需要输入副本坐标xyz
!!SN:W^FB002Trigger^/?y1;
!!if&y1=1:;
!!VRy22:Sc;
!!SN:W^FB002Timer^/?y23;
!!SN:W^FB002CD^/?y24;
!!VRy31:Sy22-y23;
!!VRy32:Sy24-1;
!!if&y31>y32:;
!!SN:W^FB002Trigger^/0;
!!en:;
!!en:;
!!SN:W^FB002Trigger^/?y1;
!!if&y1=0:;
!!IF:M^你的英雄进入了枯木森林^; 进入副本要说的话
!!HE-1:P18/4/1/1; 副本传送位置（需要输入）前3个数字
!!SN:W^FB002Trigger^/1;
!!VRy22:Sc;
!!SN:W^FB002Timer^/y22;
--这里写刷新的怪
--
!!el:;
!!IF:M^该副本还在cd中，请稍后再来^;
!!en:;
!?CM0;
!!CM:P?y2/?y3/?y4;
!!if&y2=82/y3=216/y4=1:; 需要输入改的坐标
!!CM:R0;
!!SN:W^FB002Trigger^/?y1;
!!if&y1=1:;
!!VRy22:Sc;
!!SN:W^FB002Timer^/?y23;
!!SN:W^FB002CD^/?y24;
!!VRy31:Sy22-y23;
!!VRy32:Sy24-1;
!!if&y31>y32:;
!!SN:W^FB002Trigger^/0;
!!en:;
!!en:;
!!SN:W^FB002Trigger^/?y1;
!!if&y1=0:; 如果不在cd
!!IF:M^枯木森林，副本难度1，出产生物^; 需要输入右键查看的副本信息
!!el:; 如果在cd
!!SN:W^FB002CD^/?y6;
!!SN:W^FB002Timer^/?y7;
!!VRy8:Sc;
!!VRy5:Sy6+y7-y8;
!!IF:M^枯木森林，副本难度1，出产生物，还在刷新中，还剩下%y5天开启^; 需要输入右键查看的副本信息
!!en:;
!!en:;

复制代码

gsczwzzzzz · 发表于 2020-10-22 15:58:35

继续更新一个设定，本地图移动力是一个很重要的指标，一回合内干的事越多，成长得越快，为了匹配这个设定，特别定制了寻路术的脚本。同时大幅更改各种路面消耗的移动力，满足副本的一些特质化需求。
代码参考了这个帖子戳这里

ZVSE
!?PI; 初始化
!!FU20204780:P440;
!?GM0; 读档
!!FU20204780:P440;
!?FU20204780&x1=440;
**寻路术
**改变寻路术在不同地形上移动力的消耗
**泥地100
!?FU77015; OnGameEnter
!!UN:C6546704/4/130; [无]
!!UN:C6546708/4/120; [初级]
!!UN:C6546712/4/105; [中级]
!!UN:C6546716/4/90; [高级]
**沙漠150
!!UN:C6546720/4/210; [无]
!!UN:C6546724/4/180; [初级]
!!UN:C6546728/4/150; [中级]
!!UN:C6546732/4/110; [高级]
**草地100
!!UN:C6546736/4/100; [无]
!!UN:C6546740/4/95; [初级]
!!UN:C6546744/4/90; [中级]
!!UN:C6546748/4/80; [高级]
** 雪地150
!!UN:C6546752/4/310; [无]
!!UN:C6546756/4/250; [初级]
!!UN:C6546760/4/190; [中级]
!!UN:C6546764/4/120; [高级]
**沼泽175
!!UN:C6546768/4/270; [无]
!!UN:C6546772/4/220; [初级]
!!UN:C6546776/4/170; [中级]
!!UN:C6546780/4/120; [高级]
**岩石戈壁125
!!UN:C6546784/4/160; [无]
!!UN:C6546788/4/140; [初级]
!!UN:C6546792/4/120; [中级]
!!UN:C6546796/4/100; [高级]
** 地下100
!!UN:C6546800/4/100; [无]
!!UN:C6546804/4/95; [初级]
!!UN:C6546808/4/90; [中级]
!!UN:C6546812/4/80; [高级]
** 熔岩100
!!UN:C6546816/4/400; [无]
!!UN:C6546820/4/330; [初级]
!!UN:C6546824/4/250; [中级]
!!UN:C6546828/4/160; [高级]
**水面100
!!UN:C6546832/4/100; [无]
!!UN:C6546836/4/90; [初级]
!!UN:C6546840/4/90; [中级]
!!UN:C6546844/4/90; [高级]
**深渊0
!!UN:C6546848/4/0; [无]
!!UN:C6546852/4/0; [初级]
!!UN:C6546856/4/0; [中级]
!!UN:C6546860/4/0; [高级]
** 泥路75
!!UN:C6546864/4/80; [无]
!!UN:C6546868/4/75; [初级]
!!UN:C6546872/4/70; [中级]
!!UN:C6546876/4/60; [高级]
** 沙烁路65
!!UN:C6546880/4/65; [无]
!!UN:C6546884/4/60; [初级]
!!UN:C6546888/4/55; [中级]
!!UN:C6546892/4/50; [高级]
**鹅卵石路50
!!UN:C6546896/4/50; [无]
!!UN:C6546900/4/45; [初级]
!!UN:C6546904/4/40; [中级]
!!UN:C6546908/4/35; [高级]

复制代码

gsczwzzzzz · 发表于 2020-10-22 16:00:55

cec0612734 发表于 2020-10-22 09:37
还要看玩家的兵力怎么算，如何更多更强，打完仗损耗了怎么补充。

第一就是家里的科技。
第二特别的一些野外巢穴雇佣。
第三一些副本会奖励生物。

songfx · 发表于 2020-10-22 18:22:47

我想要的刷新区域呢？

gsczwzzzzz · 发表于 2020-10-22 20:52:15

songfx 发表于 2020-10-22 18:22
我想要的刷新区域呢？

在搞别急~

gsczwzzzzz · 发表于 2020-10-23 11:44:19

日常更新，副本还在做，先更新一个新功能，之前难度选项的实际实现，和进攻英雄携带宝物战利品禁止获取（这样可以安排一些拿着天使联盟或者禁魔球等英雄来攻城，而不是送宝童子）
战斗难度的通过增加敌方英雄的攻防，如果是野怪则添加一个英雄在战场上实现。代码如下，图就不贴了

ZVSE
** 每场战斗开始设置全部置换为94号英雄
!?BA0&1000;
!!BA:H0/?y3; [获得进攻方英雄的编号]
!!BA:H1/?y4; [获得防守方英雄的编号]
!!BA:O?y88/?y81;
!!if&y88<>0:;
!!BA:H0/?y4;
!!BA:H1/?y3;
!!en:;
!!SN:W^heroA^/y3;
!!SN:W^heroB^/y4;
!!SN:W^playerbuff^/?y40;获取玩家加的攻防
!!SN:W^PCbuff^/?y41;获取电脑加的攻防
!!if&y3=-2:;玩家方案不存在英雄
!!el:;
!!HEy3:Fdy40/dy40/d0/d0; [修改英雄的攻击防御值]
!!en:;
!!if&y4=-2:;如果非玩家方不存在英雄
!!BA&y81=0:H0/94; 添加一个英雄
!!BA&y88=0:H1/94; 添加一个英雄
!!HE94:Fy41/y41/0/0;
!!CO94:D1;
!!el:;
!!HEy4:Fdy41/dy41/d0/d0; [防御方同样处理]
!!HEy4:A2/132/?y31;
!!SN:W^heroItem132^/y31;
!!HEy4:A2/134/?y31;
!!SN:W^heroItem134^/y31;
!!HEy4:A2/135/?y31;
!!SN:W^heroItem135^/y31;
!!HEy4:A2/129/?y31;
!!SN:W^heroItem129^/y31;
!!HEy4:A2/128/?y31;
!!SN:W^heroItem128^/y31;
!!HEy4:A2/126/?y31;
!!SN:W^heroItem126^/y31;
!!HEy4:A2/158/?y31;
!!SN:W^heroItem158^/y31;
!!HEy4:A2/159/?y31;
!!SN:W^heroItem159^/y31;
!!en:;
** 战斗后处理程序
!?BA1;
!!SN:W^heroA^/?y3;
!!SN:W^heroB^/?y4;
!!SN:W^playerbuff^/?y40;获取玩家加的攻防
!!SN:W^PCbuff^/?y41;获取电脑加的攻防
!!VRy40:*-1; [将进攻方四围置负]
!!VRy41:*-1; [对防守方同样处理]
!!if&y3=-2:;不存在
!!el:;
!!HEy3:Fdy40/dy40/d0/d0; [修改英雄的攻击防御值]
!!en:;
!!if&y4=-2:;不存在
!!el:;
!!HEy4:Fdy41/dy41/d0/d0; [防御方同样处理]
!!if&y3<>-2:;己方英雄存在
!!HEy3:A3/125/1/0;[移除战争枷锁]
!!SN:W^heroItem132^/?y31;
!!HEy3:A3/132/y31/0;[移除诅咒铠甲]
!!SN:W^heroItem134^/?y31;
!!HEy3:A3/134/y31/0;[移除龙王之力]
!!SN:W^heroItem135^/?y31;
!!HEy3:A3/135/y31/0;[移除泰坦之剑]
!!SN:W^heroItem129^/?y31;
!!HEy3:A3/129/y31/0;[移除天使联盟]
!!SN:W^heroItem128^/?y31;
!!HEy3:A3/128/y31/0;[移除末日之刃]
!!SN:W^heroItem126^/?y31;
!!HEy3:A3/126/y31/0;[移除禁魔球]
!!SN:W^heroItem158^/?y31;
!!HEy3:A3/158/y31/0;[移除残忍斧头]
!!SN:W^heroItem159^/?y31;
!!HEy3:A3/159/y31/0;[移除龙之心]
!!en:;
!!en:;

复制代码

yunings · 发表于 2020-10-23 20:17:42

加油1，楼主，看好你，给你一些赞助！

gsczwzzzzz · 发表于 2020-10-23 22:41:24

yunings 发表于 2020-10-23 20:17
加油1，楼主，看好你，给你一些赞助！

谢谢支持

gsczwzzzzz · 发表于 2020-10-23 22:53:45

本帖最后由 gsczwzzzzz 于 2020-10-23 22:55 编辑

又来更新了，这次做了些模块化的东西。第一个是副本生物生成，我们先进副本看看
截图202010232244027983..png

自动生成了3个兵，右键其中一个有说明

截图202010232244532947..png

进入战斗

由于难度选的是难3，可以看见对面自动生成一个英雄，攻防10的，战斗胜利后
截图202010232246473033..png

同时为了测试我的宝物概率爆系统，神奇战甲~狮王盾连续触发21次，看看概率
截图202010232249103204..png

不知道为啥项链这么少，理论上一个概率，没关系。
截图202010232250137842..png

好了我们出副本，再等副本cd好了再进看看还不会不会刷
截图202010232251117109..png

第4天副本一刷新进来后，这个枪兵又刷新了，又可以拿装备了
截图202010232252057228..png

新的一波，项链翻身做主。功能性的代码搞的不容易，这次代码量特别多，就不粘上来了。接下来我完善下数值和地形，让副本初具规模

songfx · 发表于 2020-10-24 05:42:54

大善！
又见彩旗英雄。基本功能已经实现，高手就高手。

流水不腐 · 发表于 2020-10-24 08:16:45

期待大作早日发布。

gsczwzzzzz · 发表于 2020-10-24 15:38:55

继续更新，首先交代一下最近忙完代码的模块截图202010241512558361..png

我把几个要不断调试的代码都加了【】表示，方便自己复制粘贴。其中【10】【11】【12】【13】的代码相辅相成
，比如设定了副本就要设定对应的怪物、对应的怪物提示、对应的怪物奖励*（这一块已经模块化）
现在要介绍的是我自己研究的移动力酒馆系统。放在了酒馆替换那个事件里面。
因为本防守图只允许一个英雄存在，酒馆其实是没作用的（你说复活英雄吗？读档吧少年），而且我希望限制玩家玩第二个英雄。主英雄的移动力就很关键。
我把没用的酒馆改成了可以花钱买移动力的地方。
移动力酒馆共5级，1级就是普通酒馆造起来就可以。右键点击酒馆可以选择升级酒馆，左键点击买体力。暂时的数值设计是：
      1级普通酒馆造价                                  初始 100黄金买100移动力
         2级需要 5000黄金 2各个稀有资源          初始 250 黄金买250移动力
      3级需要  20000黄金 8各个稀有资源       初始500黄金买550移动力
      4级需要 70000黄金 28各个稀有资源    初始1000黄金买1150移动力
      5级需要    24w黄金  88各个稀有资源    初始2000黄金买2400移动力
单天内，每购买一次移动力，需要的黄金翻倍、移动力奖励翻1.6倍。不限次数只要有钱。但英雄必须在城内访问酒馆。第二天，购买的黄金和移动力按照酒馆等级重置。
截图202010241533081857..png

不要吐槽那个为啥右侧移动力购买的图片也是钱币的样子，问就是代码水平有限= =。后面那个宝石其实是所有稀有资源，宝石图片代表一下，一样水平有限不知道怎么把所有图片显示出来。

关于移动力设计，我已经完成了寻路术优化、移动力酒馆，后续我再出一个针对后勤学和98号神行靴以及220号疾风战靴的优化

songfx · 发表于 2020-10-24 17:28:49

老弟，你确定你是新人吗？感觉至少是元老级别的风度啊。

ajinlin · 发表于 2020-10-24 17:54:55

善支持楼主期待作品

账号		自动登录	找回密码
密码			英雄注册\|Register

【招内测】颠覆你想象的mod地图：守卫家园

点评

点评

论坛守望者

杰出贡献

论坛元老

魅力之星

封魔玩家

社区QQ达人

论坛创始人