WOG版扑克24点游戏

贤知有您 · 发表于 2012-6-21 19:07:59

终于完成了.发现编写这个大部分是纯计算类语句.**★扑克24点游戏★ ByHanter007 2012-6-21
**使用变量FU20000&X1=800/801/802/803 TM58 v8000
**1.扑克24点游戏:从52张扑克中抽取4张,通过对各牌点数使用加减乘除得到结果为正整数24的游戏.
**2.由于ERM计算方式的特殊性,游戏采用2种计算方法,且允许负数的24,使能得到答案的几率增大.
**3.为了提高游戏可玩性,结果虽是小数,但大于23且小于25时也算过关,不奖励不惩罚.
**4.属于智力型游戏,有助于提高心算算术能力.你甚至可以上网找24点游戏的解答答案.
**5.这里右键点击英雄界面的英雄头像时触发,有需要可改成访问物体触发事件.(每天可玩3次)
**7.计算方式举例：牌面 4-2-8-4
** 顺序式计算（相当于ERM从左到右的计算） (4÷4＋2）×8＝24 或（8＋4）×4÷2＝24
** 分组式计算（分左右2部分计算再用符号连接）（8×4）－（4×2）＝24 或（4＋2）×（8－4）＝24

废话少说,试过就知道怎么玩了.将ERM放到地图事件中即可。
记得将 PK 文件夹放到游戏 DATA文件夹中,不然就没有扑克图片了.
这里是TXT脚本.二楼放直接放上脚本.

WOG版24点小游戏.txt (12.29 KB, 下载次数: 28)

PK(解压缩到DATA文件).rar (223.24 KB, 下载次数: 46)

下面放些图片看看效果：

（顺序计算的过程）

[ 本帖最后由 hanter007 于 2012-6-21 21:17 编辑 ]

贤知有您 · 发表于 2012-6-21 19:08:29

ZVSE
**★扑克24点游戏★ ByHanter007 2012-6-21
**使用变量FU20000&X1=800/801/802/803 TM58 v8000
**1.扑克24点游戏:从52张扑克中抽取4张,通过对各牌点数使用加减乘除得到结果为正整数24的游戏.
**2.由于ERM计算方式的特殊性,游戏采用2种计算方法,且允许负数的24,使能得到答案的几率增大.
**3.为了提高游戏可玩性,结果虽是小数,但大于23且小于25时也算过关,不奖励不惩罚.
**4.属于智力型游戏,有助于提高心算算术能力.你甚至可以上网找24点游戏的解答答案.
**5.这里右键点击英雄界面的英雄头像时触发,有需要可改成访问物体触发事件.(每天可玩3次)
**7.计算方式举例：牌面 4-2-8-4
** 顺序式计算（相当于ERM从左到右的计算） (4÷4＋2）×8＝24 或（8＋4）×4÷2＝24
** 分组式计算（分左右2部分计算再用符号连接）（8×4）－（4×2）＝24 或（4＋2）×（8－4）＝24
!#TM58:S1/360/1/255;
!?TM58&1000;
!!VRv8000:S0; [每天重置可玩]
!?CM2; [英雄信息界面]
!!CM:I?y1 F?y2; [点击位置/鼠标动作]
!!FU|y1<>45/y2<>512:E; [点击位置英雄头像/不是右键按下]
!!IF&v8000>2:M^扑克24点游戏每天只能玩三次哦！明天请继续！^;
!!CM:R0; [禁用标准反应]
!!FU&v8000>2:E; [这里跟对上第二句,控制每天可玩的次数]
!!FU20000:P800;
!?FU20000&x1=800; [主函数]
!!HE-1:B0/?z-1; [当前英雄的名字]
!!IF:Q10^
{Hi%Z-1,欢迎参加扑克牌24点小游戏}
详细游戏规则:
1.电脑随机给你抽取 4 张不重复的扑克牌.
2.你可使用＋－×÷来组合这些牌的点数.
3.你可通过两种方式表达运算方式和结果.
4.结果若是完美的±24,给予随机祝福奖励.
5.结果绝对值是23-25间的小数按平手处理.
6.其它情况的结果,将面临随机诅咒的惩罚.
7.抽取的牌有可能无法算出接近24的结果.
{你确定要玩这个游戏吗?}^; [询问]
!!FU&-10:E;
!!VRv8000:+1;
**随机抽取(1-52)中4个不重复数(y-11~y-14)**
**使用y-1/y-2/y-3升序排序(辅助小组)**
!!VRy-11:S1 R48; [随机1-49]
!!VRy-12:S1 R48;
!!VRy-12&y-11=y-12:+1; [相同时,+1]
!!VRy-1&y-11<y-12:Sy-11; [取最小]
!!VRy-2&y-11<y-12:Sy-12;
!!VRy-1&y-11>y-12:Sy-12; [取最小]
!!VRy-2&y-11>y-12:Sy-11;
!!VRy-13:S1 R48; [随机第三个数]
!!VRy-13&y-13=y-1:+1; [等于辅助小组的第一个数时,+1]
!!VRy-13&y-13=y-2:+1; [等于辅助小组的第二个数时,+1]
**至此已确定第三个不重复数**
**下面排序辅助小组(1-3成员)**
!!VRy-3&y-13>y-2:Sy-13; [y-13是最大值时]
!!VRy-3&y-13<y-1:Sy-2; [y-13是最小值时,y-2后移]
!!VRy-2&y-13<y-1:Sy-1; [y-1后移]
!!VRy-1&y-13<y-1:Sy-13; [y-13移动到最前]
!!VRy-3&y-13>y-1/y-13<y-2:Sy-2; [y-13是中间值,y-2后移]
!!VRy-2&y-13>y-1/y-13<y-2:Sy-13; [y-13取代y-2位置]
**至此排序完毕(辅助小组已完全确立)**
!!VRy-14:S1 R48; [随机第四个数]
!!VRy-14&y-14=y-1:+1;
!!VRy-14&y-14=y-2:+1;
!!VRy-14&y-14=y-3:+1; [确定第四个数]
**由y-11~y-14确定四张扑克点数(1-13)和花色(1-4)**
**点数y11~y14,对应花色y15~y18,中间变量y-9/y-10(整除和余数)
!!VRy-9:Sy-11:4; [(1-52)除以4,取整]
!!VRy-10:Sy-11%4; [(1-52)除以4,取余]
!!VRy11&y-10=0:Sy-9; [点数=取整]
!!VRy15&y-10=0:S4; [最后一个花色]
!!VRy11&y-10>0:Sy-9+1; [点数=取整+1]
!!VRy15&y-10>0:Sy-10; [花色是取余]
**至此确认第一张牌点数和花色,下同**
!!VRy-9:Sy-12:4;
!!VRy-10:Sy-12%4;
!!VRy12&y-10=0:Sy-9;
!!VRy16&y-10=0:S4;
!!VRy12&y-10>0:Sy-9+1;
!!VRy16&y-10>0:Sy-10; [第二张完]
!!VRy-9:Sy-13:4;
!!VRy-10:Sy-13%4;
!!VRy13&y-10=0:Sy-9;
!!VRy17&y-10=0:S4;
!!VRy13&y-10>0:Sy-9+1;
!!VRy17&y-10>0:Sy-10; [第三张完]
!!VRy-9:Sy-14:4;
!!VRy-10:Sy-14%4;
!!VRy14&y-10=0:Sy-9;
!!VRy18&y-10=0:S4;
!!VRy14&y-10>0:Sy-9+1;
!!VRy18&y-10>0:Sy-10; [全部完成]
**四张图片的路径z-2~z-5**
!!VRz-1:S^你抽到的牌面分别是:^;
!!VRz-2:S^../data/pk/%Y-11.bmp^;
!!VRz-3:S^../data/pk/%Y-12.bmp^;
!!VRz-4:S^../data/pk/%Y-13.bmp^;
!!VRz-5:S^../data/pk/%Y-14.bmp^;
!!IF:D20/z-1///z-2/z-3/z-4/z-5////////;
!!IF:E1/20;
!!IF:M^你随机抽到的牌面点数分别是：
{%Y11 － %Y12 － %Y13 － %Y14 }
思考后请选择计算方式或直接投降!
{关于算式计算方式的说明: }
方式一:相当于ERM从左往右的计算.
方式二:举例数学式 (A-B)×(C+D)
这里 (A-B) 为一组, (C-D) 是第二组.
两组之间用乘号作为连接符号. ^;
**选择第1个数字**
!!VRz-10:S^请选择计算方式: (牌面%Y11 - %Y12 - %Y13 - %Y14)^;
!!VRz-9:S^靠！霉运！这明摆算不出来的嘛，我嘞个去。^;
!!VRz-1:S^方式一：顺序式计算！^;
!!VRz-2:S^方式二：分组式计算！^;
!!IF:G1/2/4/-10/-1/-2/-9; [结果存于V2]
!!IF&v2=4:M^你只能怪人品了，哈哈哈哈，准备接受诅咒吧！^;
!!FU20000&v2=4:P803/-1/4; [诅咒]
!!UN&v2=4:R3/-1; [刷新英雄屏幕]
!!FU&v2=4:E; [选择退出]
!!FU20000&v2=1:P801/y11/y12/y13/y14;
!!FU20000&v2=2:P802/y11/y12/y13/y14;
!!UN:R3/-1; [刷新英雄屏幕]
*----------------------------------------------------
!?FU20000&x1=801; [顺序式计算]
**选择第1个数字**
!!VRz-10:S^请选择你的第一个数字：(%X2 - %X3 - %X4 - %X5)^;
!!VRz-1:S^%X2^; [1]
!!VRz-2:S^%X3^; [2]
!!VRz-3:S^%X4^; [4]
!!VRz-4:S^%X5^; [8]
!!IF:G1/1/1/-10/-1/-2/-3/-4; [结果存于V1]
!!VRy21&v1=1:Sx2;
!!VRy21&v1=2:Sx3;
!!VRy21&v1=4:Sx4;
!!VRy21&v1=8:Sx5;
!!VRx2&v1=1:S0;
!!VRx3&v1=2:S0;
!!VRx4&v1=4:S0;
!!VRx5&v1=8:S0;
**选择第1个数学符号**
!!VRz-10:S^请选择你的第一个数学符号：(%X2 - %X3 - %X4 - %X5)^;
!!VRz-1:S^＋^; [1]
!!VRz-2:S^－^; [2]
!!VRz-3:S^×^; [4]
!!VRz-4:S^÷^; [8]
!!IF:G1/1/1/-10/-1/-2/-3/-4; [结果存于V1]
!!VRy31&v1=1:S100;
!!VRy31&v1=2:S200;
!!VRy31&v1=4:S300;
!!VRy31&v1=8:S400;
!!VRz-6&v1=1:S^＋^;
!!VRz-6&v1=2:S^－^;
!!VRz-6&v1=4:S^×^;
!!VRz-6&v1=8:S^÷^;
**选择第2个数字**
!!VRz-10:S^请选择你的第二个数字：(%X2 - %X3 - %X4 - %X5)^;
!!VRz-1:S^%X2^; [1]
!!VRz-2:S^%X3^; [2]
!!VRz-3:S^%X4^; [4]
!!VRz-4:S^%X5^; [8]
!!VRz-1|x2=0:S^^;
!!VRz-2|x3=0:S^^;
!!VRz-3|x4=0:S^^;
!!VRz-4|x5=0:S^^;
!!IF:G1/1/1/-10/-1/-2/-3/-4; [结果存于V1]
!!VRy22&v1=1:Sx2;
!!VRy22&v1=2:Sx3;
!!VRy22&v1=4:Sx4;
!!VRy22&v1=8:Sx5;
!!VRx2&v1=1:S0;
!!VRx3&v1=2:S0;
!!VRx4&v1=4:S0;
!!VRx5&v1=8:S0;
**这里开始计算结果**
!!VRe10:S0;
!!VRe10&y31=100:Sy21+y22;
!!VRe10&y31=200:Sy21-y22;
!!VRe10&y31=300:Sy21*y22;
!!VRe10&y31=400:Sy21:y22;
**选择第2个数学符号**
!!VRz-10:S^请选择你的第二个数学符号：(%X2 - %X3 - %X4 - %X5)^;
!!VRz-1:S^＋^; [1]
!!VRz-2:S^－^; [2]
!!VRz-3:S^×^; [4]
!!VRz-4:S^÷^; [8]
!!IF:G1/1/1/-10/-1/-2/-3/-4; [结果存于V1]
!!VRy32&v1=1:S100;
!!VRy32&v1=2:S200;
!!VRy32&v1=4:S300;
!!VRy32&v1=8:S400;
!!VRz-7&v1=1:S^＋^;
!!VRz-7&v1=2:S^－^;
!!VRz-7&v1=4:S^×^;
!!VRz-7&v1=8:S^÷^;
**选择第3个数字**
!!VRz-10:S^请选择你的第三个数字：(%X2 - %X3 - %X4 - %X5)^;
!!VRz-1:S^%X2^; [1]
!!VRz-2:S^%X3^; [2]
!!VRz-3:S^%X4^; [4]
!!VRz-4:S^%X5^; [8]
!!VRz-1|x2=0:S^^;
!!VRz-2|x3=0:S^^;
!!VRz-3|x4=0:S^^;
!!VRz-4|x5=0:S^^;
!!IF:G1/1/1/-10/-1/-2/-3/-4; [结果存于V1]
!!VRy23&v1=1:Sx2;
!!VRy23&v1=2:Sx3;
!!VRy23&v1=4:Sx4;
!!VRy23&v1=8:Sx5;
!!VRx2&v1=1:S0;
!!VRx3&v1=2:S0;
!!VRx4&v1=4:S0;
!!VRx5&v1=8:S0;
**第二步计算**
!!VRe10&y32=100:+y23;
!!VRe10&y32=200:-y23;
!!VRe10&y32=300:*y23;
!!VRe10&y32=400::y23;
**选择第3个数学符号**
!!VRz-10:S^请选择你的第三个数学符号：(%X2 - %X3 - %X4 - %X5)^;
!!VRz-1:S^＋^; [1]
!!VRz-2:S^－^; [2]
!!VRz-3:S^×^; [4]
!!VRz-4:S^÷^; [8]
!!IF:G1/1/1/-10/-1/-2/-3/-4; [结果存于V1]
!!VRy33&v1=1:S100;
!!VRy33&v1=2:S200;
!!VRy33&v1=4:S300;
!!VRy33&v1=8:S400;
!!VRz-8&v1=1:S^＋^;
!!VRz-8&v1=2:S^－^;
!!VRz-8&v1=4:S^×^;
!!VRz-8&v1=8:S^÷^;
**自动得出第4个数字**
!!VRy24&x2<>0:Sx2;
!!VRy24&x3<>0:Sx3;
!!VRy24&x4<>0:Sx4;
!!VRy24&x5<>0:Sx5;
**计算最终结果**
!!VRe10&y33=100:+y24;
!!VRe10&y33=200:-y24;
!!VRe10&y33=300:*y24;
!!VRe10&y33=400::y24;
!!VRe23:S23;
!!VRe24:S24;
!!VRe25:S25;
!!VRe12:Se10;
!!VRe12&e12<0:*-1; [负数转正数]
!!IF&e12=e24:M^
你的算术结果是:
{((%Y21 %Z-6 %Y22) %Z-7 %Y23) %Z-8 %Y24 = %E10}
恭喜你结果是完美的±24，你将获得丰盛的祝福！^;
!!FU20000&e12=e24:P803/1/4;
!!FU&e12=e24:E;
!!IF&e12>e23/e12<e25:M^
你的算术结果是:
{((%Y21 %Z-6 %Y22) %Z-7 %Y23) %Z-8 %Y24 = %E10}
你的结果总算比较接近±24，平手，欢迎下次再来玩玩！^;
!!FU&e12>e23/e12<e25:E;
!!IF|e12<=e23/e12>=e25:M^
你的算术结果是:
{((%Y21 %Z-6 %Y22) %Z-7 %Y23) %Z-8 %Y24 = %E10}
看来你的算术不咋样，你将面临邪恶的诅咒！^;
!!FU20000|e12<=e23/e12>=e25:P803/-1/4;
*-----------------------------------------------------------------
!?FU20000&x1=802; [分组式计算]
**选择第1个数字**
!!VRz-10:S^请选择第一组的第1个数字：(%X2 - %X3 - %X4 - %X5)^;
!!VRz-1:S^%X2^; [1]
!!VRz-2:S^%X3^; [2]
!!VRz-3:S^%X4^; [4]
!!VRz-4:S^%X5^; [8]
!!IF:G1/1/1/-10/-1/-2/-3/-4; [结果存于V1]
!!VRy21&v1=1:Sx2;
!!VRy21&v1=2:Sx3;
!!VRy21&v1=4:Sx4;
!!VRy21&v1=8:Sx5;
!!VRx2&v1=1:S0;
!!VRx3&v1=2:S0;
!!VRx4&v1=4:S0;
!!VRx5&v1=8:S0;
**选择第1个数学符号**
!!VRz-10:S^请选择第一组的数学符号：(%X2 - %X3 - %X4 - %X5)^;
!!VRz-1:S^＋^; [1]
!!VRz-2:S^－^; [2]
!!VRz-3:S^×^; [4]
!!VRz-4:S^÷^; [8]
!!IF:G1/1/1/-10/-1/-2/-3/-4; [结果存于V1]
!!VRy31&v1=1:S100;
!!VRy31&v1=2:S200;
!!VRy31&v1=4:S300;
!!VRy31&v1=8:S400;
!!VRz-6&v1=1:S^＋^;
!!VRz-6&v1=2:S^－^;
!!VRz-6&v1=4:S^×^;
!!VRz-6&v1=8:S^÷^;
**选择第一组第2个数字**
!!VRz-10:S^请选择第一组的第2个数字：(%X2 - %X3 - %X4 - %X5)^;
!!VRz-1:S^%X2^; [1]
!!VRz-2:S^%X3^; [2]
!!VRz-3:S^%X4^; [4]
!!VRz-4:S^%X5^; [8]
!!VRz-1|x2=0:S^^;
!!VRz-2|x3=0:S^^;
!!VRz-3|x4=0:S^^;
!!VRz-4|x5=0:S^^;
!!IF:G1/1/1/-10/-1/-2/-3/-4; [结果存于V1]
!!VRy22&v1=1:Sx2;
!!VRy22&v1=2:Sx3;
!!VRy22&v1=4:Sx4;
!!VRy22&v1=8:Sx5;
!!VRx2&v1=1:S0;
!!VRx3&v1=2:S0;
!!VRx4&v1=4:S0;
!!VRx5&v1=8:S0;
**计算第一组结果**
!!VRe10:S0;
!!VRe10&y31=100:Sy21+y22;
!!VRe10&y31=200:Sy21-y22;
!!VRe10&y31=300:Sy21*y22;
!!VRe10&y31=400:Sy21:y22;
**选择第二组第1个数字**
!!VRz-10:S^请选择第二组的第1个数字：(%X2 - %X3 - %X4 - %X5)^;
!!VRz-1:S^%X2^; [1]
!!VRz-2:S^%X3^; [2]
!!VRz-3:S^%X4^; [4]
!!VRz-4:S^%X5^; [8]
!!VRz-1|x2=0:S^^;
!!VRz-2|x3=0:S^^;
!!VRz-3|x4=0:S^^;
!!VRz-4|x5=0:S^^;
!!IF:G1/1/1/-10/-1/-2/-3/-4; [结果存于V1]
!!VRy23&v1=1:Sx2;
!!VRy23&v1=2:Sx3;
!!VRy23&v1=4:Sx4;
!!VRy23&v1=8:Sx5;
!!VRx2&v1=1:S0;
!!VRx3&v1=2:S0;
!!VRx4&v1=4:S0;
!!VRx5&v1=8:S0;
**选择第二组第数学符号**
!!VRz-10:S^请选择第二组的数学符号：(%X2 - %X3 - %X4 - %X5)^;
!!VRz-1:S^＋^; [1]
!!VRz-2:S^－^; [2]
!!VRz-3:S^×^; [4]
!!VRz-4:S^÷^; [8]
!!IF:G1/1/1/-10/-1/-2/-3/-4; [结果存于V1]
!!VRy33&v1=1:S100;
!!VRy33&v1=2:S200;
!!VRy33&v1=4:S300;
!!VRy33&v1=8:S400;
!!VRz-8&v1=1:S^＋^;
!!VRz-8&v1=2:S^－^;
!!VRz-8&v1=4:S^×^;
!!VRz-8&v1=8:S^÷^;
**自动得出第4个数字**
!!VRy24&x2<>0:Sx2;
!!VRy24&x3<>0:Sx3;
!!VRy24&x4<>0:Sx4;
!!VRy24&x5<>0:Sx5;
**计算第二组结果**
!!VRe11&y33=100:Sy23+y24;
!!VRe11&y33=200:Sy23-y24;
!!VRe11&y33=300:Sy23*y24;
!!VRe11&y33=400:Sy23:y24;
**选择两组间数学符号**
!!VRz-10:S^请选择两组间的数学符号：(%X2 - %X3 - %X4 - %X5)^;
!!VRz-1:S^＋^; [1]
!!VRz-2:S^－^; [2]
!!VRz-3:S^×^; [4]
!!VRz-4:S^÷^; [8]
!!IF:G1/1/1/-10/-1/-2/-3/-4; [结果存于V1]
!!VRy32&v1=1:S100;
!!VRy32&v1=2:S200;
!!VRy32&v1=4:S300;
!!VRy32&v1=8:S400;
!!VRz-7&v1=1:S^＋^;
!!VRz-7&v1=2:S^－^;
!!VRz-7&v1=4:S^×^;
!!VRz-7&v1=8:S^÷^;
**计算最终结果**
!!VRe10&y32=100:+e11;
!!VRe10&y32=200:-e11;
!!VRe10&y32=300:*e11;
!!VRe10&y32=400::e11;
!!VRe23:S23;
!!VRe24:S24;
!!VRe25:S25;
!!VRe12:Se10;
!!VRe12&e12<0:*-1; [负数转正数]
!!IF&e12=e24:M^
你的算术结果是:
{(%Y21 %Z-6 %Y22) %Z-7 (%Y23 %Z-8 %Y24) = %E10}
恭喜你结果是完美的±24，你将获得丰盛的祝福！^;
!!FU20000&e12=e24:P803/1/4;
!!FU&e12=e24:E;
!!IF&e12>e23/e12<e25:M^
你的算术结果是:
{(%Y21 %Z-6 %Y22) %Z-7 (%Y23 %Z-8 %Y24) = %E10}
你的结果总算比较接近±24，平手，欢迎下次再来玩玩！^;
!!FU&e12>e23/e12<e25:E;
!!IF|e12<=e23/e12>=e25:M^
你的算术结果是:
{(%Y21 %Z-6 %Y22) %Z-7 (%Y23 %Z-8 %Y24) = %E10}
看来你的算术不咋样，你将面临邪恶的诅咒！^;
!!FU20000|e12<=e23/e12>=e25:P803/-1/4;
*---------------------------------------------------------
!?FU20000&x1=803; [随机祝福或诅咒]
**使用负的数值作为诅咒,游戏显示仍是获得祝福的.
**x2=1 正数祝福,-1 负数诅咒(数值越大,强度越大)
**x3=持续天数
!!FU|x2=0/x3<1:E;
!!VRy50:S1 R99; [随机1-100]
!!VRy60&y50>0/y50<11:Sx2*50;
!!HE-1&y50>0/y50<11:Y7/y60/x3/1; [魔法值]
!!FU&y50>0/y50<11:E;
!!VRy60&y50>10/y50<21:Sx2*2;
!!HE-1&y50>10/y50<21:Y15/y60/x3/1; [木头]
!!FU&y50>10/y50<21:E;
!!VRy60&y50>20/y50<31:Sx2*2;
!!HE-1&y50>20/y50<31:Y16/y60/x3/1; [石头]
!!FU&y50>20/y50<31:E;
!!VRy60&y50>30/y50<41:Sx2*1;
!!HE-1&y50>30/y50<41:Y17/y60/x3/1; [宝石]
!!FU&y50>30/y50<41:E;
!!VRy60&y50>40/y50<51:Sx2*1;
!!HE-1&y50>40/y50<51:Y18/y60/x3/1; [水银]
!!FU&y50>40/y50<51:E;
!!VRy60&y50>50/y50<61:Sx2*1;
!!HE-1&y50>50/y50<61:Y19/y60/x3/1; [硫磺]
!!FU&y50>50/y50<61:E;
!!VRy60&y50>60/y50<71:Sx2*1;
!!HE-1&y50>60/y50<71:Y20/y60/x3/1; [水晶]
!!FU&y50>60/y50<71:E;
!!VRy60&y50>70/y50<81:Sx2*1000;
!!HE-1&y50>70/y50<81:Y21/y60/x3/1; [金钱]
!!FU&y50>70/y50<81:E;
!!VRy60&y50>80/y50<91:Sx2*1;
!!HE-1&y50>80/y50<91:Y64/y60/x3/1; [木头+石头]
!!FU&y50>80/y50<91:E;
!!VRy60&y50>90/y50<101:Sx2*1000;
!!HE-1&y50>90/y50<101:Y65/y60/x3/1; [移动力]
!!FU&y50>90/y50<101:E;

复制代码

[ 本帖最后由 hanter007 于 2012-6-22 08:16 编辑 ]

renlinfeng · 发表于 2012-6-21 19:19:28

007终于修成正果

兽哥哥 · 发表于 2012-6-21 19:27:56

那个计算结果是错误的。居然没人发现。
另外能不能精简一下，感觉需要太多步骤了。

兽哥哥 · 发表于 2012-6-21 19:28:31

这个应该类似于之前风骚做的那个卡牌力量。很好的创意。

贤知有您 · 发表于 2012-6-21 20:58:24

请问那里出错了呢？
步骤不能精简啊。数字顺序和符号顺序都可以变化的。

兽哥哥 · 发表于 2012-6-21 21:05:53

13*2=26
26-10=16
16/4=4

贤知有您 · 发表于 2012-6-21 21:09:10

呵呵。我忘记更新图片。测试时候确实是错了。
因为我本来的结果是：（13×2）－（10÷4）＝23.5.
结果我写文字时，抄了上面顺序的那个，括号就括错了。

沧海一粟 · 发表于 2012-6-21 21:10:40

呵呵，看说明都觉得头晕了，看来算术还真的不行

兽哥哥 · 发表于 2012-6-21 21:14:20

原帖由 hanter007 于 2012-6-21 21:09 发表
呵呵。我忘记更新图片。测试时候确实是错了。
因为我本来的结果是：（13×2）－（10÷4）＝23.5.
结果我写文字时，抄了上面顺序的那个，括号就括错了。

本来我的数学是弱项，你这样明目张胆的贴出来我还紧张得要死，以为我不会算了呢。

基本的先小括号再大括号我还是没忘。

贤知有您 · 发表于 2012-6-21 21:19:19

原来更新图片这么麻烦啊。看来我不会编辑。
兽哥可以先在游戏里测试一下呢。

兽哥哥 · 发表于 2012-6-21 21:43:56

好的，没问题

无心云 · 发表于 2012-6-22 00:11:06

悄悄的说，有没有更简明的表示方式，感觉点子很好，但是表示方法有点繁琐

我是光动口不动手，别鄙视我

兽哥哥 · 发表于 2012-6-22 00:50:09

装了2追脚本好像玩不了，一点击就会出来二追的选项。

贤知有您 · 发表于 2012-6-22 08:20:44

兽哥，更改这句ERM就可以了。
!!FU|y1<>45/y2<>512:E; [点击位置英雄头像/不是右键按下]
y1＝45 是指英雄界面的英雄头像。就改45为其它。

比如以下的。随便找一个。不冲突的。

46 攻击(值)
47 防御(值)
48 力量(值)
49 知识(值)
50 攻击(图标)
51 防御(图标)
52 力量(图标)
53 知识(图标)

116 士气（图标）
117 幸运（图标）
118 特长（图标）
119 经验值（图标）
120 魔法值（图标）

灰狼王子 · 发表于 2012-6-22 08:21:29

用ERM实现起来够然是有些繁琐，不过居然能实现也很NB了

关于12,8,5,6那一组，其实是可以算出24的，(5-12/6)*8=24，但是用此ERM貌似没法实现

贤知有您 · 发表于 2012-6-22 08:22:21

没有办法啊。我也考虑了很久，怎么才能让电脑接收到玩家的算法及计算结果。
4个数字外＋3个符号的排列组合。另外还有需要括号的情况都要考虑。

贤知有您 · 发表于 2012-6-22 08:24:32

所以我允许－24的存在啊。
这样就是ERM的顺序式计算了。
(12/6－5)*8=－24

玩家懂得这个，证明知道怎样得到24了。

阿布 · 发表于 2012-6-22 10:06:17

算24点，我拿手啊

兽哥哥 · 发表于 2012-6-22 12:47:16

原帖由 hanter007 于 2012-6-22 08:20 发表
兽哥，更改这句ERM就可以了。
!!FU|y145/y2512:E; [点击位置英雄头像/不是右键按下]
y1＝45 是指英雄界面的英雄头像。就改45为其它。

比如以下的。随便找一个。不冲突的。

46 攻击(值)
47 防御(值)
48 力量 ...

改成了46，按了半天没效果

账号		自动登录	找回密码
密码			英雄注册\|Register

WOG版扑克24点游戏

评分

相关帖子

评分

回复 4# 的帖子

回复 6# 的帖子

回复 7# 的帖子

回复 10# 的帖子

回复 11# 的帖子

回复 14# 的帖子

很好玩的东东

回复 13# 的帖子

回复 16# 的帖子

浏览过的版块

论坛守望者

论坛元老

杰出贡献

魅力之星

社区QQ达人

金牌裁判

TE联赛冠军

退役版主

脚本测试狂