脚本求助

regeditxie

ZVSE

**格鲁带领的射手可以9连击（双击再叠加），只用三行字不用一个固定变量的。
!?BG&1000;
!!BG:Q?y1 N?y2 E?y3;
!!BHy1:N?y4;
!!FU9999993&y4=148:Py2/y3/9;


***以下直接复制贤知有你代码，只复制一次，类似增加射击次数的功能可无限重复调用，不用再复制。
!?FU9999993;
**A堆栈射击B堆栈且产生伤害(箭塔射击除外)
**x1=堆栈号
**x2=目标堆栈号
**x3=射击次数(需>0)
!!FU|x1<0/x1>41/x2<0/x2>41/x1=x2/x3<1:E;[#0]
!!BMx1:T?y1 N?y2;     [#1]
!!BMx2:T?y11 N?y12;
!!FU|y1<0/y11<0/y2<1/y12<1/y1=149/y11=149:E;
!!BMx1:F?i U3/?j;     [标志与弹药]
!!VRi:&4;
!!FU|i<>4/j<1:E;      [非箭手或无弹药(若无射击动作会崩溃)]
*!FU&y1>144/y1<150:E; [排除战争机器]
!!UN:C6919200/4/?y20; [内存]
!!VRy31:Sx1 *1352 +21708 +y20;[A方内存地址]
!!VRy41:Sx2 *1352 +21708 +y20;[B方内存地址]
!!SN:E4453920/2/y31/y41;      [射击且伤害]
!!BMx1:U3/d-1;                [减少弹药]
!!VRx3:-1;
!!SN&x3>0:G0;                 [循环代码]
以上脚本能实现格鲁带领的射手射9次，但不知道为什么，如果你点兵种休息或防御，兵种还是会强制射击，强制射击倒没什么不足，主要是有时候你点休息或防御时竟然会射自己人，不知道哪里错了，能不能改正，这个是我在WOG论坛上看见的。的确可以射五箭，美中不足就是点休息会射自己人。如何修改？

沧海一粟

!?BG&1000;
!!BG:Q?y1 N?y2 E?y3 A?y5;
!!BHy1:N?y4;
!!FU9999993&y4=148/y5=7:Py2/y3/9;    7=动作种类为射击时
................................

regeditxie

沧海一粟 发表于 2015-4-22 00:18
!?BG&1000;
!!BG:Q?y1 N?y2 E?y3 A?y5;
!!BHy1:N?y4;

解决了，谢了沧海大神