生物宝屋强化erm

沧海一粟

*********************************************************

      有感于部份玩家在下生物宝屋时因受读盘限制在没有副英雄踩点的情况下而出现自杀现象，故写了这个生物宝屋加强脚本，按照惯例在二楼放出两个版本，一为普通加强版，二为普通版，至于变态版视情况再更新。

     普通加强版功能说明如下：
     一、地图上所有的已访问生物宝屋每月将自动刷新一次恢复成未访问状态；
     二、英雄访问生物宝屋时宝屋守卫和奖励不再随机，而是按访问英雄的等级每5级增加，也就是说1级的英雄访问的宝屋永远都是小宝屋，6级英雄访问的宝屋永远都是中宝屋，11级英雄访问的宝屋永远都是大宝屋，15级以上英雄访问的宝屋永远都是最大的；
     三、英雄访问生物宝屋时可以事先得知宝屋守卫具体数量及所得奖励，作为加强版，其实这个功能作用并不大；
     四、强化的宝屋类型只包括只包括独眼/矮人/狮鹫/怪物/美杜莎/蛇妖/龙蝇这7种SOD生物宝屋，WOG后增加的宝屋无任何效果；
    五、在WOG初始选项若开启中立城镇和生物银行增长的选项，此生物宝屋加强ERM将自动失效，功能有冲突嘛；
    六、改换ERM名称后可作为通用脚本使用，原则上不会引起冲突，若想在地图中当事件版使用，请将此ERM置于开启生物经验事件后；
    七、erm内有功能简要说明，一切以游戏所见功能为准。

    普通版功能说明如下：
    再普通不过了，只保留事先得知宝屋守卫数量及奖励的功能，坚决杜绝下宝屋自杀现象的发生。

   以下是加强版代码：

ZVSE
**ERM制作：沧海一粟。
**V变量  v201-v204
**FU变量 48(x1=460-500)
**TM变量 64(每月触发)

!#TM64:S29/999/28/255;
!?TM64;
!!FU48:P460;
!?FU48&x1=460/1000;
!!UN:P235/?y-57;
!!FU&y-57=1:E;
!!UN:U16/-1/?x2;
!!VRv1:S-1;
!!DO48/1/x2/1&x2>0:P461/x2;
!!UN:R1;
!?FU48&x1=461;
!!UN:U16/-1/-1/1;
!!CBv1/v2/v3:T?y1;
!!FU&y1=0:E;
!!OBv1/v2/v3:U?y2;
!!FU&y2>6:E;
!!CBv1/v2/v3:T0 V0;
*********************************************************
!?OB16&1000;
!!VRv201:S0;
!!FU48:P470;
!!FU48:P480;
!?FU48&x1=470;
!!UN:P235/?y-57;
!!FU&y-57=1:E;
!!OBv998/v999/v1000:T?y1 U?y2;
!!CBv998/v999/v1000:T?y3;
!!FU&y3=1:E;
!!HE-1:Ed/?y4;
!!FU48&y2=0:P472/y4;   独眼宝屋
!!FU48&y2=1:P473/y4;   矮人宝屋
!!FU48&y2=2:P474/y4;   狮鹫宝屋
!!FU48&y2=3:P475/y4;   怪物宝屋
!!FU48&y2=4:P476/y4;   美杜莎宝屋
!!FU48&y2=5:P477/y4;   蛇妖宝屋
!!FU48&y2=6:P478/y4;   龙蝇宝屋
!?FU48&x1=472;
!!VRy5:S-1;
!!VRy5&x2<6:S4;
!!VRy5&x2>5/x2<11:S6;
!!VRy5&x2>10/x2<16:S8;
!!VRy5&x2>15:S10;
!!CBv998/v999/v1000:G0/-1/0 G1/-1/0 G2/-1/0 G3/-1/0 G4/-1/0 G5/-1/0;
!!CBv998/v999/v1000:G1/94/y5 G2/94/y5 G3/95/y5 G4/94/y5 G5/94/y5;
!!CBv998/v999/v1000:R0/y5 R1/y5 R2/y5 R3/y5 R4/y5 R5/y5;
!?FU48&x1=473;
!!VRy5:S-1; !!VRy6:S-1; !!VRy7:S-1;
!!VRy5&x2<6:S10;
!!VRy5&x2>5/x2<11:S15;
!!VRy5&x2>10/x2<16:S20;
!!VRy5&x2>15:S30;
!!VRy6&x2<6:S2;
!!VRy6&x2>5/x2<11:S3;
!!VRy6&x2>10/x2<16:S5;
!!VRy6&x2>15:S10;
!!VRy7&x2<6:S2500;
!!VRy7&x2>5/x2<11:S4000;
!!VRy7&x2>10/x2<16:S5000;
!!VRy7&x2>15:S7500;
!!CBv998/v999/v1000:G0/-1/0 G1/-1/0 G2/-1/0 G3/-1/0 G4/-1/0 G5/-1/0;
!!CBv998/v999/v1000:G1/16/y5 G2/16/y5 G3/17/y5 G4/16/y5 G5/16/y5;
!!CBv998/v999/v1000:R4/y6 R6/y7;
!?FU48&x1=474;
!!VRy5:S-1;
!!VRy5&x2<6:S10;
!!VRy5&x2>5/x2<11:S20;
!!VRy5&x2>10/x2<16:S30;
!!VRy5&x2>15:S40;
!!VRy6:Sy5:10;
!!CBv998/v999/v1000:G0/-1/0 G1/-1/0 G2/-1/0 G3/-1/0 G4/-1/0 G5/-1/0;
!!CBv998/v999/v1000:G1/4/y5 G2/4/y5 G3/5/y5 G4/4/y5 G5/4/y5;
!!CBv998/v999/v1000:M12/y6;
!?FU48&x1=475;
!!VRy5:S-1;
!!VRy5&x2<6:S20;
!!VRy5&x2>5/x2<11:S30;
!!VRy5&x2>10/x2<16:S40;
!!VRy5&x2>15:S60;
!!VRy6:Sy5:10;
!!VRy7:Sy5*50;
!!CBv998/v999/v1000:G0/-1/0 G1/-1/0 G2/-1/0 G3/-1/0 G4/-1/0 G5/-1/0;
!!CBv998/v999/v1000:G1/42/y5 G2/42/y5 G3/43/y5 G4/42/y5 G5/42/y5;
!!CBv998/v999/v1000:R1/y6 R6/y7;
!?FU48&x1=476;
!!VRy5:S-1; !!VRy6:S-1;
!!VRy5&x2<6:S4;
!!VRy5&x2>5/x2<11:S6;
!!VRy5&x2>10/x2<16:S8;
!!VRy5&x2>15:S10;
!!VRy6&x2<6:S5;
!!VRy6&x2>5/x2<11:S6;
!!VRy6&x2>10/x2<16:S8;
!!VRy6&x2>15:S10;
!!VRy7:Sy5*500;
!!CBv998/v999/v1000:G0/-1/0 G1/-1/0 G2/-1/0 G3/-1/0 G4/-1/0 G5/-1/0;
!!CBv998/v999/v1000:G1/76/y5 G2/76/y5 G3/77/y5 G4/76/y5 G5/76/y5;
!!CBv998/v999/v1000:R3/y6 R6/y7;
!?FU48&x1=477;
!!VRy5:S-1;
!!VRy5&x2<6:S2;
!!VRy5&x2>5/x2<11:S3;
!!VRy5&x2>10/x2<16:S4;
!!VRy5&x2>15:S6;
!!VRy6:Sy5*4;
!!VRy7:Sy5*2000;
!!CBv998/v999/v1000:G0/-1/0 G1/-1/0 G2/-1/0 G3/-1/0 G4/-1/0 G5/-1/0;
!!CBv998/v999/v1000:G1/38/y5 G2/38/y5 G3/39/y5 G4/38/y5 G5/38/y5;
!!CBv998/v999/v1000:R3/y6 R6/y7;
!?FU48&x1=478;
!!VRy5:S-1; !!VRy6:S-1;
!!VRy5&x2<6:S6;
!!VRy5&x2>5/x2<11:S9;
!!VRy5&x2>10/x2<16:S12;
!!VRy5&x2>15:S15;
!!VRy6&x2<6:S4;
!!VRy6&x2>5/x2<11:S6;
!!VRy6&x2>10/x2<16:S8;
!!VRy6&x2>15:S12;
!!CBv998/v999/v1000:G0/-1/0 G1/-1/0 G2/-1/0 G3/-1/0 G4/-1/0 G5/-1/0;
!!CBv998/v999/v1000:G1/105/y5 G2/105/y5 G3/105/y5 G4/105/y5 G5/105/y5;
!!CBv998/v999/v1000:M108/y6;
*********************************************************
!?FU48&x1=480;
!!UN:P235/?y-57;
!!FU&y-57=1:E;
!!OBv998/v999/v1000:T?y1 U?y2;
!!CBv998/v999/v1000:T?y3;
!!FU&y3=1:E;
!!DO48/1/5/1:P481;
!!FU48&y2=0:P482/v201;  独眼宝屋
!!FU48&y2=1:P483/v201;  矮人宝屋
!!FU48&y2=2:P484/v201;  狮鹫宝屋
!!FU48&y2=3:P485/v201;  怪物宝屋
!!FU48&y2=4:P486/v201;  美杜莎宝屋
!!FU48&y2=5:P487/v201;  蛇妖宝屋
!!FU48&y2=6:P488/v201;  龙蝇宝屋
!?FU48&x1=481;
!!CBv998/v999/v1000:Gx16/d/?x2;
!!VRv201:+x2;
!?FU48&x1=482;
!!CBv998/v999/v1000:R0/?x3;
!!IF:Q1/21/94/1^{独眼宝屋}
%X2只独眼宝屋的卫兵看护着数量为%X3的各类资源。^;
!?FU48&x1=483;
!!CBv998/v999/v1000:R4/?x3 R6/?x4;
!!IF:Q1/21/16/4//6//1^{矮人宝屋}
%X2只矮人宝屋的卫兵看护着%X3水晶和%X4金币。^;
!?FU48&x1=484;
!!CBv998/v999/v1000:Md/?x3;
!!IF:Q1/21/4/21/12/1^{狮鹫宝屋}
击败%X2只狮鹫宝屋的卫兵，你将可以得到%X3只天使。^;
!?FU48&x1=485;
!!CBv998/v999/v1000:R1/?x3 R6/?x4;
!!IF:Q1/21/42/1//6//1^{怪物宝屋}
%X2只怪物宝屋的卫兵看护着%X3水银和%X4金币。^;
!?FU48&x1=486;
!!CBv998/v999/v1000:R3/?x3 R6/?x4;
!!IF:Q1/21/76/3//6//1^{美杜莎宝屋}
%X2只美杜莎宝屋的卫兵看护着%X3硫磺和%X4金币。^;
!?FU48&x1=487;
!!CBv998/v999/v1000:R3/?x3 R6/?x4;
!!IF:Q1/21/38/3//6//1^{蛇妖宝屋}
%X2只蛇妖宝屋的卫兵看护着%X3硫磺和%X4金币。^;
!?FU48&x1=488;
!!CBv998/v999/v1000:Md/?x3;
!!IF:Q1/21/105/21/108/1^{龙蝇宝屋}
击败%X2只龙蝇宝屋的卫兵，你将可以得到%X3只飞龙。^;
*********************************************************

[ 本帖最后由 沧海一粟 于 2012-5-30 02:27 编辑 ]

沧海一粟

RT

[ 本帖最后由 沧海一粟 于 2012-5-30 08:48 编辑 ]

eva2000as

问下，普通版可以和官方生物银行加强一起使用么？（当我没说好了……因为我刚想起来WOG的强化是给战旗的……）
还有沧海前辈不来尝试一下修复强化幸运术导致银行手动战斗跳出么=w=~

[ 本帖最后由 eva2000as 于 2012-5-30 08:53 编辑 ]

沧海一粟

原帖由 eva2000as 于 2012-5-30 08:38 发表
问下，普通版可以和生物银行加强一起使用么？
还有沧海前辈不来尝试一下修复强化幸运术导致银行手动战斗跳出么=w=~

哦，你提醒我了，已取消普通版与官方脚本一起使用无效的限制，但我很久没用过官方生物银行加强了，感觉可能会计算数量上出现错误，因为生物银行加强脚本好像是在空白位置添加了守卫，有可能变成6队或以上，我只按原银行计算了5队生物数量。其实我对官方脚本实现的功能根本不熟，一是很久没用了，二是代码普遍太多写法太复杂化每看到都头晕；关于修复幸运术，我好像还答应过风侠的，有时间倒可尝试一下。

兽哥哥

把显示奖励的部分去掉，普通版应该可以加到TE里面。

renlinfeng

苍老师标题还说宝屋 然后就改口成银行了

贤知有您

支持沧版新作.

其实我觉得只要得知宝屋的守卫生物个数已经比较合理了(右键显示).
玩家就可以掂量实力是否可下宝屋.

沧海一粟

原帖由 renlinfeng 于 2012-5-30 09:42 发表
苍老师标题还说宝屋 然后就改口成银行了

晕，被2000as误读了
其实按英雄等级决定宝屋的大小我觉得还是比较平衡，并不为过啊。

dadds

按照沧海的惯例一般都会有个BT版，坐等看BT到啥程度

沧海一粟

原帖由 dadds 于 2012-5-30 10:15 发表
按照沧海的惯例一般都会有个BT版，坐等看BT到啥程度

正解
变态版本：“加兵”宝屋守卫数量与英雄带兵数相关，兵越多守卫也越多；“破阵”只有按照守卫站位顺序按左上-右上-右下-左下才可以打到守卫；“地形”宝屋将会有令你感到非常纠结复杂难过的地形；“援助”在一定程度时，守卫会召唤本族援兵助战，甚至可能会出现狮鹫王之类的超级兵种......
搞笑版本：呵呵，把你的带兵位置和守卫位置全部对调......
以上暂属YY阶段。

寻梦人

记得罗马3的那个强化会出错！

也没有去研究过怎么回事！

还是沧海给力，论坛因你而精彩！

eva2000as

原帖由 沧海一粟 于 2012-5-30 08:57 发表


哦，你提醒我了，已取消普通版与官方脚本一起使用无效的限制，但我很久没用过官方生物银行加强了，感觉可能会计算数量上出现错误，因为生物银行加强脚本好像是在空白位置添加了守卫，有可能变成6队或以上，我只按 ...

不是在空白的地方添加了守卫，而是除了小规模级别外所有的银行/宝屋都加了指挥官，获得的奖励也会有额外的增加。只是官方的因为是和无人城加强放在一起，不太好动手（记得生物增长率是一样的）。
至于宝屋/银行么……原文里就是叫做Bank的=_,=
WOG新加的银行/宝屋记得是两个吸血鬼、一个地下城、一个塔楼、一个壁垒还有骨头塔。规则和官方的一样是固定档次随机分布。不过说实话，我倒是很习惯进银行/宝屋前存档，因为以前不知道是强化幸运的毛病。不过就算知道银行/宝屋里的守卫是超过自己的部队，挑战而后胜之也是很好的体验呢=w=

[ 本帖最后由 eva2000as 于 2012-5-30 12:42 编辑 ]

兽哥哥

沧海有时间的话帮我把元老殿堂剩下的几个脚本搞定吧，我叫水手帮忙意淫一下内容，不然在这样下去都搞TJ了

eva2000as

原帖由 兽哥哥 于 2012-5-30 12:43 发表
沧海有时间的话帮我把元老殿堂剩下的几个脚本搞定吧，我叫水手帮忙意淫一下内容，不然在这样下去都搞TJ了

哥哥你是想让沧海过劳死么=w=
我们来算算他手上的坑吧：
生物强化III——超大规模，目前3/8。
强化幸运修复——规模不明。
生物银行/宝屋——规模中等，目前1/2。
各种生物、宝物系统还有论坛上大家要求的定制——规模不明。
其他……

-w-请大家爱护沧海前辈。

兽哥哥

哈哈。我打算把沧海废了

沧海一粟

呵呵，兽哥我现在都被K版主说是不务正业了，怪物强化III和狮鹫王1.6近期都得先应付着，这个脚本我还是觉得猪大来写比较合适。他现在只是没时间，有时间我相信他会完成的。

兽哥哥

呵呵，你猪大哥都消失半年了

沧海一粟

原帖由 eva2000as 于 2012-5-30 12:47 发表
哥哥你是想让沧海过劳死么=w=
我们来算算他手上的坑吧：
生物强化III——超大规模，目前3/8。
强化幸运修复——规模不明。
生物银行/宝屋——规模中等，目前1/2。
各种生物、宝物系统还有论坛上大家要求的定制— ...

还不止，狮鹫王1.6近期要更新，火之殇和诸神两个图接着怪物强化III要进行全面更新，还有诸神套和英雄套两套神装备今年也要全部完善......

无心云

沧海啊，那个桑田

沧海一粟

原帖由 eva2000as 于 2012-5-30 08:38 发表
问下，普通版可以和官方生物银行加强一起使用么？（当我没说好了……因为我刚想起来WOG的强化是给战旗的……）
还有沧海前辈不来尝试一下修复强化幸运术导致银行手动战斗跳出么=w=~

我只开生物经验和技能强化，在有幸运术加强没加任何非官方脚本（当然基本上官方脚本也没加，我是用官方脚本内置地图事件禁止WOG化测试的，不然看到那么多选项都头晕）的情况下打了半天生物银行，怎么就没看到黑屏出现呢

[ 本帖最后由 沧海一粟 于 2012-5-30 18:01 编辑 ]