{已解决}有奖问题

ycpop

最近学ERM，看到个单筒望远镜脚本，感觉不错，结果用到地图中出错，提示错误在!#BU:Ey20/?y88编号出错, 我水平有限，解决者有奖
ZVSE
103．单筒望远镜：拥有该物品的英雄，带领的独眼巨人和高级独眼巨人战斗中伤害加20%.
!#VRz702:S^{单筒望远镜}^;
!#VRz703:S^{单筒望远镜}
拥有该物品的英雄，带领的独眼巨人和高级独眼巨人战斗中伤害加20%.并可能让碎石杀伤周围敌人(有点象火球攻击)。并让独眼巨人无视障碍。（碎石杀伤能区分敌我不会误伤。）
^;
!#UN:A53/9/702;
!#UN:A53/10/703;
!#UN:A53/1/10000;
!#UN:A53/3/16;
!?BA0;
!!VRv35:S0;
!!VRv36:S0;
!!BA:H0/?v9555 H1/?v9560;
!!HEv9555&v9555>=0:A2/53/d/?v35;
!!HEv9560&v9560>=0:A2/53/d/?v36;
!?BF;
!!DO7056/0/20/1&v35>0:P;
!?FU7056;
!!BMx16:T?y1 F?y25;
!!FU|y1<94/y1>95:E;
!!BMx16:U1/?y8 U2/?y20;
!!VRy8::5;
!!VRy20::5;
!!BMx16:U1/dy8 U2/dy20;
!!VRy27:|2048;              
!!VRy26&y25>0:Sy25|y27;
!!BMx16&y27<>0:Fy26;

!?BF&v36>0;
!!DO6650/21/41/1&v36>0:P;
!?FU6650;
!!BMx16:T?y1 F?y25;
!!FU|y1<94/y1>95:E;
!!BMx16:U1/?y1 U2/?y2;
!!VRy1::5;
!!VRy2::5;
!!BMx16:U1/dy1 U2/dy2;
!!VRy27:|2048;              
!!VRy26&y25>0:Sy25|y27;
!!BMx16&y27<>0:Fy26;   
!?MF1&v35>0;
!!BG:A?y1 N?y3 E?y4;
!!FU&y1<>7:E;
!!BMy3:T?y80 I?y6;
!!MF&y1=7:F?y86;
!!VRy86:Sy86:2;
!!BMy4:P?y5;
!!DO7511/0/6/1&y80>93/y80<96/y6=0/v35>0:Py5/y86;
!?FU7511;
!!VRy-80:Sx1 :17 +1;                  
!!VRy-81:S0;                          
!!VRy-82:S0;
!!VRy-81|y-80=1/y-80=3/y-80=5/y-80=7/y-80=9/y-80=11:S1;
!!VRy-82|y-80=2/y-80=4/y-80=6/y-80=8/y-80=10:S1;
!!VRy20&x16=1:Sx1 +1;                  
!!VRy20&x16=2:Sx1 +16 +y-81;
!!VRy20&x16=3:Sx1 +17 +y-81;
!!VRy20&x16=4:Sx1 -1;
!!VRy20&x16=5:Sx1 -16 -y-82;
!!VRy20&x16=6:Sx1 -17 -y-82;
!!BU:Ey20/?y88;
!!BMy88&y88>-1:I?y60;
!!BMy88&y88>-1/y60<>0/v35>0:Kx2;
!?MF1&v36>0;
!!BG:A?y1 N?y3 E?y4;
!!FU&y1<>7:E;
!!BMy3:T?y80 I?y6;
!!MF&y1=7:F?y86;
!!VRy86:Sy86:2;
!!BMy4:P?y5;
!!DO7510/0/6/1&y80>93/y80<96/y6=1/v36>0:Py5/y86;
!?FU7510;
!!VRy-80:Sx1 :17 +1;                  
!!VRy-81:S0;                          
!!VRy-82:S0;
!!VRy-81|y-80=1/y-80=3/y-80=5/y-80=7/y-80=9/y-80=11:S1;
!!VRy-82|y-80=2/y-80=4/y-80=6/y-80=8/y-80=10:S1;
!!VRy20&x16=1:Sx1 +1;                  
!!VRy20&x16=2:Sx1 +16 +y-81;
!!VRy20&x16=3:Sx1 +17 +y-81;
!!VRy20&x16=4:Sx1 -1;
!!VRy20&x16=5:Sx1 -16 -y-82;
!!VRy20&x16=6:Sx1 -17 -y-82;
!!BU:Ey20/?y88;
!!BMy88&y88>-1:I?y60;
!!BMy88&y88>-1/y60<>1/v36>0:Kx2;

[ 本帖最后由 ycpop 于 2011-7-4 20:05 编辑 ]

兽哥哥

只有在精神上支持你了。

格鲁

好复杂，支持，如果改成功了，偷个脚本

泽拉图

哪里是!#BU:Ey20/?y88;
应该是!!BU:Ey20/?y88;
------------------------------------
我也看不出有什么错，只好等高人了

寻梦人

原帖由 ycpop 于 2011-7-3 20:34 发表
最近学ERM，看到个单筒望远镜脚本，感觉不错，结果用到地图中出错，提示错误在!#BU:Ey20/?y88编号出错, 我水平有限，解决者有奖
ZVSE
103．单筒望远镜：拥有该物品的英雄，带领的独眼巨人和高级独眼巨人战斗中伤害 ...

那是因为y20的值没有在0----186之间的原因，只要定义y20的值在0---186之间就可以解决这个问题！

寻梦人

!!BU&y20>0/y20<186:Ey20/?y88;

viper_ou

看的头昏眼花  没耐心的直接剽窃而过

骷髅召唤师

或者同寻梦大大的改，或者这样也可以加上红色的两句
ZVSE
!#VRz702:S^{单筒望远镜}^;
!#VRz703:S^{单筒望远镜}
拥有该物品的英雄，带领的独眼巨人和高级独眼巨人战斗中伤害加20%.并可能让碎石杀伤周围敌人(有点象火球攻击)。并让独眼巨人无视障碍。（碎石杀伤能区分敌我不会误伤。）
^;
!#UN:A53/9/702;
!#UN:A53/10/703;
!#UN:A53/1/10000;
!#UN:A53/3/16;
!?BA0;
!!VRv35:S0;
!!VRv36:S0;
!!BA:H0/?v9555 H1/?v9560;
!!HEv9555&v9555>=0:A2/53/d/?v35;
!!HEv9560&v9560>=0:A2/53/d/?v36;
!?BF;
!!DO7056/0/20/1&v35>0:P;
!?FU7056;
!!BMx16:T?y1 F?y25;
!!FU|y1<94/y1>95:E;
!!BMx16:U1/?y8 U2/?y20;
!!VRy8::5;
!!VRy20::5;
!!BMx16:U1/dy8 U2/dy20;
!!VRy27:|2048;              
!!VRy26&y25>0:Sy25|y27;
!!BMx16&y27<>0:Fy26;

!?BF&v36>0;
!!DO6650/21/41/1&v36>0:P;
!?FU6650;
!!BMx16:T?y1 F?y25;
!!FU|y1<94/y1>95:E;
!!BMx16:U1/?y1 U2/?y2;
!!VRy1::5;
!!VRy2::5;
!!BMx16:U1/dy1 U2/dy2;
!!VRy27:|2048;              
!!VRy26&y25>0:Sy25|y27;
!!BMx16&y27<>0:Fy26;   
!?MF1&v35>0;
!!BG:A?y1 N?y3 E?y4;
!!FU&y1<>7:E;
!!BMy3:T?y80 I?y6;
!!MF&y1=7:F?y86;
!!VRy86:Sy86:2;
!!BMy4:P?y5;
!!DO7511/0/6/1&y80>93/y80<96/y6=0/v35>0:Py5/y86;
!?FU7511;
!!VRy-80:Sx1 :17 +1;                  
!!VRy-81:S0;                          
!!VRy-82:S0;
!!VRy-81|y-80=1/y-80=3/y-80=5/y-80=7/y-80=9/y-80=11:S1;
!!VRy-82|y-80=2/y-80=4/y-80=6/y-80=8/y-80=10:S1;
!!VRy20&x16=1:Sx1 +1;                  
!!VRy20&x16=2:Sx1 +16 +y-81;
!!VRy20&x16=3:Sx1 +17 +y-81;
!!VRy20&x16=4:Sx1 -1;
!!VRy20&x16=5:Sx1 -16 -y-82;
!!VRy20&x16=6:Sx1 -17 -y-82;
!!FU|y20<0/y20>185:E;
!!BU:Ey20/?y88;
!!BMy88&y88>-1:I?y60;
!!BMy88&y88>-1/y60<>0/v35>0:Kx2;
!?MF1&v36>0;
!!BG:A?y1 N?y3 E?y4;
!!FU&y1<>7:E;
!!BMy3:T?y80 I?y6;
!!MF&y1=7:F?y86;
!!VRy86:Sy86:2;
!!BMy4:P?y5;
!!DO7510/0/6/1&y80>93/y80<96/y6=1/v36>0:Py5/y86;
!?FU7510;
!!VRy-80:Sx1 :17 +1;                  
!!VRy-81:S0;                          
!!VRy-82:S0;
!!VRy-81|y-80=1/y-80=3/y-80=5/y-80=7/y-80=9/y-80=11:S1;
!!VRy-82|y-80=2/y-80=4/y-80=6/y-80=8/y-80=10:S1;
!!VRy20&x16=1:Sx1 +1;                  
!!VRy20&x16=2:Sx1 +16 +y-81;
!!VRy20&x16=3:Sx1 +17 +y-81;
!!VRy20&x16=4:Sx1 -1;
!!VRy20&x16=5:Sx1 -16 -y-82;
!!VRy20&x16=6:Sx1 -17 -y-82;
!!FU|y20<0/y20>185:E;
!!BU:Ey20/?y88;
!!BMy88&y88>-1:I?y60;
!!BMy88&y88>-1/y60<>1/v36>0:Kx2;

[ 本帖最后由 骷髅召唤师 于 2011-7-4 08:40 编辑 ]

兽哥哥

都是高手啊！！！

龙巫妖

看不懂的来支持一下

泽拉图

终于有答案了

ycpop

原帖由 xxb19780916 于 2011-7-3 21:28 发表



那是因为y20的值没有在0----186之间的原因，只要定义y20的值在0---186之间就可以解决这个问题！

我说呢，怎么总是在战场边上的怪发生这个错误，原来是超出战场范围了，高人就是高人啊，一看就明白了

hellmatrix

支持你，纯精神的

兽哥哥

原帖由 hellmatrix 于 2011-7-4 20:19 发表
支持你，纯精神的

小靓女一来，论坛都活跃不少啊！