哎，等了好久了。脚本之神圣复活(已解决)

水手

寻梦大大退隐一段时间，一直比较关注他的这个好脚本。但不是通用的，不能加在事件里。话说神圣复活BT图很需要啊，哪位大大出手编辑一下成为通用的呢？创作仍属寻梦人，修改者也注明。不过我也搞不清这样做是不是违反了论坛的宗旨，应该没有吧。


ZVSE
************************************
!#VRz703:S^{元老殿堂}^;
!#OB35/52/1:Hz703;
!#VRv3800:C0/-1;
存储英雄编号
!?OB35/52/1&1000/v3800=0;这里可以改为定义好的建筑,目前以坐标代替
!!HE-1:N?v1 B0/?z1;
!!IF:Q2^你好,{%Z1},这里是{元老殿堂},我是{寻梦人},能够碰到我真是幸运,我可以教你一项很变态的技能,每次当你施法的时候,你的部队只要没有全部阵亡,我都可以让他们起死回生,等级越高回复越快,最高50%!你想要这个技能吗?^;
!!IF&-2:M^这样变态的技能都不要,太可惜了!^;
!!FU&-2:E;
!!IF&2:M^恭喜你!{%Z1}你选择拥有了{神 圣 复 活}秘技!^;
!!VRv3800:S1;不能重复访问
!!VRv3801:Sv1;定义英雄编号


!?BA0;
!!BA:H0/?v9555 H1/v9560;

************************************************

!?BG&1000;
!!FU&v997<1:E;
!!BG:A?y3 Q?y2;
!!BU:T?y-1;
!!FU&y-1=1:E;
!!FU|y3<>1:E;
!!DO999/0/20/1&v9555=v3801/y2=0:P1/v9555;  
!!DO999/21/40/1&v9560=v3801/v9560>-1/y2=1:P1/v9560;




!?FU999&x1=1;

!!BMx16:N?y7 B?y4 T?y-15;
!!FU|y7>=y4/y7<1/y4<1:E;
!!HEx2:Ed/?y-10;
!!VRy-20&y-10<10:S10;
!!VRy-20&y-10>9/y-10<20:S9;
!!VRy-20&y-10>19/y-10<30:S8;
!!VRy-20&y-10>29/y-10<40:S7;
!!VRy-20&y-10>39/y-10<50:S6;
!!VRy-20&y-10>49/y-10<60:S5;
!!VRy-20&y-10>59/y-10<70:S4;
!!VRy-20&y-10>69/y-10<80:S3;
!!VRy-20&y-10>79:S2;
!!VRy5:Sy4-y7;
!!VRy6:Sy5:y-20;
!!VRy6&y6<1:S1;
!!BMx16:Ndy6 L0 V4;
!!UN:N3/-1/y-15/1;
!!VRz10:S^{秘 技 神 圣 复 活}让{%Y6}  个 {%Z-1}  起 死 回 生^;
!!BU:Mz10 R;

兽哥哥

这个是二期元老殿堂的脚本吧？应该是通用的吧？就算不是也很容易修改。

水手

兽哥哥 发表于 2013-10-16 13:42
这个是二期元老殿堂的脚本吧？应该是通用的吧？就算不是也很容易修改。

额，这个应该是要访问特定建筑才能生效的，估计直接添加事件不行。多好的ERM啊，我感觉修改起来应该也比较容易，只是咱这ERM水平太低，没法弄

沧海一粟

水手 发表于 2013-10-16 23:58
额，这个应该是要访问特定建筑才能生效的，估计直接添加事件不行。多好的ERM啊，我感觉修改起来应该也比 ...

你把!?BA0;前面的文字全部删除，后面两处：v9555=v3801换成v9555>-1，v9560=v3801换成v9560>-1应该就行了。

水手

沧海一粟 发表于 2013-10-17 01:06
你把!?BA0;前面的文字全部删除，后面两处：v9555=v3801换成v9555>-1，v9560=v3801换成v9560>-1应该就行了 ...

感谢苍老师指点，我回家试试哈！，，

水手

额，我也有这个疑问，这样的话电脑也能拥有这个技能了吧。试了一下，自己的确能行了，还没碰到电脑英雄

沧海一粟

水手 发表于 2013-10-18 12:21
额，我也有这个疑问，这样的话电脑也能拥有这个技能了吧。试了一下，自己的确能行了，还没碰到电脑英雄

是所有英雄有效啊，你想怎么改都可以的

1. !?BG&1000;
   
2. !!FU&v997<1:E;
   
3. !!BG:A?y3 Q?y2;
   
4. !!BU:T?y-1;
   
5. !!FU&y-1=1:E;
   
6. !!FU|y3<>1:E;
   
7. !!DO999/0/20/1&v9555>-1/y2=0:P1/v9555;   **如想指定英雄有效，直接换成编号，如殴灵v9555>-1换成v9555=0
   
8. !!DO999/21/40/1&v9560>-1/y2=1:P1/v9560; **这句同上一起改，如v9560>-1改成v9560=0
   
9. 
   
10. !?FU999&x1=1;
    
11. !!HEx2:O?y1;
    
12. !!OW:Iy1/?y2;
    
13. !!FU&y2=1:E;  **这里=1表示电脑英雄退出，如=0表示玩家英雄退出，即电脑英雄才有效，然后接原来的

复制代码

水手

沧海一粟 发表于 2013-10-18 22:38
是所有英雄有效啊，你想怎么改都可以的

请再帮我看个脚本（抄自永远的精灵光复脚本）：

超级复活：
ZVSE


!?BA0;
!!BA:H0/?v9555 H1/?v9560;
!!HE148:Fd/d/?v108/d;


!?BG0&1000;
!!BG:A?v101 D?v102 E?v103 H?v104 N?v105 Q?v106 S?v107;   
!!FU220&v104=148/v101=1/v107=38/v103>=0/v103<=41:Pv103/v108;超级复活 x1目标堆栈 x2英雄力量                 



!?FU220;
!!FU|x1<0/x1>41:E;目标堆栈不存在退出
!!BMx1:N?x5 B?x6;目标堆栈原始数量和现存数量
!!FU|x5<1/x6<1/x5>=x6:E;如果全部阵亡或没有伤亡退出
!!BMx1:H?x7 T?y10; 目标堆栈的生命值
!!VRx8:Sx6-x5;阵亡数量
!!VRx9:Sx2 *500;恢复的生命值
!!VRx9::x7;算出恢复的数量
!!VRy1:Sx2 *50 +160;算出正常重生值
!!VRy1::x7;算出正常恢复数量
!!VRy1:+1;恢复数量加1
!!VRx8:-y1;阵亡数量减去正常恢复数量
!!FU|x8<1/x9<1:E;
!!BMx1&x8<x9:Ndx8 V4;
!!BMx1&x8>=x9:Ndx9 V4;
!!UN:N3/1/y10/0;
!!VRz10&x8<x9:S^ 超级转世重生让 %X8{%Z1}起死回生^;
!!VRz10&x8>=x9:S^ 超级转世重生让 %X9{%Z1}起死回生^;
!!MM:Sz10;

昨晚看了大半天，文科生整这个到底不行，搞半天大概搞懂了一点：HE是指英雄，148是英雄代号，148就是格鲁，V108大概指108级以下有效吧，也就是说这个ERM就是格鲁专用的，我晕，我尝试着把!!HE148:Fd/d/?v108/d;
去掉，把下面的FU220&v104=148改成了>-1大概全体英雄适用是要>-1吧，好吧，彻底失败
我就是想把这个脚本改成对玩家英雄有用，成为一个通用的，上面那个神圣复活实际是施法就复活，比较BT，要把下面这个超级复活改成通用的该怎么弄呢

兽哥哥

那段不能去掉的，是触发器来的。你改英雄编号就行了---猜的

水手

兽哥哥 发表于 2013-10-19 11:46
那段不能去掉的，是触发器来的。你改英雄编号就行了---猜的

我试过了，把148全部用0代替，我只知道0是指欧玲啊，其他英雄代码不知道，在博德之门里测试了，不行。不过博得之门里的初始英雄（原H3地图阿泰2首发是欧玲）不知道是谁？

水手

兽哥哥 发表于 2013-10-19 11:46
那段不能去掉的，是触发器来的。你改英雄编号就行了---猜的

精灵光复里的格鲁一开始没有超级复活吧，多少级开始有的？还是需要访问某个建筑？

兽哥哥

水手 发表于 2013-10-19 11:51
精灵光复里的格鲁一开始没有超级复活吧，多少级开始有的？还是需要访问某个建筑？

学到后一直都有，根据你的P值来定。我自己玩把这个脚本增加了10倍还是多少倍的，忘了。

沧海一粟

水手 发表于 2013-10-19 11:43
请再帮我看个脚本（抄自永远的精灵光复脚本）：

超级复活：

晕，v108是力量，代表格鲁的力量值，这个要改成对玩家全体英雄都有效也差不多，只是必须得增加个变量，因为通用于英雄除了得考虑进攻还得防守，而特定英雄则不必。

1. ZVSE
   
2. 
   
3. !?BA0;
   
4. !!BA:H0/?v9555 H1/?v9560;
   
5. !!HEv9555:Fd/d/?v108/d;
   
6. !!HEv9560&v9560>-1:Fd/d/?v109/d;  **增加个v109代表守方英雄的力量
   
7. 
   
8. 
   
9. !?BG0&1000;
   
10. !!BG:A?v101 D?v102 E?v103 H?v104 N?v105 Q?v106 S?v107;   
    
11. !!FU220&v104=v9555/v101=1/v107=38/v103>=0/v103<=20:Pv103/v108/v9555;     **函数一分为二，堆栈也跟着分
    
12. !!FU220&v9560>-1/v104=v9560/v101=1/v107=38/v103>=21/v103<=41:Pv103/v109/v9560;
    
13. 
    
14. !?FU220;
    
15. !!HEx3:O?y11;
    
16. !!OW:Iy11/?y12;
    
17. !!FU&y12=1:E;
    
18. !!FU|x1<0/x1>41:E;这里接下去....

复制代码

等级...........

水手

沧海一粟 发表于 2013-10-19 15:26
晕，v108是力量，代表格鲁的力量值，这个要改成对玩家全体英雄都有效也差不多，只是必须得增加个变量，因 ...

好，谢谢额，回家试试

水手

沧海一粟 发表于 2013-10-19 15:26
晕，v108是力量，代表格鲁的力量值，这个要改成对玩家全体英雄都有效也差不多，只是必须得增加个变量，因 ...

搞了，成功了，好神奇啊，再次谢谢沧大师。两个脚本都保存好了，又看了一下ERM帮助，哎，不是这块料，一头雾水，作罢了