【请教】关于scritp51指挥官加强脚本

yexian7

51脚本改变了指挥官宝石的作用，原wog是增加固定数值，在51脚本变为提升技能等级。
这是51脚本中关于“红宝石”的命令：
**  object trigger - ruby
!?OB101/8&v7185=1;
!!HE-1:N?y-1;
!!COy-1:S0/?y-2 S3/?y-3 D?y-6 E?y-7 N?z1;                    [get Attack / Damage levels, check if alive, enabled, get name]
!!OB998&y-6=0/y-7=1:T101 U6;                                 [set to chest 6 if commander is alive, enabled]
!!COy-1&y-6=0/y-7=1/y-2>y-3:S3/d1;                           [if Attack > Damage add 1 to Damage level]
!!COy-1&y-6=0/y-7=1/y-2<y-3:S0/d1;                           [if Attack < Damage add 1 to Attack level]
!!VRy-4&y-6=0/y-7=1/y-2=y-3/y-2<5:S0 T99;                    [percentage roll]
!!COy-1&y-6=0/y-7=1/y-2=y-3/y-2<5/y-4<50:S3/d1;              [if Attack = Damage and < 6 and roll is < 50 add 1 to Damage level]
!!COy-1&y-6=0/y-7=1/y-2=y-3/y-2<5/y-4>49:S0/d1;              [if Attack = Damage and < 6 and roll is < 50 add 1 to Attack level]

其中最后一句!!COy-1&y-6=0/y-7=1/y-2=y-3/y-2<5/y-4>49:S0/d1; 增加攻击技能等级的意思，S0代表攻击技能，1代表升一级，d的意思还不清楚。问题是这样的，已知S0/d1代表提升攻击技能1级，能否把它给为增加原wog的固定值呢？比如增加攻击力2点，这个“增加攻击力2点”应该怎么来写呢？

yexian7

问题是这样的，已知S0/d1代表提升攻击技能1级，能否把它改为像原wog一样增加固定值呢？比如增加攻击力2点，这个“增加攻击力2点”应该怎么来写呢？

克招

d2

克招

d的含义是在原数值上增加

克招

具体命令看CO接受器的帮助部分

yexian7

S0代表“攻击技能等级”，S0/d2则代表“攻击技能等级加2”
那“攻击力加2”中“攻击力值”是由什么表示呢？
在51脚本中编辑指挥官攻击技能的命令是这样的：
** function to edit commander stats
!?FU7070;         x1=hero number

!!COx1:X2/?y2 T?y5;                              [get commander level & type]
** attack - base 5 + 1/2 x level - skill adds +25%,+50%,+75%,+100%,+125%
!!COx1:S0/?y3;                                   [get attack level]
!!VRy4&y3=0:Sy2 :2 +5;                           [if attack=0 set attack to 5 + 1/2 level]
!!VRy4&y3=1:Sy2 :2 +5 *125 :100 -2;              [if attack=1 set attack to 5 + 1/2 level x 125%]
!!VRy4&y3=2:Sy2 :2 +5 *150 :100 -5;              [if attack=2 set attack to 5 + 1/2 level x 150%]
!!VRy4&y3=3:Sy2 :2 +5 *175 :100 -9;              [if attack=3 set attack to 5 + 1/2 level x 175%]
!!VRy4&y3=4:Sy2 :2 +5 *2 -15;                    [if attack=4 set attack to 5 + 1/2 level x 200%]
!!VRy4&y3=5:Sy2 :2 +5 *225 :100 -25;             [if attack=5 set attack to 5 + 1/2 level x 225%]
!!COx1:P0/y4;                                    [set attack]

其中!!COx1:S0/?y3;                                   [get attack level] 表示S0为“攻击技能等级”
最后一行!!COx1:P0/y4;                                    [set attack]，有这句我推断P0应该代表“攻击力值”的意思，不过不确定。如果P0确实是攻击力值的意思，那么把S0/d2改为P0/d2应该就是攻击力值加2。但问题是，测试结果是这样的，拾取宝石后没有任何效果（只有虚假的文本提示，技能等级和攻击值都没有改变），这是怎么回事呢？（编辑红宝石的命令位于脚本331-346行）

克招

都叫你看ERM帮助了，给攻击值+2的命令是：
!!CO-1:P0/d2;

克招

!!CO$:...;
!#CO$:...;    $=-2 - 对所有指挥官 Commanders应用
   $=-1 - 对当前指挥官Commander 应用(当前英雄的)
   $>=0 -对一个特定的指挥官 Commander应用

P#/$;
Commander 状态
   # - 状态类型
         0 - Attack
         1 - Defense
         2 - Hit Points
         3 - Damage
         4 - Magic Power
         5 - Speed
         6 - Magic Resistance
   $ - 值

yexian7

比如原脚本这一句         !!COy-1&y-6=0/y-7=1/y-2=y-3/y-2<5/y-4>49:S0/d1;
我写成这样？             !!COy-1&y-6=0/y-7=1/y-2=y-3/y-2<5/y-4>49:P0/d2;
还是这样？               !!CO-1:P0/d2;

两个句子在测试中都没有真正效果，只有虚假的对话提示。

（这些含义是我的推测：y-1代表当前[wiki]英雄[/wiki]的指挥官，y-2代表攻击力，y-3代表伤害力，y-6代表生死，y-7代表enabled）

克招

y-1是一个变量，知道什么是变量吧？如果这都不知道我也懒得解释了。
你看看前面对y-1的定义就知道是什么值了，CO-1代表的是当前英雄，而y-1不一定等于-1，所以如果你要改当前英雄的话，建议改为
!!CO-1&y-6=0/y-7=1/y-2=y-3/y-2<5/y-4>49:P0/d2;
当然&y-6=0/y-7=1/y-2=y-3/y-2<5/y-4>49这个部分是条件，要看你是否需要条件，如果不需要条件就是!!CO-1:P0/d2;

yexian7

9楼的两个改写句子实际上都是对的，问题不在“红宝石”的脚本语句中，而是在“指挥官升级的攻击技能等级”脚本中，即6楼我贴的那段脚本。那段脚本的最后一句
!!COx1:P0/y4;     
这句命令在起作用，这段是  [set attack]    设置攻击力值的命令。如果删掉这句则上面讨论修改的命令都有效(真正有增加攻击数值)，但会因为少取了他的攻击值设置作用而使指挥官升级失去攻击技能的属性提升。如果这段命令存在，则关于“红宝石”的修改命令都没有效果（只有提示，没有增加值）。我的程度只能做脚本最基本的修改，对于这样的情况无能为力。
谢谢你，耐心的解答非常感谢！

yexian7

翻翻老贴，发现入门时问题好白痴，多谢克招耐心。