【悬赏】求在封神下可用的一键加兵的Era

魔导士德肯

求一个 在封神下可用的Erm脚本在大地图下（如图） 鼠标左键点击 红色箭头指向的 英雄头像区域 后
可以弹出对话框：“提示需要增加兵种的ID” 输入兵种ID后 继续输入添加的生物数量 （可以一键免费添加的那种）

不需要全部的生物， 只需要能一键添加： 所有的八级兵 和 先知有您 骷髅召唤师 灭世者 欺诈者

不知道有没有高手可以帮我解决
最后附上生物ID ：所有八级兵的ID151~158 先知有您122 骷髅召唤师126 灭世者128 欺诈者195  （如果我没记错的话）

另外问一下，点击英雄头像区域 触发对话框，这个脚本怎么写？

——————————————分割线——————————————

经试验后发现，封神下的这些特殊生物，增加入英雄部队后，只变成了毫无特性的普通兵种。此贴讨论宣告完结。

最后，感谢各路大神回复

canary

这个早就尝试过了，我给十字军加了个特殊升级形态，只有索萨能够升级，问题升级后的贤知有您只有基础属性跟生物特技存在，那个3段变身能力莫名消失了。。。。。。其他类似的特殊生物都有各种问题，比如原罪魔王应该是随着游戏时间变强的，可你自己升级出来的就失去了这些特性，只能变成很初期的魔王，没啥实际意义。

魔导士德肯

虽然 说有“训练者”这样的修改器，可是并不针对封神，无法增加出 封神新增的生物，如先知有您 骷髅召做唤师 。所以希望有大神可以帮我做一个这样的脚本

XEricSin

还是算了吧，特殊的容易出错。

魔导士德肯

XEricSin 发表于 2017-3-10 18:26
还是算了吧，特殊的容易出错。

版主，那鼠标左键点击英雄头像触发对话框的 代码是什么呀？

YangChao01

ly18298207150 发表于 2017-3-10 18:40
版主，那鼠标左键点击英雄头像触发对话框的 代码是什么呀？

如果不知道代码可以学会查ERM help，鼠标点击类型看CM接收器的 S命令，点击位置看CM:I命令，弹出对话框具体有多种命令，在IF接收器

魔导士德肯

在地图上的难民营里偶然发现可以招募“骷髅召唤师”，突发奇想搞一个erm可以增加这些特殊生物，进战斗界面发现bug ，这些生物原自带的魔法书没有了，生物原有属性也没了，相当于变成一个普通的近战兵种，只是血量多一点…此外，当招募出“骷髅召唤师”时候，进入酒馆查看国王军队实力，生物最强代表从至高大天使变成了攻防只有10的骷髅召唤师…看来boss的存在是无敌的…好吧，果断放弃了。

sstszwl3

这些兵种的特技，攻防还有魔法都是后期根据条件添加上去的。。如果只添加这几个兵种，他们的原型都是原来的中立兵。

魔导士德肯

sstszwl3 发表于 2017-3-13 13:51
这些兵种的特技，攻防还有魔法都是后期根据条件添加上去的。。如果只添加这几个兵种，他们的原型都是原来的 ...

求助一下 大神看下炼宝机制这段文本的红色文字有什么区别？我修改了这两段上面的2500后，首先利用元素城的天赋炼制卷轴以后再选用塔楼的炼宝天赋会弹出脚本错误，如何修改可以让炼宝的花费成每次固定的1000，而不随周增长？
************塔楼开始
!?FU11000&x1=113;   还原DL内容
!!VRvx16:S-1;
!!VRx2:Sx16 -700;    ID 1-7
!!VRx3:Sx16 -685;    ID 16-22
!!VRx4:Sx16 -671;    ID 30-36
!!VRx5:Sx16 -657;    ID 44-50
!!VRz5:S230090;  CPrL.def
!!VRz6:S230091;  APHLF1X.def
!!VRz7:S^^;
!!VRx6:Sx2 +100;  Z101-Z107
!!VRzx6:S^^;
!!VRx7:Sx4 +100;  Z130-Z136
!!VRzx7:S^^;
!!VRx8:Sx5 +100;  Z144-Z150
!!VRzx8:S^^;
!!DL138:Ax2/9/z5 Ax5/9/z6 Ax2/4/0/1;
!!DL138:Ax3/4/8/1 Ax4/3/z7/1;

!?FU11000&x1=114;
!!VRvx16:S-1;

!?FU11000&x1=115;  检查装备宝物（递增0..18）
!!FU&x16>12/x16<18:E;
!!HEx2:A1/?vx3/x16;
!!FU|vx3<7/vx3>170:E;
!!VRx3:+1;

!?FU11000&x1=116;
!!VRv701:C-1/-1/-1/-1/-1/-1/-1;
!!VRv701&x2=1:Cv708/v709/v710/v711/v712/v713/v714;
!!VRv701&x2=2:Cv715/v716/v717/v718/v719/v720/v721;

!?FU11000&x1=117;
!!VRx4:Sx16 -1 +x3;    701-707
!!VRx5:Svx4;
!!FU&x5<0:E;
!!VRz5:S230092;  ArtiFact58.def
!!DL138:Ax16/9/z5;
!!DL138:Ax16/4/x5/1; 设置宝物图片 及暗示文本
!!UN:N0/2/x5;
!!VRx6:Sx16 +100;
!!VRzx6:Sz2;
!!VRx7:Sx16 +15;  黄金图片ID  16-22
!!VRx8:Sx16 +29; 黄金数量ID  30-36
!!VRx9:Sx8 +100; Z130-Z136
!!HEx2:O?x10;
!!OW:Rx10/6/?x11;
!!VRx12:Sc -1 :7 +1 *2500;  每周 +1000
!!VRz6:S^%X12^;
!!VRzx9:S^{黄金} %X12^;
!!DL138:Ax7/4/6/1 Ax8/3/z6/1;
!!SN:W^宝物转换^/?x13;
!!SN:Mx13/x5/?x14;
!!if&x14=1:;
  !!VRy1:Sx16 +43;   升级ID  44-50
  !!VRy2:Sy1 +100;  Z144-Z150
  !!UN:N0/8/x5;
  !!VRzy2:S^{炼制} %Z8^;
  !!VRz7:S230042;   APHLF1R.def
  !!DL138:Ay1/9/z7;  设置不能升级DEF
!!el:;
!!if&x14=0:;
  !!if&x11<x12:;
    !!VRy1:Sx16 +43;   升级ID  44-50
    !!VRy2:Sy1 +100;  Z144-Z150
    !!VRz7:S230042;   APHLF1R.def
    !!UN:N0/8/x5;
    !!VRzy2:S^{炼制} %Z8^;
    !!DL138:Ay1/9/z7;   设置不能升级DEF
  !!el:;
  !!if&x11>=x12:;
    !!VRy1:Sx16 +43;   升级ID  44-50
    !!VRy2:Sy1 +100;  Z144-Z150
    !!VRz7:S230043;   APHLF1G.def
    !!UN:N0/8/x5;
    !!VRzy2:S^{炼制} %Z8^;
    !!DL138:Ay1/9/z7;   设置能升级DEF
  !!el:;
!!en:;

!?FU11000&x1=118;   暗示文本
!!VRx4:Sx16 +100; Z101-Z107
!!DL138:Hx16/zx4;
!!VRx5:Sx16 +29; 黄金数量ID  30-36
!!VRx6:Sx16 +129; Z130-Z136
!!DL138:Hx5/zx6;
!!VRx7:Sx16 +43;   升级ID  44-50
!!VRx8:Sx16 +143; Z144-Z150
!!DL138:Hx7/zx8;

!?FU11000&x1=119;  塔楼点击
!!VRx5:Sx3 -44 +x4;
!!VRx6:Svx5;
!!FU&x6<0:E;
!!HEx2:O?x7;
!!OW:Rx7/6/?x8;
!!VRx9:Sc -1 :7 +1 *2500;  每周 +2500
!!SN:W^宝物转换^/?x10;
!!SN:Mx10/x6/?x11;
!!if&x11=1:;
  !!VRz10:S230093;
  !!IF:M^%Z10^;
  !!FU:E;
!!en:;
!!if&x11=0:;
  !!if&x8<x9:;
    !!VRz10:S230094;
    !!IF:M^%Z10^;
    !!FU:E;
  !!en:;
  !!if&x8>=x9:;
    !!SN:W^Lian Po^/-1;
    !!DL148:N^Lian Po.txt^;  //DL148 2015-06-08
    !!FU200148:P1/x2/x6/x9/x8;  x2=英雄ID,x3=宝物编号,x4=消耗金币,x5=现有金币,x6=形式
    !!DL148:S1;
    !!SN:W^Lian Po^/?x12;
    !!FU&x12=-1:E;
    !!VRy1:Sx3 -28;  黄金图片ID  16-22
    !!VRy2:Sx3 -14;  黄金数量ID  30-36
    !!VRy3:Sy2 +100; Z130-Z136
    !!VRzy3:S^^;
    !!VRz11:S230042;   APHLF1R.def
    !!DL138:Ax3/9/z11;  设置不能升级DEF
    !!DL138:Ay1/4/8/1 Ay2/3/zy3/1;  设置黄金图片及数量
    !!VRx11:S1;
    !!SN:Mx10/x6/x11;
  !!en:;
!!en:;

***新增DL148部分 z78-z84 v991-v993
!?DL&v998=148/v999=30722/v1000=13;
!!SN:W^Lian Po^/-1;
!!DL:C1;

!?DL&v998=148/v999>5/v999<8/v1000=13;
!!FU200148:P1/x2/x6/x9/x8/1; 点击翻页

!?DL&v998=148/v999>1/v999<5/v1000=13;
!!FU200148:P2/v999/0/10;     选择宝物1

!?DL&v998=148/v999>11/v999<15/v1000=13;
!!FU200148:P2/v999/10/0;     选择宝物2

!?DL&v998=148/v999>1/v999<5/v1000=14;
!!FU200148:P3/v999/0/10;     选择宝物3

!?DL&v998=148/v999>11/v999<15/v1000=14;
!!FU200148:P3/v999/10/0;     选择宝物4

!?DL&v998=148/v999=10/v1000=13;
!!FU200148:P4/x2/x6/x9/x8;   炼制宝物

!?FU200148&x1=1;
!!SN:W^Lian Po^/-1;
!!VRy1:Sx3 +172170;
!!VRz78:Szy1;
!!VRz79:S^{~Gold}炼制{~}%Z78^;
!!DL148:A11/3/z79/1;   11
!!VRz80:S^%X4^;
!!DL148:A8/3/z80/1;    8
!!VRv991:C143/143/143;
!!UN:J6/6/?y2;  #8
!!SN&y2=x3:G8;
!!UN:J6/6/?y3;  #10
!!SN|y3=x3/y3=y2:G10;
!!UN:J6/6/?y4;  #12
!!SN|y4=x3/y4=y2/y4=y3:G12;
!!VRz9&x6=1:S^MClick.wav^;
!!SN&x6=1:Pz9;
!!DL148:A1/4/x3/1 A2/4/y2/1 A3/4/y3/1 A4/4/y4/1;  1-4
!!DL148:A12/4/0/1 A13/4/0/1 A14/4/0/1;  12-14
!!VRy5:Sy2 +172170;
!!VRy6:Sy3 +172170;
!!VRy7:Sy4 +172170;
!!VRz81:Szy5;
!!VRz82:Szy6;
!!VRz83:Szy7;
!!VRz84:S^^;
!!VRv991:Sy2; !!VRv992:Sy3; !!VRv993:Sy4;
!!DL148:E10/0;

!?FU200148&x1=2;
!!VRy1:Sx2 -x3 -2 +991;
!!VRy2:Svy1 +172170;
!!VRz78:Szy2;
!!VRz79:S^{~Red}炼成{~}%Z78^;
!!DL148:A11/3/z79/1;
!!VRz9:S^MClick.wav^;
!!SN:Pz9;
!!DL148:A12/4/0/1 A13/4/0/1 A14/4/0/1;  12-14
!!VRy3:Sx2 +x4;
!!DL148:A1/4/vy1/1 Ay3/4/1/1 E10/1;
!!VRy4:Svy1;
!!SN:W^Lian Po^/y4;

!?FU200148&x1=3;
!!VRy1:Sx2 -x3 -2 +991;
!!VRy2:Svy1;
!!FU&y2<0:E;
!!FU90001:Py2;
!!IF:Q1/8/y2/4^%Z2^;

!?FU200148&x1=4;
!!SN:W^Lian Po^/?y9;
!!FU&y9=-1:E;
!!VRy10:Sx4 *-1;
!!FU90003:Px3/?v2/?v3/?v4/?v5/0;  //调用检测或设置宝物的四维指数 By 007
!!HEx2:A3/x3/1/1 A4/y9;
!!HEx2:F?y11/?y12/?y13/?y14;
!!VRy11:-v2;
!!VRy12:-v3;
!!VRy13:-v4;
!!VRy14:-v5;
!!HEx2:Fy11/y12/y13/y14;
!!DO11000/0/69/1:P151/x2;   移去宝物加成魔法
!!OW:R-1/6/dy10;
!!VRz9:S^Flagmine.wav^;
!!SN:Pz9;
!!DL:C1;

********************
!?FU11000&x1=120;  塔楼右键点击
!!VRx4:Sx2 -1 +x3;
!!VRx5:Svx4;
!!FU&x5<0:E;
!!UN:C6687592/4/?x6;
!!VRx7:Sx5 *32 +x6 +16;
!!UN:Cx7/4/?x8;
*!SN:X?x9 Xx8 X?z1 Xx9;
!!SN:Xx8 X?z1;
!!IF:Q1/8/x5/4^%Z1^;

!?FU11000&x1=151;
!!HEx2:M=x16/1;
!!FU&1:E;
!!HEx2:Mx16/0;

**************塔楼结束

canary

7天一周 28天一个月 你可以考虑改成28天也就是每个月才一变什么的

或者把那个赋值去掉乘法，改成固定数字就行了。

!!VRx9:Sc -1 :7 +1 *2500;  每周 +2500

你红字这两句都改成

!!VRx9:S10000; 固定每次制宝1W花费，既然是自己DIY，随心所欲改吧，先爽过了，才是考虑平衡问题。

魔导士德肯

canary 发表于 2017-3-13 15:20
7天一周 28天一个月 你可以考虑改成28天也就是每个月才一变什么的

或者把那个赋值去掉乘法，改成固定数 ...

点击塔楼天赋，弹出以下错误，是怎么回事？

canary

可能因为俩地方改的不同步，还有脚本里面注意别用拼音输入法输入！；这些符号，以前自己瞎改也遇到过这种问题。

我给你改个算了，改成每个月变一次的，初始2500，2月5000，4个月基本游戏就结束了，也不过是个10000，这个价格你应该能接受。

魔导士德肯

canary 发表于 2017-3-13 15:53
可能因为俩地方改的不同步，还有脚本里面注意别用拼音输入法输入！；这些符号，以前自己瞎改也遇到过这种问 ...

十分感谢

魔导士德肯

sstszwl3 发表于 2017-3-13 13:51
这些兵种的特技，攻防还有魔法都是后期根据条件添加上去的。。如果只添加这几个兵种，他们的原型都是原来的 ...

那有什么可行的方法解决这问题吗？

canary

ly18298207150 发表于 2017-3-13 18:07
那有什么可行的方法解决这问题吗？

你把这些战场召唤生物的触发条件改了就能所有英雄都获得
比如贤知有您这个人类守护神
他的召唤条件
1.检查部队是否全部为城堡
2.检查敌人是否为城堡
由此可见，你在28号脚本里，完全可以找到这些判定语句，自行修改其召唤出现条件。

还有骷髅召唤师的属性增长是按对方实力增强的，你也可以改成跟贤知有您一样是参照自己部队实力增强属性之类。

总之多改改，有益身心健康

canary

这些特殊兵种，没了这些脚本的支持，其实就是一普通兵，有了这些脚本才是超级兵。

魔导士德肯

canary 发表于 2017-3-13 19:25
你把这些战场召唤生物的触发条件改了就能所有英雄都获得
比如贤知有您这个人类守护神
他的召唤条件

首先感谢大神不厌其烦得回复了我好几个帖子的疑问，修改召唤条件…其实我本意的设想是想着这些封神特有的生物可以在城镇升级了特殊的三级兵种后，再进行升级。例如十字军-皇家卫士-先知有您，僵尸-木乃伊-骷髅召唤师，我只用过先知大大上传的简易erm编辑器把十字军改成还可以升级成大天使…这种大工程量的东西感觉好麻烦呀

canary

ly18298207150 发表于 2017-3-13 20:03
首先感谢大神不厌其烦得回复了我好几个帖子的疑问，修改召唤条件…其实我本意的设想是想着这些封神特有的 ...

我在一开始不就回答过你了么？就算添加了这些新生物升级，问题就来了，没对应脚本支持，也就只能看看而已。

canary

http://bbs.h3wog.com/forum.php?m ... D%D6%AA%D3%D0%C4%FA
还有你可以借鉴下这个帖子

魔导士德肯

canary 发表于 2017-3-13 20:22
http://bbs.h3wog.com/forum.php?mod=viewthread&tid=58286&highlight=%CF%CD%D6%AA%D3%D0%C4%FA
还 ...

表示正在研究中，最后一个小期望，希望可以帮我把这个追随者erm 修改一下：

1 删除里面 5级自动召唤宠物的功能
2 开始选取追随者时只要输入生物ID即可设置相应的生物作为追随者，不需要依据英雄携带的兵种设置追随者