新宝物制造者V1.1

hdwjf

2017/1/21 新宝物制造者1.11
修正
1、战后加移动，确定其上限的是幸运而不是士气

2017/1/19 新宝物制造者1.1
新增
1、菜单加入帮助信息，点击显示7-127号宝物的等级，和当前宝物可炼化成的宝物
改进
2、融合后功防属性小于0 则为0 魔力和知识属性小于1则为1
3、访问宝物制造者后刷新英雄界面
4、如对宝物没有改变则恢复缺省右键的提示信息
修正
5、战后影响士气和幸运的宝物加入龙眼指环
6、融合铠甲类加的不是魔力而是知识
7、融合泰坦之剑和守护神盾参数+12 -3

2017/1/15 新宝物制造者1.0
1、远程访问宝物制造者                                                                                                                 
2、炼化宝物                                                                                                                                   
3、融合宝物与英雄（加指数宝物）                                                                                                
4、售出宝物                                                                                                                                   
5、战后根据英雄幸运（宝物有效）发现战利品 概率5%×（幸运+1）最高50%                             
6、战后根据英雄士气（宝物有效）加移动 50×（士气+1）最高300                                             
7、英雄界面右键点击背囊前5格触发     

适用于封神的脚本在11楼，封神没有宝物制造者，都不知道该叫什麽名，

大骷髅

弄来研究研究，到底是啥

xuzhouhudajz

学习下！

8899511

出错了 宝物属性全没有了！！

hdwjf

8899511 发表于 2017-1-20 02:45
出错了 宝物属性全没有了！！

说一说是什么情况？

121033

这个封神能用吗？

hdwjf

封神的52号脚本改过，不是宝物制造者了，如果嫁接过去是无法访问宝物造者，其他的功能到可以。

云海茫茫

没试过....有没有试过的贴效果.

hdwjf

有朋友问，能不能在封神中使用，封神的52号脚本改过，没有宝物制造者，其他功能应该可以，
把以下脚本，随便起个名字，放入封神目录下的Data\S\目录下就可以。
ZVSE
!?CM2&999;
!!HE-1:N?x2; !!FU|x2<0/x2>155:E;
!!CM:I?y11 F?y12;                  读取鼠标控制点y11  检查鼠标动作 y12
!!CM&y11>39/y11<45/y12=512:R0;     40-44背囊1-5格  禁用右键512的标准反应
!!CM|y11>44/y11<40/y12<>512:R1;
!!FU|y11>44/y11<40/y12<>512:E;
!!VRy11:Sy11-21;
!!HEx2:A1/?y1/y11;
!!VRy2:Sv4528;
!!VRv4528:S-1;
!!if|y1<7/y1>170:;
  *!FU4523:P369169;
!!el:;
  !!DO4523/1/64/1:P369168/x2/y1;
!!en:;
!!VRy3:Sv4528;
!!VRv4528:Sy2;
!!CM&y3=-1:R1;

!?FU4523&x1=369169;
!!FU&x1<>369169:E;
!!VRv160:S1;
!!FU168:P;
!!UN:R3/-1;

!?FU4523&x1=369168;
!!FU&x1<>369168:E;
!!VRz-2:S^炼化^;
!!VRz-3:S^融合^;
!!VRz-4:S^出售^;
!!VRz-5:S^帮助^;
!!VRz-6:S^退出^;
!!UN:Ax3/3/?y2;
!!UN:N0/z-8/x3;
!!VRy3&y2=2:S1;
!!VRy3&y2=4:S2;
!!VRy3&y2=8:S3;
!!VRy3&y2=16:S4;
!!VRy3&y2>16:S5;
!!VRz-1:S^%Y3级宝物%Z-8^;
!!VRy2:Sv4522;
!!IF:G1/4522/16/-1/-2/-3/-4/-5/-6/;
!!VRy3:Sv4522;
!!VRv4522:Sy2;
!!if&y3=1:;
  !!DO4522/1/64/1:P369170/x2/x3;
  !!VRx16:S1000;
!!en:;
!!if&y3=2:;
  !!FU4522&y3=2:P369168/x2/x3;
  !!VRx16:S1000;
!!en:;
!!if&y3=4:;
  !!FU4522&y3=4:P369171/x2/x3;
  !!VRx16:S1000;
!!en:;
!!if&y3=8:;
  !!FU4522:P369173/x2/x3;
  !!VRx16:S1;
!!en:;
!!if&y3=16:;
  !!VRx16:S1000;
!!en:;
!!UN:R3/-1;


!?FU4522&x1=369173;
!!FU&x1<>369173:E;
!!UN:Ax3/3/?y2;
!!UN:N0/z-7/x3;
!!VRy3&y2=2:S1;
!!VRy3&y2=4:S2;
!!VRy3&y2=8:S3;
!!VRy3&y2=16:S4;
!!FU|y2<2/y2>16:E;
!!VRz-1:Sz300;
!!VRz-2:Sz301;
!!VRz-3:Sz302;
!!VRz-4:Sz303;
!!VRz-5:Sz304;
!!VRz300:S^
所有宝物(7-127)
一级宝物:^;
!!VRz301:S^
二级宝物:^;
!!VRz302:S^
三级宝物:^;
!!VRz303:S^
四级宝物:^;
!!VRz304:S^%Y3级宝物%Z-7可炼化为:^;
!!VRy23:Sv4523;
!!VRy24:Sv4524;
!!VRy25:Sv4525;
!!VRy26:Sv4526;
!!VRy27:Sv4527;
!!VRv4523:S0;
!!VRv4524:S0;
!!VRv4525:S0;
!!VRv4526:S0;
!!VRv4527:S0;
!!DO4524/7/127/1:P369168/x2/x3;
!!IF:M^%Z304
%Z300
%Z301
%Z302
%Z303^;
!!VRv4523:Sy23;
!!VRv4524:Sy24;
!!VRv4525:Sy25;
!!VRv4526:Sy26;
!!VRv4527:Sy27;
!!VRz300:Sz-1;
!!VRz301:Sz-2;
!!VRz302:Sz-3;
!!VRz303:Sz-4;
!!VRz304:Sz-5;

!?FU4524&x1=369168;
!!FU&x1<>369168:E;
!!UN:Ax16/3/?y1;
!!UN:N0/z-7/x16;
!!VRz-7:M4/?y6;
!!UN:Ax3/3/?y8;
!!UN:Ax16/?y9;
!!VRy10:Sy8-y1;
!!VRy3&y1=2:S300;
!!VRy3&y1=4:S301;
!!VRy3&y1=8:S302;
!!VRy3&y1=16:S303;
!!VRz-8:Szy3;
!!VRy5:Sy3+4223;
!!VRy4:S4;
!!VRz-10:S^　^;
!!VRy7:Sy6%2;
!!VRy6&y7=1:-1;
!!VRz-9&y7=1:M1/z-7/0/y6;
!!VRz-9&y7=0:Sz-7;
!!VRy6:-12*-1:2;
!!VRz-9&y6>3:+z-10;
!!VRz-9&y6>2:+z-10;
!!VRz-9&y6>1:+z-10;
!!VRz-9&y6>0:+z-10;
!!VRz-9:M4/?y7;
!!VRy2:Svy5%y4;
!!VRz-8&y2<>0:S^%Z-8%Z-9^;
!!VRz-8&y2=0:S^%Z-8
%Z-9^;
!!VRy2:Sv4527%y4;
!!VRz304&y2<>0/y9=0/y10=0:S^%Z304%Z-9^;
!!VRz304&y2=0/y9=0/y10=0:S^%Z304
%Z-9^;
!!VRvy5:+1;
!!VRzy3:Sz-8;
!!VRv4527&y9=0/y10=0:+1;

!?FU4522&x1=369171;
!!FU&x1<>369171:E;
!!UN:Ax3/1/?y1;
!!IF&y1=0:M^价格为零,无法出售^;
!!FU&y1=0:E;
!!VRy3:S0;
!!VRy4:S0;
!!VRy3&301:S1;
!!IF:Q301/8/x3/2^是否将宝物出售,以获得%Y1点经验...？^;
!!VRy4&301:S1;
!!IF:V301/y3;
!!FU&y4=0:E;
!!HEx2:Edy1;
!!HEx2:A3/x3/1/0;
!!VRv4528:S1;


!?FU4522&x1=369170;
!!FU&x1<>369170:E;
!!UN:Ax3/3/?y1;
!!FU&y1=1:E;
!!UN:J6/y1/?y2;
!!FU|y2<7/y2>170:E;
!!VRy3:Sv301;
!!IF:Q301/8/x3/8/y2/10^宝物炼化...^;
!!VRy4:Sv301;
!!VRv301:Sy3;
!!if&y4=0:;
!!VRx16:S1000;
!!en:;
!!if&y4=1:;
!!VRx16:S1;
!!en:;
!!if&y4=2:;
!!VRy5:S0;
!!VRy6:S0;
!!VRy5&301:S1;
!!IF:Q301/8/y2/2^是否将宝物炼化为...？^;
!!VRy6&301:S1;
!!IF:V301/y5;
!!HEx2&y6=1:A3/x3/1/0;
!!HEx2&y6=1:Ay2;
!!VRx16&y6=1:S1000;
!!VRv4528&y6=1:S1;
!!VRx16&y6=0:S1;
!!en:;

!?FU4522&x1=369168;
!!FU&x1<>369168:E;
*!IF:M^0 x1=%X1 x2=%X2 x3=%X3^;
!!FU|x2<0/x2>155/x3<7/x3>44:E;
!!VRy1:S0;
!!VRy2:S0;
!!VRy1&301:S1;
!!IF:Q301/8/x3/2^是否将该宝物和英雄融合？^;
!!VRy2&301:S1;
!!IF:V301/y1;
!!FU&y2=0:E;
!!VRy1:S0;
!!VRy2:S0;
!!if&x3>6/x3<12:;
!!VRy1:Sx3-5;
!!en:;
!!if&x3=12:;
!!VRy1:S12;
!!VRy2:S-3;
!!en:;
!!if&x3>12/x3<18:;
!!VRy2:Sx3-11;
!!en:;
!!if&x3=18:;
!!VRy2:S12;
!!VRy1:S-3;
!!en:;
!!if&x3>18/x3<24:;
!!VRy3:Sx3-18;
!!en:;
!!if&x3=24:;
!!VRy3:S10;
!!VRy4:S-2;
!!en:;
!!if&x3>24/x3<30:;
!!VRy4:Sx3-24;
!!en:;
!!if&x3=30:;
!!VRy4:S10;
!!VRy3:S-2;
!!en:;
!!if&x3>30/x3<37:;
!!VRy5:Sx3-30;
!!en:;
!!if&x3>36/x3<41:;
!!VRy6:Sx3-36;
!!en:;
!!if&x3>40/x3<45:;
!!VRy7:Sx3-40;
!!en:;
!!HEx2:F?y11/?y12/?y14/?y13;
!!VRy11:Sy11+y1+y5+y6;
!!VRy12:Sy12+y2+y5+y6;
!!VRy13:Sy13+y3+y5+y7;
!!VRy14:Sy14+y4+y5+y7;
!!VRy11&y11<0:S0;
!!VRy12&y12<0:S0;
!!VRy13&y13<1:S1;
!!VRy14&y14<1:S1;
!!IF|y11>99/y12>99/y13>99/y14>99:M^有属性值大于99,请卸掉一些宝物再进行融合^;
!!FU|y11>99/y12>99/y13>99/y14>99:E;
*!IF:M^1 x1=%X1 y1=%Y1 y2=%Y2 y3=%Y3 y4=%Y4 y5=%Y5  y6=%Y6 y7=%Y7^;
!!HEx2:Fy11/y12/y14/y13;
!!HEx2:A3/x3/1/0;
!!VRv4528:S1;

!?BA1&1000;  玩家战斗后触发
!!HE-1:N?x2;
!!OW:C?y20;
!!OW:Iy20/?y21;
!!FU&y21<>0:E;
!!FU4522:P369169/x2;

!?FU4522&x1=369169;
!!FU&x1<>369169:E;
!!HEx2:S9/?y1;                  幸运术等级
!!HEx2:S6/?y15;                 领导术等级
!!HEx2:A2/46/d/?y6;             幸运三叶草
!!HEx2:A2/47/d/?y7;             预言卡
!!HEx2:A2/48/d/?y8;             幸运鸟
!!HEx2:A2/108/d/?y9;            勇气挂件
!!VRy9:Sy9*3;
!!HEx2:A2/125/d/?y10;           战争枷锁
!!VRy10:Sy10*3;
!!HEx2:A2/45/d/?y14;            龙眼指环
!!HEx2:A2/49/d/?y11;            勇气勋章
!!HEx2:A2/50/d/?y12;            勇士勋章
!!HEx2:A2/51/d/?y13;            勇士令
!!VRy1:Sy1+y6+y7+y8+y9+y10+y14+1;    5%+幸运×5%
!!VRy15:Sy15+y11+y12+y13+y9+y14+1;   50+领导×50
!!VRy1&y1>10:S10;                最大50%
!!VRy15&y15>6:S6;                 最大300
!!VRy15:Sy15*50;
!!HEx2:Wdy15;
!!VRy4:Sy1*5;
!!VRy2:S0;
!!VRy2:R99;
!!VRy5:S-1;
!!VRy5&y2<y4:S1;
!!FU&y5<0:E;
!!VRy3&y1=0:S2;
!!VRy3&y1=1:S6;
!!VRy3&y1=2:S14;
!!VRy3&y1=3:S30;
!!UN:J6/y3/?y30;
!!FU&y30<0:E;
!!IF:Q301/8/y30/1^人品爆发，你的部下打扫战场时发现...^;
!!HEx2:Ay30;

westli

这个是虾米东东，仰视中