[互动]ERM有奖问答（懂ERM的或想学ERM的都进来）

克招

关于!!if;、!!el;、!!en;语法，请参见最新版ERM帮助中IF-ELSE-ENDIF部分

克招

第三期的脚本各位的实现方法和我想象中的不太相符，有时间我把我的方法也写成脚本贴出来。

沧海一粟

原帖由 da3338280 于 2011-3-3 23:16 发表
第三期的脚本各位的实现方法和我想象中的不太相符，有时间我把我的方法也写成脚本贴出来。

ERM实现的方法有很多，第三期的作品我刚开始只是看到没人写刚好有时间按LZ的要求（也就是说你要求什么我就写什么）随手写的，肯定有很多地方可以改进，比如说动作后删掉火免之类和AI有50%机率选择魔法攻击之类的。

[ 本帖最后由 沧海壹粟 于 2011-3-4 11:45 编辑 ]

格鲁

什么呀？来学习？？

songfx

我也想出一道题，也是求助

要求，游戏开始前，弹出难度选项，分为四级

新手，所有敌人包括野兵的HP变为原HP的80%
入门，所有敌人包括野兵的HP变为原HP的95%
普通，所有敌人包括野兵的HP变为原HP的100%
困难，所有敌人包括野兵的HP变为原HP的110%

HP的调整需考虑到翡翠塔的改造，生物经验系统等因素的影响。

谢谢

fastarrow

原帖由 songfx 于 2011-3-6 20:29 发表
我也想出一道题，也是求助

要求，游戏开始前，弹出难度选项，分为四级

新手，所有敌人包括野兵的HP变为原HP的80%
入门，所有敌人包括野兵的HP变为原HP的95%
普通，所有敌人包括野兵的HP变为原HP的100%
困难 ...

也不一定非要做个对话框吧，使用UN：J2来获取选择的地图难度，根据难度写公式就好了。BF或者BR触发都行，BR的话，冲突可能性小些，限制v997<>0时中止即可，对BM操作，是包括了所有因素的，包含翡翠塔，生物经验，血瓶等宝物。

沧海一粟

原帖由 songfx 于 2011-3-6 20:29 发表
我也想出一道题，也是求助

要求，游戏开始前，弹出难度选项，分为四级

新手，所有敌人包括野兵的HP变为原HP的80%
入门，所有敌人包括野兵的HP变为原HP的95%
普通，所有敌人包括野兵的HP变为原HP的100%
困难 ...

风大你这脚本难度很不高啊，离弦箭其实已经写出来了，就在你的楼下。

骷髅召唤师

等高人出手。

songfx

知道我没入门……
思路我知道，脚本写不出……

骷髅召唤师

好像是这样 吧。
根据沧海大大的意见和指导下修正，请高手指教.
ZVSE

!?BA0;             战斗前触发
!!UN:J2/?v9701;  获取地图选择的难度0,1,2,3,4
!!BA:O?v39/?v49;   进攻方英雄颜色存入v39，防守方英雄颜色存入v49
!!OW:Iv39/?v55;   进攻方是否人类
!!OW:Iv49/?v60;   防守方是否人类

!?BF;              战场生成时触发
!!DO12580/21/41/1&v55=0:P;
!!DO12580/0/20/1&v55=1:P;

!?FU12580;
!!BMx16:N?y1 H?y2;
!!FU&y1<1:E;
!!FU&v9701=2:E;
!!VRy3&v9701=0:Sy2*80:100;
!!VRy3&v9701=1:Sy2*95:100;
!!VRy3&v9701=3:Sy2*110:100;
!!VRy3&v9701=4:Sy2*120:100;
!!BMx16:Hy3;

[ 本帖最后由 骷髅召唤师 于 2011-3-10 19:06 编辑 ]

骷髅召唤师

这个有对话框的，上面是根据地图难度的。
根据沧海大大的意见和指导下修正，请高手指教。
ZVSE

!?PI;
!!VRz1:S^新手，所有敌人包括野兵的HP变为原HP的80%。^;
!!VRz2:S^入门，所有敌人包括野兵的HP变为原HP的95%。^;
!!VRz3:S^普通，所有敌人包括野兵的HP变为原HP的100%。^;
!!VRz4:S^困难，所有敌人包括野兵的HP变为原HP的110%。^;
!!VRz5:S^请选择你的游戏难度^;
!!IF:G1/9701/16/5/1/2/3/4;

!?BA0;             战斗前触发
!!BA:O?v39/?v49;   进攻方英雄颜色存入v39，防守方英雄颜色存入v49
!!OW:Iv39/?v55;   进攻方是否人类
!!OW:Iv49/?v60;   防守方是否人类

!?BF;              战场生成时触发
!!DO12580/21/41/1&v55=0:P;
!!DO12580/0/20/1&v55=1:P;

!?FU12580;
!!BMx16:N?y1 H?y2;
!!FU&y1<1:E;
!!FU&v9701=4:E;
!!VRy3&v9701=1:Sy2*80:100;
!!VRy3&v9701=2:Sy2*95:100;
!!VRy3&v9701=8:Sy2*110:100;
!!BMx16:Hy3;

[ 本帖最后由 骷髅召唤师 于 2011-3-10 18:50 编辑 ]

沧海一粟

原帖由 骷髅召唤师 于 2011-3-10 08:54 发表
这个有对话框的，上面是根据地图难度的。
ZVSE

!?PI;
!!VRz1:S^新手，所有敌人包括野兵的HP变为原HP的80%。^;
!!VRz2:S^入门，所有敌人包括野兵的HP变为原HP的95%。^;
!!VRz3:S^普通，所有敌人包括野兵的HP变 ...

哈哈，召唤师真厉害   ，把风大的问题都给解决了，可惜我不能加分，要不肯定也给你加，快叫风大给你加分啊。甚至你也可以尝试用BR写一下啊，只改变几个字符、加一句话就可以解决了。

话说第四期的作业都出来好几天了，却实有点难啊，有点思路但没有认真研究ERM帮助真的不会写，期待高人出手啊。

[ 本帖最后由 沧海壹粟 于 2011-3-10 17:44 编辑 ]

克招

好吧，我承认第四期太复杂了。
第五期简单点吧：
56号英雄需要保护一个农民，（这个农民会在每场战斗中出现），当这个农民在战斗中死去时，战斗立即失败，且地图立即失败。

fastarrow

ZVSE
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
ERMS_ScriptDate=9.3(March).2011
******************************************
!?BA0;
!!BA:H0/?v37;      进攻方英雄ID存入v37
!!BA:H1/?v47;      防守方英雄ID存入v47
******************************************

****************战场召唤******************
******************************************
!?BF|v37=56/v47=56;
!!HE56:Ed/?y-25;

!!VRy-23&v37=56:S0;  设置  所属方y-23
!!VRy-23&v47=56:S1;
!!VRy-24&v37=56:S71; 设置召唤位置y-24
!!VRy-24&v47=56:S80;

!!BU:S139/1/y-24/y-23/-1/-1; 召唤1农民
!!BU:Ey-24/?v505;            获取堆栈
!!BMv505&v505>-1:Ad1 Dd1 Sd1 U1/d1 U2/d1 Hdy-25;    增强攻防速命伤

!!VRy-27&v505>-1:Sv505 +1 *-1; 获得经验特技堆栈
!!EAy-27&v505>-1:B0/1/65/43/0/0/1/1/2/2/3/3/4/4/5;  攻+
!!EAy-27&v505>-1:B1/1/68/43/0/0/1/1/2/2/3/3/4/4/5;  防+
!!EAy-27&v505>-1:B2/1/72/37/0/0/0/10/20/25/30/35/40/45/50;  命+
!!EAy-27&v505>-1:B3/1/109/43/0/0/1/1/2/2/3/3/4/4/5; 最小伤害+
!!EAy-27&v505>-1:B4/1/77/43/0/0/1/1/2/2/3/3/4/4/5;  最大伤害+
!!EAy-27&v505>-1:B5/1/83/43/0/0/0/0/0/1/1/1/2/2/2;  速度+
!!EAy-27&v505>-1:B6/1/70/61/1/1/1/1/1/1/1/1/1/1/1;  恐惧
!!EAy-27&v505>-1:B7/1/66/61/0/0/0/0/0/0/0/5/5/5/10; 格挡
!!EAy-27&v505>-1:L122500;      设置最大经验点
!!EAy-27&v505>-1:E122500/2/d/d;置为双剑
!!EAy-27&v505>-1:R156/7;       装备战旗/偏移
**********************************************
****************战场召唤完成******************


***设置战场失败条件***
!?BG0|v37=56/v47=56;
!!BMv505:N?y30;
!!BG:N?y31;
!!IF&y30>0:V242/1;  农民生存时flag242置为真
!!IF&y30<1:V242/0;  农民死亡时flag242置为假
!!BG&v37=56/y30<1/y31<21:A4;      农民死亡时动作为逃走
!!BG&v47=56/y30<1/y31>20:A4;      农民死亡时动作为逃走
***战场失败条件完成***


***地图失败条件A和B任选其一即可***
*********************************

*********设置地图失败条件A*********
!?BA1|v37=56/v47=56;
!!UN&-242:Q0/1;
!!IF:M^你失去了未来的国王，无法继续游戏了。^;
*********地图失败条件A完成*********


*********设置地图失败条件A*********
!?BA1|v37=56/v47=56;
!!HE56:O?y30;
!!UN&y30<0:Q0/1;
!!IF:M^你失去了未来的国王，无法继续游戏了。^;
*********地图失败条件B完成*********

[ 本帖最后由 fastarrow 于 2011-3-13 00:28 编辑 ]

songfx

想起来了，你的三国里有没有刘备携民渡江的剧情啊？

fastarrow

这个，真没有。

江上没有船，整个地图没有召船术。

songfx

以后我的大作《赤壁》给加上类似脚本

fastarrow

三国元素太多了。要真是一一加入，估计要做个12关的战役模式。

骷髅召唤师

收藏学习。

songfx

不要断档哦