【求助】关于erm修改英雄特技和增强英雄属性语法错误

mzp1979 · 发表于 2015-7-10 11:07:16

78号脚本
ZVSE
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
ERMS_ScriptDate=10.7(July).2015

!?PI; **地图开始时触发 **************************************************
!!VRz789:S^{英雄技能强化：在防御术上每级均得到5%的额外奖励。}^
**上句引用z789变量来存储文本**
!!UN:G2/3/2/789;  **!!UN:G2/英雄编号/存储变量个数/789变量**
**特长说明(789是Z变量)**

!!HE3:X0/23; **英雄[3 斯尔维亚(骑士)]特长[防御术]**
!!HE3:X6/56/57/159; **设置英雄获得升级生物技能**
!!HE3:S23/3;  **设置英雄获得防御术技能**
**设置英雄获得升级生物和防御术技能**
!!UN:G2/3/3/16; **英雄[3 斯尔维亚(骑士)]特长图片为[防御术]**

!?BA0; 战斗前触发
!!BA:H0/?v9555;  **攻击方英雄编号**
!!BA:H1/?v9560;  **防守方英雄编号**

!?BF;  战场后触发(战斗前)
!!HEv9555&v9555=3:X0/23;
!!HEv9560&v9560=3:X0/23;
**上两句,作为攻防2种情况时改为战斗特长防御**

!?BF&1000;[战场生成后]
**英雄斯尔维亚(骑士)增加己方所有生物速度每1级1,最终得到极限为15**
!!DO20000/0/20/1&v9555=3:P2/v9555/1/1/1/15/-1;
!!DO20000/21/41/1&v9560=3:P2/v9560/1/1/1/15/-1;
**英雄斯尔维亚(骑士)增加己方所有生物弹药每1级10,最终得到极限为999**
!!DO20000/0/20/1&v9555=3:P2/v9555/2/10/1/999/-1;
!!DO20000/21/41/1&v9560=3:P2/v9560/2/10/1/999/-1;
**英雄斯尔维亚(骑士)增加己方所有生物反击次数每1级9,最终得到极限为999**
!!DO20000/0/20/1&v9555=3:P2/v9555/4/9/1/999/-1;
!!DO20000/21/41/1&v9560=3:P2/v9560/4/9/1/999/-1;
**英雄斯尔维亚(骑士)战斗前己方所有生物自带魔法祈祷20回合,等级3,第1级起每1级增强效果**
!!DO20000/0/20/1&v9555=3:P4/v9555/48/20/3/1/-1;
!!DO20000/21/41/1&v9560=3:P4/v9560/48/20/3/1/-1;

!?MR0&1000;  [魔法伤害]
**英雄斯尔维亚(骑士)减弱己方所受的魔法伤害,每1级减弱-5%极限为99%**
!!FU20000&v9555=3:P5/v9555/0/-5/1/99;
!!DO20000&v9560=3:P5/v9560/1/-5/1/99;

!?BA1;  **战斗后触发**
!!HE3:X6/56/57/159; **战斗后还原升级生物特长**

!?GM0;**读取存档时触发 ******************************************************
!!VRz789:S^{英雄技能强化：在防御术上每级均得到5%的额外奖励。}^
**上句引用z789变量来存储文本**
!!UN:G2/3/2/789;  **!!UN:G2/英雄编号/存储变量个数/789变量**
**特长说明(789是Z变量)**

!!HE3:X0/23; **英雄[3 斯尔维亚(骑士)]特长[防御术]**
!!HE3:X6/56/57/159; **设置英雄获得升级生物技能**
!!HE3:S23/3;  **设置英雄获得防御术技能**
**设置英雄获得升级生物和防御术技能**
!!UN:G2/3/3/16; **英雄[3 斯尔维亚(骑士)]特长图片为[防御术]**

!?BA0; 战斗前触发
!!BA:H0/?v9555;  **攻击方英雄编号**
!!BA:H1/?v9560;  **防守方英雄编号**

!?BF;  战场后触发(战斗前)
!!HEv9555&v9555=3:X0/23;
!!HEv9560&v9560=3:X0/23;
**上两句,作为攻防2种情况时改为战斗特长防御**

!?BA1;  **战斗后触发**
!!HE3:X6/56/57/159; **战斗后还原升级生物特长**

79号通用脚本
ZVSE
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
**新增变量:v9600-9601,战斗前左右方生物个数(差)

!?BG0&1000; **攻击前变量准备**
!!VRv1360:C-1/-1/-1/-1/-1/-1/-1/-1/-1/-1/-1/-1/-1/-1/-1;  v1360~v1374
!!VRv1375:C-1/-1/-1/-1/-1/-1/-1/-1/-1/-1/-1/-1/-1/-1/-1;  v1375~v1389
!!BG:A?v1360 E?v1362 N?v1364; [动作类型/目标堆栈/当前堆栈
!!BMv1364&v1364>-1:T?v1370; [本方生物类型]
!!BMv1362&v1362>-1:T?v1375; [敌方生物类型]

!?BA0&1000;[战斗开始时变量准备]
!!BA:H0/?v9555;  [保存进攻方英雄到v9555]
!!BA:H1/?v9560;  [防守方hero到v9560]
!!HEv9555&v9555>=0:E?v9549;  [攻击方英雄战斗前经验v9549]
!!HEv9560&v9560>=0:E?v9551;  [攻击方英雄战斗前经验v9551]
!!BA:M0/0/d/?y21;  [攻击方0-6生物槽的生物个数]
!!BA:M0/1/d/?y22;
!!BA:M0/2/d/?y23;
!!BA:M0/3/d/?y24;
!!BA:M0/4/d/?y25;
!!BA:M0/5/d/?y26;
!!BA:M0/6/d/?y27;
!!BA:M1/0/d/?y28; [防御方0-6生物槽的生物个数]
!!BA:M1/1/d/?y29;
!!BA:M1/2/d/?y30;
!!BA:M1/3/d/?y31;
!!BA:M1/4/d/?y32;
!!BA:M1/5/d/?y33;
!!BA:M1/6/d/?y34;
!!VRv9600:Sy21+y22+y23+y24+y25+y26+y27;  [攻击方总数]
!!VRv9601:Sy28+y29+y30+y31+y32+y33+y34;  [防御方总数]

!?BA1&1000;[变量准备]
!!HEv9555&v9555>=0:E?v9550;  [攻击方英雄战斗后经验v9550]
!!HEv9560&v9560>=0:E?v9552;  [攻击方英雄战斗后经验v9552]
!!BA:M0/0/d/?y21;  [攻击方0-6生物槽的生物个数]
!!BA:M0/1/d/?y22;
!!BA:M0/2/d/?y23;
!!BA:M0/3/d/?y24;
!!BA:M0/4/d/?y25;
!!BA:M0/5/d/?y26;
!!BA:M0/6/d/?y27;
!!BA:M1/0/d/?y28; [防御方0-6生物槽的生物个数]
!!BA:M1/1/d/?y29;
!!BA:M1/2/d/?y30;
!!BA:M1/3/d/?y31;
!!BA:M1/4/d/?y32;
!!BA:M1/5/d/?y33;
!!BA:M1/6/d/?y34;
!!VRy40:Sy21+y22+y23+y24+y25+y26+y27;
!!VRy41:Sy28+y29+y30+y31+y32+y33+y34;
!!VRv9600:-y40;  [攻击方总数差额]
!!VRv9601:-y41;  [防御方总数差额]

!?FU20000&x1=0;    [判断生物类别]  符合条件则返回临时V4=999
!!VRv4:S0;
!!MA:Ox3/?y50 Lx3/?y51;
!!VRy50:+1000;
!!VRy51:+2000;
!!VRv4&x4>=0/x4<=196/x4=x3:S999;
!!FU&x4>=0/x4<=196:E;
!!VRv4&x4>=999/x4<=1008/x4=y50:S999;
!!FU&x4>=999/x4<=1008:E;
!!VRv4&x4>=2000/x4<=2006/x4=y51:S999;
!!FU&x4>=2000/x4<=2006:E;
!!BMx2:F?j;  [获取堆栈标志位]
!!VRy61:Sj&1;
!!VRy62:Sj&2;
!!VRy63:Sj&4;
!!VRy64:Sj&16;
!!VRy65:Sj&262144;
!!VRy66:Sj&2147483648;
!!VRv4&x4=3001/y61<>0:S999; [双格]
!!VRv4&x4=3002/y62<>0:S999; [飞行]
!!VRv4&x4=3003/y63<>0:S999; [射击]
!!VRv4&x4=3004/y64<>0:S999; [生命]
!!VRv4&x4=3005/y65<>0:S999; [亡灵]
!!VRv4&x4=3006/y66<>0:S999; [龙属性]

!?FU20000&x1=1;    [增减生物的攻/防/命/伤(2) 通用函数]
!!BMx16:T?y10;
!!FU&y10<0:E;
!!FU&y10>144/y10<150:E; [排除攻城武器]
!!VRv4:S0;
!!FU20000&x7>-1:P0/x16/y10/x7; [返回v4]
!!FU&x7>-1/v4<>999:E;
!!HEx2:E?y5/?y6;
!!VRy4:Sx4;
!!VRy4&y4<0:*-1; [为负时变正数]
!!VRy7&x5=0:Sy4; [固定百分比]
!!VRy7&x5>0:Sy6:x5*y4;  [等级/级别*增加百分比]
!!VRy8&x4>0:Sy7+100; [增加效果]
!!VRy8&x4>0/x5>0/x6>0/y8>x6:Sx6;  [大于极限取极限]
!!VRy8&x4<0:S100-y7; [削弱效果]
!!VRy8&x4<0/x5>0/x6>0/y8<x6:Sx6;  [小于极限取极限]
!!VRy8&y8<1:S1;       [无限制的最低极限为1%]
!!BMx16:A?y14 D?y15 H?y16 U1/?y17 U2/?y18; [获取原信息]
!!VRy14:*y8:100;
!!VRy14&y14<1:S1; [保证最低为1]
!!VRy15:*y8:100;
!!VRy15&y15<1:S1;
!!VRy16:*y8:100;
!!VRy16&y16<1:S1;
!!VRy17:*y8:100;
!!VRy17&y17<1:S1;
!!VRy18:*y8:100;
!!VRy18&y18<1:S1;
!!VRj:Sx3;
!!VRy21:Sj&1;
!!VRy22:Sj&2;
!!VRy23:Sj&4;
!!VRy24:Sj&8;
!!BMx16&y21<>0:Ay14;
!!BMx16&y22<>0:Dy15;
!!BMx16&y23<>0:Hy16;
!!BMx16&y24<>0:U1/y17 U2/y18;

!?FU20000&x1=2;    [增减生物速度/弹药/反击次数通用函数]
!!BMx16:T?y10;
!!FU&y10<0:E;
!!FU&y10>144/y10<150:E;
!!VRv4:S0;
!!FU20000&x7>-1:P0/x16/y10/x7; [返回v4]
!!FU&x7>-1/v4<>999:E;
!!HEx2:E?y5/?y6;
!!VRy4:Sx4;
!!VRy7&x5=0:Sy4; [固定数值(正负)]
!!VRy7&x5>0:Sy6:x5*y4;  [等级/级别*固定数值]
!!VRy8&y7<0:Sy7*-1;    [y8是绝对值]
!!BMx16:S?y19 U3/?y20 R?y21; [获取原信息]
!!VRy7&x4>0/x5>0/x6>0/y8>x6:Sx6;  [大于极限取极限]
!!VRy7&x4<0/x5>0/x6>0/y8<x6:S-x6;  [小于极限取极限]
!!VRy19:+y7;
!!VRy19&y19<1:S1; [保证最低为1]
!!VRy20:+y7;
!!VRy20&y20<1:S1;
!!VRy21:+y7;
!!VRy21&y21<1:S1;
!!VRj:Sx3;
!!VRy21:Sj&1;
!!VRy22:Sj&2;
!!VRy23:Sj&4;
!!BMx16&y21<>0:Sy19;
!!BMx16&y22<>0:U3/y20;
!!BMx16&y23<>0:Ry21;

!?FU20000&x1=3;  [增减生物标志,增加生物标志召船术,去除生物标志则为毁船]
!!BMx16:T?y10;
!!FU&y10<0:E;
!!FU&y10>144/y10<150:E; [排除攻城武器]
!!VRv4:S0;
!!FU20000&x6>-1:P0/x16/y10/x6; [返回v4]
!!FU&x6>-1/v4<>999:E;
!!FU|x5<0/x5>100/x3=0:E;  [几率]
!!HEx2:E?y5/?y6; [经验与等级]
!!FU&x4>0/y6<x4:E;
!!VRy97&x5>0:S0 R99;  [需要几率时]
!!FU&x5>0/y97>x5:E;
!!BMx16:F?j;  [获取怪物标志位]
!!VRi:Sx3;
!!VRi&x3<0:Sx3*-1; [转成正数]
!!VRj&x3>0:|i;
!!BMx16&x3>0:Fj;
!!BMx16&x3>0:M0/999/0;  [施法(召船术)]
!!VRj&x3<0:|i;
!!VRj&x3<0:-i;
!!BMx16&x3<0:Fj;
!!BMx16&x3<0:M1/999/0;

!?FU20000&x1=4;  [增加生物自带魔法]
!!BMx16:T?y10;
!!FU&y10<0:E;
!!FU&y10=149:E; [排除箭塔]
!!VRv4:S0;
!!FU20000&x6>-1:P0/x16/y10/x7; [返回v4][fix 007-12-822]
!!FU&x6>-1/v4<>999:E;
!!HEx2:E?y5/?y6;
!!FU&x6>0/y6<x6:E;
!!VRy8:Sx5;       [魔法等级]
!!FU&y8<0:E;
!!VRy7&x6>0:Sy6:x6; [英雄等级/每N个等级]
!!VRy8&x6>0:Sy7;
!!VRy8&y8>3:S3;  [最高3级]
!!BMx16:Mx3/x4/y8;

!?FU20000&x1=5;
!!BG:E?y2;
!!MR:D?y3;
!!FU&y3=0:E;  [非伤害性魔法,直接退出]
!!HEx2:E?y5/?y6;
!!VRy4:Sx4;
!!VRy4&y4<0:*-1; [为负时变正数]
!!VRy7&x5=0:Sy4; [固定百分比]
!!VRy7&x5>0:Sy6:x5*y4;  [等级/级别*增加百分比]
!!VRy8&x4>0:Sy7+100; [增加效果]
!!VRy8&x4>0/x5>0/x6>0/y8>x6:Sx6;  [大于极限取极限]
!!VRy8&x4<0:S100-y7; [削弱效果]
!!VRy8&x4<0/x5>0/x6>0/y8<x6:Sx6;  [小于极限取极限]
!!VRy8&y8<1:S1;       [最低极限为1%]
!!VRy3&x3=0/y2<21:*y8:100;
!!VRy3&x3=1/y2>20:*y8:100;
!!MR:Dy3;

!?FU20000&x1=6;    [战斗前简单召唤]
!!FU|x3<-1/x3>196:E;
!!VRy50:Sx3;
!!FU&y50>144/y50<150:E; [排除攻城武器]
!!VRy50&x3=-1:S150 R8; [随机8级兵]
!!VRy-11:S93;    [召唤的位置93]
!!VRy-12:S-1;
!!VRy-13:S-1;
!!BU:Ey-11/?y-12; [判断召唤位置是否有堆栈]
!!BU:Oy-11/?y-13; [判断是否有障碍物]
!!VRy-11|y-12>-1/y-13>0:S92;
!!BU&y-11=92:Ey-11/?y-12;
!!BU&y-11=92:Oy-11/?y-13;
!!VRy-11|y-12>-1/y-13>0:S94;
!!BU&y-11=94:Ey-11/?y-12;
!!BU&y-11=94:Oy-11/?y-13;
!!FU|y-12>-1/y-13>0:E;
!!VRy14&v9555=x2:S0;
!!VRy14&v9560=x2:S1;
!!FU&x4<1:E;
!!HEx2:E?y5/?y6;
!!VRy7:Sx4;
!!VRy8&x5>0:Sy6:x5;
!!VRy7&x5>0:*y8;  [等级/级别*固定数值]
!!VRy7&x5>0/x6>0/y7>x6:Sx6;  [大于极限取极限]
!!VRy7&y7<1:S1;    [至少为1]
!!BU:Sy50/y7/y-11/y14/-1/0; [生物编号/数量/位置/所属/召唤的/不重画]

!?FU20000&x1=7;  部队有几率增强伤害(祈祷动画)
!!FU&x3<1:E;
!!FU&x4<1:E;
!!BG:N?y30 E?y31 Q?y32;
!!MF:N?y2;       [fix 007-120822]
!!FU|y30<0/y31<0:E; [堆栈错误]fix 007-120822
!!BMy30:T?y40 I?y50;
!!BMy31:T?y41 I?y51;
!!FU&x2=v9555/y32<>0:E;
!!FU&x2=v9560/y32<>1:E;
!!FU&x2=v9555/y32=0/y2<21:E;  [火盾情况]fix 007-120822
!!FU&x2=v9560/y32=1/y2>20:E;  [同上]
!!VRy60&y32=y50:Sy30;
!!VRy60&y32<>y50:Sy31;
!!BMy60:T?y61;
!!HEx2:E?y5/?y6;
!!VRy8&x5>0:Sy6:x5;
!!VRy10&x3<101:Sx3; [固定几率]
!!VRy11&x3<101:Sx4; [伤害%]
!!VRy11&x3<101/x5>0:*y8; [伤害%按等级叠加]
!!VRy11&x3<101:+100;
!!VRy11&x3<101/x6>0/y11>x6:Sx6;       [大于极限取极限]
!!VRy11&x3>100:Sx3; [固定伤害]
!!VRy10&x3>100:Sx4; [几率%]
!!VRy10&x3>100/x5>0:*y8; [伤害%按等级叠加]
!!VRy10&x3>100/x6>0/y10>x6:Sx6;       [大于极限取极限]
!!VRy10&x3>100/y10<1:S1;
!!VRy10&x3>100/y10>100:S100;
!!VRy97:S0 R99;
!!FU&y97>y10:E;
!!MF:F?y12;
!!VRy13:Sy12*y11:100;
!!BMy60:V0;
!!VRz-1:S^Prayer.wav^;
!!SN:Pz-1;
!!MF:Fy13;
!!UN:N3/1/y61/0;
!!VRy15:Sy11-100;
!!VRz-10:S^英雄特技增加了{%Z1%Y15%%}的输出伤害(几率{%Y10%%},伤害值{%Y13})^;
!!BU:Mz-10 R;

!?FU20000&x1=8;  有几率减少伤害(对方生物UNLUKY动画)
!!FU|x3<1/x3>200:E;
!!FU&x4<1:E;
!!BG:N?y30 E?y31 Q?y32;
!!MF:N?y2;       [fix 007-120822]
!!FU|y30<0/y31<0:E; [堆栈错误]fix 007-120822
!!BMy30:T?y40 I?y50;
!!BMy31:T?y41 I?y51;
!!FU&x2=v9555/y32<>1:E;
!!FU&x2=v9560/y32<>0:E;
!!VRy60&y32=y50:Sy30;  [敌方生物主动进攻时]
!!VRy60&y32<>y50:Sy31;  [敌方生物反击时]
!!FU&x2=v9555/y32=1/y2>20:E;  [火盾现象]fix 007-120822
!!FU&x2=v9560/y32=0/y2<21:E;  [同上]
!!BMy60:T?y61;
!!FU&y61=149:E; [排除箭塔]fix 007-120822
!!HEx2:E?y5/?y6;
!!VRy8&x5>0:Sy6:x5;
!!VRy10&x3<101:Sx3;
!!VRy11&x3<101:Sx4*-1;
!!VRy11&x3<101/x5>0:*y8;
!!VRy11&x3<101:+100;
!!VRy11&x3<101/x6>0/y11<x6:Sx6;
!!VRy11&x3<101/y11<0:S0;
!!VRy11&x3>100:S200-x3;
!!VRy10&x3>100:Sx4;
!!VRy10&x3>100/x5>0:*y8;
!!VRy10&x3>100/x6>0/y10>x6:Sx6;
!!VRy10&x3>100/y10<1:S1;
!!VRy10&x3>100/y10>100:S100;
!!VRy97:S0 R99;
!!FU&y97>y10:E;
!!MF:F?y12;
!!VRy13:Sy12 *y11 :100;
!!BMy60:V48;    [BADLUKY动画]
!!VRz-1:S^Misfort.wav^;
!!SN:Pz-1;
!!MF:Fy13;
!!UN:N3/1/y61/0;
!!VRy15:S100-y11;
!!VRz-10:S^英雄特技减少了{%Z1%Y15%%}的输出伤害(几率{%Y10%%},实际伤害值{%Y13})^;
!!BU:Mz-10 R;

!?FU20000&x1=9;  有几率反弹伤害(对方生物闪电动画)
!!FU|x3<1:E;
!!FU&x4<1:E;
!!BG:N?y30 E?y31 Q?y32;
!!MF:N?y2;       [fix 007-120822]
!!FU|y30<0/y31<0:E; [堆栈错误]fix 007-120822
!!BMy30:T?y40 I?y50;
!!BMy31:T?y41 I?y51;
!!FU&x2=v9555/y32<>1:E;
!!FU&x2=v9560/y32<>0:E;
!!VRy60&y32=y50:Sy30;  [敌方生物主动进攻时]
!!VRy60&y32<>y50:Sy31;  [敌方生物反击时]
!!FU&x2=v9555/y32=1/y2>20:E;  [火盾等情况]fix 007-120822
!!FU&x2=v9560/y32=0/y2<21:E;  [同上]
!!BMy60:T?y61;
!!FU&y61=149:E; [排除箭塔]fix 007-120822
!!HEx2:E?y5/?y6;
!!VRy8&x5>0:Sy6:x5;
!!VRy10&x3<101:Sx3; [固定几率]
!!VRy11&x3<101:Sx4; [伤害%]
!!VRy11&x3<101/x5>0:*y8; [伤害%按等级叠加]
!!VRy11&x3<101/x6>0/y11>x6:Sx6;       [大于伤害极限取极限]
!!VRy11&x3>100:Sx3-100; [固定伤害]
!!VRy10&x3>100:Sx4; [几率%]
!!VRy10&x3>100/x5>0:*y8; [伤害%按等级叠加]
!!VRy10&x3>100/x6>0/y10>x6:Sx6;       [大于极限取极限]
!!VRy10&x3>100/y10<1:S1;
!!VRy10&x3>100/y10>100:S100;
!!VRy97:S0 R99;
!!FU&y97>y10:E;
!!MF:F?y12;
!!VRy13:Sy12 *y11 :100;
!!BMy60:H?y70 N?y71 L?y72; [被反弹伤害对象的生命/个数/差额生命值]
!!VRy73:Sy70*y71-y72;  [被反弹伤害对象的总生命值]
!!VRy13&y13>=y73:Sy73-1; [保留对方一点生命值]
!!FU&y13<1:E;  [伤害少于1,退出]
!!BMy60:V38;    [电击目标动画]
!!VRz-1:S^LightBlt.wav^;
!!SN:Pz-1;
!!BMy60:Ky13;    [对怪物造成伤害]
!!UN:N3/1/y61/0;  [获得生物名称于Z1]
!!VRy15:Sy11;
!!VRz-10:S^英雄特技反弹了{%Z1%Y15%%}的伤害(几率{%Y10%%},伤害值{%Y13})^;
!!BU:Mz-10 R;

!?FU20000&x1=10;  [特长升级生物,会替换原特长,英雄界面点击生物升级]
!!FU|x2<0/x2>196:E;
!!FU&x2>144/x2<150:E;
!!CM:I?y1;
!!FU|y1<68/y1>74:E;
!!VRy2:Sy1 -68;
!!HE-1:C0/y2/?y3/d;
!!FU&y3<0:E;
!!VRy4|y3=x3/y3=x4/y3=x5/y3=x6/y3=x7/y3=x8/y3=x9/y3=x10:S999;  [若有可升级生物]
!!HE-1&y4=999:X6/y3/y3/x2;  [更换特长]

!?FU20000&x1=11;  战斗胜利后招募到生物 (简单招募)
!!FU|x5<0/x6>196:E;
!!FU&x5>144/x5<150:E;
!!FU&y7<=0:E;
!!VRy7:Sx6;
!!VRy8:Sx4*y7:1000; [经验差额*千分数(相当于能招募到的生命值)]
!!MA:Px5/?y9; [生命值]
!!VRy10:Sy8:y9;  [个数]
!!VRy10&x7>0/y10>x3:Sx3; [大于原生物总数量时,取原生物总数量]
!!VRy10&x7>0/y10>x7:Sx7; [大于极限时取极限]
!!FU&y10<1:E;
!!UN:N3/1/x5/0;
!!HEx2:O?y11; [英雄所属0-7]
!!OW&y11>=0:Iy11/?y12; [玩家orAI,0-1]
!!IF&y12=0:Q1/21/x5/2^{英雄特技}
战斗胜利后,英雄威望远播,{%Y10个%Z1}愿意加入你的部队!^; [兵种加入,可以选择要与否]
!!HEx2&y12=0/1:C2/x5/y10/1; [询问玩家]
!!UN&y12=0/1:R1;
*!HEx2&y12=1/1:C2/x5/y10/2; [AI自动完成(若BA0/1使用1000标志,则无玩家英雄间的战斗时无效)]

!?FU20000&x1=100; [模拟生物周边召唤(自动寻找位置)]
!!BMx16:T?y1 N?y2 I?y3 P?y4 F?i;
!!FU&y2<=0:E;
!!FU&y1>144/y1<150:E;
!!FU&y1<>x2:E;
!!DO20000/0/20/1&y3=0:P103/0;
!!FU&y3=0/v7>=20:E; [21为满]
!!DO20000/21/41/1&y3=1:P103/21;
!!FU&y3=1/v7>=20:E; [21为满]
!!BMx16:T?y1 N?y2 I?y3 P?y4 F?i;
!!VRy7:Si&4194304;  [判断是否召唤物]
!!FU&y7>0:E;       [召唤物则不再召唤]
!!VRy50:Sy2*x4:100;  [召唤物个数]
!!FU&y50<1:E;
!!MA:Xx3/?j; [召唤生物的属性,检测是否双格生物]
!!VRy5:Si&1; [原堆栈是否包含1(双格),返回0是非双格,返回不为0就是双格]
!!VRy6:Sj&1; [召唤物:是否包含1(双格),返回0是非双格,返回不为0就是双格]
!!DO20000/1/8/1:P101/y4/y5/y6/y3/y50/x3/x5/x6;

!?FU20000&x1=101; [寻找最佳召唤位置,并召唤,存了 V5中(临时)]
**先判断是否有空堆栈可召唤**
!!DO20000/0/20/1&x5=0:P103/0;
!!FU&x5=0/v7>=20:E; [21为满]
!!DO20000/21/41/1&x5=1:P103/21;
!!FU&x5=1/v7>=20:E; [21为满]
!!VRv5:S0;
!!VRy-1:Sx2:17+1;  [原位置的行1-11]
!!VRy-2:Sy-1-1*-17+x2+1;  [原位置所在的列1-17]
!!VRy10&x3=0/x16=1:Sx2+1;
!!VRy10&x3=0/x16=2:Sx2-1;
!!VRy10&x3=0/x16=3:Sx2-17;
!!VRy10&x3=0/x16=4:Sx2+17;
!!VRy10&x3=0/x16=5:Sx2-18;
!!VRy10&x3=0/x16=6:Sx2+16;
!!FU&x3=0/x16>6:E;
!!VRy10&x3=1/x16=1/x5=0:Sx2+2;    [左势力,右端]
!!VRy10&x3=1/x16=1/x5=1:Sx2+1;    [右势力,右端]
!!FU&x3=1/x16=1/x5=1/x4=1/y-2>14:E;    [右势力,右端,召唤双格情况]
!!VRy10&x3=1/x16=1/x5=1/x4=1:Sx2+2; [为了能召唤双格,位置必须再退一步]
!!VRy10&x3=1/x16=2/x5=0:Sx2-1;    [左势力,左端]
!!FU&x3=1/x16=2/x5=0/x4=1/y-2<4:E;    [左势力,左端,召唤双格情况]
!!VRy10&x3=1/x16=2/x5=0/x4=1:Sx2-2; [为了能召唤双格,位置必须再退一步]
!!VRy10&x3=1/x16=2/x5=1:Sx2-2;    [右势力,左端]
!!VRy10&x3=1/x16=3:Sx2-16;
!!VRy10&x3=1/x16=4:Sx2+18;
!!VRy10&x3=1/x16=5:Sx2-17;
!!VRy10&x3=1/x16=6:Sx2+17;
!!VRy10&x3=1/x16=7:Sx2-18;
!!VRy10&x3=1/x16=8:Sx2+16;

!!FU20000:P102/y10/x4/x5;
!!FU&v6<>999:E;
!!BU:Sx7/x6/v5/x5/-1/0;
!!BU&x9=1:Ev5/?y60; [被召唤出来的堆栈编号]
!!BMy60&x9=1:F?i;
!!VRi&x9=1:|12582912; [镜像体+召唤物标志]
!!BMy60&x9=1:Fi;  [转成镜像体]
!!VRx16&v5>0/x8=0:S8; [若只召唤一次,则提前结束循环]

!?FU20000&x1=102;  [目标位置是否恰当,存于V6中]
!!VRv6:S0;
!!FU|x2<0/x2>188:E;
!!VRy-11:Sx2:17+1;  [目标的行1-11]
!!VRy-12:Sy-11-1*-17+x2+1;  [目标所在的列1-17]
!!FU|y-12=1/y-12=17:E;  [不能在边缘位置]
!!BU:Ex2/?y-13; [是否有堆栈]
!!BU:Ox2/?y-14; [是否有障碍物]
!!VRy-20&x3=1/x4=0:Sx2+1;
!!VRy-20&x3=1/x4=1:Sx2-1;
!!BU&x3=1:Ey-20/?y-15;
!!BU&x3=1:Oy-20/?y-16;
!!VRv6&x3=0/y-13=-1/y-14=0:S999;  [单格生物]
!!VRv6&x3=1/y-13=-1/y-14=0/y-15=-1/y-16=0:S999; [双格生物]
!!VRv5&v6=999:Sx2;  [v5存储目标位置]

!?FU20000&x1=103;  [返回战场堆栈个数(V7)]
!!VRv7&x16=x2:S0;
!!BMx16:T?y-31 N?y-32;
!!FU|y-31<0/y-32<1:E;
!!VRv7:+1; [累积]

!?FU20000&x1=105;  模拟生物吸血(间接方法)
!!FU&x3<1:E;
!!BG:N?y30 E?y31 Q?y32;
!!FU|y30<0/y31<0:E; [堆栈错误]fix 007-120822
!!BMy30:T?y40 I?y50;
!!BMy31:T?y41 I?y51;
!!FU&y32=y50/y40<>x2:E;  [主动攻击时,非特定生物退出]
!!FU&y32<>y50/y41<>x2:E;  [反击时,非特定生物退出]
!!MF:F?y2; [fix 007-120822]
!!FU&y32=y50/y40=x2/y30=y2:E; [火盾情况]fix 007-120822
!!FU&y32<>y50/y41=x2/y31=y2:E; [同上]
!!VRy60&y32=y50:Sy30;  [攻击时]
!!VRy60&y32<>y50:Sy31;  [反击时]
!!VRy61&y32=y50:Sy41;
!!VRy61&y32<>y50:Sy40;
!!VRy62&y32=y50:Sy31;  [特定生物攻击时]
!!VRy62&y32<>y50:Sy30;  [特定生物反击时]
!!BMy62&x4=0:F?i;
!!VRy63&x4=0:Si&16;  [是否生命系]
!!FU&y63=0/x4=0:E;
!!VRy10:Sx3;
!!VRy97:S0 R99;
!!FU&y97>y10:E;
!!MF:F?y12;
!!IF&y12=0:E;
!!BMy60:H?y70 N?y71 L?y72 B?y73;
!!FU&y73=y71/y72=0/x5=0:E; [满血时]
!!VRy74:Sy71*y70-y72; [当前总生命]
!!VRy75&x5=0:Sy73-y71*y70+y72; [总生命值差额]
!!VRy12&y75<=y12/x5=0:Sy75;  [吸满为止]
!!VRy76:Sy74+y12; [最终总血量]
!!VRy77:Sy76:y70;  [初步计算个数]
!!VRy78:Sy77*y70-y76; [差额生命值L(负)]
!!VRy78:*-1; [转成正数]
!!VRy77&y78>0:+1; [不饱满时,总个数应+1]
!!VRy79:Sy77-y71; [增加的个数]
!!BMy60:Ny77 V4 Ly78; [4吸血,52重生]
!!VRz-1:S^Drainlif.wav^;
!!SN:Pz-1;
!!UN:N3/1/y61/0;
!!UN:N3/2/x2/0;
!!VRz-10&x5=0:S^{%Z2}吸取{%Z1 %Y12}点生命值,{%Y79}个{%Z2}重生了,几率{%Y10%%}!^;
!!VRz-10&x5<>0:S^{%Z2}吸取{%Z1 %Y12}点生命值,增长了{%Y79}个{%Z2},几率{%Y10%%}!^;
!!BU:Mz-10 R;

!?FU20000&x1=106;  模拟死亡凝视(间接方法,至少保留一个生物一点血)
!!FU&x3<1:E;
!!BG:N?y30 E?y31 Q?y32;
!!FU|y30<0/y31<0:E; [堆栈错误]fix 007-120822
!!BMy30:T?y40 I?y50;
!!BMy31:T?y41 I?y51;
!!FU&y32=y50/y40<>x2:E;  [主动攻击时,非特定生物退出]
!!FU&y32<>y50/y41<>x2:E;  [反击时,非特定生物退出]
!!MF:F?y2;
!!FU&y32=y50/y40=x2/y30=y2:E; [火盾等情况]fix 007-120822]
!!FU&y32<>y50/y41=x2/y31=y2:E; [同上]
!!VRy60&y32=y50:Sy31;  [攻击时]
!!VRy60&y32<>y50:Sy30;  [反击时]
!!BMy60:T?y61;
!!VRy80&y32=y50:Sy30; [本方堆栈]
!!VRy80&y32<>y50:Sy31; [本方堆栈]
!!BMy60&x4=0:F?i;
!!VRy63&x4=0:Si&16;  [是否生命系]
!!FU&y63=0/x4=0:E;
!!VRy10:Sx3;
!!VRy97:S0 R99;
!!FU&y97>y10:E;
!!BMy60:H?y70 N?y71 L?y72 B?y73;
!!BMy80:N?y81;       [特定生物的当前个数(己方)]
!!VRy75:Sy81*x5:100; [能秒杀的个数]y75
!!FU&y75<1:E; [没有达标量,退出]
!!VRy75&y75>=y71/y71>1:Sy71-1;  [保留至少一个敌方生物]
!!VRy78&y75>=y71/y71>1:Sy70-1; [保留一点血(此处是L值)]
!!VRy78&y75<y71/y71>1:Sy72; [保留原L]
!!VRy76&y71>1:Sy71-y75;  [剩余个数]
!!VRy77&y71=1:Sy75*1000*-1+y70-y72;  [y75每个凝视能秒1000血]
!!VRy77&y71=1/y77<1:S1; [至少保留对方一点血]
!!VRy78&y71=1:Sy70-y77; [计算最终L]
!!VRy79&y71=1:Sy78-y72; [秒掉的生命]
!!BMy60&y71>1:V80 Ny76 Ly78 K0; [秒杀生物 80死亡凝视]
!!BMy60&y71=1:V80 Ly78 K0;
!!VRz-1:S^Deathstr.wav^;
!!SN:Pz-1;
!!UN:N3/1/y61/0;
!!UN:N3/2/x2/0;
!!VRz-10&y71=1:S^{%Z2}发动死亡凝视瞬间秒掉{%Z1%Y79}点生命值,几率{%Y10%%}!^;
!!VRz-10&y71>1:S^{%Z2}发动死亡凝视瞬间秒杀{%Y75}个{%Z1},几率{%Y10%%}!^;
!!BU:Mz-10 R; [显示记录并重绘]

!?FU20000&x1=110;    [模拟生物自带魔法]
!!BMx16:T?y20 N?y21; [类型/数量]
!!FU|y20<0/y21<1/y20=149:E; [fix 007-120822]
!!BMx16&y20=x2/y21>0:Mx3/x4/x5;

!?FU20000&x1=111;    [主动攻击时的攻击前施法]
!!FU|x7<1/x7>100/x6<0:E;
!!VRy97:S0 R99;
!!FU&y97>x7:E;
!!BG:N?y11 E?y12 Q?y13;
!!BMy11:T?y20 I?y21 P?y22 N?y23;
!!BMy12:T?y30;
!!BMy12&y30>0:I?y31 P?y32;
!!VRy41:Sx4;
!!VRy41&x6>0:Sy23*x6:100; [与个数有关时,计算实际强度或力量(x6>0)  ]
!!VRy41&y41<1:S1;
!!BMy11&x5=0/y21=y13:Cx2/y22/x3/y41/1; [对己方施法]
!!BMy11&x5=1/y21=y13/y30>0:Cx2/y32/x3/y41/1; [对敌方施法]

!?FU20000&x1=200;  有几率增强伤害[祈祷动画]
!!FU|x3<1/x4<1:E;
!!BG:N?y30 E?y31 Q?y32;
!!FU|y30<0/y31<0:E; [堆栈错误]fix 007-120822
!!BMy30:T?y40 I?y50;
!!BMy31:T?y41 I?y51;
!!FU&y32=y50/y40<>x2:E;
!!FU&y32<>y50/y41<>x2:E;
!!MF:F?y2;
!!FU&y32=y50/y40=x2/y30=y2:E; [火盾等现象]fix 007-120822
!!FU&y32<>y50/y41=x2/y31=y2:E; [同上]
!!VRy60&y32=y50:Sy30;
!!VRy60&y32<>y50:Sy31;
!!BMy60:T?y61;
!!VRy10:Sx4;
!!VRy10&y10>100:S100;
!!VRy11:Sx3+100;
!!VRy97:S0 R99;
!!FU&y97>y10:E;
!!MF:F?y12;
!!VRy13:Sy12*y11:100;
!!BMy60:V0;    [73死亡一击,0祈祷]
!!VRz-1:S^Prayer.wav^;
!!SN:Pz-1;
!!MF:Fy13;
!!UN:N3/1/y61/0;
!!VRy15:Sy11-100;
!!VRz-10:S^{%Z1}伤害值增加{%Y15%%},几率{%Y10%%},实际伤害值为{%Y13}^;
!!BU:Mz-10 R;

!?FU20000&x1=201;  有几率减少伤害[偏移动画]
!!FU|x3<1/x3>100/x4<1:E;
!!BG:N?y30 E?y31 Q?y32;
!!FU|y30<0/y31<0:E; [堆栈错误]fix 007-120822
!!BMy30:T?y40 I?y50;
!!BMy31:T?y41 I?y51;
!!FU&y32=y50/y41<>x2:E;
!!FU&y32<>y50/y40<>x2:E;
!!MF:F?y2;
!!FU&y32=y50/y41=x2/y30=y2:E; [火盾等现象]fix 007-120822
!!FU&y32<>y50/y40=x2/y31=y2:E; [同上]
!!VRy60&y32=y50:Sy31;
!!VRy60&y32<>y50:Sy30;
!!VRy61&y32=y50:Sy40;
!!VRy61&y32<>y50:Sy41;
!!VRy10:Sx4;
!!VRy10&y10>100:S100;
!!VRy11:S100-x3;
!!VRy97:S0 R99;
!!FU&y97>y10:E;
!!MF:F?y12;
!!VRy13:Sy12*y11:100;
!!BMy60:V86;    [84格挡,86偏移]
!!MF:Fy13;
!!UN:N3/1/y61/0;
!!UN:N3/2/x2/0;
!!VRz-10:S^{%Z2}减少了{%Z1%X3%%}的输出伤害,几率{%Y10%%},实际伤害值{%Y13}^;
!!BU:Mz-10 R;

!?FU20000&x1=202;  有几率反弹伤害[火盾动画]
!!BG:N?y30 E?y31 Q?y32;
!!FU|y30<0/y31<0:E; [堆栈错误]fix 007-120822
!!BMy30:T?y40 I?y50;
!!BMy31:T?y41 I?y51;
!!FU|x3<1/x3>100/x4<1:E;
!!FU&y32=y50/y41<>x2:E;  [敌方主动攻击]
!!FU&y32<>y50/y40<>x2:E;  [敌方反击时]
!!MF:F?y2;
!!FU&y32=y50/y41=x2/y30=y2:E; [火盾等现象]fix 007-120822
!!FU&y32<>y50/y40=x2/y31=y2:E; [同上]
!!VRy60&y32=y50:Sy30;
!!VRy60&y32<>y50:Sy31;
!!BMy60:T?y61;
!!VRy10:Sx4;
!!VRy10&y10>100:S100;
!!VRy11:Sx3;
!!VRy97:S0 R99;
!!FU&y97>y10:E;
!!MF:F?y12;
!!VRy13:Sy12*y11:100;
!!BMy60:H?y70 N?y71 L?y72;
!!VRy73:Sy70*y71-y72;
!!VRy13&y13>=y73:Sy73-1; [保留对方一点生命值]
!!FUy13&y13<1:E;
!!BMy60:V38;    [38电击目标动画,11火盾]
!!VRz-1:S^LightBlt.wav^;
!!SN:Pz-1;
!!BMy60:Ky13;
!!UN:N3/1/y61/0;
!!UN:N3/2/x2/0;
!!VRy15:Sy11;
!!VRz-10:S^{%Z2}反弹了{%Z1%Y15%%}的伤害,几率{%Y10%%},伤害值{%Y13}^;
!!BU:Mz-10 R;

!?FU20000&x1=203;  主动攻击时有几率降低对方攻防命伤(2)
!!FU|x4<1/x5<1:E;
!!BG:N?y30 E?y31 Q?y32;
!!FU|y30<0/y31<0:E; [堆栈错误]fix 007-120822
!!BMy30:T?y40 I?y50;
!!BMy31:T?y41 I?y51;
!!FU|y32<>y50/y40<>x2:E;
!!MF:N?y2;       [fix 007-120822]
!!FU&y32=y50/y40=x2/y40=y2:E; [火盾等现象]fix 007-120822
!!VRy10:Sx5;
!!VRy10&y10>100:S100;
!!VRy11:S100-x4; [最终%]
!!VRy97:S0 R99;
!!FU&y97>y10:E;
!!BMy31:A?y14 D?y15 H?y16 U1/?y17 U2/?y18;
!!VRy14:*y11:100;
!!VRy14&y14<1:S1; [保证最低为1]
!!VRy15:*y11:100;
!!VRy15&y15<1:S1;
!!VRy16:*y11:100;
!!VRy16&y16<1:S1;
!!VRy17:*y11:100;
!!VRy17&y17<1:S1;
!!VRy18:*y11:100;
!!VRy18&y18<1:S1;
!!VRz-1:S^Weakness.wav^; [减攻击的动画]
!!VRz-2:S^Acid.wav^;    [降防的动画]
!!VRz-3:S^Poison.wav^; [减血的动画]
!!VRz-4:S^Curse.wav^; [减伤害的动画]
!!VRj:Sx3;
!!VRy21:Sj&1;
!!VRy22:Sj&2;
!!VRy23:Sj&4;
!!VRy24:Sj&8;
!!BMy31&y21<>0:Ay14 V56; [减攻]
!!SN&y21<>0:Pz-1;
!!VRz-5&y21<>0:S^%Z-5 减攻{%X4%%}^;
!!BMy31&y22<>0:Dy15 V81; [减防]
!!SN&y22<>0:Pz-2;
!!VRz-5&y22<>0:S^%Z-5 减防{%X4%%}^;
!!BMy31&y23<>0:Hy16 V67;    [减血]
!!SN&y23<>0:Pz-3;
!!VRz-5&y23<>0:S^%Z-5 减血{%X4%%}^;
!!BMy31&y24<>0:U1/y17 U2/y18 V40; [减伤害]
!!SN&y24<>0:Pz-4;
!!VRz-5&y24<>0:S^%Z-5 减伤害{%X4%%}^;
!!UN:N3/1/y41/0;
!!VRz-10:S^{%Z1}被%Z-5,几率{%Y10%%}^;
!!BU:Mz-10 R;

!?FU20000&x1=204;  生物主动攻击时有机会横向或纵向攻击一排或一列目标
!!FU|x3<1:E;
!!BG:N?y30 E?y31 Q?y32;
!!FU|y30<0/y31<0:E; [堆栈错误]fix 007-120822
!!BMy30:T?y40 I?y50;
!!BMy31:T?y41 I?y51 P?y61;
!!FU|y32<>y50/y40<>x2:E;
!!MF:N?y2;       [fix 007-120822]
!!FU&y32=y50/y40=x2/y40=y2:E; [火盾等现象]fix 007-120822
!!VRy10:Sx3;
!!VRy97:S0 R99;
!!FU&y97>y10:E;
!!VRy-11:Sy61:17+1;  [目标的行1-11] y-11
!!VRy-12:Sy-11-1*-17+y61+1;  [目标所在的列1-17]  y-12
!!MF:F?y12; [原伤害值]y12
!!UN:N3/1/y40/0;
!!DO20000/0/20/1&x4=0/y50=1:P205/y-12/y31/y12; [横向伤害,也是战场纵向伤害]
!!DO20000/21/41/1&x4=0/y50=0:P205/y-12/y31/y12; [横向伤害,也是战场纵向伤害]
!!DO20000/0/20/1&x4=1/y50=1:P206/y-11/y31/y12; [纵向伤害,也是战场横向伤害]
!!DO20000/21/41/1&x4=1/y50=0:P206/y-11/y31/y12; [纵向伤害,也是战场横向伤害]
!!VRz-10&x4=0:S^{%Z1}发动{横扫千军},横向敌对生物均受到同等伤害,几率{%Y10%%}^;
!!VRz-10&x4=1:S^{%Z1}发动{纵向一击},纵向敌对生物均受到同等伤害,几率{%Y10%%}^;
!!BU:Mz-10 R;

!?FU20000&x1=205; [横向伤害]
!!FU&x16=x3:E; [排除目标本身]
!!BMx16:T?y-40 N?y-41 P?y-61; [历遍每个敌对堆栈位置]
!!FU|y-40<0/y-41<1:E;
!!VRy-21:Sy-61:17+1;  [目标的行1-11]
!!VRy-22:Sy-21-1*-17+y-61+1;  [目标所在的列1-17]
!!FU&y-22<>x2:E; [不同列]
!!BMx16:V73 Kx4;

!?FU20000&x1=206; [纵向伤害]
!!FU&x16=x3:E; [排除目标本身]
!!BMx16:T?y-40 N?y-41 P?y-61; [历遍每个敌对堆栈位置]
!!FU|y-40<0/y-41<1:E;
!!VRy-21:Sy-61:17+1;  [目标的行1-11] y-11
!!FU&y-21<>x2:E; [不同行]
!!BMx16:V73 Kx4;

为什么不能WOG化地图，总是出错，我还找不到原因，请大神出马