大家帮忙看下特定指挥官加强和多次射击哪里冲突了！

弃天帝

只能增加一次射击，2到7都是一样的远程兵会射击自己的1号位！

ZVSE

********************************************************************************
********************************************************************************
** 说    明：特定指挥官加强脚本                                               **
** 变量使用：v1、V9301--V9316、v9555、v9560                                   **
**           Z1--Z60                                                          **
**           对话框编号 02、38                                                **
**           FU编号  15010--15013                                             **
** 特技说明：1.六和甲--指挥官拥有击碎之斧、硬化之盾、密银之甲、速度之靴、     **
**                     锋利之剑 、巫术项链，游戏开始时设置修炼次数为10次。    **
**           2.灵心咒--加快指挥官宝物修炼速度为正常的10--90倍。               **
**           3.金刚盾--减物理伤害，约60级时，可以实现免物理伤害。             **
**           4.雷神锤--加攻击伤害，每升20级，攻击伤害加100%。                 **
**           5.浑天镜--拥有伤害反弹技能，每升30级，反弹伤害增加100%。         **
**           6.千手佛--群攻技能，以指挥官为中心，以六角形为基准，随等级增     **
**                     加攻击半径，一级时类似环击。                           **
** 设置说明：各项技能可以单独使用或关闭。                                     **
**                                                                            **
********************************************************************************
*********************初始设置***************************************************

!?PI;
!!UN:P3/?v1;
!!VRv9316&v1=1:S2;                      指挥官禁用开关 V9316
!!IF&v9316=2:L^您已禁用了指挥官，指挥官加强程序将无法进行!^;
!!FU&v9316=2:E;

!!VRv9302:C0/0/0/0/0/0/0/0;             V9302--V9309
!!VRv9310:C0/-2/-2/-2/-2/-2;            V9310--V9315
!!VRy1:S-2;
!!VRy2:S-2;
!!VRy3:S-2;
!!DO15010/0/7/1&v9310=0:P;
!!HEv9311&v9311>-1:B0/?z2 B2/?y1;       第一英雄名字、类型
!!HEv9312&v9312>-1:B0/?z3 B2/?y2;       第二英雄名字、类型
!!HEv9313&v9313>-1:B0/?z4 B2/?y3;       第三英雄名字、类型
!!VRy1&y1>-1:Sy1+10;
!!VRy2&y2>-1:Sy2+10;
!!VRy3&y3>-1:Sy3+10;
!!VRz2&v9311<0:S^^;
!!VRz3&v9312<0:S^^;
!!VRz4&v9313<0:S^^;

!!VRz10:S^骑士^;
!!VRz11:S^牧师^;
!!VRz12:S^巡逻兵^;
!!VRz13:S^德鲁伊^;
!!VRz14:S^炼金术士^;
!!VRz15:S^术士^;
!!VRz16:S^魔鬼^;
!!VRz17:S^异教徒^;
!!VRz18:S^死亡骑士^;
!!VRz19:S^巫师^;
!!VRz20:S^妖术师^;
!!VRz21:S^地下领主^;
!!VRz22:S^野蛮人^;
!!VRz23:S^战斗法师^;
!!VRz24:S^驯兽师^;
!!VRz25:S^女巫^;
!!VRz26:S^元素人^;
!!VRz27:S^元素使^;
!!VRz28&y1>9:Szy1;
!!VRz29&y2>9:Szy2;
!!VRz30&y3>9:Szy3;
!!VRz31:S^＝＝ 指挥官加强版 ＝＝^;
!!VRz32:S^请输入您想选择的英雄的名字^;
!!VRz33:S^拥有超级指挥官的英雄^;
!!VRz34:S^..\Data\zvs\Lib1.res\1680GAME_1001.bmp^;
!!VRz35:S^..\Data\zvs\Lib1.res\1680GAME_1002.bmp^;
!!VRz36:S^..\Data\zvs\Lib1.res\1680GAME_1003.bmp^;
!!VRz37:S^..\Data\zvs\Lib1.res\1680GAME_1004.bmp^;
!!VRz38:S^我要自己决定^;
!!VRz39:S^%Z28  ^+^%Z2^;
!!VRz40:S^%Z29  ^+^%Z3^;
!!VRz41:S^%Z30  ^+^%Z4^;
!!VRz42:S^请在左边输入姓名（小心不要让敌人雇了去哦！）^;
!!VRz43:S^人类玩家第一英雄（系统默认）^;
!!VRz44:S^人类玩家第二英雄^;
!!VRz45:S^人类玩家第三英雄^;

!!IF:D38/31/32/33/34/35/36/37/////38/39/40/41;
!!IF:F38/42/43/44/45/1;
!!IF:E9302/38;                                        英雄选择 v9302

!!VRz1:M4/?y4;                                        所选英雄 v9315
!!DO15011/0/155/1&v9302=1/y4>0:P;
!!VRv9315&v9302=-1/v9311>-1:Sv9311;
!!VRv9315&v9302=2/v9311>-1:Sv9311;
!!VRv9315&v9302=3/v9312>-1:Sv9312;
!!VRv9315&v9302=4/v9313>-1:Sv9313;
!!VRv9315&v9302=1/y4<1:Sv9311;
!!VRv9315&v9302=1/y4>0:Sv9314;

!!VRz50:S^＝＝ 指挥官特别技能设置 ＝＝^;
!!VRz51:S^六合甲--指挥官拥有全宝物^;
!!VRz52:S^灵心咒--提升修炼速度^;
!!VRz53:S^金刚盾--每级减少物理伤害1.7%^;
!!VRz54:S^雷神锤--每级增加进攻伤害5%^;
!!VRz55:S^混天镜--每级增加伤害反弹3.4%^;
!!VRz56:S^千手佛--随等级增加攻击区域^;
!!IF:G0/9303/0/50/51/52/53/54/55/56;                  技能选择 v9303

!!VRy5:Sv9303;
!!VRy6:Sv9303;
!!VRy7:Sv9303;
!!VRy8:Sv9303;
!!VRy9:Sv9303;
!!VRy10:Sv9303;
!!VRy5:&1;
!!VRy6:&2;
!!VRy7:&4;
!!VRy8:&8;
!!VRy9:&16;
!!VRy10:&32;
!!VRv9304&y5>0:S2;                                    六合甲开关   v9304
!!VRv9305&y6>0:S0;                                    灵心咒开关   v9305
!!VRv9306&y7>0:S2;                                    金刚盾开关   v9306
!!VRv9307&y8>0:S2;                                    雷神锤开关   v9307
!!VRv9308&y9>0:S2;                                    混天镜开关   v9308
!!VRv9309&y10>0:S2;                                   千手佛开关   v9309

!!VRz57:S^灵心咒--修炼速度设置^;
!!VRz58:S^初级--三重功力^;
!!VRz59:S^中级--六重功力^;
!!VRz60:S^高级--九重功力^;
!!IF:D02///57/////////58/59/60/0;
!!IF:F02/////0;
!!IF&y6>0:E9305/02;                                   灵心咒等级   V9305

*********************基本属性、扩展技能*****************************************

!!COv9315:P0/10 P1/10 P2/60 P3/20 P4/10 P5/10 P6/100;  基本属性
!!COv9315:S0/1 S1/1 S2/1 S3/1 S4/1 S5/0 S6/5;          技能等级
!!COv9315:B1/3/0 B1/7/1 B1/8/1 B1/14/1;                扩展特技

********************六合甲设置**************************************************

!!COv9315&v9304>0:A1/146/10;  击碎之斧  修炼次数=10
!!COv9315&v9304>0:A1/154/10;  硬化之盾  修炼次数=10
!!COv9315&v9304>0:A1/147/10;  密银之甲  修炼次数=10
!!COv9315&v9304>0:A1/151/10;  速度之靴  修炼次数=10
!!COv9315&v9304>0:A1/148/10;  锋利之剑  修炼次数=10
!!COv9315&v9304>0:A1/150/10;  巫术项链  修炼次数=10

********************初始设置---FU函数*******************************************

!?FU15010&v9310=0;
!!OW:Ix16/?y1;                 获取人类玩家颜色编号
!!FU&y1>0:E;
!!OW&y1=0:Hx16/9310/0;         人类玩家英雄数量
!!OW&y1=0/v9310>0:Hx16/9311/1; 第一英雄编号
!!OW&y1=0/v9310>1:Hx16/9312/2; 第二英雄编号
!!OW&y1=0/v9310>2:Hx16/9313/3; 第三英雄编号

!?FU15011&v9302=1/v9314<0;
!!VRz5:S^^;
!!HEx16:B0/?z5;                英雄名字
!!FU&z1<>z5:E;
!!VRv9314&z1=z5:Sx16;          英雄编号

********************灵心咒设置**************************************************

!?BA1&1000;
!!FU|v9316=2/v9305<1:E;
!!BA:H0/?v9555;
!!BA:H1/?v9560;
!!FU&v9555<>v9315/v9560<>v9315:E;
!!DO15012/0/5/1:P;

!?FU15012;
!!COv9315:A3/x16/?y1/?y2;
!!VRy3&y2>0:S5*v9305;        击碎之斧、硬化之盾每胜利一场，加5*v9305所选等级
!!VRy4&y2>0:S7*v9305;        密银之甲、锋利之剑每胜利一场，加7*v9305所选等级
!!VRy5&y2>0:S3*v9305;        速度之靴、巫术项链每胜利一场，加3*v9305所选等级
!!VRy2&y2>0/y1=146:Sdy3;     击碎之斧
!!VRy2&y2>0/y1=154:Sdy3;     硬化之盾
!!VRy2&y2>0/y1=147:Sdy4;     密银之甲
!!VRy2&y2>0/y1=151:Sdy5;     速度之靴
!!VRy2&y2>0/y1=148:Sdy4;     锋利之剑
!!VRy2&y2>0/y1=150:Sdy5;     巫术项链
!!COv9315&y2>0:A3/x16/y1/y2;

********************金刚盾、雷神锤、混天镜、千手佛设置**************************

!?BG0&1000
!!VRv9301:S1;                       运行开关  v9301

!?MF1&1000;
!!FU&v9316=2:E;
!!FU|v9301<1/v9301>9:E;

**设置**
!!VRx1:S0;
!!VRx2:S0;
!!VRx3:S0;
!!VRx4:S0;
!!VRx5:S0;
!!VRx6:S0;
!!VRy1:S0;
!!VRy6:S0;
!!VRy13:S0;
!!VRy14:S0;
!!VRy15:S0;
!!VRy16:S0;
!!VRy21:S0;
!!VRy26:S0;
!!VRv9301&v9301=2:S6;
!!VRv9301&v9301=3:S7;
!!VRv9301&v9301=4:S8;
!!VRv9301&v9301=5:S9;

**读取**
!!MF:F?x1 W?x2;                                        x1=伤害值 x2=进攻方编号（2=箭塔、1=护城河、0=其他）
!!BG: N?x3 E?x4 A?x5;                                  x3=进攻方堆栈 x4=防守方堆栈  x5=动作种类
!!FU&x5<>6/x5<>7/x5<>9:E;
!!BMx3:T?y1 I?y2 N?y3 F?y4 G29/?y5/?y10;              （攻）y1=编号、y2=所属、y3=当前数量、y4=不反击、y5=火盾
!!BA:Hy2/?y6;                                         （攻）y6=所属英雄编号
!!VRy4:&65536;
!!BMx4&x4>-1:T?y21 I?y22 N?y23 R?y24 G29/?y25/?y11;   （防）y21=编号、y22=所属、y23=当前数量、y24=反击次数、y25=火盾
!!BA:Hy22/?y26;                                       （防）y26=所属英雄编号
!!HEv9315:E?y12/?x6;                                   x6=v9315英雄等级

**判断**
!!VRy13|y1<174/y1>191/y6<>v9315:S1;
!!VRy14|y21<174/y21>191/y26<>v9315:S1;
!!FU&y13>0/y14>0:E;
!!VRv9301|y3<1/y23<1:S1;
!!FU|y3<1/y23<1:E;
!!VRy15&y1<150/y1>144:S2;
!!VRy16&y21<150/y21>144:S2;

**伤害**
!!VRy17&v9307=2:Sx1*x6:20+x1;     雷神锤伤害
!!VRy17&v9307<>2:Sx1;
!!VRy18:Sx1*x6:30;                混天镜伤害
!!VRy19:Sx1*2-y18:2;
!!VRy20&v9306=2/y19<=1:S1;        金刚盾伤害
!!VRy20&v9306=2/y19>1:Sy19;
!!VRy20&v9306<>2:Sx1;

**第一轮**
!!MF&v9301=1/y6=v9315:Fy17;
!!MF&v9301=1/y26=v9315:Fy20;
!!BMx3&v9308=2/v9301=1/y26=v9315/x5=6/x2=0/y15<>2/y23>0:Ky18 V84;
!!DO15013/0/20/1 &v9309=2/v9301=1/y6=v9315/y23>0/x4<21:P100/x3/x4/x6/y17;
!!DO15013/21/41/1&v9309=2/v9301=1/y6=v9315/y23>0/x4>20:P100/x3/x4/x6/y17;

!!VRv9301&v9301=1/x5=6/y6=v9315/y4<1/y5<1/y24>0:S2;
!!VRv9301&v9301=1/x5=6/y26=v9315/y4<1/y24>0/y25<1:S2;
!!VRv9301&v9301=1/x5=6/y26=v9315/y4>0/y25>0:S3;
!!VRv9301&v9301=1/x5=6/y26=v9315/y4<1/y24<1/y25>0:S3;
!!VRv9301&v9301=1/x5=6/y6=v9315/y4<1/y5>0/y24>0:S4;
!!VRv9301&v9301=1/x5=6/y26=v9315/y4<1/y24>0/y25>0:S5;
!!FU&v9301>1/v9301<6:E;

**第二轮**
!!MF&v9301=6/y6=v9315/y3>0:Fy20;
!!MF&v9301=6/y26=v9315/y23>0:Fy17;
!!BMx4&v9308=2/v9301=6/y6=v9315/x5=6/x2=0/y16<>2/y3>0:Ky18 V84;
!!VRv9301&v9301=6:S1;

!!MF&v9301=7/y23>0:Fx1;
!!VRv9301&v9301=7:S1;

!!MF&v9301=8/y3>0:Fy20;
!!BMx4&v9308=2/v9301=8/y6=v9315/x5=6/x2=0/y16<>2/y3>0:Ky18 V84;
!!VRv9301&v9301=8:S7;

!!MF&v9301=9/y23>0:Fx1;
!!VRv9301&v9301=9:S6;

********************千手佛设置**************************************************

!?FU15013&v9309=2/x1=100;    P100/x3/x4/x6/y17
!!BMx16:N?y1 P?y3;
!!FU|y1<1/x16=x3:E;    去掉攻击目标堆栈
!!BMx2:P?y2;           指挥官位置
!!FU|y2>188/y2<0:E;
!!FU|y3>188/y3<0:E;
!!VRy4:Sy2:17+1;       指挥官所在行
!!VRy5:Sy2%17+1;       指挥官所在位
!!VRy6:Sy3:17+1;       怪物所在行
!!VRy7:Sy3%17+1;       怪物所在位
!!VRy8:Sy4-y6;         行差
!!VRy9&y8>=0:Sy8;
!!VRy9&y8<0:Sy8*-1;
!!VRy10:Sx4:8;         级别
!!FU|y10<1:E;
!!VRy11:Sy4%2;         行系数
!!VRy12:Sy9+y11:2;
!!VRy13:Sy9+1-y11:2;
!!VRy14:Sy5-y10+y12;   位负值
!!VRy15:Sy5+y10-y13;   位正值
!!BMx16&v9309=2/y9<=y10/y7>=y14/y7=<y15:Kx5 V8;

********************千手佛升级提示**********************************************

!?HL-1&v9309=2/v9316<>2;
!!HE-1:N?y1;
!!FU&y1<>v9315:E;
!!HEv9315:E?y3/?y4;
!!VRy5:Sy4%8;
!!FU&y5<>0:E;
!!VRy6&y5=0:Sy4:8;
!!VRy7&y5=0:Sy6+1*y6*3;
!!IF&v9309=2:M^恭喜您，您的千手佛技能现在升到%Y6级，
您现在的攻击范围是%Y7格。^;

********************************************************************************

;------------------------------多次射击--------------------------------

!?BG&1000;
!!BG:Q?y1 N?y2 E?y3 A?y5;
!!BHy1:N?y4;
!!FU|y2<0/y3<0/y4<>v9315/y4<0/y5<>7:E;[限制条件]y2和y3为存在堆栈编号,y4=v85为指定英雄,y5=7表示是堆栈射击的动作
!!BMy2:T?y11 N?y12;
!!BMy3:T?y13 N?y14;
!!FU|y11<0/y13<0/y12<1/y14<1/y11=149:E;[本堆栈和目标生物存在,且本堆栈不是箭塔]
!!HEv9315:E?j/?k;
!!VRy42&k>0/k<20:S0;
!!VRy42&k>19/k<30:S1;
!!VRy42&k>29/k<40:S2;
!!VRy42&k>39/k<60:S3;
!!VRy42&k>59/k<80:S4;
!!VRy42&k>79|k=0:S9;
!!FU15019:Py2/y3/y42;

***
!?FU15019;
**A堆栈射击B堆栈且产生伤害(箭塔射击除外)
**x1=堆栈号
**x2=目标堆栈号
**x3=射击次数(需>0)
!!FU|x1<0/x1>41/x2<0/x2>41/x1=x2/x3<1:E;[#0]
!!BMx1:T?y1 N?y2;     [#1]
!!BMx2:T?y11 N?y12;
!!FU|y1<0/y11<0/y2<1/y12<1/y1=149/y11=149:E;
!!BMx1:F?i U3/?j;     [标志与弹药]
!!VRi:&4;
!!FU|i<>4/j<1:E;      [非箭手或无弹药(若无射击动作会崩溃)]
*!FU&y1>144/y1<150:E; [排除战争机器]
!!UN:C6919200/4/?y20; [内存]
!!VRy31:Sx1 *1352 +21708 +y20;[A方内存地址]
!!VRy41:Sx2 *1352 +21708 +y20;[B方内存地址]
!!SN:E4453920/2/y31/y41;      [射击且伤害]
!!VRx3:-1;
!!SN&x3>0:G0;                 [循环代码]

爱的燃火

不懂只能帮顶了。
ps：其实弃总你用小摊手就可以了嘛。