大家来写修改游戏日期的erm

khdfkj

今天想探讨一下如何修改游戏的日期，即游戏右下角的月，周，日。周末发答案给大家。嘿嘿😁！
天天都是星期一。
大家踊跃发言。

公布一下答案。      用红色玩家，欧灵英雄，左键点击日期 (月/周/日)，你可以掌控时间了
!?CM5&1000;          掌控时间
!!OW:A-1/?y1;        当前玩家编号
!!FU&y1<>0:E;        红色玩家继续
!!CM:I?y2;
!!FU&y2<>1008:E;     左键点击日期 (月/周/日)
!!VRz-1:S^请输入月数。^;
!!VRz-2:S^数值<1则默认为取消^;
!!VRz-3:S^^;
!!IF:D2/-1/-2/-3;
!!IF:E1/2;         v1选项结果 z1输入月数
!!FU&v1=-1:E;
!!VRy3:Vz1;         定义月数
!!FU&y3<1:E;
!!VRz-1:S^请选择周数。^;
!!VRz1:S^第一周^;
!!VRz2:S^第二周^;
!!VRz3:S^第三周^;
!!VRz4:S^第四周^;
!!VRz5:S^取消^;
!!VRv1:S0;
!!IF:G1/1/16/-1/1/2/3/4/5;       单选对话框
!!VRy4:Sv1;
!!VRv1:S0;
!!FU&y4=16:E;
!!VRy5&y4=1:S1;    定义周数
!!VRy5&y4=2:S2;
!!VRy5&y4=4:S3;
!!VRy5&y4=8:S4;
!!VRz-1:S^请选择日数。^;
!!VRz1:S^第一日^;
!!VRz2:S^第二日^;
!!VRz3:S^第三日^;
!!VRz4:S^第四日^;
!!VRz5:S^第五日^;
!!VRz6:S^第六日^;
!!VRz7:S^第七日^;
!!VRz8:S^取消^;
!!VRv1:S0;
!!IF:G1/1/128/-1/1/2/3/4/5/6/7/8;      单选对话框
!!VRy6:Sv1;
!!VRv1:S0;
!!FU&y6=128:E;
!!VRy7&y6=1:S1;    定义日数
!!VRy7&y6=2:S2;
!!VRy7&y6=4:S3;
!!VRy7&y6=8:S4;
!!VRy7&y6=16:S5;
!!VRy7&y6=32:S6;
!!VRy7&y6=64:S7;
!!UN:C6919480/4/?y8;<699538>           获取动态内存地址
!!VRy9:Sy8 +128578;    月内存地址
!!VRy10:Sy8 +128576;   周内存地址
!!VRy11:Sy8 +128574;   日内存地址
!!UN:Cy9/1/y3;     修改月数
!!UN:Cy10/1/y5;    修改周数
!!UN:Cy11/1/y7;    修改日数
!!UN:R2;           刷新日期显示

贤知有您

任何修改都是探索，说不定某个地图是时间旅行，穿越回去呢

canary

ZVSE
!#MCv1:S@day@;!!VRv1:Sc; 当前天数
!#MCv2:S@weekday@;!!VRv2:Sc%7+1; !!VRv2&v2<>1:S1;强制周一
!#MCv3:S@month@; !!VRv3:Sc+27:28;!!VRv3&v3<>1:S1; 强制一月!#MCv4:S@week@;!!VRv4:Sc+6:7;!!VRv4&v4<>1:S1;强制第一周
!#MCv5:S@monthweek@;!!VRv5:Sc+6:7%4+1;!!VRv5<>1:S1;强制每月第一周

简单试了试 没报错 问题也没生效
感觉这个要生效 起码得屏蔽了自带的日期计算脚本，问题我不知道哪个才是。

XEricSin

erm应该是改不了日期的。除非把原版的码改了。
楼上 的macro只是改的era带的变量吧，并不能改变游戏原版的日期。

khdfkj

canary 发表于 2017-3-10 13:38
ZVSE
!#MCv1:S@day@;!!VRv1:Sc; 当前天数
!#MCv2:S@weekday@;!!VRv2:Sc%7+1; !!VRv2&v21:S1;强制周一

很有创意，让我学到很多东西。比如c，%。这个想法也是我一开始的设想之一。当然操作起来有点累，需要玩家自己算月周日。写一段erm没有生效，可能存在的问题是多方面的。