【任意地点复活指挥官】脚本

fastarrow

有没有遇见过这种情形：走了一半的路，指挥官阵亡了，继续征战还是回去复活指挥官？
有点尴尬。
现在这个问题可以解决了，下面的脚本允许你在任意地点复活指挥官，当然，你得花钱。

说明：
1.这段代码是结合官方76#脚本写的，即指挥官避难所。只有开了这个选项，该脚本才会执行。
你可以把这段代码拷贝到76#脚本的后面，本脚本使用的变量不会与官方脚本冲突，如果作为
事件版加入到地图中，请按脚本的起始段说明检查那些变量。临时变量不需要检查。
2.用该脚本复活指挥官比在城堡中复活要贵，费用为等级*1000,不在自己底盘，说话就是不硬气啊。
3.同时也增强了AI，AI的指挥官如果阵亡了，他们会在作战前复活他，且完全免费。
4.点击指挥官对话框时，如果指挥官阵亡，就会先弹出是否要复活指挥官的提示。





ZVSE
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except [wiki]ERM[/wiki]_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
ERMS_ScriptDate=3.12(December).2010
**v变量使用：v46，用来接收玩家是否选择复活指挥官
**Z变量使用：z-1，z356，z357，z358，z359，z384
**对话框编号使用：21
**y变量使用：y1-y4,y7-y9,y20-y22,y30,y-20-y-22,y-30


!?CO0;           [打开指挥官对话框Commander Dialog之前触发]
!!UN:P3/?y1;     [检查在WOG选项中是否启用了指挥官，y-1=0为启用]
!!CO-1:D?y2;     [检查当前英雄指挥官的状态，y2=0，生存，y2=1，死亡]
!!UN:P76/?y3;    [检查脚本P76是否激活，y3=1激活]
!!FU|y1<>0/y2<>1/y3<>1:E; [指挥官未启用终止，指挥官生存时终止，脚本未激活时终止]
!!CO-1:T?y4 N?z-1;  [获取当前英雄指挥官类型保存到y4,指挥官姓名到z-1]
!!CO-1:X2/?y7;      [获取当前英雄指挥官等级保存到y7]
!!VRy8:Sy7 *1000;   [复活指挥官所需要的黄金为等级*1000]
!!VRz355:S^复活指挥官：
你的指挥官<%Z-1>不幸阵亡了，一个巫师声称可以帮
你复活他，但需要你支付一些黄金作为报酬，接受吗？^;[z355赋值]
!!VRz356:S^接受^;                                 [z356赋值]
!!VRz357:S^拒绝^;                                 [z357赋值]
!!VRz358:S^..\Data\zvs\Lib1.res\NPC%Y4.gif^;      [z358赋值，根据指挥官类型调用图片]
!!VRz359:S^当前%Z-1级别为%Y7，复活需要%Y8黄金^;   [z359赋值]
!!VRz384:S^提示：比在城堡中复活要贵！^;           [z384赋值]
!!IF:D21/355//384/358////////356/357;             [设置对话框21内容]
!!IF:F21/359/0/0/0/0;                             [对话框21的鼠标文本提示]
!!IF:E46/21;                                      [调用对话框21，用v46来接收玩家选项]
!!FU&v46<>1:E;              [上面对话框玩家选择否时函数终止]
!!OW&v46=1:R-1/6/?y9;       [当前玩家黄金存入y7]
!!IF:Q2/36/y8/2^需要支付{%Y8}黄金，继续吗？^;[对话2,用flag2接收玩家选择，勾为真，圈为假]
!!IF&2/y8>y9:Q1/36/y8/1^{你付不起复活的费用！！！}^;[对话3。只需要点确定]
!!FU&2/y8>y9:E;                   [标志2为真，黄金不足时终止]
!!FU&-2:E;                        [标志2为假时终止]
!!VRy10:Sy8 *-1;                  [需要的黄金数取相反数]
!!OW&2/y8<y9:R-1/6/dy10;          [标志2为真，当前玩家有足够黄金从当前玩家黄金中减去复活费用]
!!CO-1&2:D0;                      [复活当前英雄指挥官]
!!IF:M^恭喜，{%Z-1}已经复活了！^; [显示提示已经复活的文本]


**设置AI：AI永远会在战斗前保证它的指挥官是活的，且免费**
** 战斗前触发 **
!?BA0;                       [战斗前触发－进攻方]
!!BA:H0/?y30;                [获取进攻方英雄ID存入y30]
!!HEy30:O?y20;               [获取进攻方英雄颜色存入y20]
!!OW:Iy20/?y21;              [获取进攻方颜色控制者存入y21]
!!FU&y21<>1:E;               [进攻方不是AI时终止，1为AI，0为人类]
!!COy30:D?y22;               [进攻方指挥官状态存入y22]
!!FU&y22=0:E;                [指挥官是存活状态时则终止]
!!COy30&y22<>0/y21=1:D0;     [否则复活指挥官
!?BA0;                        [战斗前触发－防守方]
!!BA:H1/?y-30;                [获取防守方英雄ID存入y-30]
!!FU&y-30<0:E;                [防守方无英雄时中止]
!!HEy-30:O?y-20;              [获取防守方英雄颜色存入y-20]
!!OW:Iy-20/?y-21;             [获取防守方颜色控制者，存入y-21]
!!FU&y-21<>1:E;               [防守方不是AI时终止]
!!COy-30:D?y-22;              [防守方指挥官状态存入y-22]
!!FU&y-22=0:E;                [指挥官是存活状态时终止]
!!COy-30&y-22<>0/y-21=1:D0;   [否则复活指挥官]
**AI设置结束**

[ 本帖最后由 fastarrow 于 2010-12-3 22:02 编辑 ]

fastarrow

附件是增加了一楼代码的官方76#脚本。


经过简单测试，可以正常使用。

如遇见问题，请跟帖反馈。谢谢。

[ 本帖最后由 fastarrow 于 2010-12-3 21:04 编辑 ]

songfx

非常感谢你的脚本，对RPG地图很有用。

songfx

等我把它整合到内置脚本集合的帖子里去。

fastarrow

谢谢肯定

骷髅召唤师

下了，很好用，不用老回城了。

AX0221

原帖由 songfx 于 2010-12-3 23:10 发表
等我把它整合到内置脚本集合的帖子里去。

风大，你整合了内置脚本帖吗？在哪呢？我也想搞一份好用的脚本包！

AX0221

原帖由 fastarrow 于 2010-12-3 23:12 发表
谢谢肯定

应该的，你是我们论坛的才子！！

q6681909

好像不错

兽哥哥

说真的，我很敬佩你们这些写ERM高手。是你们让我们的WOG更加丰富多彩。

兽哥哥

收藏了，哈哈。对我应该是很有用

黑暗流浪者

我表示我要收藏好

linghuijingshen

下载了，怎么用？

linghuijingshen

原帖由 兽哥哥 于 2011-7-25 11:48 发表
收藏了，哈哈。对我应该是很有用

怎么用啊？兽兽哥哥！

兽哥哥

开启指挥官避难所才有用，我这里有个修改过的脚本，通用的，你要的话我看怎么发给你

兽哥哥

ZVSE
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
ERMS_ScriptDate=3.12(December).2010
**v变量使用：v46，用来接收玩家是否选择复活指挥官
**Z变量使用：z-1，z356，z357，z358，z359，z384
**对话框编号使用：21
**y变量使用：y1-y4,y7-y9,y20-y22,y30,y-20-y-22,y-30


!?CO0;           [打开指挥官对话框Commander Dialog之前触发]
!!UN:P3/?y1;     [检查在WOG选项中是否启用了指挥官，y-1=0为启用]
!!CO-1:D?y2;     [检查当前英雄指挥官的状态，y2=0，生存，y2=1，死亡]
!!FU|y1<>0/y2<>1:E; [指挥官未启用终止，指挥官生存时终止，脚本未激活时终止]
!!CO-1:T?y4 N?z-1;  [获取当前英雄指挥官类型保存到y4,指挥官姓名到z-1]
!!CO-1:X2/?y7;      [获取当前英雄指挥官等级保存到y7]
!!VRy8:Sy7 *1000;   [复活指挥官所需要的黄金为等级*1000]
!!VRz355:S^复活指挥官：
你的指挥官<%Z-1>不幸阵亡了，一个巫师声称可以帮
你复活他，但需要你支付一些黄金作为报酬，接受吗？^;[z355赋值]
!!VRz356:S^接受^;                                 [z356赋值]
!!VRz357:S^拒绝^;                                 [z357赋值]
!!VRz358:S^..\Data\zvs\Lib1.res\NPC%Y4.gif^;      [z358赋值，根据指挥官类型调用图片]
!!VRz359:S^当前%Z-1级别为%Y7，复活需要%Y8黄金^;   [z359赋值]
!!VRz384:S^提示：比在城堡中复活要贵！^;           [z384赋值]
!!IF:D21/355//384/358////////356/357;             [设置对话框21内容]
!!IF:F21/359/0/0/0/0;                             [对话框21的鼠标文本提示]
!!IF:E46/21;                                      [调用对话框21，用v46来接收玩家选项]
!!FU&v46<>1:E;              [上面对话框玩家选择否时函数终止]
!!OW&v46=1:R-1/6/?y9;       [当前玩家黄金存入y7]
!!IF:Q2/36/y8/2^需要支付{%Y8}黄金，继续吗？^;[对话2,用flag2接收玩家选择，勾为真，圈为假]
!!IF&2/y8>y9:Q1/36/y8/1^{你付不起复活的费用！！！}^;[对话3。只需要点确定]
!!FU&2/y8>y9:E;                   [标志2为真，黄金不足时终止]
!!FU&-2:E;                        [标志2为假时终止]
!!VRy10:Sy8 *-1;                  [需要的黄金数取相反数]
!!OW&2/y8<y9:R-1/6/dy10;          [标志2为真，当前玩家有足够黄金从当前玩家黄金中减去复活费用]
!!CO-1&2:D0;                      [复活当前英雄指挥官]
!!IF:M^恭喜，{%Z-1}已经复活了！^; [显示提示已经复活的文本]


**设置AI：AI永远会在战斗前保证它的指挥官是活的，且免费**
** 战斗前触发 **
!?BA0;                       [战斗前触发－进攻方]
!!BA:H0/?y30;                [获取进攻方英雄ID存入y30]
!!HEy30:O?y20;               [获取进攻方英雄颜色存入y20]
!!OW:Iy20/?y21;              [获取进攻方颜色控制者存入y21]
!!FU&y21<>1:E;               [进攻方不是AI时终止，1为AI，0为人类]
!!COy30:D?y22;               [进攻方指挥官状态存入y22]
!!FU&y22=0:E;                [指挥官是存活状态时则终止]
!!COy30&y22<>0/y21=1:D0;     [否则复活指挥官
!?BA0;                        [战斗前触发－防守方]
!!BA:H1/?y-30;                [获取防守方英雄ID存入y-30]
!!FU&y-30<0:E;                [防守方无英雄时中止]
!!HEy-30:O?y-20;              [获取防守方英雄颜色存入y-20]
!!OW:Iy-20/?y-21;             [获取防守方颜色控制者，存入y-21]
!!FU&y-21<>1:E;               [防守方不是AI时终止]
!!COy-30:D?y-22;              [防守方指挥官状态存入y-22]
!!FU&y-22=0:E;                [指挥官是存活状态时终止]
!!COy-30&y-22<>0/y-21=1:D0;   [否则复活指挥官]
**AI设置结束**
《骷髅召唤师修改》

纳样飘逸

我怎么没效果- -要点哪里啊- -

男的回首

感谢分享下图方便，

owen180

非常感谢你的脚本，对RPG地图很有用。

chaoticorder

好帖子，收藏了啊