关于城镇未招募的部队参加城镇保卫战的预备役脚本

独孤求败

贤知有您 发表于 2015-12-22 20:57
我们都喜欢偷城偷电脑城镇的兵.
我们又不喜欢电脑偷我们的城,特别在没有资金招募时.
我觉得没钱招募就是 ...

老板，很烦躁，出去的时候老是觉得家里不安全，都玩不下去了，麻烦您指导一下如何用！#ba实现梦想

XEricSin

1.建议楼主充分合理使用银行贷款功能。

2、我感觉楼主并没有理解贤知大人的意思。

独孤求败

定期，这个很需要，涉及到我的安全感和难度挑战。好可怜，由于没有安全感，已经两个月没有打开wog了？@fly123 @贤知有您 @gigichart @神奇的卡片 @灰狼王子

独孤求败

这个脚本关系到社会的维稳，很是重要的，贤知新老板！！一定要帮忙解决！！@贤知有您 @XEricSin

独孤求败

自己顶起顶起，为寻找安全的后防线和完美的攻城掠地战！

独孤求败

要是有这个ba脚本，一来后防线安稳，二来战役变得剧烈

独孤求败

自己支持自己。，希望能有人指点

独孤求败

@贤知有您 @沧海一粟 沧海老爹，关照我都四五年了，这个脚本还是要您出马🐎

独孤求败

继续要求援助交际

XEricSin

开战时突然增加很多兵力肯定是坑电脑的。如果电脑看城里人多是不会自讨没趣的。我想了下，改成这样，对于平衡可能会好点。不过还是可以在小规模战中赖死电脑。如果楼主还是想弄成自己那样，就自己改相关部分吧。

ZVSE
**守城方每回合可以紧急征召一队城里未招募的士兵，战斗时鼠标点击主箭塔下方
**征召需要花钱，但是战后不保留部队
**v5242 current round summon done
**FU29423-29425

!?BR&v997>-1;
!!VRv5242:S0;

战斗时鼠标点击主箭塔下方，CM触发询问。
!?CM4&v5242=0;
!!CM:A?y1/?y2;
!!FU|y1<610/y2<340/y2>430:E;

检测是否是攻城 防守方是否AI
如果不是攻城则退
如果是AI则退
如果是人则询问是否买部队
!!BA:S?y3 Od/?y4;
!!OW:Iy4/?y5;
!!FU&y3=0:E;
!!FU&y5=1:E;

//setup conversation box//
!!OW:Ry4/0/?y10;
!!OW:Ry4/1/?y11;
!!OW:Ry4/2/?y12;
!!OW:Ry4/3/?y13;
!!OW:Ry4/4/?y14;
!!OW:Ry4/5/?y15;
!!OW:Ry4/6/?y16;
!!VRz1:S^选取你要紧急征召的部队，每回合只能招一支部队，战后不保留。
你当前有：{%Y16黄金}，{%Y10木材}，{%Y12矿石}，
{%Y11水银}，{%Y13硫磺}，{%Y14水晶}，{%Y15宝石}^;
!!VRz2:S^只招未升级生物^;
!!VRz3:S^只招一个生物^;
!!DO29423/0/6/1:P; //setup creatures available
!!IF:G0/1/0/1/2/3/4/5/6/7/8/9/10;

!!VRy8:Sv1&1; //non-upgraded?
!!VRy9:Sv1&2; //single recruit
!!VRy10:Sv1&4; //check single creatures
!!VRy11:Sv1&8;
!!VRy12:Sv1&16;
!!VRy13:Sv1&32;
!!VRy14:Sv1&64;
!!VRy15:Sv1&128;
!!VRy16:Sv1&256;

//从高级到低级检测要招募的生物, 检测费用,决定招募数量，扣除资源和生物

!!CA998:T?y17;
!!if&y16>0:;
  !!CA998:B3/43;
  !!VRy18:S0;
  !!VRy18&1:S1-y8;
  !!UN:Ty17/6/y18/?y26; //monster type
  !!FU29424:Py26/6/y9; //buy y26 /level 6/single recruit
  !!FU:E;
!!en:;
!!if&y15>0:;
  !!CA998:B3/42;
  !!VRy18:S0;
  !!VRy18&1:S1-y8;
  !!UN:Ty17/5/y18/?y25; //monster type
  !!FU29424:Py25/5/y9; //buy y25
  !!FU:E;
!!en:;
!!if&y14>0:;
  !!CA998:B3/41;
  !!VRy18:S0;
  !!VRy18&1:S1-y8;
  !!UN:Ty17/4/y18/?y24; //monster type
  !!FU29424:Py24/4/y9; //buy y24
  !!FU:E;
!!en:;
!!if&y13>0:;
  !!CA998:B3/40;
  !!VRy18:S0;
  !!VRy18&1:S1-y8;
  !!UN:Ty17/3/y18/?y23; //monster type
  !!FU29424:Py23/3/y9; //buy y23
  !!FU:E;
!!en:;
!!if&y12>0:;
  !!CA998:B3/39;
  !!VRy18:S0;
  !!VRy18&1:S1-y8;
  !!UN:Ty17/2/y18/?y22; //monster type
  !!FU29424:Py22/2/y9; //buy y22
  !!FU:E;
!!en:;
!!if&y11>0:;
  !!CA998:B3/38;
  !!VRy18:S0;
  !!VRy18&1:S1-y8;
  !!UN:Ty17/1/y18/?y21; //monster type
  !!FU29424:Py21/1/y9; //buy y21
  !!FU:E;
!!en:;
!!if&y10>0:;
  !!CA998:B3/37;
  !!VRy18:S0;
  !!VRy18&1:S1-y8;
  !!UN:Ty17/0/y18/?y20; //monster type
  !!FU29424:Py20/0/y9; //buy y20
  !!FU:E;
!!en:;


!?FU29423; //编辑对话框生物信息
!!VRy6:S-1;
!!VRy7:S-1;
!!CA998:M1/x16/?y6/?y7;
!!VRy1:Sx16+1;
!!VRy2:Sx16+4;
!!VRzy2:S^招%Y1级生物，共%Y6个，未升级^;
!!VRzy2&y7>0:S^招%Y1级生物，共%Y7个，已升级^;


!?FU29424; //征召怪物编号 x1/等级 x2/x3=是否单招(0 or 2)
!!CA998:O?y4;
!!OW:Ry4/0/?y20; //current resources
!!OW:Ry4/1/?y21;
!!OW:Ry4/2/?y22;
!!OW:Ry4/3/?y23;
!!OW:Ry4/4/?y24;
!!OW:Ry4/5/?y25;
!!OW:Ry4/6/?y26;
!!VRy30:S-1;
!!VRy31:S-1;
!!VRy32:S-1;
!!VRy33:S-1;
!!VRy34:S-1;
!!VRy35:S-1;
!!MA:Cx1/0/?y30; //required resources
!!VRy8&y30>0:S0; //resource id
!!MA&y30=0:Cx1/1/?y31;
!!VRy8&y31>0:S1; //resource id
!!MA&y31=0:Cx1/2/?y32;
!!VRy8&y32>0:S2; //resource id
!!MA&y32=0:Cx1/3/?y33;
!!VRy8&y33>0:S3; //resource id
!!MA&y33=0:Cx1/4/?y34;
!!VRy8&y34>0:S4; //resource id
!!MA&y34=0:Cx1/5/?y35;
!!VRy8&y35>0:S5; //resource id
!!MA:Cx1/6/?y36;

!!VRy9:S30+y8; //index of y variable holding monster resource cost
!!VRy10:S20+y8; //index of y variable holding the resource stock
!!VRy11&yy9>0:Syy10:yy9;//quantity of recruits by resource
!!VRy11&yy9<=0:S10000000;
!!VRy1&y36>0:Sy26:y36; //quantity of recruits by gold
!!VRy1&y36<=0:S10000000;
!!CA998:M1/x2/?y12/?y13; //current reserve
! !IF:M^%Y1 %Y11 %Y12 %Y13^;

!!VRy1&y1>y11:Sy11; //min recruits by resources
!!VRy1&y13<=y12/y1>y12:Sy12; //min recruits by reserve
!!VRy1&y13>y12/y1>y13:Sy13; //min recruits by reserve UP
!!VRy1&x3>0/y1>1:S1; //min recruits by single recruit
!!FU&y1=0:E; //end if no available

!!VRy2:Sy36*y1*-1;  //gold cost of recruits
!!VRy3:Syy9*y1*-1; //resources cost
! !IF:M^no=%Y1 g=%Y2 r=%Y3^;

!!OW:Ry4/6/dy2; //deduct resources
!!OW:Ry4/y8/dy3;
!!VRy-1:S0-y1;
!!CA998&y13<=y12:M1/x2/dy-1/d; //reduce reserve
!!CA998&y13>y12:M1/x2/d/dy-1; //reduce reserve UP
!!DO29425/0/8/1:Px1/y1;//place on field


!?FU29425; //召唤怪物 x1=type x2=quantity
!!VRy10&x16=0:S31;
!!VRy10&x16=1:S167;
!!VRy10&x16=2:S65;
!!VRy10&x16=3:S133;
!!VRy10&x16=4:S99;
!!VRy10&x16=5:S47;
!!VRy10&x16=6:S149;
!!VRy10&x16=7:S81;
!!VRy10&x16=8:S115;
!!VRy11:Sy10-1;

!!MA:Xx1/?y1;
!!VRy1:&1;//double wide?
!!BU:Oy10/?y2 Ey10/?y3; //this grid occupied?
!!VRy6:Sy2 &4; //quick sand
!!VRy7:Sy2 &8; //mine
!!BU:Oy11/?y4 Ey11/?y5; //prev grid
!!VRy8:Sy4 &4;
!!VRy9:Sy4 &8;

!!if|y2=0/y6=4/y7=8:; //no obstacle
  !!FU&y3>-1:E; //end if occupied
  !!if&y1=0:; //single wide
    !!BU:Sx1/x2/y10/1/-1/1;
    !!VRv5242:S1;
    !!VRx16:S1000000;
  !!el:; //double wide
    !!if|y4=0/y8=4/y9=8:;
      !!FU&y5>-1:E; //end if occupied
      !!BU:Sx1/x2/y10/1/-1/1;summon
      !!VRv5242:S1;
      !!VRx16:S1000000;
    !!en:;
  !!en:;
!!en:;

独孤求败

XEricSin 发表于 2016-3-14 21:06
开战时突然增加很多兵力肯定是坑电脑的。如果电脑看城里人多是不会自讨没趣的。我想了下，改成这样，对于平 ...

我曾经很失望，终于见到曙光！赶紧测试！

独孤求败

XEricSin 发表于 2016-3-14 21:06
开战时突然增加很多兵力肯定是坑电脑的。如果电脑看城里人多是不会自讨没趣的。我想了下，改成这样，对于平 ...

招募出来色部队在战场上什么地方呢？哪行脚本阐述？

XEricSin

独孤求败 发表于 2016-3-18 17:59
招募出来色部队在战场上什么地方呢？哪行脚本阐述？

!?FU29425; //召唤怪物 x1=type x2=quantity
!!VRy10&x16=0:S31;
!!VRy10&x16=1:S167;
!!VRy10&x16=2:S65;
!!VRy10&x16=3:S133;
!!VRy10&x16=4:S99;
!!VRy10&x16=5:S47;
!!VRy10&x16=6:S149;
!!VRy10&x16=7:S81;
!!VRy10&x16=8:S115;

这9个位置挨个检测，如果全部占用，则招不出来。

独孤求败

XEricSin 发表于 2016-3-18 20:10
!?FU29425; //召唤怪物 x1=type x2=quantity
!!VRy10&x16=0:S31;
!!VRy10&x16=1:S167;

脚本还是很难。无法下手修改。
求1.攻城战中增加防守方的兵力，同时无需资源。在开始的脚本处去掉ai方检测即可。
2.统计城镇目前的可招募兵力，分出低级和高级，然后选择高级，这里有难度。如果可能，定义函数1／2，2／3，全部三种情况随机选择。
3.放置最多七个部队在战场上的位置，现在的脚本已经实现。
4.部队战斗后消失，目前已经实现。同时城镇可招募部队按战后伤亡比例减少，目前没有实现。
XEricSin大神，麻烦再高抬贵手，再动一点一点好吗？

XEricSin

这里根据对话框选择，放置怪物，我是设定的只能选一队怪，所以结尾有FU：E，如果想招7队，那么就把每段的FU：E删掉。
!!if&y16>0:;
  !!CA998:B3/43;
  !!VRy18:S0;
  !!VRy18&1:S1-y8;
  !!UN:Ty17/6/y18/?y26; //monster type
  !!FU29424:Py26/6/y9; //buy y26 /level 6/single recruit
  !!FU:E;
!!en:;

这7行是检测当前资源的，把y20到y26赋一个很大的值就类似征召不受资源限制。
!!OW:Ry4/0/?y20; //current resources
!!OW:Ry4/1/?y21;
!!OW:Ry4/2/?y22;
!!OW:Ry4/3/?y23;
!!OW:Ry4/4/?y24;
!!OW:Ry4/5/?y25;
!!OW:Ry4/6/?y26;

这两行是扣资源的，删了就不扣资源
!!OW:Ry4/6/dy2; //deduct resources
!!OW:Ry4/y8/dy3;

按战损比例扣兵太麻烦了。我也不知道在哪里查战损。

独孤求败

XEricSin 发表于 2016-3-19 22:22
这里根据对话框选择，放置怪物，我是设定的只能选一队怪，所以结尾有FU：E，如果想招7队，那么就把每段的FU ...

明白一些了，哪要战斗开始自动放置呢？

独孤求败

战损扣兵如何办？@fly123 @克招 @沧海一粟

独孤求败

XEricSin 发表于 2016-3-19 22:22
这里根据对话框选择，放置怪物，我是设定的只能选一队怪，所以结尾有FU：E，如果想招7队，那么就把每段的FU ...

能不能考虑战斗开始的兵力生命值和战斗结束的生命值作为比例，或者考虑对手或己方的英雄的经验值变化情况来确定，然后重置城镇的可招募部队数量。那这样吧，一旦守城方失败，城镇可招募兵重设为0，这个不难吧！

XEricSin

战斗开始设置一般是用!?BF
需要替换掉几排CM的

XEricSin

独孤求败 发表于 2016-3-19 23:27
能不能考虑战斗开始的兵力生命值和战斗结束的生命值作为比例，或者考虑对手或己方的英雄的经验值变化情况 ...

你死的兵不一定都是城里自动招的
失守了屯兵就没了，你不是坑电脑吗，这个坑人的事情我不做，坑电脑也不行