急死人啊！哪位能帮忙看一下这个脚本哪里有错？

szx_9933

这个是"[wiki]神[/wiki]迹3.0"里的[wiki]英雄[/wiki][wiki]转职[/wiki][wiki]ERM[/wiki]，当访问高山堡垒后[wiki]游戏[/wiki]战斗时总出错，提示错误如下面的附件图片：
下面是英雄转职ERM（script96.erm）的内容，是不是和这个ERM有关系呢？
ZVSE
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
ERMS_ScriptDate=6.5(May).2009
ERMS_PoweredBy=ERM Script Editor v.1.2.6.32
;variable used: FU29100-FU29106 ,v5900-v5903,w152,TM20
;important: w152 should not be changed in other script!!!!!
;temperary variables: Flag 1, z22-z24
; w152 - Advance class type
; w152 = 1, Archmage; 2, General; 3, Lord; 4, Breeder
; Requirement for Advance Class: level >= 20, visit Hill Fort
; Archmage:
; - 英雄为法师类，即Cleric, Druid, Wizard等 class # 为奇数
; - Wisdom,Fire/Air/Water/Earth Magic, Intelligence等6项技能到Expert
; General:
; - 英雄为骑士类，即Knight, Ranger, Alchemist等 class # 为偶数
; - Offense, Armorer, Archery, Tactics, Artillery,Ballistics等6项技能到Expert
; Lord:
; - Pathfinding, Logistics, Navigation, Estates, Sorcery, Scouting等6项技能到Expert
; Breeder:
; - Scouting, Diplomacy, Leadership, Luck, Learning,First Aid等6项技能到Expert
; Archmage - 魔法伤害力+100%
; General - 带领的部队战斗时最大伤害力+25% +1，恒定最大伤害，远程兵种弹药999 [BMx16:U#/$]
; Lord - 特技改为Estates, 每天增加Wood&Ore 4个，其他资源2个
; Breeder - 我方所有城镇生物增长+1

!?OB35; [visit School of Magic]
!!HE-1:N?y-11; [get hero #]
!!HEy-11:E?y-13/?y-12; [get hero level]
!!FU&y-12<20:E; [condition 0]
!!IF:Wy-11;
!!FU&w152<>0:E;
!!HEy-11:B2/?y-13; [get hero class]
!!VRy-13:%2;
!!FU29101&y-13=1:P1/y-11/7/14/15/16/17/24;
!!FU29101&y-13=0:P2/y-11/1/10/19/20/22/23;
!!FU29101:P3/y-11/0/2/3/5/13/25;
!!FU29101:P4/y-11/3/4/6/9/21/27;

!?FU29101;
; x1 - advance class type
; x2 - hero #
; x3~x8 - second skills
!!HEx2:Sx3/?y1 Sx4/?y2 Sx5/?y3 Sx6/?y4 Sx7/?y5 Sx8/?y6;
!!FU|y1<3/y2<3/y3<3/y4<3/y5<3/y6<3:E;
!!IF&1000:V1/0; [set Flag 1 to 0]
!!IF&1000/x1=1:Q1^你想升级成为{法师}吗?
{大法师} 能造成高达 {800%}的魔法伤害 ^;
!!IF&1000/x1=2:Q1^你想升级成为 {将军}吗?
{大将军} 所率领的所有部队都能打出:
+{110%%}+1 的
{物理伤害}
{所有射击部队} 拥有888发弹药 ^;
!!IF&1000/x1=3:Q1^你想升级成为 {领主}吗?
领主将能为你带来更多的金钱,并且每天多为你的王国赚取所有资源各 8 个.^;
!!IF&1000/x1=4:Q1^你想升级成为 {教头}吗?
教头每周能让你的王国中所有[wiki]战士[/wiki]的训练数量增加 2 .^;
!!VRy1:S0;
!!VRy1&1000/1:S1; [Human]
!!VRy1&-1000:S0 R1; [AI choose randomly]
!!FU&y1=0:E;
!!VRw152:Sx1;
!!HEx2:B0/?z22; [get hero name]
!!VRz23&x1=1:S^法师.^+z22;
!!VRz23&x1=2:S^将军.^+z22;
!!VRz23&x1=3:S^领主.^+z22;
!!VRz23&x1=4:S^.^+z22;
!!VRz24:Sz23; [Store old name in z25]
!!VRz24:M4/?y2; [Length of new name: y2]
!!VRy2&y2>12:S12;

!!VRz24:M1/z23/0/y2; [Store up to first 12 characters of new name in z25]
!!HEx2:B0/z24; [Change hero's name if text entered: z3]
!!HEx2&w152=3:X0/13; [set Lord specialist in Estates]
!!UN:P39/?v5900;
!!VRw28&v5900=1/w152=3:S2003; [if HERO SPECIALIZATION BOOST]
-----------------------------------------------------------------------------------
!?MR0; [ Archmage ]

!!BG:A?y-3 H?y-4; [action type, Hero #]
!!FU&y-3<>1:E;
!!IF:Wy-4;
!!FU&w152<>1:E;
!!MR:D?y-2; [get spell damage]
!!VRy-2:*8; [计算新杀伤。这里是×8倍]
!!MR:Dy-2; [set new damage]

!?BF; [berore battle]
!!BH0:N?v5900; [# of left hero]
!!IF&v5900>=0:Wv5900;
!!DO29103/0/20/1&v5900>=0/w152=2:Pv5900;
!!BH1:N?v5900; [# of right hero]
!!IF&v5900>=0:Wv5900;
!!DO29103/21/41/1&v5900>=0/w152=2:Pv5900;
----------------------------------------------------------------------------------
!?FU29103; [General]
;x1 - hero #
!!BMx16:T?y1; [type of monster, y1]
!!FU&y1<0:E;
!!BMx16:S?y2; [speed]
!!FU&y2<1:E; [ war machines]
!!MA:Ey1/?y2 My1/?y3; [damage of monster, y3~y2]
!!FU&y2<=0;
!!VRy4:Sy2:10+1; [这里是杀伤计算公式。前面数字的倒数是增加百分比，后面是再加1.这里就是10％＋1]
!!VRy5:Sy4 + y2 - y3;
!!BMx16:U2/dy4 U1/dy5;
!!BMx16:F?y4;
!!VRy4:&4;
!!FU&y4=0:E; [if not shooter]
!!BMx16:U3/888; [set shots to 999]
----------------------------------------------------------------------------------
!?FU29104;
;x1 = 1 Monday now
!!OW:H-1/5900/x16; [store x16th hero of that player in v5902]
!!IF:Wv5900; [set w var reference to current hero]
!!VRv5902&w152=4:+2;[increases Breeder number if Monday]
!!FU&w152<>3:E; [exit if that hero isn't Lord]
!!OW:R-1/0/d8 R-1/2/d8; [+4 Wood, +4 Ore]
!!OW:R-1/1/d8 R-1/3/d8 R-1/4/d8 R-1/5/d8 R-1/7/d8;

!?FU29105;
!!CA0/x16:O?y1;
!!OW:C?y2;
!!DO29106/0/6/1&y1=y2:Px16; [if current player is owner then cycle]

!?FU29106;
!!CA0/x1:M1/x16/dv5902/dv5902; [increase monsters in dwelling]

!?TM20; [Lord]
!!OW:H-1/5901/0; [store current color's number of heroes in v5901]
!!VRv5903:Sc%7; [v5902=1 is Monday now]
!!VRv5902:S0; [Set number of Breeder to 0 if Monday]
!!DO29104/1/v5901/1:P; [loop through every hero a player has]
!!UN:U98/-1/?v5901; [get town number on the map]
!!VRv5901:-1;
!!DO29105/0/v5901/1&v5903=1:P;[creatures grow only on mondays]

[ 本帖最后由 szx_9933 于 2009-8-27 08:50 编辑 ]

szx_9933

忘了说了，把弹药车拿下就没事了。

fly123

!?TM20这个计时器没看见那里有设定。

fly123

这个脚本我也在用。
ZVSE
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
ERMS_ScriptDate=17.5(May).2005
ERMS_PoweredBy=ERM Script Editor v.1.2.6.32
;variable used: FU29100-FU29106 ,v5900-v5903,w152,TM20
;important: w152 should not be changed in other script!!!!!
;temperary variables: Flag 1, z22-z24
; w152 - Advance class type
; w152 = 1, Archmage; 2, General; 3, Lord; 4, Breeder
; Requirement for Advance Class: level >= 20, visit Hill Fort
; Archmage:
; - 英雄为法师类，即Cleric, Druid, Wizard等 class # 为奇数
; - Wisdom,Fire/Air/Water/Earth Magic, Intelligence等6项技能到Expert
; General:
; - 英雄为骑士类，即Knight, Ranger, Alchemist等 class # 为偶数
; - Offense, Armorer, Archery, Tactics, Artillery,Ballistics等6项技能到Expert
; Lord:
; - Pathfinding, Logistics, Navigation, Estates, Sorcery, Scouting等6项技能到Expert
; Breeder:
; - Scouting, Diplomacy, Leadership, Luck, Learning,First Aid等6项技能到Expert
; Archmage - 魔法伤害力+300%
; General - 带领的部队战斗时最大伤害力+25% +1，恒定最大伤害，远程兵种弹药999 [BMx16:U#/$]
; Lord - 特技改为Estates, 每天增加Wood&Ore 4个，其他资源2个
; Breeder - 我方所有城镇生物增长+1

!?OB35; [visit School of Magic]
!!HE-1:N?y-11; [get hero #]
!!HEy-11:E?y-13/?y-12; [get hero level]
!!FU&y-12<20:E; [condition 0]
!!IF:Wy-11;
!!FU&w152<>0:E;
!!HEy-11:B2/?y-13; [get hero class]
!!VRy-13:%2;
!!FU29101&y-13=1:P1/y-11/7/14/15/16/17/24;
!!FU29101&y-13=0:P2/y-11/1/10/19/20/22/23;
!!FU29101:P3/y-11/0/2/3/5/13/25;
!!FU29101:P4/y-11/3/4/6/9/21/27;

!?FU29101;
; x1 - advance class type
; x2 - hero #
; x3~x8 - second skills
!!HEx2:Sx3/?y1 Sx4/?y2 Sx5/?y3 Sx6/?y4 Sx7/?y5 Sx8/?y6;
!!FU|y1<3/y2<3/y3<3/y4<3/y5<3/y6<3:E;
!!IF&1000:V1/0; [set Flag 1 to 0]
!!IF&1000/x1=1:Q1^你确定升级你的英雄为 {法师}?
@{法师} 施放攻击性魔法时能造成 {300%} 的魔法伤害^;
!!IF&1000/x1=2:Q1^你确定升级你的英雄为 {将军}?
@部队在{将军} 的带领下将获得能力加强:
@+{10%%}+1 的伤害
@{恒定最大伤害}
@{射手} 有 999 发弹药。^;
!!IF&1000/x1=3:Q1^你确定升级你的英雄为 {领主}?
@领主的特长是资源,每天能够提供 4 个木材和矿石以及其他资源各 2 个.^;
!!IF&1000/x1=4:Q1^你确定升级你的英雄为 {驯兽师}?
@驯兽师可以让你旗下的所有城镇生物产量 + 1。^;
!!VRy1:S0;
!!VRy1&1000/1:S1; [Human]
!!VRy1&-1000:S0 R1; [AI choose randomly]
!!FU&y1=0:E;
!!VRw152:Sx1;
!!HEx2:B0/?z22; [get hero name]
!!VRz23&x1=1:S^法师.^+z22;
!!VRz23&x1=2:S^将军.^+z22;
!!VRz23&x1=3:S^领主.^+z22;
!!VRz23&x1=4:S^驯兽师.^+z22;
!!VRz24:Sz23; [Store old name in z25]
!!VRz24:M4/?y2; [Length of new name: y2]
!!VRy2&y2>12:S12;

!!VRz24:M1/z23/0/y2; [Store up to first 12 characters of new name in z25]
!!HEx2:B0/z24; [Change hero's name if text entered: z3]
!!HEx2&w152=3:X0/13; [set Lord specialist in Estates]
!!UN:P39/?v5900;
!!VRw28&v5900=1/w152=3:S2003; [if HERO SPECIALIZATION BOOST]
-----------------------------------------------------------------------------------
!?MR0; [ Archmage ]

!!BG:A?y-3 H?y-4; [action type, Hero #]
!!FU&y-3<>1:E;
!!IF:Wy-4;
!!FU&w152<>1:E;
!!MR:D?y-2; [get spell damage]
!!VRy-2:*3; [计算新杀伤。这里是×3倍]
!!MR:Dy-2; [set new damage]

!?BF; [berore battle]
!!BH0:N?v5900; [# of left hero]
!!IF&v5900>=0:Wv5900;
!!DO29103/0/20/1&v5900>=0/w152=2:Pv5900;
!!BH1:N?v5900; [# of right hero]
!!IF&v5900>=0:Wv5900;
!!DO29103/21/41/1&v5900>=0/w152=2:Pv5900;
----------------------------------------------------------------------------------
!?FU29103; [General]
;x1 - hero #
!!BMx16:T?y1; [type of monster, y1]
!!FU&y1<0:E;
!!BMx16:S?y2; [speed]
!!FU&y2<1:E; [ war machines]
!!MA:Ey1/?y2 My1/?y3; [damage of monster, y3~y2]
!!FU&y2<=0;
!!VRy4:Sy2:10+1; [这里是杀伤计算公式。前面数字的倒数是增加百分比，后面是再加1.这里就是10％＋1]
!!VRy5:Sy4 + y2 - y3;
!!BMx16:U2/dy4 U1/dy5;
!!BMx16:F?y4;
!!VRy4:&4;
!!FU&y4=0:E; [if not shooter]
!!BMx16:U3/999; [set shots to 999]
----------------------------------------------------------------------------------
!?FU29104;
;x1 = 1 Monday now
!!OW:H-1/5900/x16; [store x16th hero of that player in v5902]
!!IF:Wv5900; [set w var reference to current hero]
!!VRv5902&w152=4:+1;[increases Breeder number if Monday]
!!FU&w152<>3:E; [exit if that hero isn't Lord]
!!OW:R-1/0/d4 R-1/2/d4; [+4 Wood, +4 Ore]
!!OW:R-1/1/d2 R-1/3/d2 R-1/4/d2 R-1/5/d2;

!?FU29105;
!!CA0/x16:O?y1;
!!OW:C?y2;
!!DO29106/0/6/1&y1=y2:Px16; [if current player is owner then cycle]

!?FU29106;
!!CA0/x1:M1/x16/dv5902/dv5902; [increase monsters in dwelling]

!?TM20; [Lord]
!!OW:H-1/5901/0; [store current color's number of heroes in v5901]
!!VRv5903:Sc%7; [v5902=1 is Monday now]
!!VRv5902:S0; [Set number of Breeder to 0 if Monday]
!!DO29104/1/v5901/1:P; [loop through every hero a player has]
!!UN:U98/-1/?v5901; [get town number on the map]
!!VRv5901:-1;
!!DO29105/0/v5901/1&v5903=1:P;[creatures grow only on mondays]
-----------------------------------------------------------------------------------
!?FU29100;
!!IF:Wx16;
!!VRw152:S0; [set all heros' w152 to 0]

!?FU29102;
!!DO29100/0/155/1:P;
-----------------------------------------------------------------------------------
!#FU29102:P;
!#TM20:S2/999/1/255;

szx_9933

那应该怎么改呢？