为攻击方式切换增加快捷键
切换攻击方式的选项框太小了，点着麻烦。而且影响游戏流畅度。
所以想给这几个切换弄几个快捷键。
我一直以为这几个切换功能是封神的，前几天询问贤知和其他大人的时候，才发现居然是era自带的，而且是硬编码的。
也就是说，没有现成的erm脚本。
经参考了寻梦人关于切换攻击方式的脚本后，我自己写了一个，并加入了快捷键。
关闭和启用：
射击，快捷键Q
生物施法，快捷键G
攻击返回，快捷键Z（仅对飞马等有攻返经验特技的生物有效。暗黑龙，鹰身女妖（巫）的攻返不属于生物标记，也不是经验特技，erm改不了，还得用era自带的右击防御键切换。）
回合结束时，自动切换回默认攻击方式。
没有屏蔽自带的切换，但是最好不要在同一个回合内混用。
脚本
ZVSE
**variables used: v5190-v5194
**End of action, return to default
**Not affecting Harpy and Darkness Dragon's Att & Return
!#VRv5190:S0;//shots remaining
!#VRv5191:S0;//spells remaining
!#VRv5192:S-1;//stack number
!#VRv5193:S0;//stack number for !!EA
!#VRv5194:S-1;//A&R exp line
!?FU77003; when press a key
!!SN:L^Era.dll^/?y1 Ay1/^GetGameState^/?y2 Ey2/1/?y98;
!!FU&y99<>4662240:E; exit if not combat screen
!!SN:X?y3;
!!BG:N?v5192;
!!FU|v5192<0/v5192>41;
!!if&y3=81:; //press Q
!!BMv5192:F?y5;
!!VRy6:Sy5 &4; //chek shooting flag
!!FU&y6=0:E;
!!if&v5190<=0:;
!!BMv5192:U3/?v5190;//store shots
!!FU&v5190<=0:E;//**0 shots no need to turn off**
!!BMv5192:U3/0;//set shots to 0
!!IF:L^射击已关闭^;
!!FU:E;
!!el:;
!!BMv5192:U3/v5190; //restore shots
!!VRv5190:S0;//clear stored
!!IF:L^射击已启用^;
!!FU:E;
!!en:;
!!en:;
!!if&y3=71:;//press G=71
!!if&v5191<=0:;
!!BMv5192:E?v5191;//store casts
!!FU&v5191<=0:E;//**0 casts no need to turn off**
!!BMv5192:E0;//set casts to 0
!!IF:L^施法已关闭^;
!!FU:E;
!!el:;
!!BMv5192:Ev5191;//restore casts
!!VRv5191:S0;//clear stored
!!IF:L^施法已开启^;
!!FU:E;
!!en:;
!!en:;
!!if&y3=90:;//press Z, att & return
!!VRv5193:S-1 -v5192;
!!EAv5193:F102/98/?v5194;
!!FU|v5194<0/v5194>13:E;
!!EAv5193:Bv5194/?y7/?y8/?y9/d/d/d/d/d/d/d/d/d/d/d;
!!if&y7=1/y8=102/y9=98:;
!!EAv5193:Bv5194/0/d/d/d/d/d/d/d/d/d/d/d/d/d;
!!IF:L^攻返已关闭^;
!!FU:E;
!!en:;
!!if&y7=0/y8=102/y9=98:;
!!EAv5193:Bv5194/1/d/d/d/d/d/d/d/d/d/d/d/d/d;
!!IF:L^攻返已开启^;
!!FU:E;
!!en:;
!!en:;
!?BG1&v5190>0;//auto restore shots after action
!!BMv5192:U3/v5190; //restore shots
!!VRv5190:S0; //clear stored
!?BG1&v5191>0;//auto restore casts after action
!!BMv5192:Ev5191; //restore casts
!!VRv5191:S0; //clear stored
!?BG1&v5193<0;//auto restore attack and return after action
!!EAv5193:Bv5194/d/?y1/?y2/d/d/d/d/d/d/d/d/d/d/d;
!!EAv5193&y1=102/y2=98:Bv5194/1/d/d/d/d/d/d/d/d/d/d/d/d/d;
!!VRv5193:S0;
话说有3个键来切换,感觉变得更复杂了吧.
用一个快捷键弹出原版那个选项框可能更好点吧.
不过说那选择框太小不好点,就另当别论了. 贤知有您 发表于 2016-2-21 09:57
话说有3个键来切换,感觉变得更复杂了吧.
用一个快捷键弹出原版那个选项框可能更好点吧.
不过说那选择框太 ...
设一个弹框快捷键，是按一下键盘，再点选一个，是两步。
设3个快捷键，记得多一点，但是只按一下，是一步。
各有优势吧。
我有点犹豫的就是，该设成开关功能，还是像原来一样直接选取攻击方式。
另外，你说的弹窗原版那个框是什么意思？erm能做到吗？感觉不行啊。 XEricSin 发表于 2016-2-21 12:21
设一个弹框快捷键，是按一下键盘，再点选一个，是两步。
设3个快捷键，记得多一点，但是只按一下，是一 ...
别忘了我的特长.;aieol;
!?FU77003; [按键Q]弹出攻击方式
!!SN:X?y1;
!!FU&y1<>81:E;
!!SN:L^Era.dll^/?y1 Ay1/^GetGameState^/?y2 Ey2/0/?y3;
!!FU|y3<>4205280/y4<>4662240:E;[战场]
!!SN:X?y1/1; [禁止原功能]
!!UN:C7742986/1/235;
!!SN:E7742949/0;
!!UN:C7742986/1/116; 贤知有您 发表于 2016-2-21 20:34
别忘了我的特长.
!?FU77003; [按键Q]弹出攻击方式
还是贤知大人这个来的爽快。{:2_142:}
页:
[1]
