求教 看到编好的 erm代码 如何导入script .erm文件中？

轩辕云剑

在别的论坛看到如下代码  但是不会导入到erm 的文件中  求教
ZVSE

ERMS_ScriptDate=6.3(March).2005

_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!

ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918

** Dungeon of the Dragonmaster
** Wogify Name: script53.erm
** This strengthens all Dragon Utopias an a map. AI will visit normal DU but gets some extra bonuses.

** Requires ERM v2.80 or higher
** Version: 1.2
** Updated: May 12. 2004
** Made by Hermann the Weird
** Idea by Janus

** To use this code, copy it (from ZVSE to the end) into a global event, set day of first occurence
** to something after 600.

** v-Variables used: v8033, v8035-v8043
** Functions: 20001-20003
** Strings: z455-461

** Uses FU709 from script01 (map rules) to determine the strength of the DOTDM.
** Compatible with script57 (neutral units).

** This script will only give enabled artifacts (Map or WoG options).
** If all artifacts of one level are disabled, artifacts of other random levels will be given.


***** Check for WoGify option *****
!#UN:P53/?v1;

***** Setting hint text *****
!#VRz455&v1=1:Sz153000;
!#VRz456&v1=1:Sz153001;
!#HT25/-1&v1=1:T455;

***** Section for human attacker *****
!?OB25&1000;
!!UN:P53/?y-1; [Check if enabled in WoG options]
!!FU&y-1=0:E; [Exit if it isn't]

!!VRv100:S1; [Activate Neutral Units]

!!HE-1:P?v8040/?v8041/?v8042; [Get position]
!!OBv8040/v8041/v8042:S; [Disable normal DU]
!!HE-1:O?v8043; [Checks hero's owner before battle - used to check if battle won]

***** Ask player for battle *****
!!IF:Q1/21/132/2/z153002;

!!FU&-1:E; [Exit if no answered]

!!VRv8033:S0 R3 +1; [Generate random number as classification for the strength of the Bank]

!!FU709:P15; [Check for map rule 15]
!!VRy-7&3:Sv8033 +9 *9999; [Translate to number of Dragons if rule 15 selected]
!!VRy-7&-3:Sv8033 *9999; [Translate to number of Dragons if rule 15 not selected]

!!VRv8033:+1; [Number of relics]

!!HE-1:Tv8040/v8041/v8042/132/y-7; [Provoke battle]

!!HE-1:O?y-2; [Checks hero's owner after battle - used to check if battle won]
!!FU&v8043<>y-2:E; [Exit if battle lost]

!!DO20001/1/v8033/1:P8035/457; [Loop for generating relics]

!!DO20002/1/v8033/1:P8035; [Loop for passing relics to hero]

***** Displaying relics *****
!!IF&v8033=2:Q1/8/v8035/8/v8036/1/z153003;
!!IF&v8033=3:Q1/8/v8035/8/v8036/8/v8037/1/z153004;
!!IF&v8033=4:N8/v8035/8/v8036/8/v8037/8/v8038;
!!IF&v8033=4:N^%Z153005^;
!!IF&v8033=5:N8/v8035/8/v8036/8/v8037/8/v8038/8/v8039;
!!IF&v8033=5:N^%Z153006^;

!!DO20003/1/3/1:P8035/457; [Loop for minor/major artifacts]

***** Displaying and passing minor/major artifacts *****

!!UN:P900/?y-3; [Check for Stack Experience]
!!UN:P143/?y-4; [Check for New Artifacts]
!!UN:P234/?y-5; [Check for Warlord's Banner banning]

***** If Stack Experience and New Arts enabled *****
!!IF&y-3=1/y-4=1/y-5=0:N8/v8035/8/v8036/8/v8037/8/156;
!!IF&y-3=1/y-4=1/y-5=0:N^%Z153007^;
!!HE-1&y-3=1/y-4=1/y-5=0:A4/156;

***** If Stack Experience and New Arts not enabled *****
!!IF|y-3<>1/y-4<>1/y-5<>0:Q1/8/v8035/8/v8036/8/v8037/1/z153008;

!!HE-1:A4/v8035;
!!HE-1:A4/v8036;
!!HE-1:A4/v8037;


***** Preparing variables for money or experience *****
!!VRv8033:*500000;
!!VRy-8:Sv8033;
!!VRy-8::2;

***** Asking for money or experience *****
!!IF:Q1/6/v8033/17/y-8/7/z153009;

***** Displaying and passing money *****
!!IF&1:Q1/6/v8033/1/z153010;
!!OW&1:R-1/6/dv8033;

***** Displaying and passing experience *****
!!IF&-1:Q1/17/y-8/1/z153011;
!!HE-1&-1:Edy-8;

!!IF:M1/z153012;

***** End of section for human attacker *****


***** Section for AI attacker *****

!?OB25&-1000;
!!UN:P53/?y-1; [Check if enabled in WoG options]
!!FU&y-1=0:E; [Exit if it isn't]

!!HE-1:P?v8040/?v8041/?v8042; [Get position]
!!HE-1:O?v8043; [Checks hero's owner before battle - used to check if battle won]

!$OB25&-1000; [Post visit trigger]
!!UN:P53/?y-1; [Check if enabled in WoG options]
!!FU&y-1=0:E; [Exit if it isn't]

!!HE-1:O?y-2; [Checks hero's owner after battle - used to check if battle won]
!!FU&v8043<>y-2:E; [Exit if battle lost]

!!HE-1:Fd5/d5/d5/d5; [AI receives additional primary skills]
!!HE-1:Ed15000; [AI receives additional experience]
!!OW:R-1/6/d30000; [AI receives additional gold]

***** End of section for AI attacker *****


********** Function Section **********

!?FU20001; [Function for generating relics]

!!UN:J6/16/?y1; [Generates relic]
!!VRvx1:Sy1; [Store result in v-variable for use outside function]
!!UN:N0/zx2/y1; [Look up artifacts name]
!!VRx1:+1; [Increase v-var index]
!!VRx2:+1; [Increase z-var index]


!?FU20002; [Function for passing relics to hero]

!!HE-1:A4/vx1; [Passes relics to hero]
!!VRx1:+1; [Increase v-var index]


!?FU20003; [Function for generating 3 minor/major]

!!UN:J6/12/?y1; [Generates minor/major]
!!VRvx1:Sy1; [Store result in v-variable for use outside function]
!!UN:N0/zx2/y1; [Look up artifacts name]
!!VRx1:+1; [Increase v-var index]
!!VRx2:+1; [Increase z-var index]

轩辕云剑

在论坛中下载的erm  对比了下  貌似是格式  应该如何导入？

贤知有您

直接到游戏的官方脚本文件夹下(某MOD的DATA/S文件夹)
随便找一个后缀为 *.ERM的脚本文件.
复制出来,用文本编辑器打开清空,并把你的脚本放进去即可.
更改脚本文件的名字(WOG是需要SCRIPT开头+2个数字格式,ERA的脚本任意不重复即可)
ERM脚本文件的开头一定是 ZVSE 这个标识.

轩辕云剑

贤知有您 发表于 2014-12-9 09:20
直接到游戏的官方脚本文件夹下(某MOD的DATA/S文件夹)
随便找一个后缀为 *.ERM的脚本文件.
复制出来,用文 ...

你好  还是同一个问题   我玩的是   wog2.58f  我在  data/s  目录下 打开任意一个rem文件   看到的是  下载的erm文件打开后的样子如下图    而我自己打开这样的文件然后复制帖子中的代码粘贴后   是下图  自己粘贴的样子   貌似自己复制粘贴的无法生效   

贤知有您

貌似这个脚本时改 龙之国的脚本.
也就是改原来script53.erm 脚本.
你应该直接改为 script53.erm并覆盖原文件 (记得备份).
然后开启ERM菜单的相关选项再测试.

轩辕云剑

麻烦帮我看一下  我把下载来的   erm的压缩包和  自己复制粘贴的erm压缩包都上传了    确实我复制别人的代码  复制粘贴进文件之后  就是无法生效      实在是形容不出来  只好发文件上来  麻烦帮忙看下 多谢  

贤知有您

看起来这个脚本没啥问题.
你已把这个自己复制的脚本, 改名为 script53.erm 并覆盖了原来的吗?

轩辕云剑

覆盖了原来的53无法起效
不知道是我用的编辑模式不对还是  别人做好的erm 在我的机子上  如果只用 文本模式打开会发现其中代码没有分段 代码之间没有空格  而我自己复制粘贴的有分行