请教界面的按钮位置问题

极道九幽

请问下怎么修改Miser_能量石打包这个ERM的按钮位置，改到英雄天赋边上，现在的情况是和英雄天赋按钮有点叠加，不是完全的叠加，这样不好看，所以想修改下位置

顺便问下怎么做DEF图，要用什么工具

!#VRv6460:C0/0/0/0/0/0/0/0;   国库能量石清0
********************************************************************************



********************************************************************************
*英雄界面下，鼠标点击能量石打包图标*
!?CM2;         英雄界面下，点击鼠标触发
!!CM:F?y-1 I?y-2;          y-1=点击的按键   y-2=点击位置
!!SN:L^Era.dll^/?y-6 Ay-6/^GetButtonID^/?y-7;         加载定制图标库
!!SN:Ey-7/0/^Miser_能量石打包^;                           执行定制图标函数
!!FU&y-2<>v1:E;                                      点击位置不是图标，结束   **v1目测为图标位置ID**
!!FU&y-1<>512/y-1<>0:E;    不是左键和右键点击无效
!!FU&y-1=512:E;      右键点击结束
**左键点击时**
!!DL6461:N^6461.Miser^;    分析DL
!!FU&-1:E;                 分析失败退出
!!FU646004:P;       调整显示元素
!!DL6461:S1;         显示DL
!!UN:R3/-1;  重画
!!FU:E;
********************************************************************************



********************************************************************************
!?DL&v998=6461/v1000=13;   左键点击（按下后抬起）DL6461
**准备**
!!HE-1:N?v22;       取当前英雄ID
!!VRv21&v999>6/v999<61:Sv999-1%10+1;  取能量石ID
!!VRz29&v21=7:S^猫眼石^;              能量石名称
!!VRz29&v21=8:S^红宝石^;
!!VRz29&v21=9:S^蓝宝石^;
!!VRz29&v21=10:S^绿宝石^;
!!FU646003:P0//?v7/?v8/?v9/?v10;  取能量石数量
!!OW:R-1/7/?y1;                 取秘银数

!!if&v999>6/v999<11;   立即使用
  !!IF&vv21<1:M^你的国库当前没有 {%Z29} ！^;
  !!FU&vv21<1:E;    没有能量石退出
  !!IF:V2/0;   标志位2是否成功消耗掉能量石
  !!FU646001:P2;   立即使用
  !!FU&-2:E;      使用失败退出
  !!FU646003:P-1;   成功后国库能量石-1
  !!FU646004:P;       调整显示元素
  !!FU:E;
!!en:;

!!if&v999>16/v999<21;   合成宝石
  !!IF&y1<20:Q1/7/20/1^合成 {%Z29} 需要使用20个 {秘银} ，你的国库当前只有 {%Y1个} ！^;
  !!FU&y1<20:E;   秘银不足退出
  !!FU646003:P1/?y-1;   国库能量石+1
  !!FU&y-1=0:E;   增加失败(>255)退出
  !!OW:R-1/7/d-20;  -20秘银
  !!FU646004:P;       调整显示元素
  !!FU:E;
!!en:;

!!if&v999>26/v999<31;   分解宝石
  !!FU646003:P-1/?y-1;   国库能量石-1
  !!FU&y-1=0:E;   失败(<1)退出
  !!OW:R-1/7/d5;  +5秘银
  !!FU646004:P;       调整显示元素
  !!FU:E;
!!en:;

!!if&v999>145/v999<156;   合成宝物
  !!UN:N0/2/v999;        取宝物名称
  !!IF|v7<1/v8<1/v9<1/v10<1:Q1/8/v999/1^合成 {%Z2} 需要 {猫眼石} 、 {红宝石} 、 {蓝宝石} 和 {绿宝石} 各一个，你国库中目前能量石不够！^;
  !!FU|v7<1/v8<1/v9<1/v10<1:E;   宝石不足退出
  !!COv22:A1/v999/0;   给指挥官装备宝物
  !!IF&v1=0:Q1/8/v999/1^合成 {%Z2} 成功， {%Z2} 已经直接装备给你的指挥官！^;
  !!if&v1>0:;   给指挥装备失败
    !!DO646005/19/82/1:P?y-1;   检查英雄背包第一个空格子  y-1=-1没有空格
    !!IF&y-1>18/y-1<83:Q1/8/v999/1^合成 {%Z2} 成功， {%Z2} 已经放入英雄背包内！^;
    !!HEv22&y-1>18/y-1<83:A1/v999/y-1;    给英雄添加宝物
    !!IF&y-1=-1:M^英雄背包已满，无法再添加宝物！^;
    !!FU&y-1=-1:E;   背包满退出
  !!en:;
**扣除能量石**
  !!VRv21:S7;
  !!FU646003:P-1;   国库能量石-1
  !!VRv21:S8;
  !!FU646003:P-1;   国库能量石-1
  !!VRv21:S9;
  !!FU646003:P-1;   国库能量石-1
  !!VRv21:S10;
  !!FU646003:P-1;   国库能量石-1
  !!FU646004:P;       调整显示元素
  !!FU:E;
!!en:;

!!DL6461&v999=30721:C1; 关闭DL
!!FU:E;
********************************************************************************



********************************************************************************
!?DL&v998=6461/v1000=14/v999>0;   DL6461右键按下对话框（暗示文本）
!!if&v999>6/v999<61:;  DL能量石使用部分
  !!VRy1:Sv999-1%10+1;  取能量石ID
  !!VRz-1&y1=7:S^猫眼石^;              能量石名称
  !!VRz-1&y1=8:S^红宝石^;
  !!VRz-1&y1=9:S^蓝宝石^;
  !!VRz-1&y1=10:S^绿宝石^;
**按钮**
  !!VRz1&v999>6/v999<11:S^立即使用国库中的 {%Z-1} 强化英雄的指挥官^;
  !!VRz1&v999>16/v999<21:S^使用20个秘银合成1个 {%Z-1} ^;
  !!VRz1&v999>26/v999<31:S^将国库中的1个 {%Z-1} 分解成5个秘银^;
**资源**
  !!VRz-1|v999=51/v999=61:S^秘银^;      多了秘银
  !!VRz1&v999>36/v999<62:S^国库中的 {%Z-1} 数量^;
!!en:;

!!if&v999>145/v999<256:;  DL合成宝物部分
  !!VRy1:Sv999;    宝物ID
  !!VRy1&y1>200:-100;   图标ID修正
  !!UN:N0/-1/y1;        取宝物名称
  !!VRz1&v999>200:S^{%Z-1}^;     图标
  !!VRz1&v999<200:S^使用国库中的4种能量石各1个合成宝物 {%Z-1} ^;
!!en:;

!!VRz1&v999=900:S^国库中的能量石^;
!!VRz1&v999=901:S^使用国库中的4种能量石各1个合成1个指挥官宝物^;
!!VRz1&v999=902:S^信息提示框^;
!!VRz1&v999=30721:S^退出“国库中的能量石”界面^;
!!IF:M/4/z1;  显示暗示文本
!!FU:E;
********************************************************************************



********************************************************************************
!?OB101&1000;      人类访问宝箱时（能量石大类属于宝箱）
!!VRv7185&v7185=-1:S1;   防后面漏写指挥官加强恢复导致出错
!!OB998:U?v21;         取宝箱子类型（7～10是能量石）
!!FU|v21<7/v21>10:E;    不是能量石退出
!!VRv23:Cv998/v999/v1000;  暂存能量石位置（别的触发器会更新v998~v1000）
!!HE-1:N?v22;       取当前英雄ID
!!DL6460:N^6460.Miser^;    分析DL
!!FU&-1:E;           失败退出
**宝石图标**
!!VRy-1:Sv21-7;  索引
!!DL6460:A9/4/y-1/1;
**定义文本**
!!VRz21:S^立即使用能量石强化当前英雄的指挥官^;
!!VRz22:S^将能量石打包到国库以便你所有英雄随时使用（消耗1秘银）^;
!!VRz23:S^将能量石分解成5个秘银^;
!!VRz24:S^将能量石放回原处^;
**z25和z29**
!!VRz29&v21=7:S^猫眼石^;
!!VRz29&v21=8:S^红宝石^;
!!VRz29&v21=9:S^蓝宝石^;
!!VRz29&v21=10:S^绿宝石^;
!!VRz25:S^你发现了一个%Z29^;
**z26**
!!FU646001:P0;   检查宝石直接使用效果
**z27-z28**文本和资源框，不定义

***z26显示文本***
!!DL6460:A5/3/z25/1;    大标题
!!DL6460:A6/3/z26/1;    能量石作用
***暗示文本***
!!DL6460:H1/z21;
!!DL6460:H2/z22;
!!DL6460:H3/z23;
!!DL6460:H4/z24;
!!DL6460:H5/z25;
!!DL6460:H6/z26;
!!DL6460:H9/z29;
!!IF:V2/0;   标志位2是否成功消耗掉能量石
!!IF:V3/0;   标志位3是否是原版使用能量石  =0表示Miser版本使用能量石
!!DL6460:S1;         显示DL
**DL关闭后**
!!FU&3:E;    原版使用能量石退出（不处理，使用原版提示和消耗）
**Miser版本**
!!VRv7185&v7185=1:S-1;   暂时屏蔽指挥官加强
**没消耗能量石**
!!OB23&-2:T-101;   如果没消耗掉能量石 能量石主类型转-101（屏蔽原版）
!!FU&-2:E;   没消耗能量石退出
**如果消耗掉**
!!OB23:U6;      能量石类型改为6 (酒桶，宝石无作用直接从地图上消失)
!!FU:E;
********************************************************************************



********************************************************************************
!$OB101;      访问宝箱后
!!OB998:T?y1;
!!OB998&y1=-101:T101;   恢复能量石主类型
!!VRv7185&v7185=-1:S1;  恢复指挥官加强
!!FU:E;
********************************************************************************



********************************************************************************
!?DL&v998=6460/v1000=13/v999>0/v999<5;   左键点击（按下后抬起）对话框6460
!!FU646001&v999=1:P1;   立即使用
!!FU&v999=1/-2:E;   使用失败退出(不关DL)
!!if&v999=2:;  打包国库
  !!OW:R-1/7/?y1;  取当前玩家秘银数
  !!IF&y1<1:Q1/7/1/1^打包%Z29需要消耗 {1个秘银}，
  你目前没有秘银！^;
  !!FU&y1<1:E;    没秘银退出(不关DL)
  !!FU646003:P1/?y2;   国库能量石+1     y2=是否成功 >255个失败
  !!FU&y2=0:E;    失败退出
  !!OW:R-1/7/d-1;  秘银-1;
  !!IF:V2/1;   使用成功
!!en:;
!!if&v999=3:;  分解秘银
  !!OW:R-1/7/d5;  +5秘银
  !!IF:V2/1;   使用成功
!!en:;
!!DL6460:C1; 使用成功关闭DL
!!FU:E;
********************************************************************************



********************************************************************************
!?DL&v998=6460/v1000=14/v999>0/v999<10;   DL6460右键按下对话框（暗示文本）
!!FU&v999>6/v999<9:E;  不显示的
!!VRy1:Sv999+20;   暗示文本脚码
!!IF:M/4/zy1;  显示暗示文本
!!FU:E;
********************************************************************************



********************************************************************************
!?FU646001;  使用能量石 需要v21宝石ID v22=英雄ID   x1=0只输出文本 =1DL6460使用宝石 =2DL6461使用宝石
!!COv22:D?y1 E?y2;  y1=是否死亡  y2=是否支持
!!VRz26&y2=0:S^指挥官被禁用，能量石对指挥官无效！^;      宝石作用文本
!!IF&y2=0/x1>0:M^%Z26^;
!!FU&y2=0:E;
!!VRz26&y1=1:S^指挥官死亡，能量石对指挥官无效！^;
!!IF&y1=1/x1>0:M^%Z26^;
!!FU&y1=1:E;
!!if&v7185=0:;   普通模式
  !!VRz26&v21=7:S^猫眼石可以使指挥官 {魔力+1} ^;
  !!VRz26&v21=8:S^红宝石可以使指挥官 {攻击力+2} ^;
  !!VRz26&v21=9:S^蓝宝石可以使指挥官 {防御力+2} ^;
  !!VRz26&v21=10:S^绿宝石可以使指挥官 {速度+1} ^;
  !!IF:V2/1;   使用成功
  !!IF:V3/1;   原版使用能量石
  !!FU&x1<2:E;    非DL6461使用宝石退出
**DL6461使用**
**显示文本**
  !!IF&v21=7:M^你使用了一个库存的 {猫眼石}，
  你的指挥官 {魔力+1} ！^;
  !!IF&v21=8:M^你使用了一个库存的 {红宝石}，
  你的指挥官 {攻击力+2} ！^;
  !!IF&v21=9:M^你使用了一个库存的 {蓝宝石}，
  你的指挥官 {防御力+2} ！^;
  !!IF&v21=10:M^你使用了一个库存的 {绿宝石}，
  你的指挥官 {速度+1} ！^;
**DL6461增加属性**
  !!COv22&v21=7:P4/d1;
  !!COv22&v21=8:P0/d2;
  !!COv22&v21=9:P1/d2;
  !!COv22&v21=10:P5/d1;
  !!IF:V2/1;   使用成功
  !!FU:E;
!!en:;   普通模式结束
!!if&v7185=1:;   指挥官加强模式
  !!if&v21=7:;  猫眼石
    !!COv22:B0/?y3;   取已有特技数位
    !!VRy3:&32767;   防别的ERM占用其它数位
    !!VRz26&y3<32767:S^猫眼石可以使指挥官获得一个特殊技能^;   特技没学满
    !!VRz26&y3=32767:S^指挥官特殊技能已学满，猫眼石对指挥官无效！^;   特技学满
    !!FU&x1=0:E;    只输出文本退出
    !!IF&y3=32767:M^%Z26^;   学满提示
    !!FU&y3=32767:E;         学满退出
    !!DO646002/1/2/0:P;    猫眼石学习特技
    !!IF:V2/1;   使用成功
    !!FU:E;
  !!en:;
  !!if&v21=8:;  红宝石
    !!COv22:S0/?y4 S3/?y5;   取指挥官攻击等级和伤害等级
    !!VRz26&y4>5:S^红宝石可以使指挥官 {伤害技能+1级！}^;
    !!VRz26&y4<5:S^红宝石可以使指挥官 {攻击技能+1级！}^;
    !!VRz26&y4=y5:S^红宝石可以使指挥官 {攻击技能或伤害技能+1级！}^;
    !!VRz26&y4=5/y5=5:S^指挥官 {攻击和伤害技能} 已学满，红宝石对指挥官无效！^;
    !!FU&x1=0:E;    只输出文本退出
    !!IF&y4=5/y5=5:M^%Z26^;   学满提示
    !!FU&y4=5/y5=5:E;         学满退出
    !!COv22&y4>y5:S3/d1;    **直接升级低级别特技**
    !!COv22&y4<y5:S0/d1;
    !!IF&y4>y5:M^红宝石使指挥官 {伤害技能+1级！}^;
    !!IF&y4<y5:M^红宝石使指挥官 {攻击技能+1级！}^;
    !!if&y4=y5:;    级别相同
      !!IF:Q1^你想要提高指挥官的什么技能等级？

      确定={ 伤害 }    取消={ 攻击 }^;
      !!COv22&1:S3/d1;
      !!COv22&-1:S0/d1;
    !!en:;
    !!IF:V2/1;   使用成功
    !!FU:E;
  !!en:;
  !!if&v21=9:;  蓝宝石
    !!COv22:S1/?y4 S2/?y5;   取指挥官防御等级和生命等级
    !!VRz26&y4>5:S^蓝宝石可以使指挥官 {生命技能+1级！}^;
    !!VRz26&y4<5:S^蓝宝石可以使指挥官 {防御技能+1级！}^;
    !!VRz26&y4=y5:S^蓝宝石可以使指挥官 {生命技能或防御技能+1级！}^;
    !!VRz26&y4=5/y5=5:S^指挥官 {生命和防御技能} 已学满，蓝宝石对指挥官无效！^;
    !!FU&x1=0:E;    只输出文本退出
    !!IF&y4=5/y5=5:M^%Z26^;   学满提示
    !!FU&y4=5/y5=5:E;         学满退出
    !!COv22&y4>y5:S2/d1;    **直接升级低级别特技**
    !!COv22&y4<y5:S1/d1;
    !!IF&y4>y5:M^蓝宝石使指挥官 {生命技能+1级！}^;
    !!IF&y4<y5:M^蓝宝石使指挥官 {防御技能+1级！}^;
    !!if&y4=y5:;    级别相同
      !!IF:Q1^你想要提高指挥官的什么技能等级？

      确定={ 生命 }    取消={ 防御 }^;
      !!COv22&1:S2/d1;
      !!COv22&-1:S1/d1;
    !!en:;
    !!IF:V2/1;   使用成功
    !!FU:E;
  !!en:;
  !!if&v21=10:;  绿宝石
    !!COv22:S4/?y4 S5/?y5;   取指挥官魔力和速度等级
    !!VRz26&y4>5:S^绿宝石可以使指挥官 {速度技能+1级！}^;
    !!VRz26&y4<5:S^绿宝石可以使指挥官 {魔力技能+1级！}^;
    !!VRz26&y4=y5:S^绿宝石可以使指挥官 {魔力技能或速度技能+1级！}^;
    !!VRz26&y4=5/y5=5:S^指挥官 {魔力和速度技能} 已学满，绿宝石对指挥官无效！^;
    !!FU&x1=0:E;    只输出文本退出
    !!IF&y4=5/y5=5:M^%Z26^;   学满提示
    !!FU&y4=5/y5=5:E;         学满退出
    !!COv22&y4>y5:S5/d1;    **直接升级低级别特技**
    !!COv22&y4<y5:S4/d1;
    !!IF&y4>y5:M^绿宝石使指挥官 {速度技能+1级！}^;
    !!IF&y4<y5:M^绿宝石使指挥官 {魔力技能+1级！}^;
    !!if&y4=y5:;    级别相同
      !!IF:Q1^你想要提高指挥官的什么技能等级？

      确定={ 魔力 }    取消={ 速度 }^;
      !!COv22&1:S4/d1;
      !!COv22&-1:S5/d1;
    !!en:;
    !!IF:V2/1;   使用成功
    !!FU:E;
  !!en:;
  !!FU:E;
!!en:;   指挥官加强模式结束
!!FU:E;
********************************************************************************



********************************************************************************
!?FU646002;   猫眼石学习特技
!!VRz10:S^
请选择你希望指挥官学习的特技
第 %X16 页，共 2 页
^;                           标题
!!COv22&x16=1:B1/0/?y1 B1/1/?y2 B1/2/?y3 B1/3/?y4 B1/4/?y5 B1/5/?y6 B1/6/?y7 B1/7/?y8;  取前8个特技学习情况
!!COv22&x16=2:B1/8/?y1 B1/9/?y2 B1/10/?y3 B1/11/?y4 B1/12/?y5 B1/13/?y6 B1/14/?y7;  取后7个特技学习情况
!!VRz1:S^^;   空文本
!!VRz2:S^^;
!!VRz3:S^^;
!!VRz4:S^^;
!!VRz5:S^^;
!!VRz6:S^^;
!!VRz7:S^^;
!!VRz8:S^^;
!!if&x16=1:;     第1页 前8个特技
  !!VRz1&y1=0:S^减少目标防御50%^;                   没学的特技名称
  !!VRz2&y2=0:S^恐惧^;
  !!VRz3&y3=0:S^永远最大伤害^;
  !!VRz4&y4=0:S^敌人无法反击^;
  !!VRz5&y5=0:S^射击^;
  !!VRz6&y6=0:S^无限反击^;
  !!VRz7&y7=0:S^环击^;
  !!VRz8&y8=0:S^永久火盾^;
  !!VRz8&y8=0/v7185=1:S^魔镜^;            指挥官强化
!!en:;
!!if&x16=2:;     第2页 后7个特技
  !!VRz1&y1=0:S^格挡^;                   没学的特技名称
  !!VRz2&y2=0:S^双击^;
  !!VRz3&y3=0:S^麻痹^;
  !!VRz4&y4=0:S^再生^;
  !!VRz5&y5=0:S^死亡凝视^;
  !!VRz5&y5=0/v7185=1:S^中毒^;         指挥官强化
  !!VRz6&y6=0:S^冲锋^;
  !!VRz7&y7=0:S^无视障碍（飞行）^;
!!en:;
!!VRy9&x16=1:S2;   另一页数
!!VRy9&x16=2:S1;
!!VRz9:S^切换到 第 %Y9 页^;
!!IFG1/2/256/10/1/2/3/4/5/6/7/8/9;  显示选框，输出v2
!!VRx16&v2=256:Sy9;   切换到另一页
!!FU&v2=256:E;
!!VRv2&x16=2:*256;  第二页的数位
!!COv22:B0/?y10;   取已有特技数位
!!VRy10:|v2;      新特技数位
!!COv22:B0/y10;    给新特技
!!VRx16:S3;     停止循环
!!FU:E;
********************************************************************************



********************************************************************************
!?FU646003;   国库能量石+-1(+-多个需要年前判定数量0～255)    类型v21 名称z29   x1=0只计算数量 -1减少一个 1增加一个  输出x2=1成功=0失败 x3~x6=数量
!!OW:C?y1;  取当前玩家旗帜
!!VRy2:Sy1+6460;   对应国库存储v变量脚码
**计算数量**
!!VRx3:Svy2&255;     猫眼石数量
!!VRx4:Svy2&65280:256;     红宝石数量
!!VRx5:Svy2&16711680:65536;     蓝宝石数量
!!VRx6:Svy2&2130706432:16777216;     绿宝石数量 <128
!!VRx6&vy2<0:+128;                         负数>=128
!!FU&x1=0:E;  计算数量结束
**增加/减少**
!!VRy3:Sv21-4;  脚码换算
!!VRxy3:+x1;    增加/减少一个
!!IF&xy3<0:M^你的国库当前没有 {%Z29} ！^;
!!IF&xy3>255:M^国库 {%Z29} 上限为255个，
你的 {%Z29} 已达上限，无法再增加！^;
!!VRx2:S1;       预设成功
!!VRx2|xy3<0/xy3>255:S0;   超出范围失败
!!VRxy3&xy3<0:S0;       小修正
!!VRxy3&xy3>255:S255;   大修正
**变量合成**
!!VRvy2&x6<128:Sx6*256|x5*256|x4*256+x3;   正数
!!VRvy2&x6>127:Sx6-128*256|x5*256|x4*256|x3|-2147483648;   负数
!!FU:E;
********************************************************************************



********************************************************************************
!?FU646004;       调整DL6461显示元素
!!FU646003:P0//?y1/?y2/?y3/?y4;  取能量石数量
!!OW:R-1/7/?y5;                 取秘银数

!!VRz-1:S^%Y1^;         数字转文本
!!VRz-2:S^%Y2^;
!!VRz-3:S^%Y3^;
!!VRz-4:S^%Y4^;
!!VRz-5:S^%Y5^;

!!DL6461:A57/3/z-1/1;     刷新数量
!!DL6461:A58/3/z-2/1;
!!DL6461:A59/3/z-3/1;
!!DL6461:A60/3/z-4/1;
!!DL6461:A61/3/z-5/1;
!!FU:E;
********************************************************************************



********************************************************************************
!?FU646005;      检查英雄背包是否有空位  x1=第一个空位置  x1=-1没有空位
!!VRx1:S-1;
!!HEv22:A1/?y1/x16;  检查宝物格是否为空
!!VRx1&y1=-1:Sx16;   存第一个空位置
!!VRx16&y1=-1:S100;   退出循环
!!FU:E;
********************************************************************************

贤知有您

用txt编辑器打开 Miser_能量石打包.btn 文件，其内容就是界面按钮的参数。

Hero;Miser_能量石打包;646总按钮.def;270;53;30;30;欢迎使用Miser_能量石打包;左键单击进入国库中的能量石界面;

其中270;53;就是屏幕上的位置，你改动一下就行了。（希望记忆没错吧，反正4个参数中2个坐标，2个def尺寸）

极道九幽

贤知有您 发表于 2018-1-2 22:31
用txt编辑器打开 Miser_能量石打包.btn 文件，其内容就是界面按钮的参数。

Hero;Miser_能量石打包;646总 ...

谢谢，已经修改成功了