组合宝物泰坦之箭的加强

cj00cd

一直有个愿望：泰坦之箭和泰坦、雷神能够联动，泰坦和雷神能够加强泰坦之箭的杀伤力，泰坦和雷神每次远程攻击后追加泰坦之箭打击目标！！自己鼓捣ERM弄不出来呀，那位大大帮个忙实现俺的愿望吧 。比如泰坦之箭的最终杀伤可以改为：600+英雄力量x[(泰坦数量x5)+(雷神数量x20)]

[ 本帖最后由 cj00cd 于 2011-7-17 14:48 编辑 ]

兽哥哥

可惜我不会，但是我觉得这个不难实现。。。

兽哥哥

就跟雷神近身攻击后追加闪电是一个道理。

ycpop

这个在沧海做的诸神脚本里实现了，至尊箭神的ERM，那个是把TT之箭强化为施放后伤害为雷神数量*600，你的要求不难实现，至于怪物攻前施放TT之箭，这简直是鸡肋，费时间，且伤害固定600，要写这个脚本，我现在还没那能力，写出来也不知道对不对，看其他大神吧

骷髅召唤师

如图，额外增加泰坦之箭的英雄力量为13*泰坦数量为5*5+雷神数量*20=1625点魔法杀伤力
ZVSE

!#VRz210:S^{超级泰坦之箭}

可施放不消耗魔力的魔法泰坦之箭，伤害600点。
并按 {英雄力量*(泰坦数量*5+雷神数量*20)} 增加泰坦之箭的魔法杀伤力。^;
!#UN:A135/10/210;

!?BA0&1000;
!!VRv55:C-1/-1/-1/-1;
!!BA:H0/?v9555;
!!BA:H1/?v9560;
!!HEv9555:A2/135/d/?v55;
!!HEv9560&v9560>-1:A2/135/d/?v56;
!!HEv9555&v55>0:Fd/d/?v57/d;
!!HEv9560&v9560>-1/v56>0:Fd/d/?v58/d;

!?MR0&1000;
!!FU26000&v55>0:P0;
!!FU26000&v56>0:P1;

!?FU26000&x1=0;
!!FU&v55<1:E;
!!BM0:T?y1 N?y-1;
!!BM1:T?y2 N?y-2;
!!BM2:T?y3 N?y-3;
!!BM3:T?y4 N?y-4;
!!BM4:T?y5 N?y-5;
!!BM5:T?y6 N?y-6;
!!BM6:T?y7 N?y-7;

!!VRy10:S0;
!!VRy10&y1=41:+y-1;
!!VRy10&y2=41:+y-2;
!!VRy10&y3=41:+y-3;
!!VRy10&y4=41:+y-4;
!!VRy10&y5=41:+y-5;
!!VRy10&y6=41:+y-6;
!!VRy10&y7=41:+y-7;

!!VRy11:S0;
!!VRy11&y1=152:+y-1;
!!VRy11&y2=152:+y-2;
!!VRy11&y3=152:+y-3;
!!VRy11&y4=152:+y-4;
!!VRy11&y5=152:+y-5;
!!VRy11&y6=152:+y-6;
!!VRy11&y7=152:+y-7;

!!VRy12:Sy10 *5;
!!VRy13:Sy11 *20;
!!VRy14:Sy12 +y13;

!!BG:A?y21 S?y22 Q?y23;
!!FU|y21<>1/y22<>57/y23<>0:E;
!!MR:D?y20;
!!VRy25:Sv57*y14;
!!VRy20:+y25;
!!MR:Dy20;
!!BU:R;

!?FU26000&x1=1;
!!FU&v56<1:E;
!!BM21:T?y1 N?y-1;
!!BM22:T?y2 N?y-2;
!!BM23:T?y3 N?y-3;
!!BM24:T?y4 N?y-4;
!!BM25:T?y5 N?y-5;
!!BM26:T?y6 N?y-6;
!!BM27:T?y7 N?y-7;

!!VRy10:S0;
!!VRy10&y1=41:+y-1;
!!VRy10&y2=41:+y-2;
!!VRy10&y3=41:+y-3;
!!VRy10&y4=41:+y-4;
!!VRy10&y5=41:+y-5;
!!VRy10&y6=41:+y-6;
!!VRy10&y7=41:+y-7;

!!VRy11:S0;
!!VRy11&y1=152:+y-1;
!!VRy11&y2=152:+y-2;
!!VRy11&y3=152:+y-3;
!!VRy11&y4=152:+y-4;
!!VRy11&y5=152:+y-5;
!!VRy11&y6=152:+y-6;
!!VRy11&y7=152:+y-7;

!!VRy12:Sy10 *5;
!!VRy13:Sy11 *20;
!!VRy14:Sy12 +y13;

!!BG:A?y21 S?y22 Q?y23;
!!FU|y21<>1/y22<>57/y23<>1:E;
!!MR:D?y20;
!!VRy25:Sv58*y14;
!!VRy20:+y25;
!!MR:Dy20;
!!BU:R;

[ 本帖最后由 骷髅召唤师 于 2011-7-17 17:53 编辑 ]

泽拉图

强帖留名，一直都觉得泰坦之箭没啥用，这样一改就有用了

骷髅召唤师

好像是我没看仔细，LZ要攻击后泰坦之箭打击目标，我是英雄施放泰坦之箭增加伤害。不好意思
怪物攻前施放泰坦之箭，伤害固定600，但可以模拟泰坦之箭伤害。

[ 本帖最后由 骷髅召唤师 于 2011-7-17 22:06 编辑 ]

黑暗流浪者

LZ的意思是联动，600+英雄力量x[(泰坦数量x5)+(雷神数量x20)]，假如队伍里有100泰坦，50雷神
，英雄力量S，每次泰坦或雷神攻击，都能造成目标损伤：600+S*[100*5+50*20]

骷髅召唤师

直接泰坦之箭伤害增加不行，但可以模拟泰坦之箭增加伤害

灰狼王子

记得以前有个专门帖子是加强各类H3的宝物，包括诅咒铠甲、泰坦之箭、海洋之帽、神圣血瓶等等，好像论坛的新浪微博上还发布消息了呢 http://bbs.h3wog.com/thread-25981-1-1.html 【重塑SOD时代辉煌，打造WOG全新神器】

cj00cd

感谢召唤师，已经实现了我的一半意图，英雄释放的泰坦神箭加强；再追加泰坦或雷神远程攻击后，英雄自动释放一次泰坦神箭打击被攻击目标就行了

cj00cd

回复 10# 的帖子
那个我早看过了，还没有做完

沧海一粟

引用:再追加泰坦或雷神远程攻击后，英雄自动释放一次泰坦神箭打击被攻击目标就行了

这个还是容易实现的，上午有时间帮你写这个，不过不能够在攻击后只能在攻击前（攻击后英雄施法会引起未知的错误）至于那些组合宝物不是没做完,而是没时间做

[ 本帖最后由 沧海壹粟 于 2011-7-18 08:39 编辑 ]

沧海一粟

类似的东西很多我前些时间已经在四神脚本中实现了（300+技能），包括召唤师大大写的增加神箭伤害的东西，以后有机会放出来。

ZVSE
!?BG0;              动作前触发
!!BG:A?y1 D?y2 N?y3 Q?y4; 动作参数：动作种类、目的位置、动作堆栈、攻击方
!!BHy4:N?y5;              检查当前攻击方英雄ID
!!FU28000&y5>-1:P1/y1/y2/y3/y4/y5;  魔武合一x1=1

!?FU28000&x1=1;     x1=1时执行函数28000（如上面改为循环函数则可以全体施放）
!!FU|x1<>1:E;
!!FU&x2<>6/x2<>7:E; 动作种类不为移动且攻击或射击时则退出
!!FU|x4<0/x4>41:E;   堆栈小于0大于41则退出
!!BMx4:T?x7 N?x8;    动作怪物堆栈类型、数量
!!BHx5:M?x9;            检查英雄是否施放过魔法
!!HEx6:A2/135/?x10/?x11; 检查英雄是否装备泰坦之箭
!!FU&x7<>41/x7<>152:E;   堆栈类型不为泰坦或雷神则退出
!!FU|x11<1/x8<1:E;  没有装备泰坦之箭且本身没有部队则退出
!!BHx5:C57/x3/3/1;  英雄附加施放泰坦之箭（有魔免生物会抵抗）
!!BHx5:Mx9;             重置英雄施法后状态（如改成其它魔法需重置魔法点）

[ 本帖最后由 沧海壹粟 于 2011-7-18 09:51 编辑 ]

骷髅召唤师

沧海大大

cj00cd

感谢两位大大的奉献 ，拿下用之！

黑暗流浪者

这个如果属于魔法攻击，碰到魔免也不爽吧

hellmatrix

知足常乐，不能求全责备

cj00cd

沧海壹粟大大，用你的这个和召唤师大大的那个结合起来用，英雄可以直接放出加强的泰坦之箭，泰坦攻击前英雄也自动放泰坦之箭，但是这个自动放的泰坦之箭杀伤力只有600，我的想法是要自动释放的泰坦之箭也是威力加强的，不然在变态地图这600的杀伤根本没啥用，能否再帮我改一改？

沧海一粟

以下代码实现的是当英雄装备泰坦之箭后，泰坦雷神攻击时英雄可联动施放加强型泰坦之箭，并按生物数量每个增加600点魔法伤害。脚本本身没有用到任何变量，所用函数也限定了触发条件，原则上不会和任何脚本引起冲突。

ZVSE

!?BG0;              动作前触发
!!BG:A?y1 D?y2 N?y3 Q?y4; 动作参数：动作种类、目的位置、动作堆栈、攻击方
!!BHy4:N?y5;              检查当前攻击方英雄ID
!!FU28000&y5>-1:P1/y1/y2/y3/y4/y5;  魔武合一x1=1

!?FU28000&x1=1;      x1=1时执行函数28000（如上改循环函数则可全体施放）
!!FU|x1<>1:E;
!!FU&x2<>6/x2<>7:E;  动作种类不为攻击或射击时则退出
!!FU|x4<0/x4>41:E;   堆栈小于0大于41则退出
!!BMx4:T?x7 N?x8;    动作怪物堆栈类型、数量
!!BHx5:M?x9;             检查动作方英雄是否施放过魔法
!!HEx6:A2/135/?x10/?x11; 检查动作方英雄是否装备泰坦之箭
!!FU&x7<>41/x7<>152:E;   堆栈类型不为泰坦或雷神则退出
!!FU|x11<1/x8<1:E;       没有装备泰坦之箭且本身没有部队则退出
!!BHx5:C57/x3/3/1;       英雄附加施放泰坦之箭（有魔免生物会抵抗）
!!BHx5:Mx9;              重置英雄施法后状态（如改成其它魔法需重置魔法点）

!?MR0;               堆栈魔法伤害前触发
!!BG:A?y1 N?y2 Q?y3; 动作参数：动作种类、动作堆栈、攻击方
!!BHy3:N?y4;         检查当前攻击方英雄ID
!!FU28000&y4>-1:P2/y1/y2/y4;   雷神之箭x1=2

!?FU28000&x1=2;     x1=2时执行函数28000
!!FU|x1<>2:E;
!!FU&x2<>6/x2<>7:E; 动作种类不为攻击或射击时则退出
!!BMx3:T?x5 N?x6;   动作怪物堆栈类型、数量
!!HEx4:A2/135/?x7/?x8;  检查动作方英雄是否装备泰坦之箭
!!FU&x5<>41/x5<>152:E;  堆栈类型不为泰坦或雷神则退出
!!FU|x8<1/x6<2:E;       没有装备泰坦之箭且部队小于2则退出
!!MR:D?x9;              取得魔法伤害值（如果添加其它杀伤魔法一样会起效）
!!VRx10:Sx6*600-600;    按泰坦或雷神数量每个增加600伤害
!!VRx9:+x10;            增加魔法伤害
!!MR:Dx9;                 重置魔法伤害

[ 本帖最后由 沧海壹粟 于 2011-7-19 09:32 编辑 ]