谁能帮我看看这个erm，是否有什么错误

akgod

地址是这个，在erm区。最终15L的问题我求助了好几天，没人理。大概那边没人气吧。只好来这边求助了~~~
http://bbs.h3wog.com/viewthread.php?tid=37368&page=1&extra=page%3D1#pid395802
地址没办法点，我直接复制到2楼了，麻烦哪位大大帮忙看看

[ 本帖最后由 akgod 于 2012-7-26 07:21 编辑 ]

akgod

ZVSE
********************************************************************************
********************************************************************************
** 说    明：特定指挥官加强脚本                                               **
** 变量使用：v1、V9301--V9316、v9555、v9560                                   **
**           Z1--Z60                                                          **
**           对话框编号 02、38                                                **
**           FU编号  15010--15013                                             **
** 特技说明：1.六和甲--指挥官拥有击碎之斧、硬化之盾、密银之甲、速度之靴、     **
**                     锋利之剑 、巫术项链，游戏开始时设置修炼次数为10000次。 **
**           2.灵心咒--加快指挥官宝物修炼速度为正常的10--90倍。               **
**           3.金刚盾--减物理伤害，约4级时，可以实现免物理伤害。              **
**           4.雷神锤--加攻击伤害，每升2级，攻击伤害加100%。                  **
**           5.浑天镜--拥有伤害反弹技能，每升4级，反弹伤害增加100%。          **
**           6.千手佛--群攻技能，以指挥官为中心，以六角形为基准，随等级增     **
**                     加攻击半径，一级时类似环击。                           **
** 设置说明：各项技能可以单独使用或关闭。                                     **
**                                                                            **
********************************************************************************
*********************初始设置***************************************************
!?PI;
!!UN:P3/?v1;
!!VRv9316&v1=1:S2;                      指挥官禁用开关 V9316
!!IF&v9316=2:L^您已禁用了指挥官，指挥官加强程序将无法进行!^;
!!FU&v9316=2:E;
!!VRv9302:C0/0/0/0/0/0/0/0;             V9302--V9309
!!VRv9310:C0/-2/-2/-2/-2/-2;            V9310--V9315
!!VRy1:S-2;
!!VRy2:S-2;
!!VRy3:S-2;
!!DO15010/0/7/1&v9310=0:P;
!!HEv9311&v9311>-1:B0/?z2 B2/?y1;       第一英雄名字、类型
!!HEv9312&v9312>-1:B0/?z3 B2/?y2;       第二英雄名字、类型
!!HEv9313&v9313>-1:B0/?z4 B2/?y3;       第三英雄名字、类型
!!VRy1&y1>-1:Sy1+10;
!!VRy2&y2>-1:Sy2+10;
!!VRy3&y3>-1:Sy3+10;
!!VRz2&v9311<0:S^^;
!!VRz3&v9312<0:S^^;
!!VRz4&v9313<0:S^^;
!!VRz10:S^骑士^;
!!VRz11:S^牧师^;
!!VRz12:S^巡逻兵^;
!!VRz13:S^德鲁伊^;
!!VRz14:S^炼金术士^;
!!VRz15:S^术士^;
!!VRz16:S^魔鬼^;
!!VRz17:S^异教徒^;
!!VRz18:S^死亡骑士^;
!!VRz19:S^巫师^;
!!VRz20:S^妖术师^;
!!VRz21:S^地下领主^;
!!VRz22:S^野蛮人^;
!!VRz23:S^战斗法师^;
!!VRz24:S^驯兽师^;
!!VRz25:S^女巫^;
!!VRz26:S^元素人^;
!!VRz27:S^元素使^;
!!VRz28&y1>9:Szy1;
!!VRz29&y2>9:Szy2;
!!VRz30&y3>9:Szy3;
!!VRz31:S^＝＝ 指挥官加强版 ＝＝^;
!!VRz32:S^请输入您想选择的英雄的名字^;
!!VRz33:S^拥有超级指挥官的英雄^;
!!VRz34:S^..\Data\zvs\Lib1.res\1680GAME_1001.bmp^;
!!VRz35:S^..\Data\zvs\Lib1.res\1680GAME_1002.bmp^;
!!VRz36:S^..\Data\zvs\Lib1.res\1680GAME_1003.bmp^;
!!VRz37:S^..\Data\zvs\Lib1.res\1680GAME_1004.bmp^;
!!VRz38:S^我要自己决定^;
!!VRz39:S^%Z28  ^+^%Z2^;
!!VRz40:S^%Z29  ^+^%Z3^;
!!VRz41:S^%Z30  ^+^%Z4^;
!!VRz42:S^请在左边输入姓名（小心不要让敌人雇了去哦！）^;
!!VRz43:S^人类玩家第一英雄（系统默认）^;
!!VRz44:S^人类玩家第二英雄^;
!!VRz45:S^人类玩家第三英雄^;
!!IF:D38/31/32/33/34/35/36/37/////38/39/40/41;
!!IF:F38/42/43/44/45/1;
!!IF:E9302/38;                                        英雄选择 v9302
!!VRz1:M4/?y4;                                        所选英雄 v9315
!!DO15011/0/155/1&v9302=1/y4>0:P;
!!VRv9315&v9302=-1/v9311>-1:Sv9311;
!!VRv9315&v9302=2/v9311>-1:Sv9311;
!!VRv9315&v9302=3/v9312>-1:Sv9312;
!!VRv9315&v9302=4/v9313>-1:Sv9313;
!!VRv9315&v9302=1/y4<1:Sv9311;
!!VRv9315&v9302=1/y4>0:Sv9314;
!!VRz50:S^＝＝ 指挥官特别技能设置 ＝＝^;
!!VRz51:S^六合甲--指挥官拥有全宝物^;
!!VRz52:S^灵心咒--提升修炼速度^;
!!VRz53:S^金刚盾--每级减少物理伤害25%^;
!!VRz54:S^雷神锤--每级增加进攻伤害50%^;
!!VRz55:S^混天镜--每级增加伤害反弹25%^;
!!VRz56:S^千手佛--随等级增加攻击区域^;
!!IF:G0/9303/0/50/51/52/53/54/55/56;                  技能选择 v9303
!!VRy5:Sv9303;
!!VRy6:Sv9303;
!!VRy7:Sv9303;
!!VRy8:Sv9303;
!!VRy9:Sv9303;
!!VRy10:Sv9303;
!!VRy5:&1;
!!VRy6:&2;
!!VRy7:&4;
!!VRy8:&8;
!!VRy9:&16;
!!VRy10:&32;
!!VRv9304&y5>0:S2;                                    六合甲开关   v9304
!!VRv9305&y6>0:S0;                                    灵心咒开关   v9305
!!VRv9306&y7>0:S2;                                    金刚盾开关   v9306
!!VRv9307&y8>0:S2;                                    雷神锤开关   v9307
!!VRv9308&y9>0:S2;                                    混天镜开关   v9308
!!VRv9309&y10>0:S2;                                   千手佛开关   v9309
!!VRz57:S^灵心咒--修炼速度设置^;
!!VRz58:S^初级--三重功力^;
!!VRz59:S^中级--六重功力^;
!!VRz60:S^高级--九重功力^;
!!IF:D02///57/////////58/59/60/0;
!!IF:F02/////0;
!!IF&y6>0:E9305/02;                                   灵心咒等级   V9305
*********************基本属性、扩展技能*****************************************
!!COv9315:P0/10 P1/10 P2/60 P3/20 P4/10 P5/10 P6/100;  基本属性
!!COv9315:S0/1 S1/1 S2/1 S3/1 S4/1 S5/0 S6/5;          技能等级
!!COv9315:B1/3/0 B1/7/1 B1/8/1 B1/14/1;                扩展特技
********************六合甲设置**************************************************
!!COv9315&v9304>0:A1/146/10000;  击碎之斧  修炼次数=10000
!!COv9315&v9304>0:A1/154/10000;  硬化之盾  修炼次数=10000
!!COv9315&v9304>0:A1/147/10000;  密银之甲  修炼次数=10000
!!COv9315&v9304>0:A1/151/10000;  速度之靴  修炼次数=10000
!!COv9315&v9304>0:A1/148/10000;  锋利之剑  修炼次数=10000
!!COv9315&v9304>0:A1/150/10000;  巫术项链  修炼次数=10000
********************初始设置---FU函数*******************************************
!?FU15010&v9310=0;
!!OW:Ix16/?y1;                 获取人类玩家颜色编号
!!FU&y1>0:E;
!!OW&y1=0:Hx16/9310/0;         人类玩家英雄数量
!!OW&y1=0/v9310>0:Hx16/9311/1; 第一英雄编号
!!OW&y1=0/v9310>1:Hx16/9312/2; 第二英雄编号
!!OW&y1=0/v9310>2:Hx16/9313/3; 第三英雄编号
!?FU15011&v9302=1/v9314<0;
!!VRz5:S^^;
!!HEx16:B0/?z5;                英雄名字
!!FU&z1<>z5:E;
!!VRv9314&z1=z5:Sx16;          英雄编号
********************灵心咒设置**************************************************
!?BA1&1000;
!!FU|v9316=2/v9305<1:E;
!!BA:H0/?v9555;
!!BA:H1/?v9560;
!!FU&v9555<>v9315/v9560<>v9315:E;
!!DO15012/0/5/1:P;
!?FU15012;
!!COv9315:A3/x16/?y1/?y2;
!!VRy3&y2>0:S5*v9305;        击碎之斧、硬化之盾每胜利一场，加5*v9305所选等级
!!VRy4&y2>0:S7*v9305;        密银之甲、锋利之剑每胜利一场，加7*v9305所选等级
!!VRy5&y2>0:S3*v9305;        速度之靴、巫术项链每胜利一场，加3*v9305所选等级
!!VRy2&y2>0/y1=146:Sdy3;     击碎之斧
!!VRy2&y2>0/y1=154:Sdy3;     硬化之盾
!!VRy2&y2>0/y1=147:Sdy4;     密银之甲
!!VRy2&y2>0/y1=151:Sdy5;     速度之靴
!!VRy2&y2>0/y1=148:Sdy4;     锋利之剑
!!VRy2&y2>0/y1=150:Sdy5;     巫术项链
!!COv9315&y2>0:A3/x16/y1/y2;
********************金刚盾、雷神锤、混天镜、千手佛设置**************************
!?BG0&1000
!!VRv9301:S1;                       运行开关  v9301
!?MF1&1000;
!!FU&v9316=2:E;
!!FU|v9301<1/v9301>9:E;
**设置**
!!VRx1:S0;
!!VRx2:S0;
!!VRx3:S0;
!!VRx4:S0;
!!VRx5:S0;
!!VRx6:S0;
!!VRy1:S0;
!!VRy6:S0;
!!VRy13:S0;
!!VRy14:S0;
!!VRy15:S0;
!!VRy16:S0;
!!VRy21:S0;
!!VRy26:S0;
!!VRv9301&v9301=2:S6;
!!VRv9301&v9301=3:S7;
!!VRv9301&v9301=4:S8;
!!VRv9301&v9301=5:S9;
**读取**
!!MF:F?x1 W?x2;                                        x1=伤害值 x2=进攻方编号（2=箭塔、1=护城河、0=其他）
!!BG: N?x3 E?x4 A?x5 Q?x7;                             x3=进攻方堆栈 x4=防守方堆栈  x5=动作种类 x7=动作方
!!FU&x5<>6/x5<>7/x5<>9:E;
!!BMx3:T?y1 I?y2 N?y3 F?y4 G29/?y5/?y10;              （攻）y1=编号、y2=所属、y3=当前数量、y4=不反击、y5=火盾
!!BA:Hy2/?y6;                                         （攻）y6=所属英雄编号
!!VRy4:&65536;
!!BMx4&x4>-1:T?y21 I?y22 N?y23 R?y24 G29/?y25/?y11;   （防）y21=编号、y22=所属、y23=当前数量、y24=反击次数、y25=火盾
!!BA:Hy22/?y26;                                       （防）y26=所属英雄编号
!!HEv9315:E?y12/?x6;                                   x6=v9315英雄等级
**判断**
!!VRy13|y1<174/y1>191/y6<>v9315:S1;
!!VRy14|y21<174/y21>191/y26<>v9315:S1;
!!FU&y13>0/y14>0:E;
!!VRv9301|y3<1/y23<1:S1;
!!FU|y3<1/y23<1:E;
!!VRy15&y1<150/y1>144:S2;
!!VRy16&y21<150/y21>144:S2;
**伤害**  
!!VRy17&v9307=2:Sx1*x6:2+x1;   雷神锤50%=伤害*等级:2
!!VRy17&v9307<>2:Sx1;          没开雷神锤取原伤害
!!VRy18:Sx1*x6:4;              混天镜25%=伤害*等级:4
!!VRy19:Sx1-y18;               金刚盾25%=伤害-反弹计算结果
!!VRy20&v9306=2/y19<=1:S1;     开金刚盾最少伤害为1
!!VRy20&v9306=2/y19>1:Sy19;    开金刚盾伤害取上面那个y19的计算
!!VRy20&v9306<>2:Sx1;          没开金刚盾取原伤害
**第一轮**
!!MF&v9301=1/y6=v9315:Fy17;
!!MF&v9301=1/y26=v9315:Fy20;
!!BMx3&v9308=2/v9301=1/y26=v9315/x5=6/x2=0/y15<>2/y23>0:Ky18 V84;
!!DO15013/0/20/1&v9309=2/v9301=1/y6=v9315/y23>0/x7=1:P100/x4/y17;
!!DO15013/21/41/1&v9309=2/v9301=1/y6=v9315/y23>0/x7=0:P100/x4/y17;
!!VRv9301&v9301=1/x5=6/y6=v9315/y4<1/y5<1/y24>0:S2;
!!VRv9301&v9301=1/x5=6/y26=v9315/y4<1/y24>0/y25<1:S2;
!!VRv9301&v9301=1/x5=6/y26=v9315/y4>0/y25>0:S3;
!!VRv9301&v9301=1/x5=6/y26=v9315/y4<1/y24<1/y25>0:S3;
!!VRv9301&v9301=1/x5=6/y6=v9315/y4<1/y5>0/y24>0:S4;
!!VRv9301&v9301=1/x5=6/y26=v9315/y4<1/y24>0/y25>0:S5;
!!FU&v9301>1/v9301<6:E;
**第二轮**
!!MF&v9301=6/y6=v9315/y3>0:Fy20;
!!MF&v9301=6/y26=v9315/y23>0:Fy17;
!!BMx4&v9308=2/v9301=6/y6=v9315/x5=6/x2=0/y16<>2/y3>0:Ky18 V84;
!!VRv9301&v9301=6:S1;
!!MF&v9301=7/y23>0:Fx1;
!!VRv9301&v9301=7:S1;
!!MF&v9301=8/y3>0:Fy20;
!!BMx4&v9308=2/v9301=8/y6=v9315/x5=6/x2=0/y16<>2/y3>0:Ky18 V84;
!!VRv9301&v9301=8:S7;
!!MF&v9301=9/y23>0:Fx1;
!!VRv9301&v9301=9:S6;
********************千手佛设置**************************************************
!?FU15013&v9309=2/x1=100;
!!BMx16:N?y1 T?y2 P?y3;
!!FU|y1<1/y2=149/x16=x2:E;
!!BMx16:Kx3;

akgod

********************千手佛设置**************************************************
!?FU15013&v9309=2/x1=100;
!!BMx16:N?y1 T?y2 P?y3;
!!FU|y1<1/y2=149/x16=x2:E;
!!BMx16:Kx3;

顺带问问，这个千手佛的设置，100是代表范围么？是否我更改了100这个数字，就可以更改范围？？？

格鲁

都是一个论坛，哪有那边没人气？你帖子板块也发错了。
我小白，什么都不知道

沧海一粟

楼主，每个人的实际情况不同，视工作及其它情况不可能每天都抽出时间来帮你完善ERM；每个人写脚本的思路不同，实现方式也会不同，看别人的脚本有时会比自己重新写麻烦很多，因为要把自己的思路强加到别人的思路上去。该脚本作者在创作这个脚本时也是学习ERM不久，虽然进步很快，原理条理也基本清楚，但毕竟时间有限，写法还是啰嗦纠结了点。
=================================
此帖已经重复，既然楼主觉得我们ERM没人气，麻烦管理员或超级版主帮忙把楼主发到ERM区的重复内容帖子移到游戏讨论区来，谢谢

akgod

原帖由 沧海一粟 于 2012-7-26 08:46 发表
楼主，每个人的实际情况不同，视工作及其它情况不可能每天都抽出时间来帮你完善ERM；每个人写脚本的思路不同，实现方式也会不同，看别人的脚本有时会比自己重新写麻烦很多，因为要把自己的思路强加到别人的思路上去。 ...

不好意思，可能我说的不太准确，但是我确实急着想知道原因。
之前你帮助我修改的内容，我一个字不差的贴了进去。然后就出现我之前说的情况了。虽然能全屏攻击了，但是每次进战场都要点很久的回车。

这几天比较闲，所以一直在玩wog。但是这样一个问题，一直困扰着我。  我仔细检查了你给我修改的内容，确认了没有复制错。但是偏偏问题就放在那里。

我不了解erm，但是我看过去有人贴出erm，高手很快就能看到里面的错误。所以我才想来论坛求助一下，看看是否我哪里复制粘贴错误了。

但是就这样一个对错的问题，我问了2天，也没人回复。我才会思考是不是erm区没人去看。迫于无奈只好发到这里问问。

沧海一粟

你这问题我不会，但我相信有很多人会。
WOG论坛每个版块都是一家，如果有时间我上论坛必定会每帖包括每个新的回帖都浏览一遍，并不分什么区，我相信很多人都和我一样。至于ERM没人气，应该还不至于吧，我们那里藏龙卧虎，高手云集，只不过有时需要时间和条件允许而已。

贤知有您

这几天不知道为什么，上论坛总是莫名的断开，甚至开不了网页。

楼主莫急。有时候出现问题并不一定是某段ERM的错误，可能是整体的冲突。而这个整体就比较难判断了。
而且要测试出问题也要花一定的时间，除非脚本是自己写的，不然一段一段看也很让人抓狂的。
我也是ERM入门，但也觉得自己去判断比别人判断来得容易些，毕竟自己用了什么脚本都一清二楚。
然后在脚本处加一些判断标识，比如脚本运行到什么地方，运行中显示出一些变量的参数，看看是否参数有误等等。

论坛一家亲，每个版区都一样。我有空也帮你测试一下吧。

akgod

原帖由 沧海一粟 于 2012-7-26 09:09 发表
你这问题我不会，但我相信有很多人会。
WOG论坛每个版块都是一家，如果有时间我上论坛必定会每帖包括每个新的回帖都浏览一遍，并不分什么区，我相信很多人都和我一样。至于ERM没人气，应该还不至于吧，我们那里藏龙 ...

我知道了，我没有埋怨你的意思，我很感谢之前你对我的帮助。现在玩wog的人很多年就都30左右了，正是比较忙的阶段，我能理解。主要这几天我正好对wog又痴迷了，而这个erm又是我对wog痴迷的很重要的因素之一。所以我有点急切想知道解决办法了。

这么看来，我至少，复制粘贴你帮我改的内容都没错误吧。   我之前最担心的，是因为我对erm不熟悉，连你帮我改的内容都复制粘贴错误了

akgod

原帖由 hanter007 于 2012-7-26 09:27 发表
这几天不知道为什么，上论坛总是莫名的断开，甚至开不了网页。

楼主莫急。有时候出现问题并不一定是某段ERM的错误，可能是整体的冲突。而这个整体就比较难判断了。
而且要测试出问题也要花一定的时间，除非脚本是 ...

严重感谢。其实我刚才已经测试了，貌似用纯净版是没问题的。
我比较担心的是因为我对erm太小白，连之前复制粘贴的位置都错误，所以才那么急切的在论坛询问。
现在我多少搞明白一点了，我总是把erm当成war3来理解，因为war3的编辑，一看别人的dd就很明了，所以我想着erm的错误也是可以一眼看出来的

akgod

原帖由 沧海一粟 于 2012-7-26 09:09 发表
你这问题我不会，但我相信有很多人会。
WOG论坛每个版块都是一家，如果有时间我上论坛必定会每帖包括每个新的回帖都浏览一遍，并不分什么区，我相信很多人都和我一样。至于ERM没人气，应该还不至于吧，我们那里藏龙 ...

********************千手佛设置**************************************************
!?FU15013&v9309=2/x1=100;
!!BMx16:N?y1 T?y2 P?y3;
!!FU|y1<1/y2=149/x16=x2:E;
!!BMx16:Kx3;

顺带问问，这个千手佛的设置，100是代表范围么？是否我更改了100这个数字，就可以更改范围？？？


沧海，这个是你之前给我写的内容，弱弱问一下，这里有没有哪个数字，是改动一下就可以更改攻击范围的？？

贤知有您

刚才试了一下楼主贴出的脚本。
没有楼主说的战斗前的错误。

反弹伤害也是正确的,楼主你不要直接看下面的战斗信息.要看实际产生的伤害,计算一下对方死了多少兵一共掉了多少血.
下面战斗信息栏只显示了原反弹伤害.
你将这个 原伤害*英雄等级/4 就是新增的伤害了,总体反弹伤害就是这个新增伤害+原伤害.

效果是正确的.
不过说实在的,这个ERM设置的有点不合理，连对方攻击伤害都增强了。不过好在指挥官有那个减少伤害的。

akgod

原帖由 hanter007 于 2012-7-26 10:09 发表
刚才试了一下楼主贴出的脚本。
没有楼主说的战斗前的错误。

反弹伤害也是正确的,楼主你不要直接看下面的战斗信息.要看实际产生的伤害,计算一下对方死了多少兵一共掉了多少血.
下面战斗信息栏只显示了原反弹伤害 ...

严重感谢~~~
我贴出来那个   你知道改哪个数字是更改范围么？
11L的内容

贤知有您

脚本已经是全屏攻击，还想改什么呢？
X1=100只是一个辅助条件，没关系。
以下语句是全屏攻击的语句：
!!DO15013/0/20/1&v9309=2/v9301=1/y6=v9315/y23>0/x7=1:P100/x4/y17;
!!DO15013/21/41/1&v9309=2/v9301=1/y6=v9315/y23>0/x7=0:P100/x4/y17;

0－20或21－41代表了左右两种势力的全部部队。循环伤害一次，所以就是全屏攻击了。

akgod

原帖由 hanter007 于 2012-7-26 10:13 发表
脚本已经是全屏攻击，还想改什么呢？
X1=100只是一个辅助条件，没关系。
以下语句是全屏攻击的语句：
!!DO15013/0/20/1&v9309=2/v9301=1/y6=v9315/y23>0/x7=1:P100/x4/y17;
!!DO15013/21/41/1&v9309=2/v9301=1/y ...

我是想把范围改小，因为以前的原作者脚本，我发现玩一会后千手佛就无效了。也许是原作者的失误，也许是我erm太多造成的。但是这个erm的我貌似是可以用的。但是这个设置是全屏的，做bos可以，自己玩就没劲了，所以我才想问问能否把这个改小

贤知有您

原来的那个设定是如何的呢？
你又想达到什么样的效果呢？
这个指挥官也太强悍了，用作BT地图还可以。
一刀下去几百的龙巫妖都挂了。
可以改改升级设定，每级不要增加得太多了。

[ 本帖最后由 hanter007 于 2012-7-26 10:37 编辑 ]

akgod

原帖由 hanter007 于 2012-7-26 10:34 发表
原来的那个设定是如何的呢？
你又想达到什么样的效果呢？
这个指挥官也太强悍了，用作BT地图还可以。
一刀下去几百的龙巫妖都挂了。
可以改改升级设定，每级不要增加得太多了。

http://www.wogcn.net/thread-35381-1-1.html
这个是原作者的设定，都很好，不过我发现，如果只开千手佛、浑天镜、金刚盾，那我玩一会千手佛就无效了……也没任何报错，就是直接无效了~~~
所以我只好从沧海这个千手佛来入手寻求帮助了，如果可以，我是想沧海这个千手佛的脚本，能否更改攻击范围。（以前我以为那个100就是范围，改成50就是半屏幕……）

贤知有您

将原来的替换现在的.没发现什么问题呢.


ZVSE
********************************************************************************
********************************************************************************
** 说    明：特定指挥官加强脚本                                               **
** 变量使用：v1、V9301--V9316、v9555、v9560                                   **
**           Z1--Z60                                                          **
**           对话框编号 02、38                                                **
**           FU编号  15010--15013                                             **
** 特技说明：1.六和甲--指挥官拥有击碎之斧、硬化之盾、密银之甲、速度之靴、     **
**                     锋利之剑 、巫术项链，游戏开始时设置修炼次数为10000次。 **
**           2.灵心咒--加快指挥官宝物修炼速度为正常的10--90倍。               **
**           3.金刚盾--减物理伤害，约4级时，可以实现免物理伤害。              **
**           4.雷神锤--加攻击伤害，每升2级，攻击伤害加100%。                  **
**           5.浑天镜--拥有伤害反弹技能，每升4级，反弹伤害增加100%。          **
**           6.千手佛--群攻技能，以指挥官为中心，以六角形为基准，随等级增     **
**                     加攻击半径，一级时类似环击。                           **
** 设置说明：各项技能可以单独使用或关闭。                                     **
**                                                                            **
********************************************************************************
*********************初始设置***************************************************
!?PI;
!!UN:P3/?v1;
!!VRv9316&v1=1:S2;                      指挥官禁用开关 V9316
!!IF&v9316=2:L^您已禁用了指挥官，指挥官加强程序将无法进行!^;
!!FU&v9316=2:E;
!!VRv9302:C0/0/0/0/0/0/0/0;             V9302--V9309
!!VRv9310:C0/-2/-2/-2/-2/-2;            V9310--V9315
!!VRy1:S-2;
!!VRy2:S-2;
!!VRy3:S-2;
!!DO15010/0/7/1&v9310=0:P;
!!HEv9311&v9311>-1:B0/?z2 B2/?y1;       第一英雄名字、类型
!!HEv9312&v9312>-1:B0/?z3 B2/?y2;       第二英雄名字、类型
!!HEv9313&v9313>-1:B0/?z4 B2/?y3;       第三英雄名字、类型
!!VRy1&y1>-1:Sy1+10;
!!VRy2&y2>-1:Sy2+10;
!!VRy3&y3>-1:Sy3+10;
!!VRz2&v9311<0:S^^;
!!VRz3&v9312<0:S^^;
!!VRz4&v9313<0:S^^;
!!VRz10:S^骑士^;
!!VRz11:S^牧师^;
!!VRz12:S^巡逻兵^;
!!VRz13:S^德鲁伊^;
!!VRz14:S^炼金术士^;
!!VRz15:S^术士^;
!!VRz16:S^魔鬼^;
!!VRz17:S^异教徒^;
!!VRz18:S^死亡骑士^;
!!VRz19:S^巫师^;
!!VRz20:S^妖术师^;
!!VRz21:S^地下领主^;
!!VRz22:S^野蛮人^;
!!VRz23:S^战斗法师^;
!!VRz24:S^驯兽师^;
!!VRz25:S^女巫^;
!!VRz26:S^元素人^;
!!VRz27:S^元素使^;
!!VRz28&y1>9:Szy1;
!!VRz29&y2>9:Szy2;
!!VRz30&y3>9:Szy3;
!!VRz31:S^＝＝ 指挥官加强版 ＝＝^;
!!VRz32:S^请输入您想选择的英雄的名字^;
!!VRz33:S^拥有超级指挥官的英雄^;
!!VRz34:S^..\Data\zvs\Lib1.res\1680GAME_1001.bmp^;
!!VRz35:S^..\Data\zvs\Lib1.res\1680GAME_1002.bmp^;
!!VRz36:S^..\Data\zvs\Lib1.res\1680GAME_1003.bmp^;
!!VRz37:S^..\Data\zvs\Lib1.res\1680GAME_1004.bmp^;
!!VRz38:S^我要自己决定^;
!!VRz39:S^%Z28  ^+^%Z2^;
!!VRz40:S^%Z29  ^+^%Z3^;
!!VRz41:S^%Z30  ^+^%Z4^;
!!VRz42:S^请在左边输入姓名（小心不要让敌人雇了去哦！）^;
!!VRz43:S^人类玩家第一英雄（系统默认）^;
!!VRz44:S^人类玩家第二英雄^;
!!VRz45:S^人类玩家第三英雄^;
!!IF:D38/31/32/33/34/35/36/37/////38/39/40/41;
!!IF:F38/42/43/44/45/1;
!!IF:E9302/38;                                        英雄选择 v9302
!!VRz1:M4/?y4;                                        所选英雄 v9315
!!DO15011/0/155/1&v9302=1/y4>0:P;
!!VRv9315&v9302=-1/v9311>-1:Sv9311;
!!VRv9315&v9302=2/v9311>-1:Sv9311;
!!VRv9315&v9302=3/v9312>-1:Sv9312;
!!VRv9315&v9302=4/v9313>-1:Sv9313;
!!VRv9315&v9302=1/y4<1:Sv9311;
!!VRv9315&v9302=1/y4>0:Sv9314;
!!VRz50:S^＝＝ 指挥官特别技能设置 ＝＝^;
!!VRz51:S^六合甲--指挥官拥有全宝物^;
!!VRz52:S^灵心咒--提升修炼速度^;
!!VRz53:S^金刚盾--每级减少物理伤害25%^;
!!VRz54:S^雷神锤--每级增加进攻伤害50%^;
!!VRz55:S^混天镜--每级增加伤害反弹25%^;
!!VRz56:S^千手佛--随等级增加攻击区域^;
!!IF:G0/9303/0/50/51/52/53/54/55/56;                  技能选择 v9303
!!VRy5:Sv9303;
!!VRy6:Sv9303;
!!VRy7:Sv9303;
!!VRy8:Sv9303;
!!VRy9:Sv9303;
!!VRy10:Sv9303;
!!VRy5:&1;
!!VRy6:&2;
!!VRy7:&4;
!!VRy8:&8;
!!VRy9:&16;
!!VRy10:&32;
!!VRv9304&y5>0:S2;                                    六合甲开关   v9304
!!VRv9305&y6>0:S0;                                    灵心咒开关   v9305
!!VRv9306&y7>0:S2;                                    金刚盾开关   v9306
!!VRv9307&y8>0:S2;                                    雷神锤开关   v9307
!!VRv9308&y9>0:S2;                                    混天镜开关   v9308
!!VRv9309&y10>0:S2;                                   千手佛开关   v9309
!!VRz57:S^灵心咒--修炼速度设置^;
!!VRz58:S^初级--三重功力^;
!!VRz59:S^中级--六重功力^;
!!VRz60:S^高级--九重功力^;
!!IF:D02///57/////////58/59/60/0;
!!IF:F02/////0;
!!IF&y6>0:E9305/02;                                   灵心咒等级   V9305
*********************基本属性、扩展技能*****************************************
!!COv9315:P0/10 P1/10 P2/60 P3/20 P4/10 P5/10 P6/100;  基本属性
!!COv9315:S0/1 S1/1 S2/1 S3/1 S4/1 S5/0 S6/5;          技能等级
!!COv9315:B1/3/0 B1/7/1 B1/8/1 B1/14/1;                扩展特技
********************六合甲设置**************************************************
!!COv9315&v9304>0:A1/146/10000;  击碎之斧  修炼次数=10000
!!COv9315&v9304>0:A1/154/10000;  硬化之盾  修炼次数=10000
!!COv9315&v9304>0:A1/147/10000;  密银之甲  修炼次数=10000
!!COv9315&v9304>0:A1/151/10000;  速度之靴  修炼次数=10000
!!COv9315&v9304>0:A1/148/10000;  锋利之剑  修炼次数=10000
!!COv9315&v9304>0:A1/150/10000;  巫术项链  修炼次数=10000
********************初始设置---FU函数*******************************************
!?FU15010&v9310=0;
!!OW:Ix16/?y1;                 获取人类玩家颜色编号
!!FU&y1>0:E;
!!OW&y1=0:Hx16/9310/0;         人类玩家英雄数量
!!OW&y1=0/v9310>0:Hx16/9311/1; 第一英雄编号
!!OW&y1=0/v9310>1:Hx16/9312/2; 第二英雄编号
!!OW&y1=0/v9310>2:Hx16/9313/3; 第三英雄编号
!?FU15011&v9302=1/v9314<0;
!!VRz5:S^^;
!!HEx16:B0/?z5;                英雄名字
!!FU&z1<>z5:E;
!!VRv9314&z1=z5:Sx16;          英雄编号
********************灵心咒设置**************************************************
!?BA1&1000;
!!FU|v9316=2/v9305<1:E;
!!BA:H0/?v9555;
!!BA:H1/?v9560;
!!FU&v9555<>v9315/v9560<>v9315:E;
!!DO15012/0/5/1:P;
!?FU15012;
!!COv9315:A3/x16/?y1/?y2;
!!VRy3&y2>0:S5*v9305;        击碎之斧、硬化之盾每胜利一场，加5*v9305所选等级
!!VRy4&y2>0:S7*v9305;        密银之甲、锋利之剑每胜利一场，加7*v9305所选等级
!!VRy5&y2>0:S3*v9305;        速度之靴、巫术项链每胜利一场，加3*v9305所选等级
!!VRy2&y2>0/y1=146:Sdy3;     击碎之斧
!!VRy2&y2>0/y1=154:Sdy3;     硬化之盾
!!VRy2&y2>0/y1=147:Sdy4;     密银之甲
!!VRy2&y2>0/y1=151:Sdy5;     速度之靴
!!VRy2&y2>0/y1=148:Sdy4;     锋利之剑
!!VRy2&y2>0/y1=150:Sdy5;     巫术项链
!!COv9315&y2>0:A3/x16/y1/y2;
********************金刚盾、雷神锤、混天镜、千手佛设置**************************
!?BG0&1000
!!VRv9301:S1;                       运行开关  v9301
!?MF1&1000;
!!FU&v9316=2:E;
!!FU|v9301<1/v9301>9:E;
**设置**
!!VRx1:S0;
!!VRx2:S0;
!!VRx3:S0;
!!VRx4:S0;
!!VRx5:S0;
!!VRx6:S0;
!!VRy1:S0;
!!VRy6:S0;
!!VRy13:S0;
!!VRy14:S0;
!!VRy15:S0;
!!VRy16:S0;
!!VRy21:S0;
!!VRy26:S0;
!!VRv9301&v9301=2:S6;
!!VRv9301&v9301=3:S7;
!!VRv9301&v9301=4:S8;
!!VRv9301&v9301=5:S9;
**读取**
!!MF:F?x1 W?x2;                                        x1=伤害值 x2=进攻方编号（2=箭塔、1=护城河、0=其他）
!!BG: N?x3 E?x4 A?x5 Q?x7;                             x3=进攻方堆栈 x4=防守方堆栈  x5=动作种类 x7=动作方
!!FU&x5<>6/x5<>7/x5<>9:E;
!!BMx3:T?y1 I?y2 N?y3 F?y4 G29/?y5/?y10;              （攻）y1=编号、y2=所属、y3=当前数量、y4=不反击、y5=火盾
!!BA:Hy2/?y6;                                         （攻）y6=所属英雄编号
!!VRy4:&65536;
!!BMx4&x4>-1:T?y21 I?y22 N?y23 R?y24 G29/?y25/?y11;   （防）y21=编号、y22=所属、y23=当前数量、y24=反击次数、y25=火盾
!!BA:Hy22/?y26;                                       （防）y26=所属英雄编号
!!HEv9315:E?y12/?x6;                                   x6=v9315英雄等级
**判断**
!!VRy13|y1<174/y1>191/y6<>v9315:S1;
!!VRy14|y21<174/y21>191/y26<>v9315:S1;
!!FU&y13>0/y14>0:E;
!!VRv9301|y3<1/y23<1:S1;
!!FU|y3<1/y23<1:E;
!!VRy15&y1<150/y1>144:S2;
!!VRy16&y21<150/y21>144:S2;
**伤害**  
!!VRy17&v9307=2:Sx1*x6:2+x1;   雷神锤50%=伤害*等级:2
!!VRy17&v9307<>2:Sx1;          没开雷神锤取原伤害
!!VRy18:Sx1*x6:4;              混天镜25%=伤害*等级:4

!!VRy19:Sx1-y18;               金刚盾25%=伤害-反弹计算结果
!!VRy20&v9306=2/y19<=1:S1;     开金刚盾最少伤害为1
!!VRy20&v9306=2/y19>1:Sy19;    开金刚盾伤害取上面那个y19的计算
!!VRy20&v9306<>2:Sx1;          没开金刚盾取原伤害
**第一轮**
!!MF&v9301=1/y6=v9315:Fy17;
!!MF&v9301=1/y26=v9315:Fy20;
!!BMx3&v9308=2/v9301=1/y26=v9315/x5=6/x2=0/y15<>2/y23>0:Ky18 V84;
!!DO15013/0/20/1&v9309=2/v9301=1/y6=v9315/y23>0/x7=1:P100/x4/y17;
!!DO15013/21/41/1&v9309=2/v9301=1/y6=v9315/y23>0/x7=0:P100/x4/y17;
!!VRv9301&v9301=1/x5=6/y6=v9315/y4<1/y5<1/y24>0:S2;
!!VRv9301&v9301=1/x5=6/y26=v9315/y4<1/y24>0/y25<1:S2;
!!VRv9301&v9301=1/x5=6/y26=v9315/y4>0/y25>0:S3;
!!VRv9301&v9301=1/x5=6/y26=v9315/y4<1/y24<1/y25>0:S3;
!!VRv9301&v9301=1/x5=6/y6=v9315/y4<1/y5>0/y24>0:S4;
!!VRv9301&v9301=1/x5=6/y26=v9315/y4<1/y24>0/y25>0:S5;
!!FU&v9301>1/v9301<6:E;
**第二轮**
!!MF&v9301=6/y6=v9315/y3>0:Fy20;
!!MF&v9301=6/y26=v9315/y23>0:Fy17;
!!BMx4&v9308=2/v9301=6/y6=v9315/x5=6/x2=0/y16<>2/y3>0:Ky18 V84;
!!VRv9301&v9301=6:S1;
!!MF&v9301=7/y23>0:Fx1;
!!VRv9301&v9301=7:S1;
!!MF&v9301=8/y3>0:Fy20;
!!BMx4&v9308=2/v9301=8/y6=v9315/x5=6/x2=0/y16<>2/y3>0:Ky18 V84;
!!VRv9301&v9301=8:S7;
!!MF&v9301=9/y23>0:Fx1;
!!VRv9301&v9301=9:S6;
********************千手佛设置**************************************************
********************千手佛设置**************************************************

!?FU15013&v9309=2/x1=100;    P100/x3/x4/x6/y17
!!BMx16:N?y1 P?y3;
!!FU|y1<1/x16=x3:E;    去掉攻击目标堆栈
!!BMx2:P?y2;           指挥官位置
!!FU|y2>188/y2<0:E;
!!FU|y3>188/y3<0:E;
!!VRy4:Sy2:17+1;       指挥官所在行
!!VRy5:Sy2%17+1;       指挥官所在位
!!VRy6:Sy3:17+1;       怪物所在行
!!VRy7:Sy3%17+1;       怪物所在位
!!VRy8:Sy4-y6;         行差
!!VRy9&y8>=0:Sy8;
!!VRy9&y8<0:Sy8*-1;
!!VRy10:Sx4:8;         级别
!!FU|y10<1:E;
!!VRy11:Sy4%2;         行系数
!!VRy12:Sy9+y11:2;
!!VRy13:Sy9+1-y11:2;
!!VRy14:Sy5-y10+y12;   位负值
!!VRy15:Sy5+y10-y13;   位正值
!!BMx16&v9309=2/y9<=y10/y7>=y14/y7=<y15:Kx5 V8;

********************千手佛升级提示**********************************************

!?HL-1&v9309=2/v9316<>2;
!!HE-1:N?y1;
!!FU&y1<>v9315:E;
!!HEv9315:E?y3/?y4;
!!VRy5:Sy4%8;
!!FU&y5<>0:E;
!!VRy6&y5=0:Sy4:8;
!!VRy7&y5=0:Sy6+1*y6*3;
!!IF&v9309=2:M^恭喜您，您的千手佛技能现在升到%Y6级，
您现在的攻击范围是%Y7格。^;

********************************************************************************

akgod

原帖由 hanter007 于 2012-7-26 12:35 发表
将原来的替换现在的.没发现什么问题呢.


ZVSE
********************************************************************************
********************************************************************** ...

这个是把原作者的千手佛加到我粘贴的里面了？？？

贤知有您

有问题吗?