这是错误信息是什么意思?

gigichart

就重复这错误信息要点半天才点完




怎么解决?

a968574

是什么地图，名字是什么

gigichart

a968574 发表于 2013-9-2 15:22
是什么地图，名字是什么

是用了fly的英雄转世极限版脚本后玩什么图都这样
想知道是哪里出错了

贤知有您

楼主必须说明你的游戏状态.
游戏版本啊,加载什么地图,什么额外脚本之类都通通列出来.
还有出现图片上的错误后,你点确定之后,游戏目录下 WOGERMLOG.TXT 关于脚本的那部分也得贴上来.

gigichart

贤知有您 发表于 2013-9-2 15:27
楼主必须说明你的游戏状态.
游戏版本啊,加载什么地图,什么额外脚本之类都通通列出来.
还有出现图片上的错 ...

这个错误信息WOGERMLOG.TXT不保存的，那东西似乎只保存会造成游戏崩溃的错误信息
这问题是在用了fly的英雄转世极限版脚本后才出现了，所以应该是那脚本问题，但是不知道具体是哪个地方的问题

ZVSE
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_ScriptName=攻防重置
ERMS_ScriptAuthor=syz
ERMS_ScriptVersion=1.0.0
ERMS_ScriptDate=22.6(June).2013
ERMS_ScriptERMVersion=2.70
ERMS_ScriptLanguage=中文(简体，中国) or 中文(简体) (native)
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
**w143=A，D，w144=P, K FU66 AHI v94 DFI v95 ACT v300-v305 v76 v4711-v4712 V9-V10
********************************
!?PI;
!!DO66/0/155/1:P1;
********************************
********************************
!?CM2;
!!CM:I?f F?g;
!!CM:H?h/?i;
!!FU66:P-4/h/f/g P-5/h/f/g;
********************************
********************************
!?BA0;         战斗一开始增加魔法值
!!IF:V9/0V10/0;
!!BA:H0/?v94 H1/?v95;
!!FU66:P-1/v94;
!!FU66&v95>-1:P-1/v95;

!?FU66&x1=-1;  英雄知识重转函数
!!IF:Wx2;
!!HEx2:Fd/d/d/?j/1 S24/?y-1;
!!VRj&y-1=0:*10;
!!VRj&y-1=1:*125:100;
!!VRj&y-1=2:*15;
!!VRj&y-1=3:*20;
!!HEx2:I?t/1;
!!VRk:S0;
!!VRk:Sw144:1000;         knowlege
!!VRk:*2;
!!FU&t>j:E;
!!HEx2:Idk/1;

!?BF;
!!DO66/0/20/1&v94>-1:P2/v94;
!!DO66/21/41/1&v95>-1:P2/v95;

!?BG0;
!!BG:A?v300 S?v301 H?v302 Q?v303 D?v304 E?v305;
!!FU66:P3/v301/v302/v300 P4/v301/v302/v300;
!!DO66/0/21/1&v303=1:P5/v301/v302/v300/v303/v304;群体疯狂
!!DO66/21/41/1&v303=0:P5/v301/v302/v300/v303/v304;
!!DO66/0/21/1&v303=1:P6/v301/v302/v300/v303/v304;群体攻击魔法
!!DO66/21/41/1&v303=0:P6/v301/v302/v300/v303/v304;
!!DO66/0/20/1&v303=0:P14/v301/v302/v303/v304/v300;Resurrection Magic
!!DO66/21/41/1&v303=1:P14/v301/v302/v303/v304/v300;
!!DO66/0/20/1&v303=0:P15/v301/v302/v303/v304/v300;Animate Dead Magic
!!DO66/21/41/1&v303=1:P15/v301/v302/v303/v304/v300;
!!FU66&v300=1/v301=38:P16/v305/v302;超级复活 x2目标堆栈 x3英雄
!!FU66&v300=1/v301=39:P17/v305/v302;超级聚灵 x2目标堆栈 x3英雄

!?FU66&x1=3;
!!FU|x4<>1:E;
!!IF:Wx3;
!!VRe1:S0;
!!VRe1:Sw144%1000;         POWER
!!VRe1::70;
!!FU&e1<1:E;
!!FU|x2<27/x2=38/x2=39/x2=40/x2=47/x2=57/x2=59/x2=60/x2>61:E;
!!BG:D-1;        全体施法

!?FU66&x1=4;  群体失明
!!FU|x4<>1:E;
!!IF:Wx3;
!!VRe1:S0;
!!VRe1:Sw144%1000;         POWER
!!VRe1::130;
!!FU|e1<1/x2<>62:E;
!!BG:D-1;

!?FU66&x1=5;  群体疯狂
!!FU|x4<>1:E;
!!IF:Wx3;
!!HEx3:I?g/1;
!!VRe1:S0;
!!VRe1:Sw144%1000;         POWER
!!VRe1::150;
!!FU|e1<1/x2<>59:E;
!!BMx16:N?y1 T?y2 P?y3;
!!FU&y2>144/y2<150|y1<1/x6=y3/g<100:E;
!!BHx5:Cx2/y3/1/1;

!?FU66&x1=6;  群体攻击魔法
!!FU|x4<>1:E;
!!IF:Wx3;
!!HEx3:I?g/1 Fd/d/?j/d/1;
!!VRe1:S0;
!!VRe1:Sw144%1000;         POWER
!!VRe1::100;
!!VRy1:S-1;
!!VRy1&x2>14/x2<19:S2;
!!VRy1&x2>19/x2<24:S2;
!!FU|e1<1/y1<0:E;
!!BMx16:N?y-1 T?y2 P?y3;
!!FU&y2>144/y2<150|y-1<1/x6=y3/g<50:E;
!!BHx5:Cx2/y3/j/1;

!?BG1;          英雄魔力重转函数，增加魔法持续时间
!!DO66/0/20/1&v303=0:P-6/v301/v300/v302/v303;
!!DO66/21/41/1&v303=1:P-6/v301/v300/v302/v303;
!!DO66/0/20/1&v303=1:P-7/v301/v300/v302/v303;
!!DO66/21/41/1&v303=0:P-7/v301/v300/v302/v303;
!!FU66:P7/v303/v300;一回合多次施法
!!FU66:P18/v300/v301/v302/v305/v303; 魔力重转后复活或者聚灵魔法威力计算

!?FU66&x1=18;
!!FU|x2<>1/x3<>38/x3<>39:E;
!!IF:Wx4;
!!VRh:S0;
!!VRh:Sw144%1000;         POWER
!!BMx5:I?g P?t N?y-1 B?y-2;
!!FU|g<>x6/y-1<1/y-1>=y-2/h<1:E;
!!BMx5:Cx3/t/3/h/1;

!?FU66&x1=7;  玩家知识重转函数,一回合多次施法
!!FU|x3<>1:E;
!!BHx2:N?y1;
!!OW:C?i;
!!HEy1:O?g;
!!FU&i<>g:E;
!!IF&y1>-1:Wy1;
!!VRv1:S0;
!!VRv1:Sw144:1000;         knowlege
!!VRv1::30;
!!VRv2:Sv1-v76;
!!FU|v2=<0/v76>4:E;
!!BHx2:M0;
!!VRv76:+1;

!?FU66&x1=-6;  有益魔法
!!IF:Wx4;
!!FU|x3<>1:E;
!!FU|x2<27/x2=35/x2=38/x2=39/x2=40/x2=42/x2=45/x2=50/x2=52/x2=47/x2=54/x2>55:E;
!!BMx16:Gx2/?y-1/?y-2;
!!FU&y-1=0:E;
!!HEx4:Fd/d/?y11/d/1;
!!VRh:S0;
!!VRh:Sw144%1000;         POWER
!!VRy-1:+h;
!!VRy12:Sy11+h;
!!BMx16:I?g;
!!FU|g<>x5/y-1>y12:E;
!!BMx16:Mx2/y-1/y-2;

!?FU66&x1=-7;  诅咒魔法
!!IF:Wx4;
!!FU|x3<>1:E;
!!VRy21:S0;
!!VRy21|x2=42/x2=45/x2=50/x2=52/x2=54/x2=60/x2=61/x2=62:S1;
!!FU|y21<>1:E;
!!BMx16:Gx2/?y-1/?y-2;
!!FU&y-1=0:E;
!!HEx4:Fd/d/?y11/d/1;
!!VRh:S0;
!!VRh:Sw144%1000;         POWER
!!VRy-1:+h;
!!VRy12:Sy11+h;
!!BMx16:I?g;
!!FU|g=x5/y-1>y12:E;
!!BMx16:Mx2/y-1/y-2;

!?CM4;
!!BG:H?v1 Q?v2;
!!FU|v76>4:E;
!!IF:Wv1;
!!VRm:S0;
!!VRm:Sw144%1000;         POWER
!!VRm::20;
!!VRn:S0;
!!VRn:Sw144:1000;         knowlege
!!VRn::20;
!!CM:I?y30 S?y31 F?y32;
!!FU66:P9/y30/y31/y32/m;
!!FU66:P10/y30/y31/y32/n;

!?FU66&x1=9;  玩家魔力重转函数,一回合多次高级诅咒魔法
!!FU|x2<>2005/x3<>14/x4<>512/x5<1/v76>x5:E;
!!CM:R0;
!!VRz-1:S^（请选择您想对敌方部队施放的6级魔法{MP>=:100}）^;
!!VRz-2&x5>=3:S^70. 石化 Required MP=60，10回合有效^; v1=1
!!VRz-3&x5>=1:S^71. 中毒 Required MP=20^; v1=2
!!VRz-4&x5>=5:S^72. 缠绕 Required MP=100,3回合有效^; v1=4
!!VRz-5&x5>=1:S^73. 疾病 Required MP=10^; v1=8
!!VRz-6&x5>=3:S^74. 麻痹 Required MP=60，10回合有效^; v1=16
!!VRz-7&x5>=4:S^75. 老化 Required MP=50^; v1=32
!!VRz-8&x5>=2:S^78. 驱散有益魔法 Required MP=30^; v1=64
!!VRz-9&x5>=2:S^80. 酸液攻击 Required MP=25^; v1=128
!!VRz-10:S^退出，我不想施法了。^; v1=256
!!IF:G1/1/256/-1/-2/-3/-4/-5/-6/-7/-8/-9/-10;
!!FU|v1=256:E;
!!VRv4711&v1=1:S70;
!!VRv4711&v1=2:S71;
!!VRv4711&v1=4:S72;
!!VRv4711&v1=8:S73;
!!VRv4711&v1=16:S74;
!!VRv4711&v1=32:S75;
!!VRv4711&v1=64:S78;
!!VRv4711&v1=128:S80;
!!IF:V9/1; enables another mouse click trigger
!!UN:R5/3/0 R7/0/1;

!?FU66&x1=10;  玩家知识重转函数,一回合多次高级祝福魔法
!!FU|x2<>2010/x3<>14/x4<>512/x5<1/v76>x5:E;
!!CM:R0;
!!VRz-1:S^（请选择您想对本方部队施放的6级魔法{MP>=:100}）^;
!!VRz-2&x5>=6:S^镜像大法---单体双剑实体克隆。Required MP=100^; v1=1
!!VRz-3&x5>=5:S^狂暴大法---嗜血，孤注一掷，屠龙。Required MP=50^; v1=2
!!VRz-4&x5>=1:S^神行太保---加速，祈祷，石肤。Required MP=30^; v1=4
!!VRz-5&x5>=3:S^天堂之盾---护盾，气盾，火盾。Required MP=40^; v1=8
!!VRz-6&x5>=2:S^神之祝福---医疗，祝福，祈祷。Required MP=35^; v1=16
!!VRz-7&x5>=4:S^手舞足蹈---幸运,欢欣鼓舞,反戈一击。Required MP=40^;v1=32
!!VRz-8&x5>=3:S^一箭穿心---祝福,精确,孤注一掷。Required MP=35^; v1=64
!!VRz-9&x5>=2:S^终极魔盾---御气，御火，御水，御土，魔镜。Required MP=60^; v1=128
!!VRz-10:S^退出，我不想施法了。^; v1=256
!!IF:G1/1/256/-1/-2/-3/-4/-5/-6/-7/-8/-9/-10;
!!FU|v1=256:E;
!!VRv4711&v1=1:S1;
!!VRv4711&v1=2:S2;
!!VRv4711&v1=4:S3;
!!VRv4711&v1=8:S4;
!!VRv4711&v1=16:S5;
!!VRv4711&v1=32:S6;
!!VRv4711&v1=64:S7;
!!VRv4711&v1=128:S8;
!!IF:V10/1; enables another mouse click trigger
!!UN:R5/3/0 R7/0/1;

!?MM0&9; trigger for mouse hint text
!!MM:D?y-1;   hex number
!!FU|y-1<1/y-1>185:E; Exit if invalid hex
!!VRz-10&9:S^选择施法位置（左键点击敌方部队）。^;
!!MM&9:Mz-10;

!?CM4&9;
!!CM:R0;
!!BG:H?y1 Q?y2;
!!CM:D?y-1 S?y31;   hex number
!!FU|y-1<1/y-1>185:E; Exit if invalid hex
!!IF:V9/0;
!!FU66:P11/y-1/y2/y31/y1;
!!UN:R7/0/0;

!?MM0&10; trigger for mouse hint text
!!MM:D?y-1;   hex number
!!FU|y-1<1/y-1>185:E; Exit if invalid hex
!!VRz-10&10:S^选择施法位置（左键点击我方部队）。^;
!!MM&10:Mz-10;

!?CM4&10;
!!CM:R0;
!!BG:H?y1 Q?y2;
!!CM:D?y-1 S?y31;   hex number
!!FU|y-1<1/y-1>185:E; Exit if invalid hex
!!IF:V10/0;
!!FU66:P12/y-1/y2/y31/y1;
!!UN:R7/0/0;

!?FU66&x1=11; cast slow at x1 (if valid)
!!BU:Ex2/?y2; get stack # at hex x1 (-1 if none)
!!FU&y2=-1:E;
!!BMy2:I?y1 P?y3 T?y4;
!!BMy2:G34/?y-1/?y-2;
!!VRk:S0;!!VRj:S0;
!!VRk:Sw144%1000;         POWER
!!VRk::200;
!!VRj&y4>173/y4<192|y4=27/y4=83/y4=132/y4=151/y4=155/y4=116/y4=117:S1;
!!VRj|k>0:-1;
!!IF|j>0:M^施法目标为黑龙类魔免生物。此魔法无效。^;
!!IF|y-1>0:M^施法目标有抗魔大法附体。无法施放此魔法。^;
!!IF|y1=x3:M^你不能对本方部队施放此魔法。^;
!!FU|y1=x3/y3<>x2/x4<>12/y-1>0/j>0:E;
!!HEx5:I?y12/1;
!!IF|y12<100:M^你的魔法值不够100点，无法施放此魔法。^;
!!FU|y12<100:E;
!!VRy13:Sv4711;!!VRy14:S0;
!!VRy14|y13=70:S59;   60
!!VRy14|y13=71:S19;   20
!!VRy14|y13=72:S99;   100
!!VRy14|y13=73:S9;    10
!!VRy14|y13=74:S59;   60
!!VRy14|y13=75:S49;   50
!!VRy14|y13=78:S29;   30
!!VRy14|y13=80:S24;   25
!!VRy12:-y14;
!!HEx5:Iy12/1;
!!VRy15:S0;
!!VRy15|y13=70/y13=74:S1;
!!BHx3|y15=0:Cy13/y3/3/1;
!!BMy2&y2>-1/y15=1:Cy13/y3/1/10/1;
!!BG:N?y50;
!!BMy50:C2/y3/0/0/0;
!!VRy9&y2>-1/y2<21/y13=72:S7520+y2;
!!VRy9&y2>20/y13=72:S7500+y2;
!!VRy10&y2>-1/y2<21/y13=72:S7500+y2;
!!VRy10&y2>20/y13=72:S7480+y2;
!!VRvy9&y2>-1/y13=72:Sv997+3;
!!VRvy10&y2>-1/y13=72:Sy2;
!!VRv76:+1;
!!IF:Wx5;
!!VRm:S0;
!!VRm:Sw144%1000;         POWER
!!VRm::20;
!!FU&v76>m:E;
!!BHx3:M0;

!?FU66&x1=-100;
!!BMvx16&vx16>-1:G72/?y-1/?y-2;
!!FU&y-1=0:E;
!!VRy3:S-1;
!!VRy1:Sv997;
!!VRy2:Sx16+20;
!!VRy3:Svy2-y1;
!!BMvx16&vx16>-1:P?g;
!!BMvx16&vx16>-1/y3=0:C63/g/1/1/1 Pg V26;

!?FU66&x1=12; cast slow at x1 (if valid)
!!BU:Ex2/?y2; get stack # at hex x1 (-1 if none)
!!FU&y2=-1:E;
!!BMy2:I?y1 P?y3;
!!IF|y1<>x3:M^你不能对敌方部队施放此魔法。^;
!!FU|y1<>x3/y3<>x2/x4<>12:E;
!!HEx5:I?y12/1;
!!IF|y12<100:M^你的魔法值不够100点，无法施放此魔法。^;
!!FU|y12<100:E;
!!VRy13:Sv4711;!!VRy14:S0;
!!VRy14|y13=1:S80; 20+     need 100
!!VRy14|y13=2:S22; 28+     need 50
!!VRy14|y13=3:S9;  21+     need 30
!!VRy14|y13=4:S15; 25+     need 40
!!VRy14|y13=5:S14; 21+     need 35
!!VRy14|y13=6:S6;  34+     need 40
!!VRy14|y13=7:S13; 22+     need 35
!!VRy14|y13=8:S18; 42+     need 60
!!VRy12:-y14;
!!HEx5:Iy12/1;
!!HEx5:S14/?v5 S15/?v6 S16/?v7 S17/?v8;
!!HEx5:S14/1 S15/1 S16/1 S17/1;
!!FU66:P13/y3/x3/y13/y2;
!!BHx3&y13=2:C43/y3/2/1 C55/y3/2/1 C56/y3/2/1;
!!BHx3&y13=3:C53/y3/2/1 C46/y3/2/1 C48/y3/2/1;
!!BHx3&y13=4:C27/y3/2/1 C28/y3/2/1 C29/y3/2/1;
!!BHx3&y13=5:C37/y3/2/1 C41/y3/2/1 C48/y3/2/1;
!!BHx3&y13=6:C49/y3/2/1 C51/y3/2/1 C58/y3/2/1;
!!BHx3&y13=7:C41/y3/2/1 C44/y3/2/1 C56/y3/2/1;
!!BHx3&y13=8:C30/y3/2/1 C31/y3/2/1 C32/y3/2/1 C33/y3/2/1 C36/y3/2/1;
!!HEx5:S14/v5 S15/v6 S16/v7 S17/v8;
!!VRv76:+1;
!!IF:Wx5;
!!VRn:S0;
!!VRn:Sw144:1000;         knowlege
!!VRn::20;
!!FU&v76>n:E;
!!BHx3:M0;

!?FU66&x1=13;
!!FU&x4<>1:E;
!!BHx3:C65/x2/2/1;
!!BMx5&x5>-1:U5/?y1;
!!BMy1:F?g F?h;
!!VRg:&12582912;
!!VRh&g>0:-8388608;
!!BMy1:Fh;
!!VRy-4&y1>-1:Sy1;
!!VRy-4&y1>-1:+1 *-1;
!!EAy-4&y1>-1:E10/12/d/d;
!!EAy-4&y1>-1:R156/7;

!?FU66;
!!FU|x1<>14/x6<>1:E;
!!BMx16:T?y10 N?y11 B?y12 O?y13;
!!BMx16:P?y14 H?y15 F?i F?j F?k;
!!BMx16:G34/?y9/d;
!!FU|y9>0/y10<0/y11=>y12/y13=-1:E;
!!FU&y10>29/y10<34:E;
!!FU&y10>111/y10<118:E;
!!FU&y10>159/y10<169:E;
!!FU&y10>173/y10<192:E;
!!FU|y10=27/y10=83/y10=120/y10=121/y10=123/y10=125:E;
!!FU|y10=127/y10=129/y10=132/y10=151/y10=155/y10=156:E;
!!VRi:&16;
!!VRj:&1;
!!VRy19:S0;
!!IF:Wx3;
!!VRe1:S0;
!!VRe1:Sw144:1000;         knowlege
!!VRe1::70;
!!VRm:S0;
!!VRm:Sw144%1000;         POWER
!!FU|e1<1/i=0:E;
!!HEx3:Fd/d/?y-99/d/1 I?y-9/1;
!!VRy-9:-30;
!!VRy19&x4=0:Sy14+1; !!VRy19&x4=1:Sy14-1;
!!BU:Ey14/?y20 Ey19/?y21;
!!FU|x2<>38/y-9<0:E;
!!BHx4&y11>0/y14<>x5:Cx2/y14/y-99/1;
!!BMx16&y11>0:Cx2/y14/3/m/1;
!!BHx4&y11<1/j=0/y20=-1/y14<>x5:Cx2/y14/y-99/0;
!!BMx16&y11>0/j=0/y20=-1:Cx2/y14/3/m/1;
!!BHx4&y11<1/j>0/y20=-1/y21=-1/y14<>x5:Cx2/y14/y-99/0;
!!BMx16&y11>0/j>0/y20=-1/y21=-1:Cx2/y14/3/m/1;
!!HEx3:Iy-9/1;

!?FU66;
!!FU|x1<>15/x6<>1:E;
!!BMx16:T?y10 N?y11 B?y12 O?y13;
!!BMx16:P?y14 H?y15 F?i F?j F?k;
!!BMx16:G34/?y9/d;
!!FU|y9>0/y10<0/y11=>y12/y13=-1:E;
!!FU&y10>173/y10<192:E;
!!VRi:&16;
!!VRj:&1;
!!VRk:&262144;
!!FU|i<>0/k=0:E;
!!FU|y10=196:E;
!!VRy19:S0;
!!IF:Wx3;
!!VRe1:S0;
!!VRe1:Sw144:1000;         knowlege
!!VRe1::100;
!!VRm:S0;
!!VRm:Sw144%1000;         POWER
!!FU|e1<1:E;
!!HEx3:Fd/d/?y-99/d/1 I?y-9/1;
!!VRy-9:-40;
!!VRy19&x4=0:Sy14+1; !!VRy19&x4=1:Sy14-1;
!!BU:Ey14/?y20 Ey19/?y21;
!!FU|x2<>39/y-9<0:E;
!!BHx4&y11>0/y14<>x5:Cx2/y14/y-99/1;
!!BMx16&y11>0:Cx2/y14/3/m/1;
!!BHx4&y11<1/j=0/y20=-1/y14<>x5:Cx2/y14/y-99/0;
!!BMx16&y11>0/j=0/y20=-1:Cx2/y14/3/m/1;
!!BHx4&y11<1/j>0/y20=-1/y21=-1/y14<>x5:Cx2/y14/y-99/0;
!!BMx16&y11>0/j>0/y20=-1/y21=-1:Cx2/y14/3/m/1;
!!HEx3:Iy-9/1;

!?FU66;
!!FU|x1<>16/x2<0/x2>41:E;目标堆栈不存在退出
!!IF:Wx3;
!!VRm:S0;
!!VRm:Sw144:1000;         knowlege
!!VRe1:Sm:130;
!!HEx3:Fd/d/?n/d/1 I?y-9/1;
!!BMx2:N?x5 B?x6;目标堆栈原始数量和现存数量
!!FU|x5<1/x6<1/x5>=x6/e1<1/y-9<50:E;如果全部阵亡或没有伤亡退出
!!VRx12:Sm+n;
!!VRy-9:-50;
!!BMx2:H?x7 T?x10; 目标堆栈的生命值
!!VRx8:Sx6-x5;阵亡数量
!!VRv9:Sx12 *500;恢复的生命值
!!VRv9::x7;算出恢复的数量
!!VRy1:Sx12 *50 +160;算出正常重生值
!!VRy1::x7;算出正常恢复数量
!!VRy1:+1;恢复数量加1
!!VRx8:-y1;阵亡数量减去正常恢复数量
!!FU|x8<1/v9<1:E;
!!BMx2&x8<v9:ndx8 v4;
!!BMx2&x8>=v9:Ndv9 V4;
!!UN:N3/1/x10/0;
!!VRz10&x8<v9:s^ 超级转世重生让="" %x8{%z1}起死回生^;
!!VRz10&x8>=v9:S^ 超级转世重生让 %V9{%Z1}起死回生^;
!!MM:Sz10;
!!HEx3:Iy-9/1;

!?FU66;
!!FU|x1<>17/x2<0/x2>41:E;目标堆栈不存在退出
!!IF:Wx3;
!!VRm:S0;
!!VRm:Sw144:1000;         knowlege
!!VRe1:Sm:150;
!!HEx3:Fd/d/?n/d/1 I?y-9/1;
!!BMx2:N?x5 B?x6;目标堆栈原始数量和现存数量
!!FU|x5<1/x6<1/x5>=x6/e1<1/y-9<50:E;如果全部阵亡或没有伤亡退出
!!VRx12:Sm+n;
!!VRy-9:-60;
!!BMx2:H?x7 T?x10; 目标堆栈的生命值
!!VRx8:Sx6-x5;阵亡数量
!!VRv9:Sx12 *500;恢复的生命值
!!VRv9::x7;算出恢复的数量
!!VRy1:Sx12 *50 +160;算出正常重生值
!!VRy1::x7;算出正常恢复数量
!!VRy1:+1;恢复数量加1
!!VRx8:-y1;阵亡数量减去正常恢复数量
!!FU|x8<1/v9<1:E;
!!BMx2&x8<v9:ndx8 v4;
!!BMx2&x8>=v9:Ndv9 V4;
!!UN:N3/1/x10/0;
!!VRz10&x8<v9:s^ 超级聚灵奇术让="" %x8{%z1}起死回生^;
!!VRz10&x8>=v9:S^ 超级聚灵奇术让 %V9{%Z1}起死回生^;
!!MM:Sz10;
!!HEx3:Iy-9/1;
*******************************
!?BR;              每回合回复魔法值
!!FU&v997<1:E;
!!FU66&v95<0:P-8/v94;
!!FU66&v95>-1:P8/v94/v95;
!!DO66/7500/7520/1:P-100;
!!VRv76:S0;

!?FU66&x1=-8;  野兵作战根据知识重转值增加魔法值
!!IF:Wx2;
!!VRh:S0;
!!VRh:Sw144:1000;         knowlege
!!HEx2:Fd/d/d/?j/1 S24/?y-1;
!!HEx2:I?y1/1;
!!VRj&y-1=0:*10;
!!VRj&y-1=1:*125:100;
!!VRj&y-1=2:*15;
!!VRj&y-1=3:*20;
!!FU|y1>=j:E;
!!VRy1:+h;
!!HEx2:Iy1/1;

!?FU66&x1=8;  英雄之间作战根据知识重转值增减魔法值
!!IF:Wx2;
!!VRv1:C0/0/0;
!!VRv1:Sw144:1000;         knowlege
!!IF:Wx3;
!!VRv2:Sw144:1000;         knowlege
!!VRv3:Sv1-v2;
!!HEx2:Fd/d/d/?j/1 S24/?y-1;
!!HEx2:I?y1/1;
!!VRj&y-1=0:*20;
!!VRj&y-1=1:*25;
!!VRj&y-1=2:*30;
!!VRj&y-1=3:*40;
!!VRm:Sv1;
!!VRm&y-1=0:*20;
!!VRm&y-1=1:*25;
!!VRm&y-1=2:*30;
!!VRm&y-1=3:*40;
!!VRj:+m;
!!VRy1:+v3;
!!VRy1&y1<0:S0;
!!HEx2&y1<j:Iy1/1;
!!HEx3:Fd/d/d/?k/1 S24/?y-2;
!!HEx3:I?y2/1;
!!VRk&y-2=0:*20;
!!VRk&y-2=1:*25;
!!VRk&y-2=2:*30;
!!VRk&y-2=3:*40;
!!VRn:Sv2;
!!VRn&y-2=0:*20;
!!VRn&y-2=1:*25;
!!VRn&y-2=2:*30;
!!VRn&y-2=3:*40;
!!VRk:+n;
!!VRy2:-v3;
!!VRy2&y2<0:S0;
!!HEx3&y2<k:Iy2/1;
********************************
!?FU66&x1=1;  英雄变量复位函数
!!IF:Wx16;
!!VRw143:S0;  A,D储存
!!VRw144:S0;  P,K储存
********************************
********************************
!?FU66&x1=-2;   四围刷新函数
!!HEx2:F?v1/?v2/d/d/1;  获取四围
!!FU|v1<85/v2<85:E;   不足85时中止
!!VRy11:Sv1 -85;
!!VRy12:Sv2 -85;
!!IF:Wx2;           使用英雄变量
!!VRw143:+y11;       攻击储存
!!VRy12:*1000;
!!VRw143:+y12;       防御储存
!!HEx2:F85/85/d/d;  四围刷新
!!HEx2:B0/?z7;
!!IF&x3=0:M^{恭喜，%Z7 成功重转}^;
!!UN&x3=0:R3/-1;

!?FU66&x1=-3;   四围刷新函数
!!HEx2:Fd/d/?v3/?v4/1;  获取四围
!!FU|v3<80/v4<80:E;   不足80时中止
!!VRy13&v3>80:Sv3 -80;
!!VRy14&v4>80:Sv4 -80;
!!IF:Wx2;           使用英雄变量
!!VRw144:+y13;      魔力储存
!!VRy14:*1000;
!!VRw144:+y14;      知识储存
!!HEx2:Fd/d/80/80;  四围刷新
!!HEx2:B0/?z7;
!!IF&x3=0:M^{恭喜，%Z7 成功重转}^;
!!UN&x3=0:R3/-1;
********************************
********************************
!?FU66&x1=2;战场攻防补偿函数
!!BMx16:T?y10 N?y11;
!!FU|y10<0/y11<1:E;
!!IF:Wx2;
!!VRm:S0; !!VRn:S0;
!!VRm:Sw143:1000;  D+
!!VRn:Sw143%1000; A+
!!BMx16:Adn Ddm;
*******************************
********************************
!?FU66&x1=-4;
!!FU|x3<103/x3>104/x4<>512:E;
!!HEx2:B0/?z7;
!!HEx2:F?y11/?y12/d/d/1;
!!IF|y11<85/y12<85:Q3/31/0/32/0/4^{%Z7} 还不够重转条件

攻击防御同时大于85才能重转^;
!!FU|y11<85/y12<85:E;
!!IF:Q10/31/0/32/0/2^%Z7已满足重转条件，要重转吗？^;
!!FU66&10:P-2/x2/0;
!!CM&10:R0;

!?FU66&x1=-5;
!!FU|x3<105/x3>106/x4<>512:E;
!!HEx2:B0/?z7;
!!HEx2:Fd/d/?y13/?y14/1;
!!IF|y13<80/y14<80:Q4/33/0/34/0/4^{%Z7} 还不够重转条件

魔力知识同时大于80才能重转^;
!!FU|y13<80/y14<80:E;
!!IF:Q10/33/0/34/0/2^%Z7已满足重转条件，要重转吗？^;
!!FU66&10:P-3/x2/0;
!!CM&10:R0;
********************************
********************************
!?CM2;
!!CM:I?y30 S?y31 F?y32;
!!FU|y30<>1/y31<>14/y32<>512:E;
!!HE-1:B0/?z7;
!!IF:W-1;
!!VRm:S0; !!VRn:S0; !!VRg:S0; !!VRh:S0;
!!VRm:Sw143:1000;         defense
!!VRn:Sw143%1000;         attack
!!VRg:Sw144:1000;         knowlege
!!VRh:Sw144%1000;         POWER
!!IF:Q2/31/n/32/m/1^%Z7攻防重置后的附加能力：^;
!!IF:Q2/33/h/34/g/1^%Z7魔智重置后的附加能力：^;
!!CM:R0;
********************************
!?MR0;    英雄魔力重转<=>魔法伤害加成
!!BG:A?y-1 S?y-2 H?y-3;
!!IF:Wy-3;
!!FU|y-1<>1:E;
!!MR:D?y-9;
!!VRy-4:S0;!!VRk:S0;
!!VRy-4&y-2=15:S10;   magic arrow
!!VRy-4&y-2=16:S20;   Ice Bolt
!!VRy-4&y-2=17:S25;   Lightning Bolt
!!VRy-4&y-2=18:S80;   Implosion
!!VRy-4&y-2=19:S40;   Chain Lightning
!!VRy-4&y-2=20:S10;   Frost Ring
!!VRy-4&y-2=21:S10;   Fireball
!!VRy-4&y-2=22:S10;   Inferno
!!VRy-4&y-2=23:S25;   Meteor Shower
!!VRy-4&y-2=24:S5;    Death Ripple
!!VRy-4&y-2=25:S10;   Destroy Undead
!!VRy-4&y-2=26:S50;   Armageddon
!!VRy-4&y-2=57:S600;   Titan's Lightning Bolt
!!VRk:Sw144%1000;         POWER
!!VRy-10:Sk*y-4;
!!VRy-9:+y-10;
!!HEy-3:Ed/?m;
!!VRy-9&k>199:*m;  魔力重转值大于200魔法伤害=基本伤害*英雄等级
!!MR:Dy-9;
********************************
!?MR2;    英雄魔力重转<=>无视魔法免疫
!!IF:Wv302;
!!VRe1:S0;
!!VRe1:Sw144%1000;         POWER
!!VRe1::200;
!!FU|e1<1/v300<>1:E;
!!MR:F0;
********************************
!#TM5:S2/999/1/255;

!?TM5;
!!DO66/0/155/1:P-99;

!?FU66&x1=-99;
!!HEx16:N?j O?y-1;
!!OW&y-1>-1:Iy-1/?y-1;
!!HEj&j>-1:F?y1/?y2/?y3/?y4/1; 获取英雄四围
!!FU66&y-1=1:P-9/j/y1/y2;
!!FU66&y-1=1:P-10/j/y3/y4;

!?FU66&x1=-9;   四围刷新函数
!!FU|x3<75/x4<75:E;   不足75时中止
!!VRy11:Sx3 -75;
!!VRy12:Sx4 -75;
!!IF:Wx2;           使用英雄变量
!!VRw143:+y11;       攻击储存
!!VRy12:*1000;
!!VRw143:+y12;       防御储存
!!HEx2:F75/75/d/d;  四围刷新

!?FU66&x1=-10;   四围刷新函数
!!FU|x3<70/x4<70:E;   不足70时中止
!!VRy13:Sx3 -70;
!!VRy14:Sx4 -70;
!!IF:Wx2;           使用英雄变量
!!VRw144:+y13;       魔力储存
!!VRy14:*1000;
!!VRw144:+y14;       知识储存
!!HEx2:Fd/d/70/70;  四围刷新
**过天判断**英雄移动是魔法值是否为满值作为判断条件
!?HM-1;
!!HE-1:N?j;
!!FU66:P-11/j;

!?FU66&x1=-11;
!!HEx2:Fd/d/d/?y1 S24/?y-1;
!!IF:Wx2;!!VRy11:S0;!!VRy12:S0;!!VRy13:S0;
!!VRy11:Sw144:1000; knowlege
!!FU|y11<1:E;
!!VRv1&y-1=0:Sy1*10;
!!VRv1&y-1=1:Sy1*125:100;
!!VRv1&y-1=2:Sy1*15;
!!VRv1&y-1=3:Sy1*20;
!!VRv2&y-1=0:Sy1*20;
!!VRv2&y-1=1:Sy1*25;
!!VRv2&y-1=2:Sy1*30;
!!VRv2&y-1=3:Sy1*40;
!!HEx2:I?y2;
!!VRy12&y-1=0/y2=v1:Sy11*10;
!!VRy12&y-1=1/y2=v1:Sy11*125:100;
!!VRy12&y-1=2/y2=v1:Sy11*15;
!!VRy12&y-1=3/y2=v1:Sy11*20;
!!VRy13&y-1=0/y2=v2:Sy11*20;
!!VRy13&y-1=1/y2=v2:Sy11*25;
!!VRy13&y-1=2/y2=v2:Sy11*30;
!!VRy13&y-1=3/y2=v2:Sy11*40;
!!VRv3&y2=v1:Sy2+y12;
!!VRv4&y2=v2:Sy2+y13;
!!HEx2&y2=v1:Iv3;
!!HEx2&y2=v2:Iv4;

!?CM4&1000;                               mouse move trigger
!!CM:D?y-1 F?y1;
!!BG:Q?y-10;                       attacking side? (0=left, 1= right)
!!BHy-10:N?y-5;
!!IF:Wy-5;
!!HEy-5:B0/?z7;
!!VRm:S0; !!VRn:S0; !!VRg:S0; !!VRh:S0;
!!VRm:Sw143:1000;         defense
!!VRn:Sw143%1000;         attack
!!VRg:Sw144:1000;         knowlege
!!VRh:Sw144%1000;         POWER
!!VRy2&y-10=0:S252;!!VRy2&y-10=1:S253;
!!IF&y1=512/y-1=y2:Q2/31/n/32/m/4^%Z7攻防重置后的附加能力：^;
!!IF&y1=512/y-1=y2:Q2/33/h/34/g/4^%Z7魔智重置后的附加能力：^;
!!VRy-11&y-10=0:S1; !!VRy-11&y-10=1:S0;   opponent hero?
!!BHy-11:N?y-30;                          is this a hot seat 2 hero battle?
!!FU&y-30=-1:E;                           end if no hero opponent on field]
!!IF:Wy-30;
!!HEy-30:B0/?z7;
!!VRm:S0; !!VRn:S0; !!VRg:S0; !!VRh:S0;
!!VRm:Sw143:1000;         defense
!!VRn:Sw143%1000;         attack
!!VRg:Sw144:1000;         knowlege
!!VRh:Sw144%1000;         POWER
!!VRy3&y-10=0:S253;!!VRy3&y-10=1:S252;
!!IF&y1=512/y-1=y3:Q2/31/n/32/m/4^%Z7攻防重置后的附加能力：^;
!!IF&y1=512/y-1=y3:Q2/33/h/34/g/4^%Z7魔智重置后的附加能力：^;

贤知有您

FLY的脚本是不是已经修正过了呢?
貌似这里显示的脚本中
v300-v305 变量用错了.
查看官方脚本变量可以看到  (v300-v308) 是作为临时变量用的.
而且这里脚本是跨触发器使用 v300-v305
当其它脚本用到这个临时V变量时,就会出错了.

gigichart

贤知有您 发表于 2013-9-2 16:28
FLY的脚本是不是已经修正过了呢?
貌似这里显示的脚本中
v300-v305 变量用错了.

这脚本是我前天下的,帖子里显示的最后编辑时间是6月23,所以应该是没被发现的BUG吧.
贤知能帮忙解决下么?其他额外的施法次数和超级魔法之类的功能有没有无所谓，只要保留英雄四围转世功能就行了