How to make an artifact with ERM-Primary Skill Bonuses

yunings · 发表于 2011-10-15 22:58:31

Original Posted @ Heroes Community by gnollking

Okay, so in this guide we will use one of the Blank ERM Artifacts #161-170. Let's use the Shield #163, it looks nice.
So of course, the first line is:

ZVSE

Then we'll have to add a these lines:

!?OB5/163;
!!UN:Ov998/v999/v1000;
!!UN:Iv998/v999/v1000/5/163;
!!ARv998/v999/v1000:M^{GnollKing's Shield}

When equipped, this Shield gives +2 bonus to all primary skills.^;

These lines set the hint text of the artifact 163, when the artifact is equipped. (you can edit the name and description as you wish)
So, next we'll need to give the bonuses to the primary skills, when hero has the Shield equipped, to do this, we add these lines:

!?AE1&v998=163;
!!HE-1:Fd2/d2/d2/d2;

First line says: When artifact 163 equipped, next occurs.
And the second line increases the hero's (-1 (current hero)), who equipped the artifact, all primary skills by +2. When there's a "d" in front of the number, it tells we add numbers to the current value.
So, next we'll have to decrease the skills when hero unequips the artifacts. This is done easily:

!?AE0&v998=163;
!!HE-1:Fd-2/d-2/d-2/d-2;

Almost the same, but after the "!?AE" is a number "0", it means the artifact is unequipped ("1" means equipped).
The second line has "d-", it tells we will reduce amount from the current value.
Very simple.
Now we only need to show text, when hero finds the artifact on the map, and equips it. This is done easily:

!#VRz429:S^{GnollKing's Shield}

When equipped, this Shield gives +2 bonus to all primary skills.^;
!#HT5/163:T429;

The first line saves the text to variable "429", and the second line adds it to 5=Artifact, 163=Artifact number. (Btw, when text is written in the middle of "{" and "}", the text turns to golden. Not a WoG feature, works with all versions).
This text is shown, when hero right-clicks the artifact on his inventory.

Not hard at all, right? So, the whole code is here:

ZVSE
!?OB5/163; Artifact 163
!!UN:Ov998/v999/v1000;
!!UN:Iv998/v999/v1000/5/163;
!!ARv998/v999/v1000:M^{GnollKing's Shield}

When equipped, this Shield gives +2 bonus to all primary skills.^; Show text when equipped
!?AE1&v998=163; Equip Artifact 163
!!HE-1:Fd2/d2/d2/d2; Increase all primary skills by +2
!?AE0&v998=163; Unequip Artifact 163
!!HE-1:Fd-2/d-2/d-2/d-2; Decrease all primary skills by -2
!#VRz429:S^{GnollKing's Shield}

When equipped, this Shield gives +2 bonus to all primary skills.^;
!#HT5/163:T429; Show text when right-clicked

To use this script, place it to a timed event on your map, and set day to about 500 or more (so it will never occur).
If you're planning to do many new artifacts on your map, change the variable (429) to something different to all artifacts, and do not Wogify the map. :)