ERM修改：部队属性随战斗次数增加而增加

laoguier

[wiki]ERM[/wiki]修改：根据kally的全兵种特长[wiki]英雄[/wiki]ERM修改，再次表示感谢
使用方法：将下列代码复制，在地图中建立一个500天以上的事件粘贴，初始变量位置改为自己使用的英雄代码。
使用效果：
1。每次战斗胜利，增加该英雄所带领部队2％的攻、防、杀伤，5％的生命。
2。每10级增加本方部队1点速度，即11－20级增加1点，51－60级增加5点。
3。按照敌方速度减少其速度。
敌方速度=20的兵种，其速度减少4；
4。本方部队获得护盾＋气盾魔法各3回合。
5。敌方部队受到悲伤＋大难魔法各3回合。
试验地图：chaser2.2f，tds2.05
注意：该erm比较BT，仅适用于BT地图，否则丧失意义
     战斗次数过多，有可能使数据溢出，请大家自行控制
     erm使用了英雄变量w5，有可能与其它erm冲突，如有冲突，大家可自行调整。
     本erm仅在chaser2.2f和tds2.05试验成功。

ZVSE
;------------------------------选择特长英雄--------------------------------------------
!#VRv84:C63; 初始化变量（将你所希望的英雄代码写入此处，此处63表示tds中的橙色主英雄，红色主英雄是4，蓝色是27，青色是149，chaser中的主英雄是27）
;---------------------------战斗开始-------------------------------------------
!?BA0&1000;
!!IF:Wv84; 确定特长英雄
!!VRw5&w5=0:S1;英雄变量
!!VRw5:+1; 计数器开始累计
!!BA:H0/?v9555; 保存进攻方英雄到v9555
!!BA:H1/?v9560; 防守方hero到v9560
!?BF&1000; 战场生成后
!!DO7055/0/20/1&v9555=v84:P;本方数据
!!DO7055/21/41/1&v9560=v84:P;
!!DO7056/21/41/1&v9555=v84:P; 敌方数据
!!DO7056/0/21/1&v9560=v84:P;
;--------------------------战斗中属性增加-------------------------------
!?FU7055; 己方触发
!!HEv84:E?y21/?y22; 取得英雄的等级y22
!!BMx16:T?y-30;
!!FU&y-30=145:E; 下列几行都是排除攻城武器
!!FU&y-30=146:E;
!!FU&y-30=147:E;
!!FU&y-30=148:E;
!!FU&y-30=149:E;
!!BMx16:H?y-31; 每次战斗增加部队5%的生命
!!VRy-31::20;
!!VRy-32:Sy-31 *w5;
!!VRy-32&y-32=0:S1;
!!BMx16:Hdy-32;
!!BMx16:A?y-33; 每次战斗增加部队2%的攻击
!!VRy-33::50;
!!VRy-34:Sy-33 *w5;
!!VRy-34&y-34=0:S1;
!!BMx16:Ady-34;
!!BMx16:D?y-35; 每次战斗增加部队2%的防御
!!VRy-35::50;
!!VRy-36:Sy-35 *w5;
!!VRy-36&y-36=0:S1;
!!BMx16:Ddy-36;
!!BMx16:U1/?y-37; 每次战斗增加部队2%的最低伤害
!!VRy-37::50;
!!VRy-38:Sy-37 *w5;
!!VRy-38&y-38=0:S1;
!!BMx16:U1/dy-38;
!!BMx16:U2/?y-39; 每次战斗增加部队2%的最高伤害
!!VRy-39::50;
!!VRy-40:Sy-39 *w5;
!!VRy-40&y-40=0:S1;
!!BMx16:U2/dy-40;
!!VRy23&y22<11:S0; 按等级增加1-5点速度
!!VRy23&y22>10/y22<21:S1;
!!VRy23&y22>20/y22<31:S2;
!!VRy23&y22>30/y22<41:S3;
!!VRy23&y22>40/y22<51:S4;
!!VRy23&y22>50:S5;
!!BMx16:Sdy23;
!!BMx16:M27/3/2 M46/3/2; +护盾,石肤
!?FU7056; 敌方触发
!!BMx16:S?y32;
!!FU&y32=0:E;
!!VRy33&y32<8:S-1; 根据敌方怪物速度减少其速度
!!VRy33&y32>7/y32<15:S-2;
!!VRy33&y32>14/y32<20:S-3;
!!VRy33&y32>=20:S-4;
!!BMx16:Sdy33;
!!BMx16:M52/3/2 M50/3/2; +大难,悲伤
;------------------------------END--------------------------------

[ 本帖最后由 laoguier 于 2008-8-29 14:12 编辑 ]

laoguier

200次战斗后效果如下：

妖術_滅

BT 这样[wiki]游戏[/wiki]难度就增加了啊

laoguier

原帖由 妖術_滅 于 2008-8-29 17:51 发表
BT 这样游戏难度就增加了啊

只是战场显示，游戏难度不会增大

skyx7c3

LZ为什么我一直用不了啊
放在全局事件里面后就会导致地图WOG话失败啊
我的事件内容是这样的
ZVSE
;--------------------------------------------------------------------------
!#VRv84:C35;
;----------------------------------------------------------------------
!?BA0&amp;1000;
!!IF:Wv84;
!!VRw5&w5=0:S1;
!!VRw5:+1;
!!BA:H0/?v9555;
!!BA:H1/?v9560;
!?BF&1000;
!!DO7055/0/20/1&v9555=v84:P;
!!DO7055/21/41/1&v9560=v84:P;
!!DO7056/21/41/1&v9555=v84:P;
!!DO7056/0/21/1&v9560=v84:P;
;---------------------------------------------------------
!?FU7055;
!!HEv84:E?y21/?y22;
!!BMx16:T?y-30;
!!FU&y-30=145:E;
!!FU&y-30=146:E;
!!FU&y-30=147:E;
!!FU&y-30=148:E;
!!FU&y-30=149:E;
!!BMx16:H?y-31;
!!VRy-31::20;
!!VRy-32:Sy-31 *w5;
!!VRy-32&y-32=0:S1;
!!BMx16:Hdy-32;
!!BMx16:A?y-33;
!!VRy-33::50;
!!VRy-34:Sy-33 *w5;
!!VRy-34&y-34=0:S1;
!!BMx16:Ady-34;
!!BMx16:D?y-35;
!!VRy-35::50;
!!VRy-36:Sy-35 *w5;
!!VRy-36&y-36=0:S1;
!!BMx16:Ddy-36;
!!BMx16:U1/?y-37;
!!VRy-37::50;
!!VRy-38:Sy-37 *w5;
!!VRy-38&y-38=0:S1;
!!BMx16:U1/dy-38;
!!BMx16:U2/?y-39;
!!VRy-39::50;
!!VRy-40:Sy-39 *w5;
!!VRy-40&y-40=0:S1;
!!BMx16:U2/dy-40;
!!VRy23&y22<11:S0;
!!VRy23&y22>10/y22<21:S1;
!!VRy23&y22>20/y22<31:S2;
!!VRy23&y22>30/y22<41:S3;
!!VRy23&y22>40/y22<51:S4;
!!VRy23&y22>50:S5;
!!BMx16:Sdy23;
!!BMx16:M27/3/2 M46/3/2;
!?FU7056;
!!BMx16:S?y32;
!!FU&y32=0:E;
!!VRy33&y32<8:S-1;
!!VRy33&y32>7/y32<15:S-2;
!!VRy33&y32>14/y32<20:S-3;
!!VRy33&y32>=20:S-4;
!!BMx16:Sdy33;
!!BMx16:M52/3/2 M50/3/2;
;------------------------------END--------------------------------
把所有中文的都去掉了
还有哪里不对，请指教下

laoguier

哪个地图，我试验一下？

skyx7c3

我玩的是人在清华

laoguier

原帖由 skyx7c3 于 2008-8-30 11:26 发表
我玩的是人在清华

试了一下有效果

laoguier

可能是变量冲突了

skyx7c3

我前面用了个修改兵种的事件

skyx7c3

还有个英雄全技能的
那么我上面写的事件内容是没错了吧？

skyx7c3

是不是用了你这个事件就不能用那个新英雄的ERM了啊？

laoguier

原帖由 skyx7c3 于 2008-8-30 13:16 发表
还有个英雄全技能的
那么我上面写的事件内容是没错了吧？

内容没错，我复制你的

laoguier

原帖由 skyx7c3 于 2008-8-30 13:19 发表
是不是用了你这个事件就不能用那个新英雄的ERM了啊？

你把w5改一下吧，w1-w49随便选择一个，可能是变量冲突
我再考虑怎么修改一下

skyx7c3

哦
我去试试看

skyx7c3

刚试了下
该了W5
这下可以了
估计问题就是你说的变量冲突
谢谢LZ了

skyx7c3

另外我还想问下这个是英雄全技能的事件么？
怎么我在“人在清华”这个图里就可以用
搬到其他图就无法WOG化了呢？
ZVSE
!?GE999;
!!HE35:S0/3;
!!HE35:S1/3;
!!HE35:S2/3;
!!HE35:S3/3;
!!HE35:S4/3;
!!HE35:S5/3;
!!HE35:S6/3;
!!HE35:S7/3;
!!HE35:S8/3;
!!HE35:S9/3;
!!HE35:S10/3;
!!HE35:S11/3;
!!HE35:S12/3;
!!HE35:S13/3;
!!HE35:S14/3;
!!HE35:S15/3;
!!HE35:S16/3;
!!HE35:S17/3;
!!HE35:S18/3;
!!HE35:S19/3;
!!HE35:S20/3;
!!HE35:S21/3;
!!HE35:S22/3;
!!HE35:S23/3;
!!HE35:S24/3;
!!HE35:S25/3;
!!HE35:S26/3;
!!HE35:S27/3;

laoguier

原帖由 skyx7c3 于 2008-8-30 16:02 发表
另外我还想问下这个是英雄全技能的事件么？
怎么我在“人在清华”这个图里就可以用
搬到其他图就无法WOG化了呢？
ZVSE
!?GE999;
!!HE35:S0/3;
!!HE35:S1/3;
!!HE35:S2/3;
!!HE35:S3/3;
!!HE35:S4/3;
!!HE3 ...

以上只是针对35号英雄吧，其它地图用的话，改英雄编号应该可以吧，没有试验过

skyx7c3

我改了编号但是还是不行

daneric

我记得这个好像有人发过一个全特长英雄什么的