【第一篇结束】ERM初级进阶心得（附大量ERM实例）

沧海一粟

         以下内容，均为本人在ERM学习过程中，积累的一些心得，用ERM的实例写出，给一些ERM入门的初级爱好者提供一些可用的思路，高手请无视之。
        由于本人ERM水平有限，讲得不正确的地方还请大家见谅，另本贴实例均有现成的脚本提供给大家，下载后可直接在任何地图上使用。
        另外，本贴将不定期进行更新，并无限欢迎会员朋友们多进来讨论、交流，只要有时间，本人一定解答所有玩家的疑问。

[ 本帖最后由 沧海壹粟 于 2011-9-7 16:32 编辑 ]

沧海一粟

        我们通过查找ERM帮助v2.06中文版（以下简称为ERM帮助，WOG论坛克招翻译）下的MA：X命令，
可以得知这个命令是用来设置怪物所拥有标志位技能（即通常我们所讲的生物特技）的。MA：X命令最基本的应用是给怪物设置一些标志性能力，如给大天使增加环击、九头怪增加飞行等。有了一定的修改生物特技的基础后，我们肯定不会满足仅仅用MA给生物增加特技，会想到把更多稀奇古怪的特技添加到生物身上，那这些想法要如何实现呢？
        譬如说给生物增加“绝对反击”的特技就是个很好例子，就是通过动作前给有不反击特技的攻击目标生物减去不反击特技后，动作后恢复不反击特技来间接实现绝对反击的目的。（“绝对反击”的ERM在论坛上搜索可以找到，我就不在赘述）。
       但是，仅仅通过MA：X是无法实现更多古怪想法的，我们又继续查找ERM帮助的BM：F命令，可以看到如下说明：

怪物标志(类似MA:X)
提示：
可以使用 MA:X将以下几个新的战场中的标志增加给怪物：
0x01000000 = 16777216 - 当前堆栈士气向上
0x02000000 = 33554432 - 当前堆栈为待机
0x04000000 = 67108864 - 当前堆栈已行动
0x08000000 = 134217728 - 当前堆栈为防御状态
0x00400000 = 4194304 – 当前堆栈为召唤物(在杀死后消失)
0x00800000 = 8388608 – 当前堆栈为克隆体 (蓝色显示，且只能承受一次攻击)
0x00C00000 = 12582912 – 当前堆栈是由克隆魔法召唤的怪物（等于上面的召唤物+克隆体）

       不要小看这几个命令，个个可都是精品，但知道了命令的作用后，要如何合理地添加这些特技给生物又是一个不小的难题，因为这些命令想依靠MA，甚至是BF、BR等添加是没有效果的，最好的添加方式是用BG（当然有些用BR添加也有效果）。
        至于如何添加和添加后有什么作用，我将在下面以英雄施法附加能力的ERM实例一一列举，由于本人时间有限，所列举的脚本均未在增加详细注释，有基础的朋友可以自己查找ERM帮助看看，如果真的看不懂，我再另外详细附加说明。




[ 本帖最后由 沧海壹粟 于 2011-9-6 08:51 编辑 ]

沧海一粟

        我们通过查找ERM帮助我们可以得知16777216为当前堆栈士气向上的意思，但这个命令不能简单阐述为堆栈永远都有正士气，它的合理解释应该大致理解为使当前堆栈获得优先行动的能力。现在论坛上的ERM对这个的应用不多，所以不能提供现成的例子，我写了一个姆多克爵士施放加速大法后使本方生物获得先制攻击的ERM实例（就是说施放加速大法后，连农民都将比对方的神凤都要优先行动，但行动速度并不改变），希望初学者能通过该实例体会一下这个命令的用法，融汇到自己定制的脚本中。


ERM实例1：姆多克可以通过施放加速大法使本方生物获得先制攻击。

ZVSE

**************超级姆拉克*******************
************ERM制作：沧海壹粟****************

**************初始英雄设置*******************
!?PI;
!!VRz905:S^所有生物速度+3，并可通过施放加速大法魔法使本方生物该回合内获得先制攻击的能力（仅限自带生物）。^;
!!UN:G2/144/2/905;
!!HE144:S6/1 S15/3;
!!HE144:A1/0/17 M53/1;
**************战斗前触发变量设置*******************
!?BA0;
!!BA:H0/?v9555;
!!BA:H1/?v9560;
**************动作前触发变量设置*******************
!?BG0;
!!VRv9800:C-1/-1/-1/-1/-1/-1/-1/-1/-1;
!!BG:A?v9800 D?v9801 E?v9802;
!!BG:H?v9803 N?v9804 Q?v9805 S?v9806;
!!BHv9805:N?v9807;
!!HEv9807:E?y-1/?v9808;
**************动作后触发先制攻击*******************
!?BG1;
!!FU|v9800<>1/v9806<>53/v9807<>144:E;
!!DO29000/0/20/1&v9555=144:P56/v9807;
!!DO29000/21/41/1&v9560=144:P56/v9807;
!?FU29000&x1=56;
!!FU|x1<>56:E;
!!BMx16:T?y1 F?y2 F?y3 N?y4 O?y5;
!!FU&y1>144/y1<150:E;
!!FU|y4<1/y5=-1:E;
!!HEx2:B0/?z-1;
!!UN:N1/-2/53/1;
!!UN:N3/-3/y1/1;
!!VRy2:&67108864;  检查堆栈是否已行动
!!FU&y2>0:E;
!!VRz901:S^Luck.wav^;
!!SN:Pz901;
!!VRy3:|16777216;  给未行动的堆栈添加先行动的能力
!!BMx16:V18 Fy3;
!!VRz900:S^{%Z-1施放%Z-2魔法后，%Z-3获得先制攻击能力。^;
!!BU:Mz900 R;
**************战场上生成速度再+1*******************
!?BF;
!!DO29000/0/20/1&v9555=144:P57;
!!DO29000/21/41/1&v9560=144:P57;

!?FU29000&x1=57;
!!FU|x1<>57:E;
!!BMx16:T?y1;
!!FU&y1>144/y1<150:E;
!!BMx16:Sd1;
*********************结束*************************

(第二节从12L起）

[ 本帖最后由 沧海壹粟 于 2011-9-6 10:06 编辑 ]

骷髅召唤师

好，谢谢沧海兄的说明。

songfx

哈哈，我看到了“杀死后消失”，期待沧海把所有生物牵到战场上打酱油。

xuzuonan

技术贴，纯支持了

无心云

先顶一个，有空的时候就学一断。

灰狼王子

沧海兄加油冲精！哥顶你

沧海一粟

啊哈，本来昨天计划把第一篇全部写完，不料下午领导一个电话，害我从下午一直工作到今天凌晨

兽哥哥

文兄

沧海出手，与众不同

沧海一粟

         我们继续往下可以看到如下三个命令：33554432等于当前堆栈为待机，67108864为当前堆栈已行动，134217728等于当前堆栈为防御状态。这三个命令作用相似，用法相当，说白了我们可以用33554432检查生物是否为待机状态或把未行动的生物强制为待机状态等；通过67108864把未行动的生物强制为已行动（类似圣龙的恐惧效果）或把已行动的生物转换为未行动，至于134217728的作用基本同上两个命令。

         以下我将用ERM实例逐步讲解33554432和67108864。

沧海一粟

        ERM帮助文件对这个命令已经说得很清楚了，它的意思为当前堆栈为待机状态，这个解释是很准确的，写ERM时可以通过该命令检查堆栈是否有待机标志来确定添加其它功能，或直接给未行动的堆栈增加（改变）为待机状态。
        但现ERM对这命令的应用不多，就个人而言，我认为33554432才是最精华、最好玩的生物标志所在！因为我们完全可以通过它，去实现生物行动秩序完全颠倒及16777216命令的全部功能。

实例2：罗德哈特在施放恶咒附身后使对方生物滞后行动，并且行动秩序完全颠倒。


ZVSE

**************超级罗德哈特*******************
************ERM制作：沧海壹粟****************

**************初始英雄设置*******************
!?PI;
!!VRz906:S^使用恶咒附身时效果大增，无视魔免，可以使生物滞后行动并且行动秩序完全颠倒。^;
!!UN:G2/150/2/906;
!!HE150:X3/42;
!!HE150:S14/3;
!!HE150:M42/1;
**************战斗前触发变量设置*******************
!?BA0;
!!BA:H0/?v9555;
!!BA:H1/?v9560;
**************动作前触发变量设置*******************
!?BG0;
!!VRv9800:C-1/-1/-1/-1/-1/-1/-1/-1/-1;
!!BG:A?v9800 D?v9801 E?v9802;
!!BG:H?v9803 N?v9804 Q?v9805 S?v9806;
!!BHv9805:N?v9807;
!!HEv9807:E?y-1/?v9808;
**************动作后触发行动颠倒*******************
!?BG1;
!!FU|v9800<>1/v9806<>42/v9807<>150:E;
!!DO29000/21/41/1&v9555=150:P58/v9807;
!!DO29000/0/20/1&v9560=150:P58/v9807;

!?FU29000&x1=58;
!!FU|x1<>58:E;
!!BMx16:T?y1 F?y2 F?y3 N?y4;
!!FU&y1>144/y1<150:E;
!!FU&y4<1:E;
!!HEx2:B0/?z-1;
!!UN:N1/-2/42/1;
!!UN:N3/-3/y1/1;
!!VRy2:&67108864;   检查堆栈是否为已行动
!!FU&y2>0:E;             已行动则退出
!!VRz901:S^view.wav^;
!!SN:Pz901;
!!VRy3:|33554432;
!!BMx16:V15 Fy3;
!!VRz900:S^{%Z-1施放%Z-2魔法后，%Z-3的行动秩序完全颠倒。}^;
!!BU:Mz900 R;
**************魔抗前触发无视魔免*******************
!?MR2;
!!FU|v9800<>1/v9806<>42/v9807<>150:E;
!!MR:F0;
*********************结束*************************

[ 本帖最后由 沧海壹粟 于 2011-9-6 10:36 编辑 ]

songfx

这两个脚本相当有趣。

沧海一粟

        67108864意思是当前堆栈已行动，这个命令是所有BM：F命令中应用算是比较多的一个，也算是很强大的生物标志。我们可以通过使用它给已行动或未行动的堆栈生物增加或减少行动的机会，论坛上的实例不少，有大天使施法后再次行动、Air写的宝物铁弓及老实猪9合1英雄特长里的部分功能，还有我当初写的剑圣风火轮及其它不少脚本，应用的都是这个命令功能的拓展。

实例3：罗兰德在施放欢欣鼓舞后使本方生物机率获得再次行动的机会。


ZVSE

**************超级罗兰德*******************
************ERM制作：沧海壹粟****************

**************初始英雄设置*******************
!?PI;
!!VRz904:S^施放欢欣鼓舞魔法时效果大增，可以使本方已行动生物在该回合获得再次行动的机会（机率与英雄等级有关，仅限自带生物）。^;
!!UN:G2/152/2/904;
!!HE152:X3/49;
!!HE152:S16/3 S23/0;
!!HE152:A1/0/17 M49/1;
**************战斗前触发变量设置*******************
!?BA0;
!!BA:H0/?v9555;
!!BA:H1/?v9560;
**************动作前触发变量设置*******************
!?BG0;
!!VRv9800:C-1/-1/-1/-1/-1/-1/-1/-1/-1;
!!BG:A?v9800 D?v9801 E?v9802;
!!BG:H?v9803 N?v9804 Q?v9805 S?v9806;
!!BHv9805:N?v9807;
!!HEv9807:E?y-1/?v9808;
**************动作后触发再次行动*******************
!?BG1;
!!FU|v9800<>1/v9806<>49/v9807<>152:E;
!!DO29000/0/20/1&v9555=152:P54/v9807/v9808;
!!DO29000/21/41/1&v9560=152:P54/v9807/v9808;
!?FU29000&x1=54;
!!FU|x1<>54:E;
!!BMx16:T?y1 F?y2 F?y3 N?y4 O?y5;
!!FU&y1>144/y1<150:E;
!!FU|y4<1/y5=-1:E;
!!HEx2:B0/?z-1;
!!UN:N1/-2/49/1;
!!UN:N3/-3/y1/1;
!!VRy2:&67108864;   检查堆栈是否行动
!!FU&y2<1:E;             未行动则退出
!!VRy6:S0 R99;
!!VRy7:Sx3;
!!VRy7&y7<30:S30;
!!VRy7&y7>50:S50;
!!FU&y6>y7:E;    机率为30%~50%，按英雄等级提高
!!VRz901:S^Expernce.wav^;
!!SN:Pz901;
!!VRy3:-67108864;
!!BMx16:V20 Fy3;
!!VRz900:S^{%Z-1陛下施放%Z-2魔法后，%Z-3获得了再次行动的机会。^;
!!BU:Mz900 R;

**************战场上生成增加士气*******************
!?BF;
!!DO29000/0/20/1&v9555=152:P55;
!!DO29000/21/41/1&v9560=152:P55;

!?FU29000&x1=55;
!!FU|x1<>55:E;
!!HE152:R0/10;  临时士气+10
*********************结束*************************

（第二节完）

[ 本帖最后由 沧海壹粟 于 2011-9-6 10:36 编辑 ]

沧海一粟

本来还有几个更有趣的ERM实例想今天上午全部把第一篇讲完，现在看来是没办法了，领导的电话又来了

兽哥哥

慢慢来，不要紧，也让其他人有时间慢慢消化。

沧海一粟

（接15L继续）

一、关于4194304应用

        命令4194304的意思当前堆栈为召唤物标志。既然是召唤物，战场中被杀死后肯定是消失的，战后即使胜利了也和经验特技召唤出来的生物一样不复存在（当然指挥官和一追二追等每场战斗都可以召唤物除外）。
       知道了这个命令的作用，就可以想像它有多么地强大，你可以在战场上给召唤的生物（如元素及其它ERM召唤的生物）删除召唤物标志，前提是你所带的部队没有超编，超编了就会引起错误（呵呵，你可以想像用元素召唤魔法召唤出永远存在的元素），也可以给非召唤的生物增加召唤物标志，这样生物被杀死后就不复存在了（尸体都消失，用复活和聚灵亦无效）。
      现ERM对这个命令的应用貌似不多，不过我个人还是很喜欢用这个命令的。下面贴个很好玩的ERM，实现的是伯拉格施放亡灵杀手后和对方英雄同归于尽，不论对方英雄是否带领7*9999圣龙还是1农民，哈哈，只要伯哥一招亡灵杀手下去，统统成了过眼云烟。

实例4：伯拉格在施放亡灵杀手后和对方英雄同归于尽。


ZVSE
**************超级伯拉格*******************
************ERM制作：沧海壹粟****************

**************初始英雄设置*******************
!?PI;
!!VRz907:S^伯拉格的特长没什么好说的，就是施放亡灵杀手魔法后和敌方英雄同归于尽。^;
!!UN:G2/154/2/907;
!!HE154:X3/25;
!!HE154:B2/13;
!!HE154:A1/0/17 M25/1 Id5;
**************战斗前触发变量设置*******************
!?BA0;
!!BA:H0/?v9555;
!!BA:H1/?v9560;
**************动作前触发变量设置*******************
!?BG0;
!!VRv9800:C-1/-1/-1/-1/-1/-1/-1/-1/-1;
!!BG:A?v9800 D?v9801 E?v9802;
!!BG:H?v9803 N?v9804 Q?v9805 S?v9806;
!!BHv9805:N?v9807;
!!HEv9807:E?y-1/?v9808;
**************战场后生成增加死灵*******************
!?BF;  
!!DO29000/0/20/1&v9555=154:P59;
!!DO29000/21/41/1&v9560=154:P59;
!?FU29000&x1=59;
!!FU|x1<>59:E;
!!BMx16:T?y1 F?y2 F?y3 N?y4;
!!FU&y1>144/y1<150:E;
!!FU&y4<1:E;
!!VRy2:&262144;
!!FU&y2>0:E;
!!VRy3:|262144;
!!BMx16:Fy3;
**************动作后触发变成召唤*******************
!?BG1;
!!FU|v9800<>1/v9806<>25/v9807<>154:E;
!!DO29000/21/41/1&v9555=154:P60;
!!DO29000/0/20/1&v9560=154:P60;
!!BU&v9555=154:V0;
!!BU&v9560=154:V1;
!?FU29000&x1=60;
!!FU|x1<>60:E;
!!BMx16:T?y1 N?y2 F?y3 O?y4;
!!FU&y1>144/y1<150:E;
!!FU|y2<1/y4=-1:E;
!!VRy3:|4194304;
!!BMx16:Fy3;
*********************结束*************************

[ 本帖最后由 沧海壹粟 于 2011-9-6 16:46 编辑 ]

沧海一粟

         命令8388608的意思是当前堆栈为克隆体，效果类似镜像大法克隆的生物（只能说是类似，因为镜像大法克隆的生物标志见下段），等同生物经验特技复制克隆体，这又是一个极为强大的命令，因为拥有克隆体标志的生物只能承受一次攻击（不管生物是否有格档和魔抗）。所以说一般情况下还是不要给本方堆栈添加，除非你要达到某种好玩目的，如我以前写的剑圣指挥官召唤幻影战神，反之如果给敌方生物添加的话，嘿嘿，只要你的1个农民小指头那么轻轻一点，9999圣龙就玩完了（实例可见GB四合一英雄魔法天尊的水之怒）。
        命令12582912的意思是当前堆栈是由克隆魔法召唤的怪物，效果等同镜像大法召唤克隆体（即召唤物4194304+克隆体8388608=12582912）。这个命令的用法相当于8388608，不过某些时候用起来比8388608用起来更不会引起错误，起码我的小农民要想点9999圣龙我就不会选择用8388608而是用12582912，这些只能自己在ERM创作中慢慢体会。
        当然，上述这两个命令你也可以反其道而行之，譬如删除本方堆栈克隆体标志后，这样生物就成了召唤物，能承受很多次攻击了，结合上楼4194304命令，你甚至可以用镜像大法给自己增加生物，第三节的这三个命令用好了可是相当厉害。

实例5：凯瑟琳在施放镜像大法后能使目标的克隆体转变为召唤物，即传说中的实体召唤。


ZVSE

**************超级凯瑟琳*******************
************ERM制作：沧海壹粟****************

**************初始英雄设置*******************
!?PI;
!!VRz903:S^可以通过施放镜像大法魔法，将镜像体转变为召唤体，但禁止对召唤体使用镜像大法。^;
!!UN:G2/146/2/903;
!!HE146:X3/65;
!!HE146:S16/3 S22/0;
!!HE146:B2/1;
!!HE146:A1/0/17 M65/1 Id10;
**************战斗前触发变量设置*******************
!?BA0;
!!BA:H0/?v9555;
!!BA:H1/?v9560;
**************动作前触发变量设置*******************
!?BG0;
!!VRv9800:C-1/-1/-1/-1/-1/-1/-1/-1/-1;
!!BG:A?v9800 D?v9801 E?v9802;
!!BG:H?v9803 N?v9804 Q?v9805 S?v9806;
!!BHv9805:N?v9807;
!!HEv9807:E?y-1/?v9808;
**************动作前触发禁止镜像*******************
!?BG0;
!!FU|v9800<>1/v9806<>65/v9807<>146:E;
!!FU29000:P52/v9802/v9807;

!?FU29000&x1=52;
!!FU|x1<>52:E;
!!BMx2:N?y1 T?y2 F?y3;
!!VRy3:&4194304;
!!FU|y1<1/y3<1:E;
!!HEx3:B0/?z-1;
!!UN:N1/-2/65/1;
!!UN:N3/-3/y2/1;
!!BMx2:V76;
!!IF:Q1/9/65/1^{%Z-1禁止对召唤物%Z-3使用%Z-2魔法。}^;
!!BG:A0;
**************动作后触发实体召唤*******************
!?BG1;
!!FU|v9800<>1/v9806<>65/v9807<>146:E;
!!DO29000/0/20/1&v9555=146:P53/v9802/v9807;
!!DO29000/21/41/1&v9560=146:P53/v9802/v9807;

!?FU29000&x1=53;
!!FU|x1<>53:E;
!!BMx16:T?y1 F?y2 F?y3 N?y4;
!!BMx2:T?y5 N?y6;
!!FU|y1<>y5/y4<>y6:E;
!!VRy2:&12582912;
!!FU&y2<1:E;
!!HEx3:B0/?z-1;
!!UN:N1/-2/65/1;
!!UN:N3/-3/y1/1;
!!VRy3:-8388608;
!!VRz901:S^killfade.82M^;
!!SN:Pz901;
!!BMx16:Fy3;
!!VRz900:S^{%Z-1用%Z-2魔法召唤了%Y6个%Z-3。}^;
!!BU:Mz900 R;
*********************结束*************************
（第三节结束）

[ 本帖最后由 沧海壹粟 于 2011-9-6 16:43 编辑 ]

songfx

沧海，有办法突破生物队数上限了吗？