如何在ERM中图片下放置解释文字？

暗黑龙守护神 · 发表于 2009-6-25 10:58:51

秘银矿脚本中秘银图片下没有“1/天”看着很不爽。

ZVSE
*Mithril Smelter
*Uses vars v1800-v1807
*Uses functions FU1800-FU1802
!#TM83:S2/999/7/255;Gives resource on day 2 every week,set up timer for 7 daily,replace 7 with 1 for daily,with 2 for two daily and so on...
!#VRz100:S^秘银熔炉^;
!#HT63/27:T100;
!#VRv1800:S0; player 0
!#VRv1801:S0; player 1
!#VRv1802:S0; player 2
!#VRv1803:S0; player 3
!#VRv1804:S0; player 4
!#VRv1805:S0; player 5
!#VRv1806:S0; player 6
!#VRv1807:S0; player 7
!?OB63/27; If visited
!!PO998:O?i; get owner
!!HE-1:O?j; get hero owner
!!FU1800&i<>j:Pi/j; if not owner then change owner
!?FU1800;
!!PO998:Ox2; set new owner
!!IF&1000:Q1/7/0/1^{秘银熔炉}
你控制了一口秘银熔炉，它将每天向你提供1秘银。^;
!!FU1801:Pj; hint text
!!VRy1:S8; default is no owner(y1=8)
!!VRy1&x1>-1/x1<8:S1800 +x1; if previous owner was a player then index to his var is y1
!!VRy2:S1800 +x2; index to visiting hero's var is y2
!!VRvy1&y1<>8:-1; decrease previous owner's var
!!VRvy2:+1; increase visitor's var
!?FU1801;
!!VRz100:S^秘银熔炉 ^; calc hint text into z100
!!VRz100&x1=0:+^红色玩家占有。(秘银)^;
!!VRz100&x1=1:+^蓝色玩家占有。(秘银)^;
!!VRz100&x1=2:+^褐色玩家占有。(秘银)^;
!!VRz100&x1=3:+^绿色玩家占有。(秘银)^;
!!VRz100&x1=4:+^橙色玩家占有。(秘银)^;
!!VRz100&x1=5:+^紫色玩家占有。(秘银)^;
!!VRz100&x1=6:+^青色玩家占有。(秘银)^;
!!VRz100&x1=7:+^粉色玩家占有。(秘银)^;
!!OB998:H100; set hint text
!?TM83; timer trigger
!!DO1802/0/1/10:P; give mithril
!?FU1802;
!!VRi:Sx16; calc index
!!VRi:+1800; calc index
!!VRj:Svi; store in j for easier reference
!!OW:Rx16/7/dj; give mithril
*!OW:Rx16/7/?k; ? current mithril
*!VRk:+j; ? new mithril
*!OW:Rx16/7/j; store new mithril

复制代码

附图。

arongpan · 发表于 2009-6-25 21:44:39

很简单,把原来的
!!IF&1000:Q1/7/0/1^{秘银熔炉}

你控制了一口秘银熔炉，它将每天向你提供1秘银。^;

改为:
!!IF&1000:Q1/7/-1/1^{秘银熔炉}

你控制了一口秘银熔炉，它将每天向你提供1秘银。^;

[ 本帖最后由 arongpan 于 2009-6-25 21:47 编辑 ]