佳丽云

英雄无敌3-WoG中文站

 找回密码
 英雄注册|Register
返回列表 发新帖
查看: 4780|回复: 8

巫术强化一地图事件版（新增附件增强脚本版）

[复制链接]
lastlrj

该用户从未签到

50

回帖

5万

金币

0

精华

1级 Hired Hero

Rank: 1

积分
157
发表于 2009-12-17 20:18:48 | 显示全部楼层 |阅读模式
Sorcery（巫术、魔力）可远程访问部分物体的那个脚本。

把wog化脚本改为地图事件版，一般需要：
1、把本脚本选项开关打开，如：!#UN:P23/1;  [自动打开本脚本选项开关]
2、把字符串资源（srt文件）导入（erm_s.exe的【Tools】->【De-ERTtify script】）
3、注意宏函数的代入。
如果还有问题或没有效果，可能就要检查flag变量、v变量、w变量与其他脚本的关系，改起来就太复杂了，不如放弃……
2009-12-19 修改：
1、扩大可访问范围。
2、支持所有增加指数的建筑的远程访问，使用了FU5038-FU5043，应该不会冲突。
2009-12-22 修改：
修正远程访问Mercenary Camp、Marletto Tower、Arena、School of Magic、School of War、Library of Enlightenment时右击点为不可访问块时会出错的bug。

使用时把下面内容直接copy，在地图设为erm事件。

ZVSE
!#UN:P23/1;
!#UN:P23/?v1;
!#IF&v1=1:V410/0;
!#UN:P23/?v1; [Check if Sorcery script is enabled]
!#TM18&v1=1:S1/999/1/255;
!#VRv550&v1=1:C1/2/4/8/16/32/64/128/256/512;
!?TM18;
!!UN:P23/?v1;
!?TM18&v1=1; [Continue trigger if Sorcery script is enabled]
!!FU5032:P;
!?FU5032;
!!OW:I-1/?y1;
!!OW&y1=1:H-1/600;
!!DO5033/1/v600/1&y1=1/v312>0:P;
!?FU5033;
!!VRy1:S600 +x16;
!!VRy2:Svy1;
!!HEy2:S25/?y3;
!!HEy2|y3=1/y3=2:Wd100;
!!HEy2&y3=3:Wd300;
!#IF:V1/0;
!#UN:V?v310/?v311;
!#IF&v310<357:V1/1;
!#IF&v311<260:V1/1;
!#IF&1:M^{警告：版本过时}

抱歉，你的[wiki]WoG[/wiki]和/或[wiki]ERM[/wiki]版本太低，不能使用{巫术技能强化脚本v1.1}。

请更新你的文件。^;
!?CM;
!!UN:P23/?v1;
!?CM&v1=1; [Continue trigger if Sorcery script is enabled]
!!CM:I?v1;
!!FU5000&v1=37:P;
!?FU5000;
!!OW:C?y-100;  [Get current/local player: y-100]
!!OW:Ay-100/?y8;
!!CM&y8>=0:P?y1/?y2/?y3;
!!OBy1/y2/y3:T?y4 U?y5 C?y6;
!!IF:V3/0;
!!HEy8&y8>=0:S25/?y9;
!!FU&y9=0:E; [Exit if hero has no Sorcery skill]
!!VRy10:Sy-100; [Copy y-100 to y10]
!!VRy10:+550;
!!VRy10:Svy10;
!!TRy1/y2/y3:V?y17;
!!VRy17:&y10;
!!OBy1/y2/y3:H?y16;
!!VRy17&y16>0:S0;
!!FU|y9<=0/y17=0/y8<0:E;
!!HEy8:Ed0/?y10;
!!VRy10:+y9 +y9 +20;
!!VRy10:*y10;
!!HEy8:P?y11/?y12/?y13;
!!VRy14:Sy11 -y1;  [(x1-x2)]
!!VRy14:*y14;      [* (x1-x2)]
!!VRy15:Sy12 -y2;  [(y1-y2)]
!!VRy15:*y15;      [* (y1-y2)]
!!VRy15:+y14;      [(x1-x2)*(x1-x2) + (y1-y2)*(y1-y2)]
!!FU|y9<=0/y3<>y13/y15>y10/y17=0/y8<0:E;
!!UN&y4=101/y5>0/y5<7:By5/?y7;
!!CM|y4=79/y4=81/y4=12/y4=93/y4=39/y4=105/y4=22/y4=112/y4=91/y4=102:R0;
!!CM|y4=55/y4=108/y4=5/y4=86/y4=29/y4=82/y4=104/y4=109:R0;
!!CM&y4=63/y5=0:R0;       [Pyramid]
!!CM&y4=101/y5=0:R0;      [Standard chest]
!!CM&y4=101/y5>0/y5<7/y7=0:R0; [New chest, non-ERM enabled]
!!IF:V1/0; [Clear flag 1]
!!FU849:P; [Flag 1 will be set if Chest script in use]
!!FU5001&y4=79:Py1/y2/y3/y5/y6; [Resource pile]
!!FU5002&y4=81:Py1/y2/y3/y8; [Scholar]
!!FU5003&y4=101/y7=0/y5<7:Py1/y2/y3; [Treasure Chest (standard)]
!!FU5037&y4=101/y5=1/y7=1/1:Py1/y2/y3; [ERM Chest - Display "Trapped/Non-Trapped"]
!!FU5004&y4=12:Py1/y2/y3; [Campfire]
!!FU5005&y4=93:Py1/y2/y3; [Scroll]
!!FU5006&y4=39:Py1/y2/y3; [Lean To]
!!FU5007&y4=105:Py1/y2/y3; [Wagon]
!!FU5008&y4=22:Py1/y2/y3; [Skeleton]
!!FU5009&y4=112:Py1/y2/y3/y9; [View/Visit Windmill]
!!FU5010|y4=91/y4=59:Py1/y2/y3; [Sign or Bottle]
!!FU5011&y4=102:Py1/y2/y3/y6; [Tree of Knowledge]
!!FU5012&y4=55:Py1/y2/y3/y6/y9; [View/Visit Mystical Garden]
!!FU5013&y4=108:Py1/y2/y3; [Warrior's Tomb]
!!FU5014|y4=113/y4=88/y4=89/y4=90:Py1/y2/y3/y6; [Witch Hut or Shrine]
!!FU5015&y4=100/y9=3/999:Py1/y2/y3/y8; [Visit Learning Stone]
!!FU5016&y4=63/y5=0:Py1/y2/y3; [Pyramid]
!!FU5017&y4=5:Py1/y2/y3/y5/y6; [Artifact]
!!FU5019&y4=86:Py1/y2/y3/y6; [Shipwreck Survivor]
!!FU5021&y4=29:Py1/y2/y3/y6; [Flotsam]
!!FU5022&y4=82:Py1/y2/y3/y6; [Sea Chest]
!!FU5023&y4=104:Py1/y2/y3; [University]
!!FU5029&y4=109:Py1/y2/y3/y9; [View/Visit Water Wheel]
!!FU5034&y4=61/y9=3/999:Py1/y2/y3/y6/y8; [Visit Star Axis]
!!FU5035&y4=32/y9=3/999:Py1/y2/y3/y6/y8; [Visit Garden of Revelation]
!!FU5038&y4=51/y6>=0/y6<=32/y9=3/999:Py1/y2/y3/y6/y8; [51  Mercenary Camp A+1]
!!FU5039&y4=23/y6>=0/y6<=32/y9=3/999:Py1/y2/y3/y6/y8; [23  Marletto Tower D+1]
!!FU5040&y4=4/y6>=0/y6<=32/y9=3/999:Py1/y2/y3/y6/y8; [4  Arena A+2 or D+2]
!!FU5041&y4=47/y6>=0/y6<=32/y9=3/999:Py1/y2/y3/y6/y8; [47  School of Magic P+1 or K+1 for 1000G]
!!FU5042&y4=107/y6>=0/y6<=32/y9=3/999:Py1/y2/y3/y6/y8; [107  School of War A+1 or D+1 for 1000G]
!!FU5043&y4=41/y6>=0/y6<=32/y9=3/999:Py1/y2/y3/y6/y8; [41  Library of Enlightenment All+2]
!?FU5001;
!!ARx1/x2/x3:V?y1;
!!VRy1&x4=6:*100;
!!IF:V1/0;
!!VRz3:S^^;
!!DO5018/0/6/1&x5<0:Px1/x2/x3;
!!FU5020:Px4/y1;
!!VRz1&1:S^    {%Z2}

守卫
%Z3^;
!!VRz1&-1:Sz2;
!!IF:Q1/x4/y1/4^%Z1^;
!?FU5002;
!!SCx1/x2/x3:T?y1 P?y2 S?y3 L?y4;
!!VRz2:S^^;
!!VRy5&y1=0:Sy2 +31;
!!VRy6&y1=0:S1;
!!VRz1&y1=0/y2<2:S^战斗学者

教导：^;
!!VRz1&y1=0/y2=2:S^[wiki]神[/wiki]秘学者

教导：^;
!!VRz1&y1=0/y2=3:S^智慧学者

教导：^;
!!HEx4&y1=1:Sy3/?y7;
!!VRy5&y1=1:S20;
!!VRy6&y1=1:Sy3 *3 +3;
!!VRy6&y1=1/y7=1:+1;
!!VRy6&y1=1/y7=2:+2;
!!VRz1&y1=1:S^学术学者

教导：^;
!!VRy5&y1=2:S9;
!!VRz1&y1=2:S^巫术学者

教导：^;
!!VRy4&y1=2:-1024;
!!VRy6&y1=2:Sy4;
!!IF:Q1/y5/y6/4^%Z1^;
!?FU5003;
!!CHx1/x2/x3:S?y1 A?y2 B?y3;
!!VRy5&y1=0:Sy3*500;
!!VRy6&y1=0:Sy5-500;
!!IF&y1=0:Q1/6/y5/17/y6/4^{宝箱}

选择：^;
!!IF&y1<>0:Q1/8/y2/4^宝箱^;
!?FU5004;
!!FRx1/x2/x3:B?y1/?y2;
!!VRy3:Sy2 *100;
!!IF:Q1/6/y3/y1/y2/4^营火^;
!?FU5005;
!!ARx1/x2/x3:V?y1;
!!OBx1/x2/x3:C?i;
!!IF:V1/0;
!!VRz3:S^^;
!!DO5018/0/6/1&i<0:Px1/x2/x3;
!!UN:N1/2/y1;
!!UN:P33/?y2; [Check if Living Scrolls is enabled: y2=1 if  yes]
!!VRy2|y1<10/y1=24/y1=25/y1=35/y1=38/y1=39/y1=40/y1=65/y1=66/y1=67/y1=68/y1=69:S0;
!!VRz-1&y2=1:S^自动释放^;
!!VRz-1&y2=0:S^^;
!!VRz1&1:S^     {%Z-1魔法卷轴}
%Z2

守卫
%Z3^;
!!VRz1&-1:S^     {%Z-1魔法卷轴}
%Z2^;
!!IF:Q1/9/y1/4^%Z1^;
!?FU5006;
!!TRx1/x2/x3:P?y3;
!!VRx1&y3=0:+1;
!!LNx1/x2/x3:B?y1/?y2;
!!FU5020:Py1/y2;
!!VRz2&y2<1:S^没有有价值的东西^;
!!VRy1&y2<1:S-1;
!!VRz1:S^可能是

%Z2^;
!!IF:Q1/y1/y2/4^%Z1^;
!?FU5007;
!!WGx1/x2/x3:S?y1 B?y2 A?y3 R?y4/?y5;
!!FU5020&y1<>0/y2=0:Py4/y5;
!!FU5036&y2<>0:Py3;
!!VRz1&y1<>0/y2=0:S^货车

%Z2^;
!!VRz1&y1<>0/y2<>0:S^货车里有一件%Z2。^;
!!VRy4&y1<>0/y2<>0:S8;
!!VRz1&y1=0:S^货车里面没有有价值的东西。^;
!!VRy4&y1=0:S-1;
!!VRy5&y1=0:S-1;
!!IF&y2=0:Q1/y4/y5/4^%Z1^;
!!IF&y2<>0:Q1/y4/y3/4^%Z1^;
!?FU5008;
!!SKx1/x2/x3:S?y1 A?y2;
!!VRy3&y1<>0:S8; [Artifact]
!!VRz1&y1=0:S^骷髅里面没有有价值的东西。^;
!!VRy2&y1=0:S-1;
!!VRy3&y1=0:S-1;
!!FU5036&y1<>0:Py2;
!!VRz1&y1<>0:S^骷髅里有一件%Z2。^;
!!IF:Q1/y3/y2/4^%Z1^;
!?FU5009;
!!MLx1/x2/x3:B?y1/?y2;
!!FU5020:Py1/y2;
!!VRz2&y2<1:S^（已访问）^;
!!VRy1&y2<1:S-1;
!!VRy2&y2<1:S-1;
!!POx1/x2/x3:N?y3;
!!VRy3|y3=2/y3=3:S2; [If y3=2 or 3, set it to 2]
!!VRz3:S^^;
!!VRz3&y3=2:S^升级的^;
!!VRz1:S^{%Z3风车}

%Z2^;
!!IF|x4<3/y2<1:Q1/y1/y2/4^%Z1^;
!!FU5027&x4=3/y2>0/999:Px1/x2/x3/y1/y2;
!?FU5027;
!!POx1/x2/x3:N?y3;
!!VRz3:S^^;
!!VRz3|y3=2/y3=3:S^升级的^;
!!IF:Q2/x4/x5/2^{%Z3风车}

你是否运用专家级巫术，从远处访问%Z3风车？^;
!!IF&2:Q2/x4/x5/1^{%Z3风车}

风车的守卫：“大人，我们辛苦[wiki]工作[/wiki]，
才得到这些资源，请下周再来吧！”^;
!!OW&2:R-1/x4/dx5;
!!MLx1/x2/x3&2:Bd0/0;
!?FU5010;
!!SGx1/x2/x3:M?z1;
!!VRz1:H1;
!!VRz1&-1:S^（无法用魔法查看）^;
!!IF:Q1/-1/-1/4^%Z1^;
!?FU5011;
!!KTx1/x2/x3:S?y1 N?y2;
!!OW:A-1/?y3;
!!VRz2&y1=0:S^免费^;
!!VRy5&y1=0:S-1;
!!VRy6&y1=0:S-1;
!!VRz2&y1=1:S^2000金币^;
!!VRy5&y1=1:S6;
!!VRy6&y1=1:S2000;
!!VRz2&y1=2:S^10宝石^;
!!VRy5&y1=2:S5;
!!VRy6&y1=2:S10;
!!HEy3:V5/y2/?y4;
!!VRz3&y4=1:S^

（已经访问）^;
!!VRz3&y4=0:S^^;
!!VRz1:S^{智慧树}

（%Z2升 1级）

%Z3^;
!!IF:Q1/y5/y6/4^%Z1^;
!?FU5012;
!!TRx1/x2/x3:E?y5;
!!GDx1/x2/x3:T?y1 B?y2;
!!VRy3|y2=5/y2=7:S5;
!!VRy3&y2=6:S500;
!!FU5020&y1<>0:Py2/y3;
!!VRz2&x4<-1600:S^（已访问）^;
!!VRy2&x4<-1600:S-1;
!!VRy3&x4<-1600:S-1;
!!VRz1:S^{神秘花园}

%Z2^;
!!VRz1&y5=1:S^神秘花园^;
!!VRy2&y5=1:S-1;
!!VRy3&y5=1:S-1;
!!IF|x5<3/x4<=-1600/y5=1:Q1/y2/y3/4^%Z1^;
!!FU5028&x5=3/x4>-1600/y5=0/999:Px1/x2/x3/y2/y3;
!?FU5028;
!!IF:Q2/x4/x5/2^{神秘花园}

你是否运用专家级巫术，从远处访问神秘花园？^;
!!IF&2:Q2/x4/x5/1^{神秘花园}

美妙的音乐带你走进一座小花园，一个
快乐的妖精正无忧无虑的跳着舞，你偷
偷的走进并抓住了他。为了换取自由，
他带着你找到了一个装满宝贝的罐子。^;
!!OW&2:R-1/x4/dx5;
!!OBx1/x2/x3&2:C-1650;
!?FU5013;
!!TRx1/x2/x3:P?y3;
!!VRx1&y3=0:+1;
!!WTx1/x2/x3:S?y1 A?y2;
!!FU5036:Py2;
!!VRy4:S8; [Artifact]
!!VRz1&y1<>0:S^勇士墓有一件%Z2。^;
!!VRz1&y1=0:S^勇士墓里面空无一物。^;
!!VRy2&y1=0:S-1;
!!VRy4&y1=0:S-1;
!!IF:Q1/y4/y2/4^%Z1^;
!?FU5014;
!!OW:C?y-100;  [Get current/local player: y-100]
!!VRy1:Sy-100; [Copy y-100 to y1]
!!VRy1:+550;
!!VRy1:Svy1;
!!VRy1:*32;
!!VRx4:|y1;
!!OBx1/x2/x3:Cx4;
!?FU5015;
!!STx1/x2/x3:N?y1;
!!HEx4:V0/y1/?y2;
!!FU&y2<>0:E; [Exit if hero has already visited this Learning Stone]
!!IF:Q2/17/1000/2^{学习石}

你是否运用专家级巫术，从远处访问学习石？^;
!!IF&2:Q2/17/1000/1^{学习石}

当你走近时，支柱表面的光滑石头开始旋转。透
过这块石头，你惊奇的看到困扰了你好多年的难
题的答案。石头突然停止了，但你已经受益匪浅。^;
!!HEx4&2:V0/y1/1;
!!HEx4&2:S21/?y3; [Level of Learning skill known: y3]
!!HEx4&2/y3=0:Ed1000; [No skill]
!!HEx4&2/y3=1:Ed1050; [Basic Learning]
!!HEx4&2/y3=2:Ed1100; [Advanced Learning]
!!HEx4&2/y3=3:Ed1150; [Expert Learning]
!!CM:R0;
!?FU5016;
!!TRx1/x2/x3:P?y3;
!!VRx1&y3=0:+1;
!!PMx1/x2/x3:S?y1 V?y2;
!!UN&y1<>0:N1/2/y1;
!!VRy5:S9;
!!VRy6:Sy1;
!!OW:A-1/?y3;
!!HEy3:My1/?y4;
!!VRz2&y4>0:S^%Z2

（已经学会）^;
!!VRz2&y2=0:S^（已访问）^;
!!VRz1&y1<>0:S^   {金字塔}

%Z2^;
!!VRy5&y2=0:S-1;
!!VRy6&y2=0:S-1;
!!IF:Q1/y5/y6/4^%Z1^;
!?FU5017;
!!IF:V1/0;
!!VRz3:S^^;
~~ARx1/x2/x3&x5<>0:X?y1; [Check if guards are turned on: y1]
!!DO5018/0/6/1&x5<>0:Px1/x2/x3;
!!FU5036:Px4;
!!VRz1&1:S^    {%Z2}

守卫
%Z3^;
!!VRz1&-1:S^%Z2^;
!!IF:Q1/8/x4/4^%Z1^;
!?FU5018;
!!ARx1/x2/x3:Gx16/?y1/?y2;
!!IF&y1<>-1/y2>0:V1/1;
!!UN&y1<>-1/y2=1:N3/2/y1/0;
!!UN&y1<>-1/y2>1:N3/2/y1/1;
!!VRz3&y1<>-1/y2>0:S^%Z3
%Y2 %Z2^;
!?FU5019;
!!FU5036:Px4;
!!IF:Q1/8/x4/4^幸存者有一件%Z2。^;
!?FU5020;
!!VRz2:S^{%X2} ^;
!!VRz2&x1=0/x2=1:+^木材^;
!!VRz2&x1=0/x2>1:+^木材^;
!!VRz2&x1=1/x2=1:+^水银^;
!!VRz2&x1=1/x2>1:+^水银^;
!!VRz2&x1=2/x2=1:+^矿石^;
!!VRz2&x1=2/x2>1:+^矿石^;
!!VRz2&x1=3/x2=1:+^硫磺^;
!!VRz2&x1=3/x2>1:+^硫磺^;
!!VRz2&x1=4/x2=1:+^水晶^;
!!VRz2&x1=4/x2>1:+^水晶^;
!!VRz2&x1=5/x2=1:+^宝石^;
!!VRz2&x1=5/x2>1:+^宝石^;
!!VRz2&x1=6/x2=1:+^金币^;
!!VRz2&x1=6/x2>1:+^金币^;
!!VRz2&x1=7/x2=1:+^秘银^;
!!VRz2&x1=7/x2>1:+^秘银^;
!?FU5021;
!!VRz2&x4=0:S^没有有价值的东西^;
!!VRy1&x4=0:S-1;
!!VRy3&x4<2:S-1;
!!VRz2&x4=1:S^5木头^;
!!VRy1&x4>0:S0;
!!VRy2&x4>0/x4<3:S5;
!!VRz2&x4=2:S^5木头和 200金币^;
!!VRy3&x4>1:S6;
!!VRy4&x4=2:S200;
!!VRz2&x4=3:S^10木头和 500金币^;
!!VRy2&x4=3:S10;
!!VRy4&x4=3:S500;
!!VRz1:S^   {漂浮物}

%Z2^;
!!IF:Q1/y1/y2/y3/y4/4^%Z1^;
!?FU5022;
!!VRy1:Sx4 &7;
!!VRy2&y1=2:Sx4 :8 &255 -1;
!!FU5036&y1=2:Py2;
!!VRz1:S^   {海上宝箱}

^;
!!IF&y1=0:Q1/-1/-1/4^%Z1空的^;
!!IF&y1=1:Q1/6/1500/4^%Z1 1500金币^;
!!IF&y1=2:Q1/36/1000/8/y2/4^%Z1 1000金币和一件%Z2^;
!?FU5023;
!!TRx1/x2/x3:E?y5;
!!URx1/x2/x3&y5=0:S?y1/?y2/?y3/?y4;
!!VRz1:S^{学院}

每个技能 2000金币，可以学习：^;
!!UN:N4/2/y1;
!!VRz1:S^%Z1
{%Z2,}^;
!!UN:N4/2/y2;
!!VRz1:S^%Z1 {%Z2}^;
!!UN:N4/2/y3;
!!VRz1:S^%Z1
{%Z2,}^;
!!UN:N4/2/y4;
!!VRz1:S^%Z1 {%Z2.}^;
!!UN:P36/?y6;
!!POx1/x2/x3:N?y7;
!!VRz-1:S^^;
!!VRz-1&y6=1/y7=2:S^中级^+^ ^;
!!IF&y5=0:Q1/-1/-1/4^%Z-1%Z1^;
!!CM&y5<>0:R1;
!?OB79&-875;
!!UN:P23/?v1;
!?OB79&v1=1; [Continue trigger if Sorcery script is enabled]
!!HE-1:S25/?v1;
!!FU5025&v1>1:Pv1;
!?FU5025;
!!ARv998/v999/v1000:V?y1;
!!OB998:U?y6;
!!PO998:N?y5;
!!PO998&y5=0:Ny1;
!!VRy1&y1>y5/y5<>0:Sy5;
!!HE-1:Ed0/?y2;
!!HE-1:B0/?z5;
!!VRy2|y6=0/y6=2/y6=6::4;
!!VRy2|y6=1/y6=3/y6=4/y6=5/y6=7::6;
!!VRy2&y2<1:S1;
!!VRy2&x1=3:+1;
!!VRy1:Sy1 +y2;
!!ARv998/v999/v1000:Vy1;
!!VRz1&x1=2:S^中级^;
!!VRz1&x1=3:S^高级^;
!!VRy3:Sy2;
!!VRy3&y6=6:*100;
!!VRy1&y6=6:*100;
!!FU5020:Py6/y3;
!!UN:B0/?y9;
!!IF&y6=7/y9=1:V410/1; [Set 410 to True if resource is mithril]
!!IF&y6<>7:V410/0; [Set 410 to False if resource isn't mithril]
!!VRz-1&410/y3=1:S^^;
!!VRz-1&410/y3>1:S^^;
!!OW:R-1/7/?y7; [Store current player's previous total mithril in y7]
!!VRy8:Sy7 +y1; [Add new mithril to previous mithril - store in y8]
!!OW:C?y10; [Current player: y10]
!!VRy10:+1; [Add 1 to y10]
!!FU3333:Py10;  [Convert to bit number: y-100]
!!VRy11:Sv3320; [Set y11 to v3320]
!!VRy11:&y-100; [Check if message is disabled for current player: y11]
!!FU&y11=y-100/-410:E; [Exit Function if message is disabled for current player unless Mithril]
!!IF&1000/-410:Q1/y6/y3/1^%Z5的%Z1巫术让这堆资源增加了 %Z2.

（{右击[系统选项]，禁止显示信息}）^;
!!IF&1000/410:Q1/y6/y1/1^%Z5的%Z1巫术让这堆秘银
增加了 %Y3%Z-1，一共是 %Y1秘银。

你现在有%Y8秘银。

（{右击[王国概况]，查看秘银总量}）^;
!?FU3333;
!!VRv3339:S1; [Set default bit value to 1]
!!DO3334/2/x1/1:P; [If bit number is 2 or larger, multiply by 2 to the power of n-1]
!!VRy-100:Sv3339; [Store converted bit value in y-100]
!!VRy-100&x1=0:S0; [If bit number is 0, set y-100 value to 0]
!!VRx2:Sv3339; [Store converted bit value in return variable]
!!VRx2&x1=0:S0; [if bit number is 0, set return variable value to 0]

!?FU3334;
!!VRv3339:*2; [double bit value]
!?OB101;
!!UN:P23/?y-1;
!!FU&y-1<>1:E; [Exit if Sorcery script isn't enabled]
!!HE-1:S25/?v1;
!!OB998:U?v2; [v2=0 for standard chest, v2>0 for new chest types, v2>6 for Power Stones]
!!FU&v2>6:E; [Exit if it's a Power Stone]
!!VRv3:S0;
!!UN&v2>0:Bv2/?v3; [v3=0 if standard operation, v3=1 if advanced (scripted)]
!!CH998&v2>0/v3=0/-875:S?v4;
!!CH998&v2=0/-875:S?v4;
!!FU5026&v1>1/v3=0/v4=0/-875:Pv1;
!?FU5026;
!!CHv998/v999/v1000:B?y1;
!!OB998&1000:M-1/1/0;
!!VRy1&x1=2:+1;
!!VRy1&x1=3:+2;
!!VRy4&x1=2:S500;
!!VRy4&x1=3:S1000;
!!VRy1&y1>15:S15;
!!CHv998/v999/v1000:By1;
!!IF:W-1;
!!VRy1&w64=3:*2;
!!VRy1&y1>15:S15;
!!VRy2:Sy1 *500;
!!VRy3:Sy2 -500;
!!VRz1&x1=2:S^中级^;
!!VRz1&x1=3:S^高级^;
!!IF&1000:Q2/6/y2/17/y3/7^{宝箱}

经过搜索这片区域，你发现了一个隐藏的
宝箱。你的%Z1巫术让金币增加了%Y4。你可以
拿走这些金币，或者把它散给农民换取经验。

你选择哪一项？^;
!?FU5029;
!!TRx1/x2/x3:E?y1;
!!WMx1/x2/x3:B?y2;
!!VRy3:Sy2 *500;
!!CM|y1<>0/y2<1:R1;
!!POx1/x2/x3:N?y4;
!!VRz3:S^^;
!!VRz3|y4=2/y4=3:S^升级的^;
!!VRz1:S^{%Z3水车}

%Y3金币^;
!!FU5030&y1=0/x4=3/y2>0/999:Px1/x2/x3/y3;
!!IF&y1=0/x4<>3/y2>0:Q1/6/y3/4^%Z1^;
!?FU5030;
!!POx1/x2/x3:N?y4;
!!VRz3:S^^;
!!VRz3|y4=2/y4=3:S^升级的^;
!!IF:Q2/6/x4/2^{%Z3水车}

你是否运用高级巫术，从远处访问%Z3水车？^;
!!IF&2:Q2/6/x4/1^{%Z3水车}

水车的守卫：“大人，我们辛苦工作，
才得到这些金币，请下周再来吧！”^;
!!OW&2:R-1/6/dx4;
!!WMx1/x2/x3&2:B0;
!!OW&2:C?y1;
!!VRy2&2/y1=0:S-8160;
!!VRy2&2/y1=1:S-8128;
!!VRy2&2/y1=2:S-8000;
!!VRy2&2/y1=3:S-7872;
!!VRy2&2/y1=4:S-7680;
!!VRy2&2/y1=5:S-7168;
!!VRy2&2/y1=6:S-6144;
!!VRy2&2/y1=7:S-4096;
!!OBx1/x2/x3&2:C?y3;
!!VRy3&2:|y2;
!!OBx1/x2/x3&2:Cy3;
!?FU5034;
!!HEx5:V4/x4/?y2;
!?FU5034&y2=0;
!!IF:Q2/33/1/2^{星轴}

你是否运用高级巫术，从远处访问星轴？^;
!!IF&2:Q2/33/1/1^{星轴}

你遇到了这个大陆上最好的几位天文学家，他
们聚集在星轴周围。好客的他们教会你如何利
用太阳、月亮和星星提高你释放魔法的能力。^;
!!HEx5&2:Fd/d/d1/d;
!!HEx5&2:V4/x4/1;
!!UN:R1;
!!CM:R0;
!?FU5035;
!!HEx5:V2/x4/?y2;
!?FU5035&y2=0;
!!IF:Q2/34/1/2^{真理花园}

你是否运用专家级巫术，从远处访问真理花园？^;
!!IF&2:Q2/34/1/1^{真理花园}

坐在花园中心的僧侣邀请你同他一起冥想。
你冥想了很短的时间，发现你更聪明了。^;
!!HEx5&2:Fd/d/d/d1;
!!HEx5&2:V2/x4/1;
!!UN:R1;
!!CM:R0;
!?FU5036;
!!UN:Ax1/3/?y1;
!!VRz2:S^宝物^;
!!VRz2&x1=0:S^魔法书^;
!!VRz2&x1=2:S^圣杯^;
!!VRz2&x1>=3/x1<=6:S^战争机器^;
!!VRz2&y1=2:S^珍宝^;
!!VRz2&y1=4:S^武器^;
!!VRz2&y1=8:S^宝物^;
!!VRz2&y1=16:S^圣物^;
!!VRz2&x1>=146/x1<=155:S^宠物宝物^;
!?FU5037;
!!VRx1:%4;
!!VRx2:%4;
!!IF&x1=0/x2=0:Q1/-1/-1/4^{宝箱}

陷阱！^;
!!IF|x1<>0/x2<>0:Q1/-1/-1/4^{宝箱}

非陷阱^;
!!CM:R0;
!?FU5038;
!!HEx5:V3/x4/?y2;
!?FU5038&y2=0;
!!IF:Q2/31/1/2^{雇佣兵营帐}

你是否运用高级巫术，从远处访问雇佣兵营帐？^;
!!IF&2:Q2/31/1/1^{雇佣兵营帐}

通过访问雇佣兵营帐，你的攻击上升了。^;
!!HEx5&2:Fd1/d/d/d;
!!HEx5&2:V3/x4/1;
!!UN:R1;
!!CM:R0;
!?FU5039;
!!HEx5:V1/x4/?y2;
!?FU5039&y2=0;
!!IF:Q2/32/1/2^{马力特塔}

你是否运用高级巫术，从远处访问马力特塔？^;
!!IF&2:Q2/32/1/1^{马力特塔}

通过访问马力特塔，你的防御上升了。^;
!!HEx5&2:Fd/d1/d/d;
!!HEx5&2:V1/x4/1;
!!UN:R1;
!!CM:R0;
!?FU5040;
!!HEx5:V7/x4/?y2;
!?FU5040&y2=0;
!!IF:Q4/31/2/32/2/10^{竞技场}

你是否运用高级巫术，从远处访问竞技场？^;
!!IF&v4=1:Q2/31/2/1^{竞技场}^; [player choose attack]
!!HEx5&v4=1:Fd2/d/d/d;[Give hero +2 attack if player chose left]
!!IF&v4=2:Q2/32/2/1^{竞技场}^; [player choose defence]
!!HEx5&v4=2:Fd/d2/d/d; [Give hero +2 defence if player chose right]
!!HEx5&v4<>0:V7/x4/1;
!!UN:R1;
!!CM:R0;
!?FU5041;
!!HEx5:V8/x4/?y2;
!?FU5041&y2=0;
!!IF:Q4/33/1/34/1/10^{魔法学校}

你是否运用高级巫术，从远处访问魔法学校？^;
!!IF:V2/1;
!!IF&v4=0:V2/0; [player clicks Cancel]
!!OW&2:R-1/6/?y55;get current player's gold
!!IF&2/y55<1000:Q2/6/1000/1^你只有{%Y55 金币}，付不起{1000 金币}的学费。^;
!!IF&2/y55<1000:V2/0;set flag 2 to 0,treat as not visited
!!OW&2:R-1/6/d-1000;take 1000 gold
!!IF&2/v4=1:Q2/33/1/6/-101000/1^{魔法学校}^;
!!HEx5&2/v4=1:Fd/d/d1/d;
!!IF&2/v4=2:Q2/34/1/6/-101000/1^{魔法学校}^;
!!HEx5&2/v4=2:Fd/d/d/d1;
!!HEx5&2:V8/x4/1;
!!UN:R1;
!!CM:R0;
!?FU5042;
!!HEx5:V9/x4/?y2;
!?FU5042&y2=0;
!!IF:Q4/31/1/32/1/10^{斗士学院}

你是否运用高级巫术，从远处访问斗士学院？^;
!!IF:V2/1;
!!IF&v4=0:V2/0; [player clicks Cancel]
!!OW&2:R-1/6/?y55;get current player's gold
!!IF&2/y55<1000:Q2/6/1000/1^你只有{%Y55 金币}，付不起{1000 金币}的学费。^;
!!IF&2/y55<1000:V2/0;set flag 2 to 0,treat as not visited
!!OW&2:R-1/6/d-1000;take 1000 gold
!!IF&2/v4=1:Q2/31/1/6/-101000/1^{斗士学院}^;[show player's choice]
!!HEx5&2/v4=1:Fd1/d/d/d;[Give hero +1 attack if player chose left]
!!IF&2/v4=2:Q2/32/1/6/-101000/1^{斗士学院}^;[show player's choice]
!!HEx5&2/v4=2:Fd/d1/d/d;[Give hero +1 defence if player chose right]
!!HEx5&2:V9/x4/1;
!!UN:R1;
!!CM:R0;
!?FU5043;
!!HEx5:V6/x4/?y2;
!?FU5043&y2=0;
!!IF:Q2^{智者图书馆}

你是否运用高级巫术，从远处访问智者图书馆？

{[wiki]英雄[/wiki]所有指数+2}^;
!!IF&2:Q2/31/2/32/2/1^{智者图书馆}^;
!!IF&2:Q2/33/2/34/2/1^{智者图书馆}^;
!!HEx5&2:Fd2/d2/d2/d2;
!!HEx5&2:V6/x4/1;
!!UN:R1;
!!CM:R0;


巫术强化增强脚本 script23.rar (11.75 KB, 下载次数: 57)

[ 本帖最后由 lastlrj 于 2009-12-22 19:51 编辑 ]
巫术, 强化, 地图, 事件, 新增

评分

1

查看全部评分

相关帖子

没有金币了？点我试试！
回复

使用道具 举报

yexian7

该用户从未签到

564

回帖

7307

金币

0

精华

4级 Famous Hero

Rank: 4

积分
1247
发表于 2009-12-18 11:06:10 | 显示全部楼层
lz辛苦了，地图爱好者的福音。
没有金币了？点我试试！
回复 支持 反对

使用道具 举报

龙巫妖
  • TA的每日心情
    怒
    5 小时前

    • 签到天数: 3902 天

    连续签到: 141 天

    [LV.Master]伴坛终老

    4480

    回帖

    14万

    金币

    0

    精华

    版主

    始祖龙巫

    Rank: 10Rank: 10Rank: 10

    积分
    155453

    论坛守望者社区QQ达人魅力之星
    发表于 2009-12-18 12:11:57 | 显示全部楼层
    都强化了什么？
    回复 支持 反对

    使用道具 举报

    lastlrj

    该用户从未签到

    50

    回帖

    5万

    金币

    0

    精华

    1级 Hired Hero

    Rank: 1

    积分
    157
     楼主| 发表于 2009-12-23 14:04:43 | 显示全部楼层
    1、扩大可访问范围。
    2、支持远程访问Mercenary Camp、Marletto Tower、Arena、School of Magic、School of War、Library of Enlightenment。
    没有金币了？点我试试！
    回复 支持 反对

    使用道具 举报

    cx2005

    该用户从未签到

    95

    回帖

    8298

    金币

    1

    精华

    2级 Adventuring Hero

    Rank: 2

    积分
    234
    发表于 2009-12-23 23:07:57 | 显示全部楼层
    智者图书馆应该改为英雄等级10级以后才能访问
    另外拥有：
    基础外交8级访问；
    高级外交6级访问；
    专家外交4级访问。
    没有金币了？点我试试！
    回复 支持 反对

    使用道具 举报

    龙巫妖
  • TA的每日心情
    怒
    5 小时前

    • 签到天数: 3902 天

    连续签到: 141 天

    [LV.Master]伴坛终老

    4480

    回帖

    14万

    金币

    0

    精华

    版主

    始祖龙巫

    Rank: 10Rank: 10Rank: 10

    积分
    155453

    论坛守望者社区QQ达人魅力之星
    发表于 2009-12-23 23:10:02 | 显示全部楼层
    好东西 收藏起来
    回复 支持 反对

    使用道具 举报

    szx_9933
  • TA的每日心情
    无聊
    昨天 10:15

    • 签到天数: 465 天

    连续签到: 4 天

    [LV.9]龙巫妖

    1251

    回帖

    1万

    金币

    0

    精华

    5级 Honorable Hero

    Rank: 5Rank: 5

    积分
    5383
    发表于 2009-12-24 07:31:01 | 显示全部楼层
    这个是好东西啊。。
    没有金币了？点我试试！
    回复 支持 反对

    使用道具 举报

    lastlrj

    该用户从未签到

    50

    回帖

    5万

    金币

    0

    精华

    1级 Hired Hero

    Rank: 1

    积分
    157
     楼主| 发表于 2009-12-24 11:05:59 | 显示全部楼层
    原帖由 cx2005 于 2009-12-23 23:07 发表
    智者图书馆应该改为英雄等级10级以后才能访问
    另外拥有：
    基础外交8级访问；
    高级外交6级访问；
    专家外交4级访问。


    这个限制没有加：
    一是已经限制expert魔力才能访问，魔力expert时等级一般不会小于4；
    二是懒得写代码获取额外英雄等级和外交等级。（这是主要原因）
    没有金币了？点我试试！
    回复 支持 反对

    使用道具 举报

    horse1971

    该用户从未签到

    88

    回帖

    7457

    金币

    0

    精华

    2级 Adventuring Hero

    Rank: 2

    积分
    321
    发表于 2009-12-29 20:41:59 | 显示全部楼层
    多谢，是否能把http://bbs.h3wog.com/thread-19834-1-2.html里面的脚本，按照楼主步骤1、把本脚本选项开关打开，如：!#UN:P23/1;  [自动打开本脚本选项开关]，都修改一下，我试着想改个作战术没成功，也不知道地图选项里面怎么能打开（在那里求助，也没高手指点如何设置地图选项）。再次先谢了

    [ 本帖最后由 horse1971 于 2009-12-29 20:43 编辑 ]
    没有金币了？点我试试！
    回复 支持 反对

    使用道具 举报

    返回列表 发新帖
    ahome_bigavatar:guest
    ahome_bigavatar:welcomelogin
    高级模式
    B Color Image Link Quote Code Smilies
    您需要登录后才可以回帖 登录 | 英雄注册|Register

    本版积分规则

    捐赠
    顶部qrcode底部
    关注我们，英3Mod一网打尽！

    WoG中文站 ( 辽B2-20210485-10 )|辽公网安备 21128202000228 号

    GMT+8, 2024-11-23 08:10 , Processed in 0.894130 second(s), 17 queries , Gzip On, File On.

    Powered by Discuz! X3.4

    Copyright © 2004-2022, Beijing Second Sight Technology Co., LTD.

    快速回复 返回顶部 返回列表