生物转换所属城市类型系统

骷髅召唤师

根据转换祭坛的内容写了个生物转换所属城市类型系统
如有BUG请指出
ZVSE
ERMS_ScriptDate=23.2(February).2012
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
****ERM名称       生物转换所属城市类型系统
****ERM制作       骷髅召唤师
****时间触发器    TM56
****FU触发器      FU2800  x1=15~19
***在英雄界面Ctrl+鼠标左键按下英雄部队格触发
***人类玩家2个可以转换成1个
***电脑英雄1个直接转换成1个英雄所属城市类型生物

***********电脑英雄***********
!#TM56:S2/999/1/255;  时间触发器第二天开始
!?TM56;
!!DO2800/0/155/1:P15;

!?FU2800&x1=15;
!!HEx16:O?x2 B2/?x3;
!!OW&x2>-1:Ix2/?x4;
!!VRx5:S-1;
!!VRx5|x3=0/x3=1:S0;
!!VRx5|x3=2/x3=3:S1;
!!VRx5|x3=4/x3=5:S2;
!!VRx5|x3=6/x3=7:S3;
!!VRx5|x3=8/x3=9:S4;
!!VRx5|x3=10/x3=11:S5;
!!VRx5|x3=12/x3=13:S6;
!!VRx5|x3=14/x3=15:S7;
!!VRx5|x3=16/x3=17:S8;
!!DO2800/0/6/1&x4=1:P16/x16/x5;

!?FU2800&x1=16;
!!HEx2:C0/x16/?x4/?x5;
!!FU|x4<0/x5<1:E;
!!MA:Lx4/?x6;
!!VRx6&x4>=150/x4<=158|x4=134:S7;
!!VRx6|x4=132/x4=133/x4=135/x4=160/x4=161/x4=162/x4=163/x4=196:S99;
!!VRx6&x4=159:S99; 鬼
!!UN:P67/?x7;   中立城镇
!!VRx6&x7=1/x4=135:S6;
!!FU2800&x6<=7:P17/x2/x16/x3/x4/x6;

!?FU2800&x1=17;
!!VRx7:Sx5 %2;
!!VRx7|x5=113/x5=115/x5=117/x5=137/x5=139/x5=141/x5=143/x5=159/x5=165/x5=167/x5=171/x5=193:S0;
!!VRx7|x5=138/x5=140/x5=172/x5=168/x5=192/x5=194/x5=136:S1;
!!UN:P67/?x8;
!!VRx7&x8=1/x5=138|x5=140/x5=194/x5=193/x5=195:S0;
!!VRx7&x8=1/x5=167|x5=143/x5=135/x5=142/x5=144:S1;
!!VRx7|x7<0/x7>1:S0;
!!UN&x6<7:Tx4/x6/x7/?x9;
!!VRx9&x6=7:Sx4 +150;
!!HEx2:C0/x3/x9/d;

***********人类玩家**************
!?CM2&1000;
!!CM:I?y1 F?y2;
!!FU|y1<68/y1>74/y2<>4:E;
!!VRy3:Sy1 -68;
!!HE-1:C0/y3/?y4/?y5 N?y6;
!!FU&y4<0:E;
!!UN:N3/-1/y4/1;
!!IF&y5<2:M^{生物转换所属城市类型系统}

对不起！%Z-1的数量<2无法转换。^;
!!FU&y5<2:E;
!!MA:Ly4/?y7 Oy4/?y8;      怪物等级,城市类型
!!UN:P67/?y9;   中立城镇
!!VRz-2&y8=-1:S^野外生物^;
!!VRz-2&y8=0:S^城堡生物^;
!!VRz-2&y8=1:S^壁垒生物^;
!!VRz-2&y8=2:S^塔楼生物^;
!!VRz-2&y8=3:S^地狱生物^;
!!VRz-2&y8=4:S^墓园生物^;
!!VRz-2&y8=5:S^地下城生物^;
!!VRz-2&y8=6:S^据点生物^;
!!VRz-2&y8=7:S^要塞生物^;
!!VRz-2&y8=8/y9=0:S^元素城生物^;
!!VRz-2&y8=8/y9=1:S^中立生物^;
!!VRy7&y4>=150/y4<=158|y4=134:S7;
!!VRy7|y4=132/y4=133/y4=135/y4=160/y4=161/y4=162/y4=163/y4=196:S99;
!!VRy7&y4=159:S99; 鬼
!!VRy7&y9=1/y4=135:S6;
!!FU2800&y7<=7:P18/y3/y4/y7/y5/y6;
!?FU2800&x1=18;
!!VRz-3:S^请输入你想要转换的城市类型

当前%Z-1所属城市类型为%Z-2  转换比率为2:1

0-城堡生物   1-壁垒生物  2-塔楼生物

3-地狱生物   4-墓园生物  5-地下城生物

6-据点生物   7-要塞生物  8-元素城生物

9-野外生物   注意：生物经验值将归 0^;
!!VRz-4:S^字母或者空白默认为0，数值>9则生物为枪兵，数值<0则游戏崩溃。^;
!!VRz-5:S^^;
!!IF:D2/-3/-4/-5;
!!IF:E1/2;
!!FU&v1=-1:E;
!!VRx7:Vz1;
!!VRz-10:S^FLAGMINE.WAV^;
!!SN:Pz-10;
!!VRx8:Sx3 %2;
!!VRx8|x3=113/x3=115/x3=117/x3=137/x3=139/x3=141/x3=143/x3=159/x3=165/x3=167/x3=171/x3=193:S0;
!!VRx8|x3=138/x3=140/x3=172/x3=168/x3=192/x3=194/x3=136:S1;
!!UN:P67/?x9;
!!VRx8&x9=1/x3=138|x3=140/x3=194/x3=193/x3=195:S0;
!!VRx8&x9=1/x3=167|x3=143/x3=135/x3=142/x3=144:S1;
!!VRx8|x8<0/x8>1:S0;
!!UN&x7<9/x4<7:Tx7/x4/x8/?x10;
!!VRx10&x4=7:Sx7 +150;
!!VRx11:Sx5 :2;
!!FU2800&x7=9:P19/x4/x8;
!!VRx10&x7=9:Sv1;
!!HEx6:C0/x2/x10/x11;
!!CM:R0;
!!UN:R3/-1;

!?FU2800&x1=19;
!!VRy2:S1 R1;
!!VRy3:S1 R2;
!!VRv1&x2=0/x3=0:S138;
!!VRv1&x2=0/x3=1:S138;
!!VRv1&x2=1/x3=0:S143;
!!VRv1&x2=1/x3=1:S140;
!!VRv1&x2=2/x3=0:S141;
!!VRv1&x2=2/x3=1/y2=1:S142;
!!VRv1&x2=2/x3=1/y2=2:S173;
!!VRv1&x2=3/x3=0/y3=1:S137;
!!VRv1&x2=3/x3=0/y3=2:S171;
!!VRv1&x2=3/x3=0/y3=3:S172;
!!VRv1&x2=3/y2=1/x3=1:S194;
!!VRv1&x2=4/y3=1/x3=0:S170;
!!VRv1&x2=4/y3=2/x3=0:S171;
!!VRv1&x2=4/y3=3/x3=0:S116;
!!VRv1&x2=4/x3=1:S169;
!!VRv1&x2=5/y3=1/x3=0:S136;
!!VRv1&x2=5/y3=2/x3=0:S193;
!!VRv1&x2=5/y3=3/x3=0:S117;
!!VRv1&x2=5/y2=1/x3=1:S172;
!!VRv1&x2=5/y2=2/x3=1:S195;
!!VRv1&x2=6/x3=0:S168;
!!VRv1&x2=6/x3=1:S168;
!!VRv1&x2=7:S134;
************************************

[ 本帖最后由 骷髅召唤师 于 2012-2-23 20:07 编辑 ]

兽哥哥

点哪里出来啊？怎么我试验不行的？

viper_ou

以后什么兵种都不浪费啊

骷髅召唤师

在英雄界面Ctrl+鼠标左键按下英雄部队格触发

无心云

！！！这样会不会造成WOG内分泌失调啊

兽哥哥

倒是成功了，但是2换1觉得有点不舍得，呵呵。

兽哥哥

有个想法提出来一下。就是不按数量来转换，按照血量来转换行不行？我是指所有的兵都可以转，不一定要按照同级兵来升级，这样会不会更好玩点？

woshijren

测试了，发现会有错误，2级元素兵(没升级)选3(地狱生物)会变成1级的小怪物。

兽哥哥

不会吧，我这边测试一切正常，是变的马格

woshijren

不知道是不是和其它的ERM(更新全部组合宝物占一格，又可拆开。)有冲突，我这里转变有时有问题出现。

[ 本帖最后由 woshijren 于 2012-2-23 19:43 编辑 ]

woshijren

把更新全部组合宝物占一格，又可拆开。删除后就一切正常了。

骷髅召唤师

这是FU函数错误了，因为我这两个ERM的函数是一样的，你把所有FU2800改成FU2900就可以了。
如果你要两个ERM一起用，我去修改一下，你另外下一次

[ 本帖最后由 骷髅召唤师 于 2012-2-23 20:05 编辑 ]

骷髅召唤师

可以啊，这样还要简单一点。

兽哥哥

那就麻烦搞一个出来吧，放到混战图里面应该很好玩。

无心云

原帖由 兽哥哥 于 2012-2-23 19:08 发表
有个想法提出来一下。就是不按数量来转换，按照血量来转换行不行？我是指所有的兵都可以转，不一定要按照同级兵来升级，这样会不会更好玩点？

兽，你这样的又会出现一些投机行为。
因为每个种族是一个综合实力，有的体现在生命，有的是在攻防，有的是魔法特技。如果你完全按生命来话，可能又会被人找出N个BUG级转换吧。

hellmatrix

谢谢楼主，好有用的脚本呢

骷髅召唤师

这个是兽哥你要的
ZVSE
ERMS_ScriptDate=23.2(February).2012
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
****ERM名称       生物转换系统
****ERM制作       骷髅召唤师
****FU触发器      FU2800  x1=20
***在英雄界面Ctrl+鼠标左键按下英雄部队格触发

***********人类玩家**************
!?CM2&1000;
!!CM:I?y1 F?y2;
!!FU|y1<68/y1>74/y2<>4:E;
!!VRy3:Sy1 -68;
!!HE-1:C0/y3/?y4/?y5 N?y6;
!!FU|y4<0/y5<1:E;
!!MA:Py4/?y7;
!!VRy8:Sy7 *y5;
!!FU2800&y6>-1:P20/y6/y3/y4/y5/y8;
!?FU2800&x1=20;
!!VRz-3:S^请输入你想要转换的生物代码（0-196）

0-13 城堡生物   14-27 壁垒生物  28-41 塔楼生物

42-55 地狱生物  56-69 墓园生物  70-83 地下城生物

84-97 据点生物  98-111 要塞生物   112-131 元素生物

132-144 SOD中立生物   145-149-战争机械   150-158 八级生物

159-173 WOG中立生物    174-191  宠物   192-196 WOG中立生物

（其中145到149为战争机器，174到191为宠物，都不可以转换。）^;
!!VRz-4:S^字母或者空白默认为0，即生物为枪兵。^;
!!VRz-5:S^^;
!!IF:D2/-3/-4/-5;
!!IF:E1/2;
!!FU&v1=-1:E;
!!VRx7:Vz1;
!!IF&x7>144/x7<150:M^不能转换成战争机器。^;
!!FU&x7>144/x7<150:E;
!!IF&x7>173/x7<192:M^不能转换成宠物。^;
!!FU&x7>173/x7<192:E;
!!IF|x7>196/x7<0:M^没有这个生物编号。^;
!!FU|x7>196/x7<0:E;
!!IF|x7=122/x7=124/x7=126/x7=128:M^没有这个生物编号。^;
!!FU|x7=122/x7=124/x7=126/x7=128:E;
!!UN:N3/-1/x4/1;
!!UN:N3/-2/x7/1;
!!MA:Px7/?x8;
!!IF&x6<x8:Q2/21/x4/21/x7/1^{对不起，英雄！！！}

当前%Z-1的总生命值无法转换成%Z-2

请重新选择要要转换的生物代码。^;
!!FU&x6<x8:E;
!!VRx9:Sx6 :x8;
!!IF:Q2/21/x4/21/x7/1^{恭喜你，英雄！！！}

基因转换议把%X5个%Z-1转换了%X9个%Z-2。^;
!!VRz-10:S^FLAGMINE.WAV^;
!!SN:Pz-10;
!!HEx2:C0/x3/x7/x9;
!!CM:R0;
!!UN:R3/-1;

[ 本帖最后由 骷髅召唤师 于 2012-2-24 09:15 编辑 ]

灰狼王子

仅按血量转换的话很容易导致不平衡，而且就像狮鹫说的会产生投机行为，比如哥拿1000个农民就能换一条圣龙呢，这两者无论是在战斗价值还是花费上简直都是天壤之别啊

泽拉图

好像很好玩，不过会破坏平衡

hellmatrix

会么，不会吧