孤注一掷 魔法修改求助

希望创师

孤注一掷和反戈一击作为 四级战斗辅助魔法，一直显得不够强力。

偶想能不能修改成这样：嗜血的单位在每次攻击/反击后可以获得+2攻击速度（间接提高了反戈一击），并且反戈一击在反击时可以攻击周围所有部队。

孤注一掷则同时提供给单位吸血的能力（类似吸血鬼王），当孤注一掷消失时，吸血效果也消失。

本以为这erm很好做，但看了半天帮助，参考了asnm555的魔法强化，但还是搞不定啊。求坛子里的各位大能仗义出手。谢谢

renlinfeng

孤注一掷还弱啊

希望创师

防御为0，极容易被敌人干掉。或者设定成孤注一掷加攻同时，加上20点速度？

ashero4

1.孤注吸血可以用MF1（个人觉得BG0可能更好点）触发器触发，然后用BM取得堆栈魔法受身状态，如果有孤注就用BM给攻击堆栈增加生命；
2.孤注加速比较麻烦，用BG0触发后给施法堆栈增加20点速度，再用BG0检测攻击堆栈是否有孤注的受身魔法状态，如果有的话用个v变量当开关，攻击完后用BG1恢复速度。不过可能有个问题是被孤注的堆栈被反击完全阵亡后，可能不能恢复速度。
3.嗜血增加速度同孤注一掷；
4.反戈后反击环击俺搞不定，主要是俺还找不到反击专用的触发器，用MF1可能有问题

希望创师

我原也想是BG0，然后在攻击前给堆栈赋予吸血技能，结果发现找不到赋予吸血能力的代码。
用BM：H  给攻击堆栈增加生命，增加的是每一个生物的生命吧。吸血应该是将当前的伤害值转化为堆栈的总生命值，可以复活死去单位啊~~找不到代码

ashero4

原帖由 希望创师 于 2012-10-20 20:25 发表
我原也想是BG0，然后在攻击前给堆栈赋予吸血技能，结果发现找不到赋予吸血能力的代码。
用BM：H  给攻击堆栈增加生命，增加的是每一个生物的生命吧。吸血应该是将当前的伤害值转化为堆栈的总生命值，可以复活死去单 ...

给你段绝地反击里面的吸血代码参考下。

ZVSE
!?MF1&1000/v102=3;  //生生不息
!!VRv5100:C-1/-1; v5100-v5101
!!MF:N?v5100 F?v5101;
!!VRv5000:C-1/-1/-1/-1/-1/-1; v5000-v5006
!!VRv5007:C-1/-1/-1/-1/-1/-1/-1/-1/-1/-1;  v5007-v5016
!!VRv5017:C-1/-1/-1/-1/-1/-1/-1/-1;  v5017-v5024
!!BG:A?v5000 D?v5001 E?v5002 N?v5003 S?v5004;
!!BG:Q?v5005 H?v5006;
!!BMv5002&v5002>-1:B?v5007 I?v5009 R?v5011 N?v5013 T?v5015 F?v5017 P?v5019 H?v5021 O?v5023;  被攻击方
!!BMv5003&v5003>-1:B?v5008 I?v5010 R?v5012 N?v5014 T?v5016 F?v5018 P?v5020 H?v5022 O?v5024;  攻击方
!!FU|v5000<6/v5000>7:E;    不是主动攻击就退出
!!FU|v5003<0/v5003>41:E;
!!FU|v5002<0/v5002>41:E;
!!FU&v5016>144/v5016<150:E;
!!FU|v5013<1/v5015<0/v5014<1/v5016<0:E;
!!FU&v5006<>9:E;   不是阿德拉退出
!!HEv5006:E?y99/?y98;
!!FU&y98<20:E; 小于20级退出
!!VRy1:S-1;
!!VRy1:Sv5008*v5022:10*4;
!!VRv5101&v5101<10:S10;
!!VRv5101&v5101>y1:Sy1;
!!DO105/v5003/v5003/1&v102=3/v5005=0:P30/0/20/v5101; 主动进攻的生生不息
!!DO105/v5003/v5003/1&v102=3/v5005=1:P30/21/41/v5101; 防守的生生不息

!?FU105&x1=30;
!!FU|x16<x2/x16>x3:E;
!!BMx16:H?y1 L?y2 N?y3 B?y4 T?y98;
!!FU&y3<1:E;
!!FU&y98>144/y98<146:E;
!!FU&y98>146/y98<150:E;
!!VRy5:Sy1 *y4;
!!VRy6:Sy1 *y3 -y2;
!!FU&y6=y5:E;
!!VRy11:Sx4;
!!VRy7&y11>y1:Sy11 :y1;
!!VRy8&y11>y1:Sy11 %y1;
!!VRy9&y8>0/y11>y1:Sy1 -y8;
!!VRy9&y8=0/y11>y1:Sy1;
!!VRy9&y11<y1:Sy11;
!!VRy10&y9>y2:Sy2 *-1;
!!VRy10&y9<y2:Sy9 *-1;
!!VRy10&y4=1/y11>y1:Sy2 *-1;
!!VRy10&y4=1/y11<y1/y11<y2:Sy11 *-1;
!!VRy10&y4=1/y11<y1/y11>=y2:Sy2 *-1;
!!VRy20:Sy4 -y3;
!!VRy7&y7>y20:Sy20;
!!VRy7&y4=1:S0;
!!BMx16:Ndy7; 此处为吸血复活代码
!!BMx16:Ldy10;
!!UN:N3/23/y98/0;
!!VRz11&y7>0/v102=3:S^{生生不息}使{%Y7 %Z23 起死回生.}^;
!!VRz11&y7=0/v102=3:S^{生生不息}使{%Z23 恢复 %Y9 生命.}^;
!!MM:Sz11;
!!BU:R;

[ 本帖最后由 ashero4 于 2012-10-20 20:29 编辑 ]

ashero4

其实如果有兴趣学erm的话，个人建议可以参考下绝地反击的脚本，俺觉得里面功能挺全的，当然仅限于初学者，进阶的话得研究木瓜大大的2追脚本

[ 本帖最后由 ashero4 于 2012-10-20 20:41 编辑 ]

无心云

老A貌似有点苏醒了，好事啊

希望创师

谢谢ashero4的帮忙，但试写了以下erm，灭有效果啊 ，请帮忙看看吧，拜谢

* post-action trigger **
!?BG1;                                       (动作后触发)
!!BG:A?y-1 N?y-2;                        （获得动作类型、位置）
!!BMy-2&y-1=6:H?y1 L?y2 N?y3 B?y4 ;   [获得攻击方生命值,伤害，当前数量，初数量]
!!VRy5:Sy1 *y4;
!!VRy6:Sy1 *y3 -y2;
!!FU&y6=y5:E;
!!VRy7:Sy2%y1;
!!VRy8:Sy7 *-1 +y2 :y1;
!!BMy-2&y2>0/y-1=6:V79;                          (生物吸血重生动画）
!!BMy-2&y2>0/y-1=6:Ndy8;                        （生物吸血重生）

[ 本帖最后由 希望创师 于 2012-10-20 22:19 编辑 ]

十三木人

!!BG1;后面用BG:A和N获得的对象与!!BG0,!!MF1不同
这个脚本的触发器应该用!!MF1才对
还有，虽然不觉的你会犯这种低级错误，不过ZVSE加了吗

希望创师

zvse自然加了。用MF1触发后，用BG判定的对象是被攻击方还是攻击方呀？

十三木人

!!BG:A获得的是攻击方的动作，!!BG:N获得的是攻击方的堆栈

fly123

!?MF1|v1004=41/v1005=41;
!!BG:A?y1 N?y2 H?y3 Q?y6;  攻击方
!!MF:N?y4 F?y5;    目标堆栈
!!BMy2&y2>-1:N?y7 T?y8 P?y9;攻击方
!!BMy4&y4>-1:N?y10 T?y11 P?y12;    目标堆栈

希望创师

动画触发部分这样写可以吗？ 试了下，攻击方和被攻击方都会触发啊，晕死

!?MF1;                                       (动作后触发)
!!BG:A?y-1;                               （获得动作类型 )
!!BG:N?y-2;                               ( 获得动作位置）
!!BMy-2:H?y1 L?y2 N?y3 B?y4 ;       [获得攻击方生命值,伤害，当前数量，初数量]
!!BMy-2&y-1=6:V79;                          (生物吸血重生动画）

fly123

那你还是用BGO+V变量来写吧。不过，动作堆键是可以检查所属英雄的，你限制一下应该用MF1也可以实现。

十三木人

!!MF1是造成物理伤害时触发
所以敌人反击时也会触发，加个限制就好
你的脚本限制太少了

希望创师

原帖由 fly123 于 2012-10-20 22:59 发表
!?MF1|v1004=41/v1005=41;
!!BG:A?y1 N?y2 H?y3 Q?y6;  攻击方
!!MF:N?y4 F?y5;    目标堆栈
!!BMy2&y2>-1:N?y7 T?y8 P?y9;攻击方
!!BMy4&y4>-1:N?y10 T?y11 P?y12;    目标堆栈

在后面接上!!BMy9:V79; 攻击时还是无复生动画产生

ashero4

孤注一掷后在物理近战前能吸血脚本，没测试过，应该可以

ZVSE

!?MF1&1000;    孤注一掷后近战攻击吸血,造成伤害时触发
!!VRv5100:C-1/-1; v5100-v5101
!!MF:N?v5100 F?v5101;  这里取得所造成的伤害，作为复活的数值
!!VRv5000:C-1/-1/-1/-1/-1/-1; v5000-v5006
!!VRv5007:C-1/-1/-1/-1/-1/-1/-1/-1/-1/-1;  v5007-v5016
!!VRv5017:C-1/-1/-1/-1/-1/-1/-1/-1;  v5017-v5024
!!BG:A?v5000 D?v5001 E?v5002 N?v5003 S?v5004; 造成伤害后用BG取得攻击方和被攻击方的堆栈
!!BG:Q?v5005 H?v5006;
!!BMv5002&v5002>-1:B?v5007 I?v5009 R?v5011 N?v5013 T?v5015 F?v5017 P?v5019 H?v5021 O?v5023;  被攻击方
!!BMv5003&v5003>-1:B?v5008 I?v5010 R?v5012 N?v5014 T?v5016 F?v5018 P?v5020 H?v5022 O?v5024;  攻击方
!!FU&v5000<>6:E;    不是主动近战攻击就退出
!!FU|v5003<0/v5003>41:E;
!!FU|v5002<0/v5002>41:E;
!!FU&v5016>144/v5016<150:E;
!!FU|v5013<1/v5015<0/v5014<1/v5016<0:E;
!!BMv5003:G56/?y1/?y2; 取得攻击堆栈身上的孤注回合数
!!FU&y1<1:E;  回合数小于1就退出吸血脚本
!!DO105/v5003/v5003/1&v5005=0:P30/0/20/v5101;  进攻方的孤注一掷
!!DO105/v5003/v5003/1&v5005=1:P30/21/41/v5101; 防守方的孤注一掷

!?FU105&x1=30;
!!FU|x16<x2/x16>x3:E;
!!BMx16:H?y1 L?y2 N?y3 B?y4 T?y98;
!!FU&y3<1:E;
!!FU&y98>144/y98<146:E;
!!FU&y98>146/y98<150:E;
!!VRy5:Sy1 *y4;
!!VRy6:Sy1 *y3 -y2;
!!FU&y6=y5:E;
!!VRy11:Sx4;
!!VRy7&y11>y1:Sy11 :y1;
!!VRy8&y11>y1:Sy11 %y1;
!!VRy9&y8>0/y11>y1:Sy1 -y8;
!!VRy9&y8=0/y11>y1:Sy1;
!!VRy9&y11<y1:Sy11;
!!VRy10&y9>y2:Sy2 *-1;
!!VRy10&y9<y2:Sy9 *-1;
!!VRy10&y4=1/y11>y1:Sy2 *-1;
!!VRy10&y4=1/y11<y1/y11<y2:Sy11 *-1;
!!VRy10&y4=1/y11<y1/y11>=y2:Sy2 *-1;
!!VRy20:Sy4 -y3;
!!VRy7&y7>y20:Sy20;
!!VRy7&y4=1:S0;
!!BMx16:Ndy7; 此处为吸血复活代码
!!BMx16:Ldy10;
!!UN:N3/23/y98/0;
!!VRz11&y7>0:S^{孤注一掷}使{%Y7 %Z23 起死回生.}^;
!!VRz11&y7=0:S^{孤注一掷}使{%Z23 恢复 %Y9 生命.}^;
!!MM:Sz11;
!!BU:R;

[ 本帖最后由 ashero4 于 2012-10-21 07:27 编辑 ]

希望创师

谢谢ashero4，经测erm可用，但有两个问题啊:
1、反击时不起作用，容易被骗反击后杀死。删掉“!!FU&v5000<>6:E;    不是主动近战攻击就退出”还是一样。
2、没用动画，在红字后面加动画，结果是在造成伤害前就出现了

ashero4

原帖由 希望创师 于 2012-10-21 09:19 发表
谢谢ashero4，经测erm可用，但有两个问题啊:
1、反击时不起作用，容易被骗反击后杀死。删掉“!!FU&v50006:E;    不是主动近战攻击就退出”还是一样。
  俺都说过了，俺找不到反击时的触发器
2、没用动画，在红字后面加动画，结果是在造成伤害前就出现了; ...

  如果你想要攻击后才复活的效果，得用BG1来触发。