有必要搞的这么变态吗？

龙腾月

人族的罗兰德不是一般变态，小天使可以直接升级至高天使。一般我都不玩直接转职的英雄，第一觉得有点犯规，第二觉得后期都不怎么厉害。可是酒馆里有转职的英雄不买就有点对不起自己了。酒馆里出了罗兰德，天使直接升至高。电脑甚至连高级的7级兵都没出。直接成碾压了。野蛮城的英雄科尔格的专长居然不加幽灵比蒙的攻，防。换句话说就是比蒙生成幽灵比蒙了，1特性就没意义了。当然你也可以不把比蒙升级。这太坑了吧。还有这鬼武者的职业真心不怎么样，等级X30的伤害。等到个20多级，基本高级兵都过千的血了，如果带了血瓶还要多。这伤害真心不给力。个人觉得等级X40.还差不多。个人觉得火焰领主这职业就很给力，完克占火师而且燃烧无法被治疗驱散。职业的特技就不应该被简单的治疗和驱散搞定。像原罪魔王，个人觉得就不怎么样。什么鸟七宗罪，完全不给力。衰老只下30%的生命不说。治疗驱散什么的，直接就解了。召出的原罪也菜到不要不要的。什么按照地狱城的兵种提高能力。我全部7种地狱城的兵，又有多强？完全不给力嘛。还有弹道术，不加强吧，伤害完全不给力。高级也就打打小兵有点用。加强吧，这伤害简直是变态，高级弹道几下8级兵都要死几个还是范围的。成了英雄必备的了。

canary

自己喜欢就好，觉得特殊英雄变态，可以在设置里关闭呀。
还有职业平衡性可以根据自己需要自行调整，你说的几个弱鸡职业我都已经自(｡･∀･)ﾉﾞ嗨调整过了，问题自己调整后的自己遇到了都头大。。。。。。像你说的占火师弱势问题就比较麻烦（其实占火师有数量叠加BUFF，只要愿意培养也不会太弱，光一招连珠火球就能吃遍天下），不光是占火师，基本上直接魔法伤害增加的职业都面临这个问题，怪物拥有超高的魔法伤害抵抗（战旗BUG）以及太多怪拥有矮人抗魔特技等等。原罪的召唤生物不给力，完全可以通过调整让它变得给力，28号脚本打开，搜索下原罪魔王，找到修改召唤物的几条命令，强制后面加个*2 *3即可调整属性，有ERM功底可以干脆重新写召唤生物攻击防御生命跟部队或者英雄属性挂钩等等，至于怎么平衡就得自行考虑。
吧啦吧啦说这么多，还真是可惜沧海老师不再继续更新了，为此只能依靠玩家自行调整平衡性问题了。

龙腾月

我只是想把原罪魔王稍微平衡一点，好对的起它的名字。不想破坏平衡怎么调呀？求大神帮忙呀
=========================================================
;14.原罪魔王
=========================================================
!?FU77006&1000/v6103=0;
!!SN:X?y1/?y2;
!!VRy3:Sy1 *21 +y2;
!!BMy3:T?y4 N?y5 I?y6;
!!FU|y4<0/y5<1:E;
!!BHy6:N?y7;
!!FU&y7=-1:E;
!!BU:T?y8;
!!FU&y8=1:E;
!!FU17033&y7>-1/v997<3:P1/14/y7/y6/y3;  &炼狱+罪恶之门

!?FU17033&x1=1;
!!SN:W^Left.Flag^/?y7 W^Right.Flag^/?y8;
!!FU&x4=0/y7>0:E;
!!FU&x4=1/y8>0:E;
!!IF:Wx3;
!!FU&w185<>14:E;
!!HEx3:B0/?z6;
!!VRv8:S0;    处理七罪责罚
!!VRv600:C0/0/0/0/0/0/0/0/0/0;
!!DO17033/0/20/1&x4=1:P-1/444;  检查敌方堆栈
!!DO17033/21/41/1&x4=0:P-1/444;
!!if&v8>0:;
!!VRv8:S0;
!!FU16043:Px4;  //调用英雄施法动作函数 By 007
!!VRz9:S^Loopdevl.wav^;
!!SN:Pz9;
!!VRz3:S^Huomo.def^;   火神像
!!FU16037:P0/3/93/100/1/0/0;  //调用更换魔法动画函数 By 007
!!VRz10:Sz222366;
!!MM:Sz10;
!!VRz3:S^BlindiS.def^;  魔眼
!!FU16041:P0/3/600/1/1/1/1;  //调用群体更换魔法动画函数 By 007
!!FU16044:Px4;
!!en:;
!!VRv9:S0;   ***处理召唤原罪魔王
!!DO17033/0/20/1&x4=0:P-1/555;  检查本方堆栈1
!!DO17033/21/41/1&x4=1:P-1/555;
!!VRy9:Sv9;
!!VRv9:S0;
!!if&y9<=19:;   超过19支部队退出
!!HEx3:Ed/?y11 I?y12/1;
!!FU16039:Px3/?y1/?y2/?y3/?y4/6/?y5/0;  //调用检查英雄4围金钱函数
!!FU90012:Px4/2/?y13;   //调用设置召唤位置函数
!!BU:S54/1/y13/x4/-1/0;
!!BU:Ey13/?y14;
!!if&y14>-1:;
!!FU16047:Py14/220840;  //调用通过ERT变换生物形象函数 By 007
!!FU16061:Py14/174061/174062;  //调用改变生物名称和说明函数 By 召唤师
!!VRv10:S0;
!!DO17033/0/20/1&x4=0:P-1/666;  检查本方堆栈2
!!DO17033/21/41/1&x4=1:P-1/666;
!!VRy20:Sv10 &1;
!!VRy21:Sv10 &2;
!!VRy22:Sv10 &4;
!!VRy23:Sv10 &8;
!!VRy24:Sv10 &16;
!!VRy25:Sv10 &32;
!!VRy26:Sv10 &64;
!!VRy27:S0;
!!VRy27&y20>0:+1;
!!VRy27&y21>0:+1;
!!VRy27&y22>0:+1;
!!VRy27&y23>0:+1;
!!VRy27&y24>0:+1;
!!VRy27&y25>0:+1;
!!VRy27&y26>0:+1;
!!VRy27&y27>3:S3;
!!VRy15:S19 +y1;  A=基础攻击+英雄攻击
!!VRy16:S21 +y2;  D
!!VRy17:S15 +y3;  U=基础伤害+英雄力量
!!VRy18:S20 +y3;
!!VRy19:Sy12 +40; H=英雄魔法点+40
!!VRy19&y19>500:S500;
!!VRy30:Sy14+1 *-1;
!!EAy30:L888888;
!!EAy30:E888888/2/d/d;
!!EAy30:R156/7;
!!BMy14:Ay15 Dy16 U1/y17 U2/y18 Hy19 S12 Ey27;
!!BMy14:M29/999/3 F1130627;    1+2+128+16384+65536+1048576
!!BMy14:Py13;
!!VRz9:S^Fireblst.wav^;
!!SN:Pz9;
!!FU16022:Py14/4;
!!VRz10:Sz222367;
!!MM:Sz10;
!!en:;
!!en:;
!!SN&x4=0:W^Left.Flag^/1;
!!SN&x4=1:W^Right.Flag^/1;
!!BU:R;

!?FU17033&x1=-1/x2=444;
!!BMx16:T?

canary

龙腾月 发表于 2018-1-10 19:09
我只是想把原罪魔王稍微平衡一点，好对的起它的名字。不想破坏平衡怎么调呀？求大神帮忙呀
============== ...

我只是想把原罪魔王稍微平衡一点，好对的起它的名字。不想破坏平衡怎么调呀？求大神帮忙呀
=========================================================
;14.原罪魔王
=========================================================
!?FU77006&1000/v6103=0;
!!SN:X?y1/?y2;
!!VRy3:Sy1 *21 +y2;
!!BMy3:T?y4 N?y5 I?y6;//这里是判定是否为地狱生物
!!FU|y4<0/y5<1:E;
!!BHy6:N?y7;
!!FU&y7=-1:E;
!!BU:T?y8;
!!FU&y8=1:E;
!!FU17033&y7>-1/v997<3:P1/14/y7/y6/y3;  &炼狱+罪恶之门

!?FU17033&x1=1;
!!SN:W^Left.Flag^/?y7 W^Right.Flag^/?y8;
!!FU&x4=0/y7>0:E; //这里就是每回合触发一次
!!FU&x4=1/y8>0:E;
!!IF:Wx3;
!!FU&w185<>14:E; //检测英雄职业是否为编号14的原罪魔王 不是就退出不执行下面的指令
!!HEx3:B0/?z6; //这里就是日志里的七宗罪
!!VRv8:S0;    处理七罪责罚
!!VRv600:C0/0/0/0/0/0/0/0/0/0;
!!DO17033/0/20/1&x4=1:P-1/444;  检查敌方堆栈
!!DO17033/21/41/1&x4=0:P-1/444;
!!if&v8>0:;
!!VRv8:S0;
!!FU16043:Px4;  //调用英雄施法动作函数 By 007
!!VRz9:S^Loopdevl.wav^; //施法音效
!!SN:Pz9;
!!VRz3:S^Huomo.def^;   火神像//施法魔法动画
!!FU16037:P0/3/93/100/1/0/0;  //调用更换魔法动画函数 By 007
!!VRz10:Sz222366;
!!MM:Sz10;
!!VRz3:S^BlindiS.def^;  魔眼
!!FU16041:P0/3/600/1/1/1/1;  //调用群体更换魔法动画函数 By 007
!!FU16044:Px4;
!!en:;
!!VRv9:S0;   ***处理召唤原罪魔王
!!DO17033/0/20/1&x4=0:P-1/555;  检查本方堆栈1
!!DO17033/21/41/1&x4=1:P-1/555;
!!VRy9:Sv9;
!!VRv9:S0;
!!if&y9<=19:;   超过19支部队退出
!!HEx3:Ed/?y11 I?y12/1;
!!FU16039:Px3/?y1/?y2/?y3/?y4/6/?y5/0;  //调用检查英雄4围金钱函数
!!FU90012:Px4/2/?y13;   //调用设置召唤位置函数
!!BU:S54/1/y13/x4/-1/0;
!!BU:Ey13/?y14;
!!if&y14>-1:;
!!FU16047:Py14/220840;  //调用通过ERT变换生物形象函数 By 007
!!FU16061:Py14/174061/174062;  //调用改变生物名称和说明函数 By 召唤师
!!VRv10:S0;
!!DO17033/0/20/1&x4=0:P-1/666;  检查本方堆栈2
!!DO17033/21/41/1&x4=1:P-1/666;
!!VRy20:Sv10 &1; 这里你需要翻到原罪魔王脚本部分最末尾判定部队中地狱生物种类的地方对比看 1705~1718这几行

!!VRy21:Sv10 &2;
!!VRy22:Sv10 &4;
!!VRy23:Sv10 &8;
!!VRy24:Sv10 &16;
!!VRy25:Sv10 &32;
!!VRy26:Sv10 &64;
!!VRy27:S0;
!!VRy27&y20>0:+1;
!!VRy27&y21>0:+1;
!!VRy27&y22>0:+1;
!!VRy27&y23>0:+1;
!!VRy27&y24>0:+1;
!!VRy27&y25>0:+1;
!!VRy27&y26>0:+1;
!!VRy27&y27>3:S3; //这几行类似的都是判定队伍中地狱生物种类 并且以此增加魔王施法次数（最低1次，最高3次 可自行调整，不过因为无限施法BUG的存在，也没什么卵用就是了）
!!VRy15:S19 +y1;  A=基础攻击+英雄攻击//这里是召唤的魔王攻击指数 魔王的初始攻击为19点 防御21点 后期加上上百的英雄攻防指数其实已经很强了       下面的是防御
!!VRy16:S21 +y2;  D
!!VRy17:S15 +y3;  U=基础伤害+英雄力量//这里是召唤的魔王最小伤害为基础伤害15+英雄的POWER数值 想修改很简单后面放大倍率即可，自行调整吧。 !!VRy17:S15 +y3*2(这里就是你自己调整的东西 =====
!!VRy18:S20 +y3; //最大伤害为基础20+英雄力量指数 想放大修改基础攻击或者放大英雄P系数都行
!!VRy19:Sy12 +40; H=英雄魔法点+40//这里是召唤的魔王血量
!!VRy19&y19>500:S500; //这里是限制魔王血量上限，意思就是你哪怕有3000魔法值，魔王的生命上限依然是500，你可以适当放大。

我是这么调整召唤物的
!!VRy15:S19 +y1 ;  A=基础攻击+英雄攻击
!!VRy16:S21 +y2 ;  D
!!VRy17:S15 +y3 *2;  U=基础伤害+英雄力量
!!VRy18:S20 +y3 *2;
!!VRy19:Sy12 *2 +40; H=英雄魔法点+40
!!VRy19&y19>2000:S2000;
!!VRy30:Sy14+1 *-1;
!!EAy30:L888888;
!!EAy30:E888888/2/d/d;
!!EAy30:R156/7;
!!BMy14:Ay15 Dy16 U1/y17 U2/y18 Hy19 S10 Ey27; 这里能看出来是定义召唤魔王的攻击A 防御D 最小最大伤害U1/U2 生命H 速度S 可释放魔法次数E（仅仅只有这个是根据地狱兵种数量挂钩的，硬实力则没有，最高也只是每次战斗最多施法3次，不过由于生物施法BUG其实并不重要，需要可以无限施法都行）
!!BMy14:M29/999/3 F1130627;    1+2+128+16384+65536+1048576  这里是自带的特技标志位自带魔法等等 可以看出魔王自带高级烈火神盾持续999回合 加的标志位有 1.双格生物 2飞行 128表示王者1（受到初级屠戮成性或者更高的效果时给打击目标造成额外伤害 ）16384表示火免疫 65536 不反击 1048576心智魔法免疫
你当然还能给他加更多天生标志 比如攻击两次32768 攻击环击524288等等 只要把F后面的数字加上对应标志位的数字即可

!?FU17033&x1=-1/x2=444;
!!BMx16:T?y20 N?y21 I?y22;
!!FU|y20=149/y21<1:E;
!!MA:Oy20/?y22;
!!FU&y22=3:E;  地狱生物免疫
!!VRv8:+1;
!!FU16000:P600/x16;
!!BMx16:M42/7/0 M45/7/0 M50/7/0 M52/7/0 M54/7/0 M73/7/1 M75/7/1; 这里就是七宗罪释放的7种负面魔法

!?FU17033&x1=-1/x2=555;
!!BMx16:T?y1 N?y2 O?y3;
!!VRv9&y1>-1:+1;    检查部队数

!?FU17033&x1=-1/x2=666;
!!BMx16:T?y1 N?y2 O?y3;
!!FU|y1<0/y2<1/y3=-1:E;
!!VRv10|y1=42/y1=43:|1;   检查本方地狱部队
!!VRv10|y1=44/y1=45:|2;
!!VRv10|y1=46/y1=47:|4;
!!VRv10|y1=48/y1=49:|8;
!!VRv10|y1=50/y1=51/y1=138:|16;
!!VRv10|y1=52/y1=53:|32;
!!VRv10|y1=54/y1=55/y1=153:|64;

基本上就这些，你需要做的就是移植 把一些比较弱的可以人为强化。

龙腾月

谢谢了，不愧是大神。我看到是眼花缭乱。

龙腾月

大神本来不想麻烦你的。可是试了很多次还是看不懂。想把鬼武者的断魂斩调成等级*40。可是怎么也找不到*30的位置
&断魂斩

!
!?FU17036&x1=1;
!!SN:W^Left.Flag^/?y7 W^Right.Flag^/?y8;
!!FU&x4=0/y7>0:E;
!!FU&x4=1/y8>0:E;
!!IF:Wx3;
!!FU&w185<>17:E;
!!VRy10:Sx5 :21 *21;
!!VRy11:Sy10 +19;
!!VRv600:C0/0/0/0/0/0/0/0/0/0;  !!VRv10:S0;
!!DO17036/y10/y11/1:P-1/x4;  检查本方堆栈
!!if&v10>0:;
!!VRv10:S0;
!!FU16043:Px4;  //调用英雄施法动作函数 By 007
!!VRz9:S^Deathcld.wav^;
!!SN:Pz9;
!!VRz3:S^ThreatenD.def^;   死亡气息
!!FU16041:P0/3/600/1/0/1/1;  //调用群体更换魔法动画函数 By 007
!!FU16044:Px4;
!!HEx3:B0/?z6;
!!VRz10:Sz222411;

龙腾月

!!FU&x4=0/y7>0:E;          大神这里要怎么改才能每回合发动七罪呢？

canary

龙腾月 发表于 2018-1-10 22:49
大神本来不想麻烦你的。可是试了很多次还是看不懂。想把鬼武者的断魂斩调成等级*40。可是怎么也找不到*30的 ...

!!FU&y10>=19:E;  超过19支部队退出
!!HEx3:B0/?z6 Ed/?y6;
!!VRy9:Sy6 *60;  造成等级*60的伤害
!!FU16012:Px4/?y11;  //调用检查随机一支敌方部队函数

鬼武者每回合一次断魂斩的伤害在这里 我改成了60.。。。你自己看着弄吧。

龙腾月

找到了，谢谢大神。我改到*40了。
大神七罪惩罚有没有办法每回合发动呀？
我在   !!FU&x4=0/y7>0:E;     后面加了每回合发动，好像没什么用。 改成!!FU&x4=0/y7>1:E;后，每回合出恶魔领主

龙腾月

试了很多次，有每回合触发七罪惩罚的，就是每回合召唤原罪恶魔。一下就全屏恶魔了
大神有没有办法只附加七罪惩罚的呀。