【目前缺一天一次、种类哦】把龙宫的暗黑龙修改为普通的随机出现的龙

独孤求败

一下是龙宫无限访问只出现暗黑龙的脚本，求修改为出现随机的龙的脚本！

ZVSE
ERMS_ScriptDate=18.2(February).2005
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
** Dungeon of the Dragonmaster
** Wogify Name: script53.erm
** This strengthens all Dragon Utopias an a map. AI will visit normal DU but gets some extra bonuses.
** Requires ERM v2.80 or higher
** Version: 1.2
** Updated: May 12. 2004
** Made by Hermann the Weird
** Idea by Janus
** To use this code, copy it (from ZVSE to the end) into a global event, set day of first occurence
** to something after 600.
** v-Variables used: v8033, v8035-v8043
** Functions: 20001-20003
** Strings: z455-461
** Uses FU709 from script01 (map rules) to determine the strength of the DOTDM.
** Compatible with script57 (neutral units).
** This script will only give enabled artifacts (Map or WoG options).
** If all artifacts of one level are disabled, artifacts of other random levels will be given.

***** Check for WoGify option *****
!#UN:P53/?v1;
***** Setting hint text *****
!#VRz455&v1=1:Sz153000;
!#VRz456&v1=1:Sz153001;
!#HT25/-1&v1=1:T455;
***** Section for human attacker *****
!?OB25&1000;
!!UN:P53/?y-1; [Check if enabled in WoG options]
!!FU&y-1=0:E; [Exit if it isn't]
!!VRv100:S1; [Activate Neutral Units]
!!HE-1:P?v8040/?v8041/?v8042; [Get position]
!!OBv8040/v8041/v8042:S; [Disable normal DU]
!!HE-1:O?v8043; [Checks hero's owner before battle - used to check if battle won]
***** Ask player for battle *****
!!IF:Q1/21/155/2/z153002;
!!FU&-1:E; [Exit if no answered]
!!VRv8033:S0 R3 +1; [Generate random number as classification for the strength of the Bank]基数为1至5随机数
!!FU709:P15; [Check for map rule 15]
!!VRy-7&3:Sv8033 +9 *8; [Translate to number of Dragons if rule 15 selected]小龙宫
!!VRy-7&-3:Sv8033 *19; [Translate to number of Dragons if rule 15 not selected]大龙宫
!!VRv8033:+1; [Number of relics]访问后基数+1
!!HE-1:Tv8040/v8041/v8042/155/y-7; [Provoke battle]y-7为重置后的数量
!!HE-1:O?y-2; [Checks hero's owner after battle - used to check if battle won]
!!FU&v8043<>y-2:E; [Exit if battle lost]
!!DO20001/1/v8033/1:P8035/457; [Loop for generating relics]
!!DO20002/1/v8033/1:P8035; [Loop for passing relics to hero]
***** Displaying relics *****
!!IF&v8033=2:Q1/8/v8035/8/v8036/1/z153003;
!!IF&v8033=3:Q1/8/v8035/8/v8036/8/v8037/1/z153004;
!!IF&v8033=4:N8/v8035/8/v8036/8/v8037/8/v8038;
!!IF&v8033=4:N^%Z153005^;
!!IF&v8033=5:N8/v8035/8/v8036/8/v8037/8/v8038/8/v8039;
!!IF&v8033=5:N^%Z153006^;
!!DO20003/1/3/1:P8035/457; [Loop for minor/major artifacts]
***** Displaying and passing minor/major artifacts *****
!!UN:P900/?y-3; [Check for Stack Experience]
!!UN:P143/?y-4; [Check for New Artifacts]
!!UN:P234/?y-5; [Check for Warlord's Banner banning]
***** If Stack Experience and New Arts enabled *****
!!IF&y-3=1/y-4=1/y-5=0:N8/v8035/8/v8036/8/v8037/8/156;
!!IF&y-3=1/y-4=1/y-5=0:N^%Z153007^;
!!HE-1&y-3=1/y-4=1/y-5=0:A4/156;
***** If Stack Experience and New Arts not enabled *****
!!IF|y-3<>1/y-4<>1/y-5<>0:Q1/8/v8035/8/v8036/8/v8037/1/z153008;
!!HE-1:A4/v8035;
!!HE-1:A4/v8036;
!!HE-1:A4/v8037;

***** Preparing variables for money or experience *****
!!VRv8033:*50000;
!!VRy-8:Sv8033;
!!VRy-8::2;
***** Asking for money or experience *****
!!IF:Q1/6/v8033/17/y-8/7/z153009;
***** Displaying and passing money *****
!!IF&1:Q1/6/v8033/1/z153010;
!!OW&1:R-1/6/dv8033;
***** Displaying and passing experience *****
!!IF&-1:Q1/17/y-8/1/z153011;
!!HE-1&-1:Edy-8;
!!IF:M1/z153012;
***** End of section for human attacker *****

***** Section for AI attacker *****
!?OB25&-1000;
!!UN:P53/?y-1; [Check if enabled in WoG options]
!!FU&y-1=0:E; [Exit if it isn't]
!!HE-1:P?v8040/?v8041/?v8042; [Get position]
!!HE-1:O?v8043; [Checks hero's owner before battle - used to check if battle won]
!$OB25&-1000; [Post visit trigger]
!!UN:P53/?y-1; [Check if enabled in WoG options]
!!FU&y-1=0:E; [Exit if it isn't]
!!HE-1:O?y-2; [Checks hero's owner after battle - used to check if battle won]
!!FU&v8043<>y-2:E; [Exit if battle lost]
!!HE-1:Fd5/d5/d5/d5; [AI receives additional primary skills]
!!HE-1:Ed15000; [AI receives additional experience]
!!OW:R-1/6/d30000; [AI receives additional gold]
!!UN:Iv8040/v8041/v8042/60/0; [Place Pillar of fire to block entrance]
!!OBv8040/v8041/v8042:S; [Disable it]
!!OBv8040/v8041/v8042:H456; [Set visited hint text]
!!TRv8040/v8041/v8042:E1; [Disables yellow trigger square]
!!TRv8040/v8041/v8042:P0; [Makes it impassable]
***** End of section for AI attacker *****

********** Function Section **********
!?FU20001; [Function for generating relics]
!!UN:J6/16/?y1; [Generates relic]
!!VRvx1:Sy1; [Store result in v-variable for use outside function]
!!UN:N0/zx2/y1; [Look up artifacts name]
!!VRx1:+1; [Increase v-var index]
!!VRx2:+1; [Increase z-var index]

!?FU20002; [Function for passing relics to hero]
!!HE-1:A4/vx1; [Passes relics to hero]
!!VRx1:+1; [Increase v-var index]

!?FU20003; [Function for generating 3 minor/major]
!!UN:J6/12/?y1; [Generates minor/major]
!!VRvx1:Sy1; [Store result in v-variable for use outside function]
!!UN:N0/zx2/y1; [Look up artifacts name]
!!VRx1:+1; [Increase v-var index]
!!VRx2:+1; [Increase z-var index]

[ 本帖最后由 独孤求败 于 2012-7-15 16:29 编辑 ]

沧海一粟

自己替换原代码部分试试：无限访问出现随机的8级巨龙。

***** Ask player for battle *****
!!VRy-77:S0 T7;
!!VRy-78&y-77=0:S132;
!!VRy-78&y-77=1:S133;
!!VRy-78&y-77=2:S134;
!!VRy-78&y-77=3:S135;
!!VRy-78&y-77=4:S151;
!!VRy-78&y-77=5:S154;
!!VRy-78&y-77=6:S155;
!!VRy-78&y-77=7:S196;
!!IF:Q1/21/y-78/2/z153002;
!!FU&-1:E; [Exit if no answered]
!!VRv8033:S0 R3 +1; [Generate random number as classification for the strength of the Bank]
!!FU709:P15; [Check for map rule 15]
!!VRy-7&3:Sv8033 +9 *8; [Translate to number of Dragons if rule 15 selected]
!!VRy-7&-3:Sv8033 *19; [Translate to number of Dragons if rule 15 not selected]
!!VRv8033:+1; [Number of relics]
!!HE-1:Tv8040/v8041/v8042/y-78/y-7; [Provoke battle]
!!HE-1:O?y-2; [Checks hero's owner after battle - used to check if battle won]
!!FU&v8043<>y-2:E; [Exit if battle lost]
!!DO20001/1/v8033/1:P8035/457; [Loop for generating relics]
!!DO20002/1/v8033/1:P8035; [Loop for passing relics to hero]

贤知有您

随机8级龙还是不错的。

话说我经常使用 SAVE LOAD 大法，移动一小步再访问龙宫，使得出现12只巨龙
赚大钱和大宝物

沧海一粟

龙之国已经够恐怖了，还无限访问得圣物得经验，AI不用活了。
如果是我用的话，肯定会把获得的宝物全改成矿石车，并且限制最多只得1000经验。

独孤求败

代码可以了。
请问：1.我可以照葫芦画瓢把七级的龙加进去吗？
2.里面随机的龙种类只有一种，能不能一次进去出4-5种龙呢？就像没有修改以前一样的效果。

沧海一粟

1、可以；
2、跟原脚本原理不同，必须完全地换个思路写，但ERM有相关命令支持，可以实现。

独孤求败

1.还有呢？龙的出现数量是如何决定的呢？
2.能不能帮忙访问周期改为一天一次或者一周一次呢？
3.幻想一下，开发一些对应城镇的旁边出现对应种族的练习场和打宝地点，是不是可以做成和传奇一样的打宝地图……

沧海一粟

1、简单看，龙的数量貌似与本身龙之国的大小及访问次数有关联；
2、这个也可以有；
3、综合评定，楼主确实是个不错的幻想家。不过想法倒是可以实现，我帮你顶下。

文兄

看不懂的路过，证明本老大关注每个帖子

灰狼王子

看不懂的评分先，证明本总版关心关注每位好童鞋

canary

这个貌似以前有人写过，龙宫奖励恢复补丁+生物银行N天恢复补丁（自定义吧）

兽哥哥

沧海写过

独孤求败

有一个生物银行两天回复的，那太可怕了，满世界都是1k以上的怪物……
所以龙宫要和生物银行分开就是这个原因。

canary

你把最后控制那句加到龙宫就行了 问题一天一次 你还玩什么
高级宝物多的都想丢 那样就没玩头了
我现在野图打好了，就想弄个高评价。
打的差到一定天就直接默认胜利就行了，再继续下去都是垃圾时间。。。
你这样玩很快就全是垃圾时间，电脑都哭死了