学了下经验特技修改，有几个不懂的地方，高手指导下

绝非善类

99/80的酸液攻击要怎么弄才能像地狱9头一样

fastarrow

靠EA不能。

绝非善类

那要怎么改，，给我发个例子吧

骷髅召唤师

用EA时酸液只有减防的作用，没有伤害作用。

绝非善类

那要怎么改

fastarrow

以你现在的ERM水平，暂时不适宜搞这个。

骷髅召唤师

只能模拟伤害

异界行者

模拟伤害其实在上面有的。就是黑龙的酸液，那个就是模拟的。不过这个有个BUG，就是模拟的酸液一旦出现效果，那么被酸液的怪就会等待。

比如我用凤凰去打黑龙，结果出了酸液效果。于是凤凰在下个回合自动等待，让黑龙先打了。

无心云

很奇怪，为什么恶魔的瞬移不能复制，那个动作挺帅的说。

hellmatrix

顶楼上的，我也很喜欢那个飘一下子

骷髅召唤师

大约实现了你的要求，但修改了塔楼和亡灵的特技。
ZVSE
ERMS_ScriptDate=17.1(January).2012
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
*每个城堡的英雄带领同族兵并且没有其他种族的兵的时候该英雄所带的生物战斗时都被赋予一种技能或者魔法
*只检查英雄的部队格中的部队，不包括战争机器，指挥官，一追，二追及战场召唤物
*人类：所有部队自带高级祈祷
*壁垒：所有部队具有龙息攻击
*塔楼：所有部队自带大气神盾+射手额外拥有百发百中
*地狱：所有部队都具有死亡一击
*亡灵：所有部队都带有驱散有益魔法
*地下城：所有生物都具有敌人无法反击
*据点：所有部队自带反戈一击
*要塞：所有部队都飞行
*元素：所有部队能抵抗1-4级魔法（有益的能接受）
******ERM变量：FU2800(x1=1~14)
******ERM变量：v55~v58 + v9555 + v9560
!?BA0;
!!VRv55:C-1/0/-1/0;
!!BA:H0/?v9555 H1/?v9560;
!!DO2800/0/6/1:P1/v9555;
!!DO2800/0/6/1&v9560>-1:P2/v9560;

!?FU2800&x1=1;
!!FU&x1<>1:E;
!!HEx2:B2/?x3;
!!HEx2:C0/x16/?x4/?x5;
!!FU&x5<1:E;
!!MA:Ox4/?x6;
!!VRv55|x3=0/x3=1:S0;   城堡
!!VRv55|x3=2/x3=3:S1;   壁垒
!!VRv55|x3=4/x3=5:S2;   塔楼
!!VRv55|x3=6/x3=7:S3;   地狱
!!VRv55|x3=8/x3=9:S4;   墓园
!!VRv55|x3=10/x3=11:S5;   地下城
!!VRv55|x3=12/x3=13:S6;   据点
!!VRv55|x3=14/x3=15:S7;   要塞
!!VRv55|x3=16/x3=17:S8;   元素城
!!VRv56&v55=0/x6<>0:-1;
!!VRv56&v55=1/x6<>1:-1;
!!VRv56&v55=2/x6<>2:-1;
!!VRv56&v55=3/x6<>3:-1;
!!VRv56&v55=4/x6<>4:-1;
!!VRv56&v55=5/x6<>5:-1;
!!VRv56&v55=6/x6<>6:-1;
!!VRv56&v55=7/x6<>7:-1;
!!VRv56&v55=8/x6<>8:-1;

!?FU2800&x1=2;
!!FU&x1<>2:E;
!!HEx2:B2/?x3;
!!HEx2:C0/x16/?x4/?x5;
!!FU&x5<1:E;
!!MA:Ox4/?x6;
!!VRv57|x3=0/x3=1:S0;   城堡
!!VRv57|x3=2/x3=3:S1;   壁垒
!!VRv57|x3=4/x3=5:S2;   塔楼
!!VRv57|x3=6/x3=7:S3;   地狱
!!VRv57|x3=8/x3=9:S4;   墓园
!!VRv57|x3=10/x3=11:S5;   地下城
!!VRv57|x3=12/x3=13:S6;   据点
!!VRv57|x3=14/x3=15:S7;   要塞
!!VRv57|x3=16/x3=17:S8;   元素城
!!VRv58&v57=0/x6<>0:-1;
!!VRv58&v57=1/x6<>1:-1;
!!VRv58&v57=2/x6<>2:-1;
!!VRv58&v57=3/x6<>3:-1;
!!VRv58&v57=4/x6<>4:-1;
!!VRv58&v57=5/x6<>5:-1;
!!VRv58&v57=6/x6<>6:-1;
!!VRv58&v57=7/x6<>7:-1;
!!VRv58&v57=8/x6<>8:-1;

!?BF;
!!DO2800/0/20/1&v55=1/v56=0:P4;      壁垒
!!DO2800/21/41/1&v9560>-1/v57=1/v58=0:P4;   壁垒
!!DO2800/0/20/1&v55=3/v56=0:P6;      地狱
!!DO2800/20/41/1&v9560>-1/v57=3/v58=0:P6;   地狱
!!DO2800/0/20/1&v55=4/v56=0:P7;      墓园
!!DO2800/21/41/1&v9560>-1/v57=4/v58=0:P7;   墓园
!!DO2800/0/20/1&v55=5/v56=0:P8;      地下城
!!DO2800/21/41/1&v9560>-1/v57=5/v58=0:P8;   地下城
!!DO2800/0/20/1&v55=7/v56=0:P10;      要塞
!!DO2800/21/41/1&v9560>-1/v57=7/v58=0:P10;   要塞
!!DO2800/0/20/1&v55=8/v56=0:P11;      元素城
!!DO2800/21/41/1&v9560>-1/v57=8/v58=0:P11;   元素城


!?BR;
!!DO2800/0/20/1&v55=0/v56=0:P3;      城堡
!!DO2800/21/41/1&v9560>-1/v57=0/v58=0:P3;   城堡
!!DO2800/0/20/1&v55=2/v56=0:P5;      塔楼
!!DO2800/21/41/1&v9560>-1/v57=2/v58=0:P5;   塔楼
!!DO2800/0/20/1&v55=6/v56=0:P9;      据点
!!DO2800/21/41/1&v9560>-1/v57=6/v58=0:P9;   据点



!?FU2800&x1=3;     城堡
!!FU&x1<>3:E;
!!BMx16:T?x2 N?x3;
!!FU|x2<0/x3<1:E;
!!BMx16:M48/999/5;     祈祷

!?FU2800&x1=4;     壁垒
!!FU&x1<>4:E;
!!BMx16:T?x2 N?x3;
!!FU|x2<0/x3<1:E;
!!FU&x2>144/x2<150:E;
!!BMx16:F?x4 F?x5;
!!VRx4:&8;
!!FU&x4>0:E;
!!VRx5:|8;      龙息
!!BMx16:Fx5;

!?FU2800&x1=5;     塔楼
!!FU&x1<>5:E;
!!BMx16:T?x2 N?x3;
!!FU|x2<0/x3<1:E;
!!BMx16:M28/999/5;     大气神盾
!!BMx16:F?x4;
!!VRx4:&4;
!!FU&x4=0:E;
!!BMx16:M44/999/5;    百发百中

!?FU2800&x1=6;     地狱
!!FU|x1<>6:E;
!!BMx16:T?x2 N?x3 O?x4;
!!FU|x2<0/x3<1/x4=-1:E;
!!VRy-1:Sx16 +1 *-1;
!!EAy-1:F101/?y-2 F0/?y-3; 双倍伤害
!!IF&y-2<y-3:V2/1;
!!EAy-1&2:By-2/1/101/61/50/50/50/50/50/50/50/50/50/50/50;
!!EAy-1&-2/y-3<14:By-3/1/101/61/50/50/50/50/50/50/50/50/50/50/50;
!!EAy-1&-2/y-3>13:B13/1/101/61/50/50/50/50/50/50/50/50/50/50/50;


!?FU2800&x1=7;     墓园
!!FU|x1<>7:E;
!!BMx16:T?x2 N?x3 O?x4;
!!FU|x2<0/x3<1/x4=-1:E;
!!VRy-1:Sx16 +1 *-1;
!!EAy-1:F99/78/?y-2 F0/?y-3; 驱散有益魔法
!!IF&y-2<y-3:V2/1;
!!EAy-1&2:By-2/1/99/78/100/100/100/100/100/100/100/100/100/100/100;
!!EAy-1&-2/y-3<14:By-3/1/99/78/100/100/100/100/100/100/100/100/100/100/100;
!!EAy-1&-2/y-3>13:B13/1/99/78/100/100/100/100/100/100/100/100/100/100/100;


!?FU2800&x1=8;     地下城
!!FU&x1<>8:E;
!!BMx16:T?x2 N?x3;
!!FU|x2<0/x3<1:E;
!!FU&x2>144/x2<150:E;
!!BMx16:F?x4 F?x5;
!!VRx4:&65536;
!!FU&x4>0:E;
!!VRx5:|65536;     不反击
!!BMx16:Fx5;

!?FU2800&x1=9;     据点
!!FU&x1<>9:E;
!!BMx16:T?x2 N?x3;
!!FU|x2<0/x3<1:E;
!!BMx16:M58/999/5;     反戈一击

!?FU2800&x1=10;     要塞
!!FU&x1<>10:E;
!!BMx16:T?x2 N?x3;
!!FU|x2<0/x3<1:E;
!!FU&x2>144/x2<150:E;
!!BMx16:F?x4 F?x5;
!!VRx4:&2;
!!FU&x4>0:E;
!!VRx5:|2;      飞行
!!BMx16:Fx5;

!?FU2800&x1=11;     元素城
!!FU|x1<>11:E;
!!BMx16:T?x2 N?x3 O?x4;
!!FU|x2<0/x3<1/x4=-1:E;
!!VRy-1:Sx16 +1 *-1;
!!EAy-1:F119/52/?y-2 F0/?y-3; 免疫1-4级魔法(容纳)
!!IF&y-2<y-3:V2/1;
!!EAy-1&2:By-2/1/119/52/50/1/1/1/1/1/1/1/1/1/1/1;
!!EAy-1&-2/y-3<14:By-3/1/119/52/1/1/1/1/1/1/1/1/1/1/1;
!!EAy-1&-2/y-3>13:B13/1/119/52/1/1/1/1/1/1/1/1/1/1/1;


*************************************************