怪物随处升级的脚本是哪个？

qkiller

怪物随处升级的脚本是哪个？

或者谁直接贴一份給我吧，谢谢！

songfx

查一下《WOG特性说明文档》吧

qkiller

自己单独提取出 25号脚本 的代码了，加到地图里已经可以正常[wiki]工作[/wiki]，帖出来給有需要的人复制吧。

－－－－－－－－－分割线－－－－－－－－－－

ZVSE
!#VRv3300:S-1; [Initialize v3300 to -1]

------------------------------------------------------------------------------------------------------------------

!?CM1;
!!UN:P174/?v1; [Check if Universal Upgrading is enabled: v1=1 if Yes]
!!FU3300&v1=1:P;

[Set/Reset town types for creature upgrading]
!?FU3300;
!!CA-1:T?y1; [Town type: y1]
!!CM:I?y2; [Position clicked: y2]

[Check creature types]
!!CA-1:P?y3/?y4/?y5; [Town's position: y3/y4/y5]

!!POy3/y4/y5:O?y6; [PO:O: y6]

!!FU3302&y6>0/y6<8:Py1; [Restore creatures unless nothing is stored yet]

[Set creature to be upgraded (if upgraded creature dwelling is built)]
!!FU3301&y2>=115/y2<=121:Py1/y2; [Garrison slots]
!!FU3301&y2>=140/y2<=146:Py1/y2; [Visiting hero slots]

------------------------------------------------------------------------------------------------------------------

[Determine which creature is clicked]
[x1=town type, x2=position clicked]
!?FU3301;
!!VRy1:S-1;  !!VRy2:S-1;

!!VRy1&x2>=115/x2<=121:Sx2 -115; [Garrison creature slot number: y1]
!!VRy2&x2>=140/x2<=146:Sx2 -140; [Visiting hero creature slot number: y2]

[Determine creature type: y5]
!!CA-1:H0/?y3 H1/?y4; [Garrison hero: y3, Visiting hero: y4]
!!HEy3&y3>=0/y1>=0:C0/y1/?y5/d; [Garrison hero creature: y5]
!!CA-1&y3<0/y1>=0:M2/y1/?y5/d; [Garrison creature: y5]
!!HEy4&y4>=0/y2>=0:C0/y2/?y5/d; [Visiting hero creature: y5]

!!FU&y5<0:E; [Exit if not a creature]

!!MA:Uy5/?y7; [Check for a custom upgrade: y7]

[Default upgrade for all towns except Conflux]
!!VRy6&y7=-1/y5<=111:Sy5 %2; [Remainder of creature number divided by 2: y6]
!!VRy7&y7=-1/y5<=111/y6=0:Sy5 +1; [If non-upgraded, upgrade is y7]

[Default upgrade for Conflux]
!!VRy7&y7=-1/y5=112:S127; [Air Elemental]
!!VRy7&y7=-1/y5=113:S125; [Earth Elemental]
!!VRy7&y7=-1/y5=114:S129; [Fire Elemental]
!!VRy7&y7=-1/y5=115:S123; [Water Elemental]
!!VRy7&y7=-1/y5=118:S119; [Pixie]
!!VRy7&y7=-1/y5=120:S121; [Psychic Elemental]
!!VRy7&y7=-1/y5=130:S131; [Firebird]

!!VRy6:S1; [Initialize y6 to 1]
!!VRy6&y7>=0:S0; [Set y6 to 0 if y7>=0]

!!FU|y6=1/y7=-2:E; [Exit if no upgrade]

!!MA:Ly5/?v3302; [Store creature's level in v3302]

!!VRy8:S37 +v3302; [Upgraded dwelling of this creature's level: y8]
!!CA-1:B3/y8; [Check if town has this upgraded dwelling built: Flag 1 True if yes]
!!CA-1&-1:B3/19; [Check if horde building 1 is built: Flag 1 is true if yes]
!!CA-1&-1:B3/25; [Check if horde building 2 is built: Flag 1 is true if yes]

!!FU&-1:E; [Exit if upgraded dwelling isn't built]

!!VRv3300:Sy5; [Store creature number: v3300]
!!MA:Oy5/?v3301;  [Store creature's town type in v3301]
!!MA:Oy5/x1; [Change creature to this town type]

!!VRv3310:Sy7; [Store upgraded creature number: v3310]
!!MA:Oy7/?v3311;  [Store upgraded creature's town type in v3311]
!!MA:Ly7/?v3312; [Store upgraded creature's level in v3312]
!!MA:Oy7/x1; [Change upgraded creature to this town type]

[Check & Store creature type and level]
!!CA-1:P?y13/?y14/?y15; [Town's position: y13/y14/y15]
!!POy13/y14/y15:B0/?y16 B1/?y17 O?y18; [PO:B0: y16  PO:B1: y17  PO:O: y18]
!!VRy9:Sy18 -1; [Subtract 1 from y18 to get real creature level: y9]
!!UN&v3302<>y9:Tx1/v3302/0/?y18; [If this level not stored, get non-upgraded type: y18]
!!UN&v3302<>y9:Tx1/v3302/1/?y19; [If this level not stored, get upgraded type: y19]
!!VRy10&v3302<>y9:Sy18 +1; [Non-upgraded type +1: y10]
!!VRy11&v3302<>y9:Sy19 +1; [Upgraded type +1: y11]
!!VRy12&v3302<>y9:Sv3302 +1; [Creature level +1: y12]
!!POy13/y14/y15&v3302<>y9:B0/y10; [If this level not stored, store non-upgraded type (+1)]
!!POy13/y14/y15&v3302<>y9:B1/y11; [If this level not stored, store upgraded type (+1)]
!!POy13/y14/y15&v3302<>y9:Oy12; [If this level not stored, store creature level (+1)]

[Set this town's creature of this level]
!!UN:Tx1/v3302/0/y5; [Set non-upgraded creature]
!!UN:Tx1/v3302/1/y7; [Set upgraded creature]

------------------------------------------------------------------------------------------------------------------

[Reset changed town creature types]
!?FU3302;
!!CA-1:P?y1/?y2/?y3; [Town's position: y1/y2/y3]

[Creature type: y4 (non-upgraded) and y5 (upgraded), y6 (level)]
!!POy1/y2/y3:B0/?y4 B1/?y5 O?y6; [PO:B0: y4  PO:B1: y5  PO:O: y6]
!!VRy4&y4>0:-1; [Subtract 1 from y4 to get non-upgraded creature number]
!!VRy5&y5>0:-1; [Subtract 1 from y5 to get upgraded creature number]
!!VRy6&y6>0:-1; [Subtract 1 from y6 to get creature level]

!!UN&y4>=0:Tx1/y6/0/y4; [Reset non-upgraded]
!!UN&y5>=0:Tx1/y6/1/y5; [Reset upgraded]

!!FU&v3300<0:E; [Exit function if no creature changed]

[Restore creature: v3300]
!!MA:Ov3300/v3301;  [Restore creature's town type]

[Restore upgraded creature: v3310]
!!MA:Ov3310/v3311;  [Restore upgraded creature's town type]

[Reset v3300 to -1]
!!VRv3300:S-1;

------------------------------------------------------------------------------------------------------------------

[Post-visit Town Trigger for the AI]
!$OB98&-1000;

!!UN:P174/?v1; [Check if Universal Upgrading is enabled: v1=1 if Yes]
!!FU&v1<>1:E; [Exit if not enabled]

!!HE-1:N?v1; [Hero number: v1]
!!CA998:T?v2; [Town type: v2]

[Check each creature in AI hero's army]
!!DO3303/0/6/1:Pv1/v2;

------------------------------------------------------------------------------------------------------------------

[Check each creature in AI hero's army]
[x1=hero number, x2=town type]
!?FU3303;

!!HEx1:C0/x16/?y1/?y7; [Type of creature: y1, Number: y7]

!!FU|y1<0/y7=0:E; [Exit if creature slot is empty]

!!MA:Oy1/?y2; [Town creature belongs to: y2]
!!MA:Uy1/?y3; [Creature's upgrade number: y3]
!!MA:Ly1/?y4; [Creature's level: y4]
!!VRy6:Sy4 +37; [Upgraded dwelling number in town: y6]
!!CA998:B3/y6; [Check if upgraded dwelling is built: Flag 1 is true if yes]
!!CA998&-1:B3/19; [Check if horde building 1 is built: Flag 1 is true if yes]
!!CA998&-1:B3/25; [Check if horde building 2 is built: Flag 1 is true if yes]

[Exit if native town, creature has no upgrade or upgraded dwelling isn't built]
!!FU|y2=x2/y3=-2/-1:E;

[Default upgrade for all towns except Conflux: y3]
!!VRy5&y3=-1/y1<=111:Sy1 %2; [Remainder of creature number divided by 2: y5]
!!VRy3&y3=-1/y1<=111/y5=0:Sy1 +1; [If non-upgraded, upgrade is y3]

[Default upgrade for Conflux: y3]
!!VRy3&y3=-1/y1=112:S127; [Air Elemental]
!!VRy3&y3=-1/y1=113:S125; [Earth Elemental]
!!VRy3&y3=-1/y1=114:S129; [Fire Elemental]
!!VRy3&y3=-1/y1=115:S123; [Water Elemental]
!!VRy3&y3=-1/y1=118:S119; [Pixie]
!!VRy3&y3=-1/y1=120:S121; [Psychic Elemental]
!!VRy3&y3=-1/y1=130:S131; [Firebird]

!!VRy5:S1; [Initialize y5 to 1]
!!VRy5&y3>=0:S0; [Set y5 to 0 if y3>=0]

!!FU|y5=1:E; [Exit if no upgrade]

!!HEx1:C0/x16/y3/d; [Upgrade creature]


－－－－－－－－－－分割线－－－－－－－－－－

songfx

厉害！
我自己没有成功提取过脚本