领导术招枪兵无bug版(发布两年纪念提供下载)

yjwlhy · 发表于 2007-2-8 23:06:56

这是我自己写的[wiki]ERM[/wiki],拿出来给些对ERM不懂的人.顺便请高手改正不合理之处.
1本ERM是用领导术招枪兵.低级为10%,高级为20%,专家级为30%.
2只有战胜方能招.
3对方无损状态下逃跑或者投降也能找到一个.
4战胜后根据对方每一队兵的伤亡数来招.每个兵的HP×招兵百分比×该队兵的伤忙数量,每10hp算一个枪兵,但不会超过该队兵的总伤亡数.
5该[wiki]英雄[/wiki]如果拥有招魂术,则领导术招兵失效.

ZVSE
!?BA0;
!!VRv9140:C0/0/0/0/0/0/0;                [no creatures to resurrect after battle attacker]
!!VRv9147:C0/0/0/0/0/0/0;                [no creatures to resurrect after battle defender]
!!BA:M0/0/?v9101/?v9140;                   [save qty in each of attacking hero's slots for after battle]
!!BA:M0/1/?v9102/?v9141;                   [to determine qty lost for first aid skill]
!!BA:M0/2/?v9103/?v9142;                   // new by Thomas Franz: save creature type in v9101-v9114
!!BA:M0/3/?v9104/?v9143;
!!BA:M0/4/?v9105/?v9144;
!!BA:M0/5/?v9106/?v9145;
!!BA:M0/6/?v9107/?v9146;
!!BA:M1/0/?v9108/?v9147;                   [save qty in each of defending hero's slots for after battle]
!!BA:M1/1/?v9109/?v9148;                   [to determine qty lost for first aid skill]
!!BA:M1/2/?v9110/?v9149;
!!BA:M1/3/?v9111/?v9150;
!!BA:M1/4/?v9112/?v9151;
!!BA:M1/5/?v9113/?v9152;
!!BA:M1/6/?v9114/?v9153;
!!BA:H0/?v9902;                            [get attacking hero #]
!!BA:H1/?v9903;                            [get defending hero #]
!?BA1;
!!HEv9902&v9902>-1:O?y20;                [get attacking hero's owner]
!!HEv9903&v9903>-1:O?y30;                [get defending hero owner]
!!BA:M0/0/?y11/?y21;                   [save qty in each of attacking hero's slots for after battle]
!!BA:M0/1/?y12/?y22;                   [to determine qty lost for first aid skill]
!!BA:M0/2/?y13/?y23;                   // new by Thomas Franz: save creature type in v9101-v9114
!!BA:M0/3/?y14/?y24;
!!BA:M0/4/?y15/?y25;
!!BA:M0/5/?y16/?y26;
!!BA:M0/6/?y17/?y27;
!!BA:M1/0/?y31/?y41;                   [save qty in each of defending hero's slots for after battle]
!!BA:M1/1/?y32/?y42;                   [to determine qty lost for first aid skill]
!!BA:M1/2/?y33/?y43;
!!BA:M1/3/?y34/?y44;
!!BA:M1/4/?y35/?y45;
!!BA:M1/5/?y36/?y46;
!!BA:M1/6/?y37/?y47;
!!VRy51&v9902>-1/y20>-1/v9108<>-1:Sv9147-y41;
!!VRy52&v9902>-1/y20>-1/v9109<>-1:Sv9148-y42;
!!VRy53&v9902>-1/y20>-1/v9110<>-1:Sv9149-y43;
!!VRy54&v9902>-1/y20>-1/v9111<>-1:Sv9150-y44;
!!VRy55&v9902>-1/y20>-1/v9112<>-1:Sv9151-y45;
!!VRy56&v9902>-1/y20>-1/v9113<>-1:Sv9152-y46;
!!VRy57&v9902>-1/y20>-1/v9114<>-1:Sv9153-y47;
!!VRy51&v9903>-1/y30>-1/v9101<>-1:Sv9140-y21;
!!VRy52&v9903>-1/y30>-1/v9102<>-1:Sv9141-y22;
!!VRy53&v9903>-1/y30>-1/v9103<>-1:Sv9142-y23;
!!VRy54&v9903>-1/y30>-1/v9104<>-1:Sv9143-y24;
!!VRy55&v9903>-1/y30>-1/v9105<>-1:Sv9144-y25;
!!VRy56&v9903>-1/y30>-1/v9106<>-1:Sv9145-y26;
!!VRy57&v9903>-1/y30>-1/v9107<>-1:Sv9146-y27;
!!MA&v9902>-1/y20>-1/v9108<>-1:Pv9108/?y61;
!!MA&v9902>-1/y20>-1/v9109<>-1:Pv9109/?y62;
!!MA&v9902>-1/y20>-1/v9110<>-1:Pv9110/?y63;
!!MA&v9902>-1/y20>-1/v9111<>-1:Pv9111/?y64;
!!MA&v9902>-1/y20>-1/v9112<>-1:Pv9112/?y65;
!!MA&v9902>-1/y20>-1/v9113<>-1:Pv9113/?y66;
!!MA&v9902>-1/y20>-1/v9114<>-1:Pv9114/?y67;
!!MA&v9903>-1/y30>-1/v9101<>-1:Pv9101/?y61;
!!MA&v9903>-1/y30>-1/v9102<>-1:Pv9102/?y62;
!!MA&v9903>-1/y30>-1/v9103<>-1:Pv9103/?y63;
!!MA&v9903>-1/y30>-1/v9104<>-1:Pv9104/?y64;
!!MA&v9903>-1/y30>-1/v9105<>-1:Pv9105/?y65;
!!MA&v9903>-1/y30>-1/v9106<>-1:Pv9106/?y66;
!!MA&v9903>-1/y30>-1/v9107<>-1:Pv9107/?y67;
!!HEv9902&v9902>-1/y20>-1:S6/?y40;
!!HEv9903&v9903>-1/y30>-1:S6/?y40;
!!HEv9902&v9902>-1/y20>-1:S12/?y50;
!!HEv9903&v9903>-1/y30>-1:S12/?y50;
!!FU&y40<1:E;
!!FU&y50<>0:E;
!!VRy71:Sy61*y51*y40;
!!VRy72:Sy62*y52*y40;
!!VRy73:Sy63*y53*y40;
!!VRy74:Sy64*y54*y40;
!!VRy75:Sy65*y55*y40;
!!VRy76:Sy66*y56*y40;
!!VRy77:Sy67*y57*y40;
!!VRy81:Sy71:100;
!!VRy82:Sy72:100;
!!VRy83:Sy73:100;
!!VRy84:Sy74:100;
!!VRy85:Sy75:100;
!!VRy86:Sy76:100;
!!VRy87:Sy77:100;
!!VRy1&y81>=y51:Sy51;
!!VRy2&y82>=y52:Sy52;
!!VRy3&y83>=y53:Sy53;
!!VRy4&y84>=y54:Sy54;
!!VRy5&y85>=y55:Sy55;
!!VRy6&y86>=y56:Sy56;
!!VRy7&y87>=y57:Sy57;
!!VRy1&y81<y51:Sy81;
!!VRy2&y82<y52:Sy82;
!!VRy3&y83<y53:Sy83;
!!VRy4&y84<y54:Sy84;
!!VRy5&y85<y55:Sy85;
!!VRy6&y86<y56:Sy86;
!!VRy7&y87<y57:Sy87;
!!VRv9901:Sy1+y2+y3+y4+y5+y6+y7;
!!VRv9901&v9901<1:S1;
!!OW:Iy20/?y95/?y96;
!!OW:Iy30/?y97/?y98;
!!UN:N3/1/0/0;    获取枪兵的怪物名称
!!IF&v9902>-1/y20>-1/y95=0/y96=0:Q446/21/0/1^{The BT Necromancy Skill}
Your hero raised {%V9901} {%Z1} after the battle by your {Leadership} skill^; 玩家攻方英雄战后招枪兵说明
!!IF&v9903>-1/y30>-1/y97=0/y98=0:Q446/21/0/1^{The BT Necromancy Skill}
Your hero raised {%V9901} {%Z1} after the battle by your {Leadership} skill^; 玩家防方英雄战后招枪兵说明
!!HEv9902&v9902>-1/y20>-1/y95=1/y96=0:C2/0/v9901/0; 没有空格时AI自动决定
!!HEv9903&v9903>-1/y30>-1/y97=1/y98=0:C2/0/v9901/0;
!!HEv9902&v9902>-1/y20>-1/y95=0/y96=0:C2/0/v9901/1; 没有空格时询问玩家
!!HEv9903&v9903>-1/y30>-1/y97=0/y98=0:C2/0/v9901/1;
!!UN:R1;
!!VRv9901:S0;
!!VRv9902:S0;
!!VRv9903:S0;

[ 本帖最后由 yjwlhy 于 2009-10-22 09:15 编辑 ]

poet · 发表于 2007-2-9 10:03:10

不要那么BT，枪兵是很厉害的角色。我建议招十字军或者剑士。数量可以适当减少。

yjwlhy · 发表于 2007-2-9 11:54:31

:-_-b: 汗一个,如果要招十字军或剑士自己改一下就行了.
!!IF&v9902>-1/y20>-1:Q446/21/0/1^{The BT Necromancy Skill}                   将Q446/21/0/1中的0改为6是剑士7是十字军.
Attacking hero raised %V9901 Pikeman after the battle by your {Leadership} skill^;          将Pikeman改为十字军的名称(可不改)
!!IF&v9903>-1/y30>-1:Q446/21/0/1^{The BT Necromancy Skill}                   同上
Defending hero raised %V9901 Pikeman after the battle by your {Leadership} skill^;       将Pikeman改为十字军的名称(可不改)
!!HEv9902&v9902>-1/y20>-1:C2/0/v9901/1;                将:C2/0/v9901/1中的0改为6是剑士7是十字军.
!!HEv9903&v9903>-1/y30>-1:C2/0/v9901/1;                同上
!!VRy81:Sy71:100;
!!VRy82:Sy72:100;
!!VRy83:Sy73:100;
!!VRy84:Sy74:100;
!!VRy85:Sy75:100;
!!VRy86:Sy76:100;
!!VRy87:Sy77:100;
将上述几句的100加大就能减少招兵数量,招兵比率=要招的兵的体力与上述设定的值的比值.例如将其设为350,则初级领导术招剑士的比率为10%,高级为20%,专家级为30%.

poet · 发表于 2007-2-9 15:20:39

直接在字符串中书写Pikeman显然是不对的，
应该通过ID或取怪物的名称：

告诉你一个办法：
使用 !!UN/N3 这个指令来获取指定ID的怪物名称。
例如剑士的代码是6
!!UN:N3/1/6/0;
就可以把剑士的名称放到z1变量中，然后你可以在显示的时候引用z1显示出来。

strongestid · 发表于 2007-2-9 19:05:32

原帖由 yjwlhy 于 2007-2-9 11:54 发表
:-_-b: 汗一个,如果要招十字军或剑士自己改一下就行了.
!!IF&v9902>-1/y20>-1:Q446/21/0/1^{The BT Necromancy Skill} 将Q446/21/0/1中的0改为6是剑士7是十字军.
Attacking h ...

如果照你说的改成招剑士，但貌似还是按10HP一个而不是35HP，请问在哪里把10HP改成35HP一个？

yjwlhy · 发表于 2007-2-10 05:39:24

!!VRy81:Sy71:100;
!!VRy82:Sy72:100;
!!VRy83:Sy73:100;
!!VRy84:Sy74:100;
!!VRy85:Sy75:100;
!!VRy86:Sy76:100;
!!VRy87:Sy77:100;
将前面几句的100改为剑士体力的一个倍数,则招兵比率为
剑士的体力÷上面设定的数值×领导术等级

感谢poet的指点.

yjwlhy · 发表于 2007-2-10 07:05:36

今天根据poet的方法做了个小改动,直接使用!!UN:N3/1/0/0;来调用兵种名称,如果要改为招其他兵种的话,请将前面的0改为要招的兵种的代码.

strongestid · 发表于 2007-2-10 10:15:23

原帖由 yjwlhy 于 2007-2-10 05:39 发表
!!VRy81:Sy71:100;
!!VRy82:Sy72:100;
!!VRy83:Sy73:100;
!!VRy84:Sy74:100;
!!VRy85:Sy75:100;
!!VRy86:Sy76:100;
!!VRy87:Sy77:100;
将前面几句的100改为剑士体力的一个倍数,则招兵比率为
剑士的体力 ...

我的理解是，如果不想改你设的招兵比率，又想招剑士，只要把上述几个100全改为350？

啊啊啊，仔细看了回复，的确是这样，多谢几位高手。

[ 本帖最后由 strongestid 于 2007-2-10 10:18 编辑 ]

strongestid · 发表于 2007-2-10 10:33:44

我刚才按照帖子回复所说了改了[wiki]ERM[/wiki]，招champion，结果胜利以后先是出好几个ERM出错的对话框，再顺利招出了champion，寒。

strongestid · 发表于 2007-2-10 10:39:10

而且用z1调用兵种名称后，招兵对话框中显示的是champion的图象，但说明文字中说招的是pikeman（最后实际招出的是champion）。

strongestid · 发表于 2007-2-10 10:43:43

逃跑以后也出一大堆出错框，但没有其他事情，譬如招黑骑的bug——逃跑也有黑骑招、守城胜利招的是骷髅而不是黑骑什么的。

yjwlhy · 发表于 2007-2-10 11:05:57

看看出来的对话框写的是哪个部分就知道哪里出错了,但我在测试时完全没有出错过,你拿你改过的[wiki]ERM[/wiki]上来看下.

strongestid · 发表于 2007-2-10 11:11:35

ZVSE
!?BA0&1000;
!!VRv9140:C0/0/0/0/0/0/0;                [no creatures to resurrect after battle attacker]
!!VRv9147:C0/0/0/0/0/0/0;                [no creatures to resurrect after battle defender]
!!BA:M0/0/?v9101/?v9140;                   [save qty in each of attacking hero's slots for after battle]
!!BA:M0/1/?v9102/?v9141;                   [to determine qty lost for first aid skill]
!!BA:M0/2/?v9103/?v9142;                   // new by Thomas Franz: save creature type in v9101-v9114
!!BA:M0/3/?v9104/?v9143;
!!BA:M0/4/?v9105/?v9144;
!!BA:M0/5/?v9106/?v9145;
!!BA:M0/6/?v9107/?v9146;
!!BA:M1/0/?v9108/?v9147;                   [save qty in each of defending hero's slots for after battle]
!!BA:M1/1/?v9109/?v9148;                   [to determine qty lost for first aid skill]
!!BA:M1/2/?v9110/?v9149;
!!BA:M1/3/?v9111/?v9150;
!!BA:M1/4/?v9112/?v9151;
!!BA:M1/5/?v9113/?v9152;
!!BA:M1/6/?v9114/?v9153;
!!BA:H0/?v9902;                            [get attacking hero #]
!!BA:H1/?v9903;                            [get defending hero #]
!?BA1&1000;
!!HEv9902&v9902>-1:O?y20;                [get attacking hero's owner]
!!HEv9903&v9903>-1:O?y30;                [get defending hero owner]
!!BA:M0/0/?y11/?y21;                   [save qty in each of attacking hero's slots for after battle]
!!BA:M0/1/?y12/?y22;                   [to determine qty lost for first aid skill]
!!BA:M0/2/?y13/?y23;                   // new by Thomas Franz: save creature type in v9101-v9114
!!BA:M0/3/?y14/?y24;
!!BA:M0/4/?y15/?y25;
!!BA:M0/5/?y16/?y26;
!!BA:M0/6/?y17/?y27;
!!BA:M1/0/?y31/?y41;                   [save qty in each of defending hero's slots for after battle]
!!BA:M1/1/?y32/?y42;                   [to determine qty lost for first aid skill]
!!BA:M1/2/?y33/?y43;
!!BA:M1/3/?y34/?y44;
!!BA:M1/4/?y35/?y45;
!!BA:M1/5/?y36/?y46;
!!BA:M1/6/?y37/?y47;
!!VRy51&v9902>-1/y20>-1/v9108<>-1:Sv9147-y41;
!!VRy52&v9902>-1/y20>-1/v9109<>-1:Sv9148-y42;
!!VRy53&v9902>-1/y20>-1/v9110<>-1:Sv9149-y43;
!!VRy54&v9902>-1/y20>-1/v9111<>-1:Sv9150-y44;
!!VRy55&v9902>-1/y20>-1/v9112<>-1:Sv9151-y45;
!!VRy56&v9902>-1/y20>-1/v9113<>-1:Sv9152-y46;
!!VRy57&v9902>-1/y20>-1/v9114<>-1:Sv9153-y47;
!!VRy51&v9903>-1/y30>-1/v9101<>-1:Sv9140-y21;
!!VRy52&v9903>-1/y30>-1/v9102<>-1:Sv9141-y22;
!!VRy53&v9903>-1/y30>-1/v9103<>-1:Sv9142-y23;
!!VRy54&v9903>-1/y30>-1/v9104<>-1:Sv9143-y24;
!!VRy55&v9903>-1/y30>-1/v9105<>-1:Sv9144-y25;
!!VRy56&v9903>-1/y30>-1/v9106<>-1:Sv9145-y26;
!!VRy57&v9903>-1/y30>-1/v9107<>-1:Sv9146-y27;
!!MA&v9902>-1/y20>-1/v9108<>-1:Pv9108/?y61;
!!MA&v9902>-1/y20>-1/v9109<>-1:Pv9109/?y62;
!!MA&v9902>-1/y20>-1/v9110<>-1:Pv9110/?y63;
!!MA&v9902>-1/y20>-1/v9111<>-1:Pv9111/?y64;
!!MA&v9902>-1/y20>-1/v9112<>-1:Pv9112/?y65;
!!MA&v9902>-1/y20>-1/v9113<>-1:Pv9113/?y66;
!!MA&v9902>-1/y20>-1/v9114<>-1:Pv9114/?y67;
!!MA&v9903>-1/y30>-1/v9101<>-1:Pv9101/?y61;
!!MA&v9903>-1/y30>-1/v9102<>-1:Pv9102/?y62;
!!MA&v9903>-1/y30>-1/v9103<>-1:Pv9103/?y63;
!!MA&v9903>-1/y30>-1/v9104<>-1:Pv9104/?y64;
!!MA&v9903>-1/y30>-1/v9105<>-1:Pv9105/?y65;
!!MA&v9903>-1/y30>-1/v9106<>-1:Pv9106/?y66;
!!MA&v9903>-1/y30>-1/v9107<>-1:Pv9107/?y67;
!!HEv9902&v9902>-1/y20>-1:S6/?y40;
!!HEv9903&v9903>-1/y30>-1:S6/?y40;
!!HEv9902&v9902>-1/y20>-1:S12/?y50;
!!HEv9903&v9903>-1/y30>-1:S12/?y50;
!!FU&y40<1:E;
!!FU&y50<>0:E;
!!VRy71:Sy61*y51*y40;
!!VRy72:Sy62*y52*y40;
!!VRy73:Sy63*y53*y40;
!!VRy74:Sy64*y54*y40;
!!VRy75:Sy65*y55*y40;
!!VRy76:Sy66*y56*y40;
!!VRy77:Sy67*y57*y40;
!!VRy81:Sy71:1000;
!!VRy82:Sy72:1000;
!!VRy83:Sy73:1000;
!!VRy84:Sy74:1000;
!!VRy85:Sy75:1000;
!!VRy86:Sy76:1000
!!VRy87:Sy77:1000;
!!VRy1&y81>=y51:Sy51;
!!VRy2&y82>=y52:Sy52;
!!VRy3&y83>=y53:Sy53;
!!VRy4&y84>=y54:Sy54;
!!VRy5&y85>=y55:Sy55;
!!VRy6&y86>=y56:Sy56;
!!VRy7&y87>=y57:Sy57;
!!VRy1&y81<y51:Sy81;
!!VRy2&y82<y52:Sy82;
!!VRy3&y83<y53:Sy83;
!!VRy4&y84<y54:Sy84;
!!VRy5&y85<y55:Sy85;
!!VRy6&y86<y56:Sy86;
!!VRy7&y87<y57:Sy87;
!!VRv9901:Sy1+y2+y3+y4+y5+y6+y7;
!!VRv9901&v9901<1:S1;
!!UN:N3/1/0/0;
!!IF&v9902>-1/y20>-1:Q446/21/11/1^{The BT Necromancy Skill}
Attacking hero raised %V9901 %Z1 after the battle by your {Leadership} skill^;
!!IF&v9903>-1/y30>-1:Q446/21/11/1^{The BT Necromancy Skill}
Defending hero raised %V9901 %Z1 after the battle by your {Leadership} skill^;
!!HEv9902&v9902>-1/y20>-1:C2/11/v9901/1;
!!HEv9903&v9903>-1/y30>-1:C2/11/v9901/1;
!!UN:R1;
!!VRv9901:S0;
!!VRv9902:S0;
!!VRv9903:S0;

这么说是我改错了，还请指教。

yjwlhy · 发表于 2007-2-10 11:43:08

!!VRy84:Sy74:1000;
!!VRy85:Sy75:1000;
!!VRy86:Sy76:1000 这行少了一个分号
!!VRy87:Sy77:1000;

如果你要显示正确的名称则要在这句 !!UN:N3/1/0/0; 中的第二个0改为你要招的兵种代码.
要招骑士的话要改为 !!UN:N3/1/11/0;

heroes3 · 发表于 2007-2-10 19:08:35

楼上的可否愿为我以及各位玩家们需要写一个降低招魂术招魂的百分比的erm吗？

poet · 发表于 2007-2-10 20:01:58

原帖由 heroes3 于 2007-2-10 19:08 发表
楼上的可否愿为我以及各位玩家们需要写一个降低招魂术招魂的百分比的erm吗？

从现有的情况上来看，似乎没有人能够使用ERM修改招魂术。

因此现有的实现都是被招魂去掉，然后自己重新计算。——相当与禁用原有的招魂，重新用ERM实现一个招魂术。这样的实现方法，个人觉得并不完美。至少令人不太愉快。

如果你需要降低招魂术的百分比，目前的办法恐怕就是这样：自己实现一个比例低一些的招魂术。方法就跟贴主的一样。

cx2005 · 发表于 2007-2-12 15:23:03

!?BA0&1000;
!?BA1&1000;
加了1000以后电脑不能招枪兵

!!IF&v9902
!!IF&v9903
这边要加1000，要不当电脑攻击你的驻地、废矿、城镇后，会认为有玩家参战，战后也会出现招兵说明

yjwlhy · 发表于 2007-2-12 18:24:46

看来我说无BUG版是错的,因为现在的bug已经发现了不少,请大家说出来,或者说一下解决方法.

cx2005 · 发表于 2007-2-12 21:55:40

!?BA0;

!?BA1;

!!IF&1000/v9902>-1/y20>-1:Q446/21/0/1^{The BT Necromancy Skill}
Attacking hero raised %V9901 %Z1 after the battle by your {Leadership} skill^;
!!IF&1000/v9903>-1/y30>-1:Q446/21/0/1^{The BT Necromancy Skill}
Defending hero raised %V9901 %Z1 after the battle by your {Leadership} skill^;

!!HEv9902&-1000/v9902>-1/y20>-1:C2/0/v9901/0; 没有空格时电脑自动决定
!!HEv9903&-1000/v9903>-1/y30>-1:C2/0/v9901/0;
!!HEv9902&1000/v9902>-1/y20>-1:C2/0/v9901/1; 没有空格时询问玩家
!!HEv9903&1000/v9903>-1/y30>-1:C2/0/v9901/1;

另外，最好用[wiki]神[/wiki]秘术、智力术或魔力术招兵，算是减小魔法英雄和力量英雄差距的一种方法。

yjwlhy · 发表于 2007-2-13 07:08:50

谢谢,CX200的帮忙改进了一下,已经在顶楼改进了.

账号		自动登录	找回密码
密码			英雄注册\|Register

领导术招枪兵无bug版(发布两年纪念提供下载)

评分

相关帖子

退役版主