【基本解决】如何把一键招兵修改为1/5、1/4、1/3、1/2、1/1几个步骤招...

独孤求败

毫无疑问，一键招兵和召唤石是很管用的脚本，可以是英雄无敌3的运动中求发展和资源经营相互制约的精神发挥到极致。可是召唤石遇上的几率比回城还困难，于是一键招兵系统出来了，是很棒的，可是它很不体贴，因为只能一次全部招完未升级的一类兵种，可是我们那里有那么多钱去把所有的相同城镇的同一类型的兵招募，而且赚钱的速度远远没有城镇和巢穴的部队的增长速度快！！是作者考虑到计算城镇的数量很麻烦，可以理解。那么，如何把一键招兵修改为1/5、1/4、1/3、1/2、1/1几个步骤招兵？求版主帮忙修改！@fly123 @gigichart @沧海一粟 @克招 @贤知有您 @灰狼王子

----------------------------------用欠款方式解决，可以出现资源和金钱是负数的情况。多谢XEricsin大神！！


原脚本如下：
ZVSE
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
ERMS_ScriptDate=3.6(June).2012


****脚本制作：寻梦人****

***v变量：v5900---v5906、v5990***

***一键招募所有己方城堡中同一城堡类型的所有生物****

***右键点击英雄名字触发*****




!?CM2&1000;

!!CM:R1;
!!CM:S?y11 I?y12;
!!FU|y11<>14/y12<>1:E;   右键点击英雄名字触发,原为士气116
!!HE-1:S2/?y4;           原为M9时空之门，改为S2后勤学
!!IF&y4=0:M^对不起，你还没有学会后勤学！不能使用一键招城堡兵系统！^;
!!FU&y4=0:E;
!!HE-1:W?y13/1;
!!IF&y13<800:M^对不起，你的移动力不够！不能使用一键招城堡兵系统！^;
!!FU&y13<800:E;
!!HE-1:I?y14/1;
!!IF&y14<10:M^对不起，你的魔法值不够！不能使用一键招城堡兵系统！^;        魔法值原为60，改为10
!!FU&y14<10:E;


!!IF:M^欢迎使用一键招兵系统,这里可以让你很快的召唤自己所有城镇里的兵种!^;
!!HE-1:O?y1;
!!VRz-10:S^请选择你想招募的城堡类型！（单项选择）^;
!!VRz-1:S^天使城！^;
!!VRz-2:S^精灵城！^;
!!VRz-3:S^泰坦城！^;
!!VRz-4:S^恶魔城！^;
!!VRz-5:S^鬼龙城！^;
!!VRz-6:S^黑龙城！^;
!!VRz-7:S^比蒙城！^;
!!VRz-8:S^九头城！^;
!!VRz-9:S^凤凰城！^;
!!IF:G1/1/1/-10/-1/-2/-3/-4/-5/-6/-7/-8/-9;
!!VRy2&v1=1:S0;
!!VRy2&v1=2:S1;
!!VRy2&v1=4:S2;
!!VRy2&v1=8:S3;
!!VRy2&v1=16:S4;
!!VRy2&v1=32:S5;
!!VRy2&v1=64:S6;
!!VRy2&v1=128:S7;
!!VRy2&v1=256:S8;
!!VRy3&v1=1:S5;
!!VRy3&v1=2:S4;
!!VRy3&v1=4:S5;
!!VRy3&v1=8:S1;
!!VRy3&v1=16:S1;
!!VRy3&v1=32:S3;
!!VRy3&v1=64:S4;
!!VRy3&v1=128:S3;
!!VRy3&v1=256:S1;
!!VRz8:S^请选择你想招募的兵种！（多项选择）^;
!!VRz1:S^一级未升级兵种！^;
!!VRz2:S^二级未升级兵种！^;
!!VRz3:S^三级未升级兵种！^;
!!VRz4:S^四级未升级兵种！^;
!!VRz5:S^五级未升级兵种！^;
!!VRz6:S^六级未升级兵种！^;
!!VRz7:S^七级未升级兵种！^;
!!IF:G0/5990/0/8/1/2/3/4/5/6/7;

!!DO5562/y2/y2/1:P1/y1/v5990/y3;



!?FU5562&x1=1;
!!UN:U98/x16/?y61; 统计城堡的数量存储于y1

!!VRv5900:C0/0/0/0/0/0/0;初始化v变量
!!DO5562/1/y61/1&y61>0:P2/x2/x16/x3;
!!UN:Tx16/0/0/?y20;
!!UN:Tx16/1/0/?y21;
!!UN:Tx16/2/0/?y22;
!!UN:Tx16/3/0/?y23;
!!UN:Tx16/4/0/?y24;
!!UN:Tx16/5/0/?y25;
!!UN:Tx16/6/0/?y26;
!!MA:Cy20/6/?y30;
!!MA:Cy21/6/?y31;
!!MA:Cy22/6/?y32;
!!MA:Cy23/6/?y33;
!!MA:Cy24/6/?y34;
!!MA:Cy25/6/?y35;
!!MA:Cy26/6/?y36;
!!MA:Cy26/x4/?y37;

!!VRy37:*v5906;计算所需资源
!!VRy40:Sv5900*y30;
!!VRy41:Sv5901*y31;
!!VRy42:Sv5902*y32;
!!VRy43:Sv5903*y33;
!!VRy44:Sv5904*y34;
!!VRy45:Sv5905*y35;
!!VRy46:Sv5906*y36;计算所需的金钱
!!VRy38:S0;
!!VRy38:+y40+y41+y42+y43+y44+y45+y46;
!!UN:N3/1/y20/1;
!!UN:N3/2/y21/1;
!!UN:N3/3/y22/1;
!!UN:N3/4/y23/1;
!!UN:N3/5/y24/1;
!!UN:N3/6/y25/1;
!!UN:N3/7/y26/1;


!!VRz8:S^恭喜你，你可以招募下列兵种了！前提是你有足够的资源！^;
!!VRz8&v5900>0:S^%Z8
一级兵种%Z1，数量：%V5900;^;
!!VRz8&v5901>0:S^%Z8
二级兵种%Z2，数量：%V5901;^;
!!VRz8&v5902>0:S^%Z8
三级兵种%Z3，数量：%V5902;^;
!!VRz8&vy13>0:S^%Z8
四级兵种%Z4，数量：%V5903;^;
!!VRz8&v5904>0:S^%Z8
五级兵种%Z5，数量：%V5904;^;
!!VRz8&v5905>0:S^%Z8
六级兵种%Z6，数量：%V5905;^;
!!VRz8&v5906>0:S^%Z8
七级兵种%Z7，数量：%V5906;^;
!!VRz8&y38>0:S^%Z8
共计费用：%Y38；^;
!!VRz8&y37>0/x4=1:S^%Z8
共需水银：%Y37；^;
!!VRz8&y37>0/x4=3:S^%Z8
共需硫磺：%Y37；^;
!!VRz8&y37>0/x4=4:S^%Z8
共需水晶：%Y37；^;
!!VRz8&y37>0/x4=5:S^%Z8
共需宝石：%Y37；^;---------------------------这个地方顺序不对，应该先跳出可招募的部队数量和需要资源，再问是否决定招募。
!!IF:Q2/6/y38/x4/y37/2^你想招募吗？^;
!!FU&-2:E;
!!IF:D5/8;
!!IF:E1/5;----------------------------------这里可跳出选择1/5、1/4、1/3、1/2、1/1的选择
!!OW:R-1/6/?y-10;
!!OW:R-1/x4/?y-11;
!!IF&y-10<y38:M^对不起，你金钱不够！^;
!!IF&y-11<y37:M^对不起，你资源不够！^;
!!FU|y-10<y38/y-11<y37:E;
!!HE-1&v5900>0:C2/y20/v5900/1;---------------给英雄增加一组新的怪物（类型、数量、空格）
!!HE-1&v5901>0:C2/y21/v5901/1;
!!HE-1&v5902>0:C2/y22/v5902/1;
!!HE-1&v5903>0:C2/y23/v5903/1;
!!HE-1&v5904>0:C2/y24/v5904/1;
!!HE-1&v5905>0:C2/y25/v5905/1;
!!HE-1&v5906>0:C2/y26/v5906/1;
!!VRy37:*-1;
!!VRy38:*-1;
!!OW:R-1/6/dy38;-----------------------------减去英雄消耗的金钱
!!OW:R-1/x4/dy37;-----------------------------减去英雄消耗的资源
!!DO5562/1/y61/1&y61>0:P3/x2/x16/x3;
!!HE-1:Id-10;               原为减少魔法值60，改为10
!!HE-1:Wd-800;              原为减少移动力800

!?FU5562&x1=2;
!!UN:U98/x3/x16/4;
!!CA4:O?y1;
!!FU&y1<>x2:E;

!!VRy21:Sv5990&1;
!!VRy22:Sv5990&2;
!!VRy23:Sv5990&4;
!!VRy24:Sv5990&8;
!!VRy25:Sv5990&16;
!!VRy26:Sv5990&32;
!!VRy27:Sv5990&64;

!!CA4&y21=1:M1/0/?y1/?y31; 只招未升级的兵种

!!CA4&y22=2:M1/1/?y2/?y32; 只招未升级的兵种

!!CA4&y23=4:M1/2/?y3/?y33; 只招未升级的兵种

!!CA4&y24=8:M1/3/?y4/?y34; 只招未升级的兵种

!!CA4&y25=16:M1/4/?y5/?y35; 只招未升级的兵种

!!CA4&y26=32:M1/5/?y6/?y36; 只招未升级的兵种

!!CA4&y27=64:M1/6/?y7/?y37; 只招未升级的兵种

!!VRy71&y31>0:Sy31;
!!VRy71&y1>0:Sy1;

!!VRy72&y32>0:Sy32;
!!VRy72&y2>0:Sy2;

!!VRy73&y33>0:Sy33;
!!VRy73&y3>0:Sy3;

!!VRy74&y34>0:Sy34;
!!VRy74&y4>0:Sy4;

!!VRy75&y35>0:Sy35;
!!VRy75&y5>0:Sy5;

!!VRy76&y36>0:Sy36;
!!VRy76&y6>0:Sy6;

!!VRy77&y37>0:Sy37;
!!VRy77&y7>0:Sy7;


!!VRv5900&y21=1:+y71;
!!VRv5901&y22=2:+y72;
!!VRv5902&y23=4:+y73;
!!VRv5903&y24=8:+y74;
!!VRv5904&y25=16:+y75;
!!VRv5905&y26=32:+y76;
!!VRv5906&y27=64:+y77;



!?FU5562&x1=3;
!!UN:U98/x3/x16/8;
!!CA8:O?y1;
!!FU&y1<>x2:E;

!!VRy21:Sv5990&1;
!!VRy22:Sv5990&2;
!!VRy23:Sv5990&4;
!!VRy24:Sv5990&8;
!!VRy25:Sv5990&16;
!!VRy26:Sv5990&32;
!!VRy27:Sv5990&64;

!!CA8&y21=1:M1/0/0/0;
!!CA8&y22=2:M1/1/0/0;
!!CA8&y23=4:M1/2/0/0;
!!CA8&y24=8:M1/3/0/0;
!!CA8&y25=16:M1/4/0/0;
!!CA8&y26=32:M1/5/0/0;
!!CA8&y27=64:M1/6/0/0;




ZVSE


****脚本制作：寻梦人****

***v变量：v5900---v5901***

***一键招募所有预定野外巢穴兵种****

***右键点击140 等级和英雄类型（文字）触发*****




!?CM2&1000;


!!CM:S?y11 I?y12;
!!FU|y11<>14/y12<>140:E;   原为运气图标140
!!HE-1:M2/?y4;        原为M9时空之门，改为M2透视之眼
!!IF&y4=0:M^对不起，你还没有学会透视之眼！不能使用一键招野外兵系统！^;
!!FU&y4=0:E;
!!HE-1:W?y13/1;
!!IF&y13<800:M^对不起，你的移动力不够！不能使用一键招野外兵系统！^;
!!FU&y13<800:E;
!!HE-1:I?y14/1;
!!IF&y14<20:M^对不起，你的魔法值不够！不能使用一键招野外兵系统！^;   原为魔法值60，改为20
!!FU&y14<20:E;


!!IF:M^欢迎使用一键招兵系统,这里可以让你很快的召唤自己野外巢穴的兵种!^;
!!HE-1:O?y1;
!!VRz-10:S^请选择你想招募的野外生产建筑类型！（单项选择）^;
!!VRz-1:S^云中城！^;
!!VRz-2:S^云殿！^;
!!VRz-3:S^比蒙巢穴！^;
!!VRz-4:S^木屋！^;
!!VRz-5:S^独眼洞穴！^;
!!VRz-6:S^黑龙穴！^;
!!VRz-7:S^冰雪之崖！^;
!!VRz-8:S^硫磺洞穴！^;
!!VRz-9:S^魔法森林！^;
!!IF:G1/1/1/-10/-1/-2/-3/-4/-5/-6/-7/-8/-9;
!!VRy2&v1=1:S8;
!!VRy2&v1=2:S44;
!!VRy2&v1=4:S1;
!!VRy2&v1=8:S15;
!!VRy2&v1=16:S9;
!!VRy2&v1=32:S41;
!!VRy2&v1=64:S62;
!!VRy2&v1=128:S65;
!!VRy2&v1=256:S64;
!!VRy3&v1=1:S5;
!!VRy3&v1=2:S5;
!!VRy3&v1=4:S4;
!!VRy3&v1=8:S4;
!!VRy3&v1=16:S4;
!!VRy3&v1=32:S3;
!!VRy3&v1=64:S1;
!!VRy3&v1=128:S3;
!!VRy3&v1=256:S5;

!!DO5562/y2/y2/1:P-1/y1/v5990/y3/y13/y14;



!?FU5562&x1=-1;
!!UN:U17/x16/?y61; 统计城堡的数量存储于y61

!!VRv5900:C0/0;初始化v变量
!!DO5562/1/y61/1&y61>0:P-2/x2/x16/x3;

!!MA:Cv5901/6/?y38;
!!MA:Cv5901/x4/?y37;

!!VRy37:*v5900;计算所需资源
!!VRy38:*v5900;
!!UN:N3/1/v5901/1;



!!VRz8:S^恭喜你，你可以招募下列兵种了！前提是你有足够的资源！^;
!!VRz8&v5900>0:S^%Z8
兵种%Z1，数量：%V5900;^;

!!VRz8&y38>0:S^%Z8
共计费用：%Y38；^;

!!VRz8&y37>0/x4=1:S^%Z8
共需水银：%Y37；^;
!!VRz8&y37>0/x4=3:S^%Z8
共需硫磺：%Y37；^;
!!VRz8&y37>0/x4=4:S^%Z8
共需水晶：%Y37；^;
!!VRz8&y37>0/x4=5:S^%Z8
共需宝石：%Y37；^;

!!IF:Q2/6/y38/x4/y37/2^你想招募吗？^;
!!FU&-2:E;
!!IF:D5/8;
!!IF:E1/5;
!!OW:R-1/6/?y-10;
!!OW:R-1/x4/?y-11;
!!IF&y-10<y38:M^对不起，你金钱不够！^;
!!IF&y-11<y37:M^对不起，你资源不够！^;
!!FU|y-10<y38/y-11<y37:E;
!!HE-1&v5900>0:C2/v5901/v5900/1;

!!VRy37:*-1;
!!VRy38:*-1;
!!OW:R-1/6/dy38;
!!OW:R-1/x4/dy37;
!!DO5562/1/y61/1&y61>0:P-3/x2/x16/x3;
!!VRx5:-800;                 原为移动力800
!!VRx6:-20;                  原为魔法值60,改为20
!!HE-1:Ix6/1;
!!HE-1:Wx5/1;

!?FU5562&x1=-2;
!!UN:U17/x3/x16/4;
!!DW4:O?y1;
!!FU&y1<>x2:E;
!!DW4:M0/?y3/?y4;
!!VRv5900:+y4;
!!VRv5901:Sy3;




!?FU5562&x1=-3;
!!UN:U17/x3/x16/4;
!!DW4:O?y1;
!!FU&y1<>x2:E;
!!DW4:M0/v5901/0;

兽哥哥

寻梦这个脚本是用到抗日英雄传那个地图的，根本不缺钱。

独孤求败

这个很重要的，请贤知版主不吝帮忙。@贤知有您

贤知有您

每个兵种还是细分几分之一.这得多麻烦啊.
其实一键招募是很难协调各种情况的.
远程招兵,普通地图来说就等于作弊了吧.

楼主可以自行写写脚本的.
比如如果钱不够的话,由高级到低级招完为止.
这都是些数字计算,没什么ERM技术的.楼主应该可以应付.

路人狠甲

新人报道 多多指教

独孤求败

贤知有您 发表于 2015-12-23 10:13
每个兵种还是细分几分之一.这得多麻烦啊.
其实一键招募是很难协调各种情况的.
远程招兵,普通地图来说就等 ...

作弊一点没什么吧，只要我们玩得开心。电脑难度系数也是作弊的一种吧。
我搞不定的，中间要跳出好几个对话框，这是难点！

独孤求败

贤知有您 发表于 2015-12-23 10:13
每个兵种还是细分几分之一.这得多麻烦啊.
其实一键招募是很难协调各种情况的.
远程招兵,普通地图来说就等 ...

贤知老板，不要鄙视体力劳动的计算嘛，我们这种占人口9成体验型玩家就是这样的，过不去了才会叫苦！要帮助我把这个计算出来嘛……

独孤求败

贤知有您 发表于 2015-12-23 10:13
每个兵种还是细分几分之一.这得多麻烦啊.
其实一键招募是很难协调各种情况的.
远程招兵,普通地图来说就等 ...

好可怜啊，这个脚本也没有人帮忙，可是我很需要啊！贤知老板,拜托您了。还有另外那个预备役的脚本！

贤知有您

贤知老板跑路了,贤知工仔还在奋斗,为社会注意事业作贡献.

楼主可以 @XEricSin 试试. 实在不好意思了.

XEricSin

还是太麻烦。要改城堡扣兵。要改资源计算。
建议楼主直接把金钱限制删了。钱不够就欠着。
!!IF&y-10<y38:M^对不起，你金钱不够！^;
!!IF&y-11<y37:M^对不起，你资源不够！^;
!!FU|y-10<y38/y-11<y37:E;

独孤求败

XEricSin 发表于 2016-2-25 15:13
还是太麻烦。要改城堡扣兵。要改资源计算。
建议楼主直接把金钱限制删了。钱不够就欠着。
!!IF&y-10

我赶紧试一下，可以类似银行贷款那样吗？

独孤求败

XEricSin 发表于 2016-2-25 15:13
还是太麻烦。要改城堡扣兵。要改资源计算。
建议楼主直接把金钱限制删了。钱不够就欠着。
!!IF&y-10

基本解决，谢谢XEricsin大神！！我改为以下。
!!IF&y-10<0:M^对不起，你金钱欠款没结清！^;
!!IF&y-11<0:M^对不起，你资源欠款没结清！^;
!!FU|y-10<0/y-11<0:E;

hutustone

看了你这个我才知道一键招兵是怎么用的              

游庵

hutustone 发表于 2020-3-16 13:08
看了你这个我才知道一键招兵是怎么用的

怎么用的？看完了我都没看懂....

水流行险

XEricSin 发表于 2016-2-25 15:13
还是太麻烦。要改城堡扣兵。要改资源计算。
建议楼主直接把金钱限制删了。钱不够就欠着。
!!IF&y-10

这里如何改为只招高级兵种？

XEricSin

水流行险 发表于 2021-1-17 00:43
这里如何改为只招高级兵种？

默认就是吧。你试试吧，如果有问题可以截个图，代码读着很累的。

无敌神猫4号

欠着应该不行吧？那相当于借兵了，那还怎么打？尤其是如果是200%难度的时候，这个功能开了，限制电脑后去获取资源的方法也不行了。很多功能是相互的，一定要考虑功能对电脑和对手是不是平等的。

水流行险

XEricSin 发表于 2021-1-17 03:39
默认就是吧。你试试吧，如果有问题可以截个图，代码读着很累的。

默认是低级兵种，怎么改成高级兵种？

!!CA4&y21=1:M1/0/?y1/?y31; 只招未升级的兵种

!!CA4&y22=2:M1/1/?y2/?y32; 只招未升级的兵种

!!CA4&y23=4:M1/2/?y3/?y33; 只招未升级的兵种

!!CA4&y24=8:M1/3/?y4/?y34; 只招未升级的兵种

!!CA4&y25=16:M1/4/?y5/?y35; 只招未升级的兵种

!!CA4&y26=32:M1/5/?y6/?y36; 只招未升级的兵种

!!CA4&y27=64:M1/6/?y7/?y37; 只招未升级的兵种

XEricSin

水流行险 发表于 2021-1-17 11:37
默认是低级兵种，怎么改成高级兵种？

!!CA4&y21=1:M1/0/?y1/?y31; 只招未升级的兵种

我是想你到游戏里实地试试，顺便截个图。

你这直接上代码了。你吧位置都找到了，就对着erm帮助看吧。

水流行险

XEricSin 发表于 2021-1-17 13:03
我是想你到游戏里实地试试，顺便截个图。

你这直接上代码了。你吧位置都找到了，就对着erm帮助看吧。

我就是以前的独孤求败。账号用不了，换了这个。
这个换成招募高级兵种，要检查是否有高级建筑物的，有些不一样。快帮忙一下！