城堡生物巢穴自动升级脚本！

寻梦人

最近玩了离弦箭大师的仙剑，里面的城堡每天升级真是烦人！

所以我想还是写个脚本，让电脑自动升级算了！

用法：城镇界面点击小城镇选择你想要升级的生物巢穴，输入值提示：1---7，就是你想升级的生物级别！

之后电脑会自动为你升级所有你的城镇的该级别生物生长率！

前提和官方脚本所要求的一样，但是资源为了方便，简化为所有资源各1和黄金3000！

废话少说，脚本奉上！

ZVSE
************脚本制作：寻梦人***********
变量使用：v7777，函数7777
***************************************
!?CM1&1000; 城镇界面点击触发

!!CM:I?y-1 F?y-2 S?y-12;  检查鼠标点击类型
!!FU|y-2>0/y-12=13:E;
!!FU&y-1<>150/y-1<>158:E;
!!VRz1:S^请输入你想升级的生物巢穴：
提示:范围只能是1~7（分别代表所招募的生物级别）。设置后将
会为你自动升级你所有城镇里面所指定的生物生长率，资源为每
种资源个1和黄金3000！^;
!!VRz2:S^现时设定为（%V7777）^;
!!VRz3:S^^;
!!IF:D94/1/2/3/3/3/3/3/3/3/3/3/3/3/3/3;
!!IF:F94/3/3/3/3/1;
!!IF:E2/94;
!!VRz1:H2;
!!FU|-2/v2<>5:E;
!!VRv2:Vz1;
!!IF|v2<1/v2>7:M^
{输入错误！}
^;
!!FU|v2<1/v2>7:E;
!!VRv7777:Sv2;

!#TM1:S1/999/1/255;每天触发
!?TM1&1000;
!!DO7777/0/7/1:P1;
!?FU7777&x1=1;
!!FU|v7777<1/v7777>7:E;加一个条件限制
!!OW:Ix16/?y1; 检查玩家是否为玩家
!!FU&y1=1:E;             不是玩家则终止
!!OW:Wx16/?y-1; 检查城镇数量
!!FU&y-1<1:E;            无城镇时终止
!!DO7777/0/y-1/1:P2/x16; 循环调用函数FU7777，自动升级

!?FU7777&x1=2;
!!OW:Wx2/x16/?y-2;
!!FU|y-2<0/y-2>48:E;
!!CA0/y-2:B3/12; !!CA0/y-2&-1:B3/13; 检查城堡议会
!!FU&-1:E; 如果没有就退出
!!OW:Rx2/0/?y21 Rx2/1/?y22 Rx2/2/?y23 Rx2/3/?y24;
!!OW:Rx2/4/?y25 Rx2/5/?y26 Rx2/6/?y27 Rx2/7/?y28; 得到玩家各类资源

*******v7777为玩家选择的升级巢穴********
!!VRy4:Sv7777+36;
!!CA0/y-2:B3/y4; 检查是否建造
!!FU&-1:E; 没有就退出
*******为了方便全部定义需要每样资源1金钱3000******
!!FU|y21<1/y22<1/y23<1/y24<1/y25<1/y26<1/y27<3000:E; 不够资源就退出
!!VRy6:Sv7777 *-1 +8; 得到奖励的个数
!!VRy7:Sv7777 -1;
!!CA0/y-2:M1/y7/d/dy6;
!!OW:Rx2/0/d-1 Rx2/1/d-1 Rx2/2/d-1 Rx2/3/d-1;
!!OW:Rx2/4/d-1 Rx2/5/d-1 Rx2/6/d-3000;






再附上一个版本：分9种城堡类型分别设置，应灰狼要求！

ZVSE

脚本制作：寻梦人
变量使用：v7770----v7778，函数7777
!?CM1&1000; 城镇界面点击触发

!!CM:I?y-1 F?y-2 S?y-12;  检查鼠标点击类型
!!FU|y-2>0/y-12=13:E;
!!FU&y-1<>150/y-1<>158:E;
!!CA-1:T?y-70;检查城镇类型
!!FU7777:P3/y-70;
!?FU7777&x1=3;
!!VRz4&x2=0:S^城堡^;
!!VRz4&x2=1:S^壁垒^;
!!VRz4&x2=2:S^塔楼^;
!!VRz4&x2=3:S^地狱^;
!!VRz4&x2=4:S^墓园^;
!!VRz4&x2=5:S^地下城^;
!!VRz4&x2=6:S^据点^;
!!VRz4&x2=7:S^要塞^;
!!VRz4&x2=8:S^元素^;
!!VRy50:S7770+x2;
!!VRy51:Svy50;
!!VRz1:S^请输入{%Z4}你想升级的生物巢穴：
提示:范围只能是1~7（分别代表所招募的生物级别）。设置后将
会为你自动升级你所有{%Z4}里面所指定的生物生长率，资源为每
种资源个1和黄金3000！^;
!!VRz2:S^现时设定为（%Y51）^;
!!VRz3:S^^;
!!IF:D94/1/2/3/3/3/3/3/3/3/3/3/3/3/3/3;
!!IF:F94/3/3/3/3/1;
!!IF:E2/94;
!!VRz1:H2;
!!FU|-2/v2<>5:E;
!!VRv2:Vz1;
!!IF|v2<1/v2>7:M^
{输入错误！}
^;
!!FU|v2<1/v2>7:E;
!!VRvy50:Sv2;

!#TM1:S1/999/1/255;每天触发
!?TM1&1000;
!!DO7777/0/7/1:P1;
!?FU7777&x1=1;
!!OW:Ix16/?y1; 检查玩家是否为玩家
!!FU&y1=1:E;             不是玩家则终止
!!OW:Wx16/?y-1; 检查城镇数量
!!FU&y-1<1:E;            无城镇时终止
!!DO7777/0/y-1/1:P2/x16; 循环调用函数FU7777，自动升级

!?FU7777&x1=2;
!!OW:Wx2/x16/?y-2;
!!FU|y-2<0/y-2>48:E;
!!CA0/y-2:B3/12; !!CA0/y-2&-1:B3/13; 检查城堡议会
!!FU&-1:E; 如果没有就退出
!!CA0/y-2:T?y-70;检查城镇类型
!!VRy50:S7770+y-70;
!!FU|vy50<1/vy50>7:E;加一个条件限制
!!OW:Rx2/0/?y21 Rx2/1/?y22 Rx2/2/?y23 Rx2/3/?y24;
!!OW:Rx2/4/?y25 Rx2/5/?y26 Rx2/6/?y27 Rx2/7/?y28; 得到玩家各类资源

*******v7777为玩家选择的升级巢穴********
!!VRy4:Svy50+36;
!!CA0/y-2:B3/y4; 检查是否建造
!!FU&-1:E; 没有就退出
*******为了方便全部定义需要每样资源1金钱3000******
!!FU|y21<1/y22<1/y23<1/y24<1/y25<1/y26<1/y27<3000:E; 不够资源就退出
!!VRy6:Svy50 *-1 +8; 得到奖励的个数
!!VRy7:Svy50 -1;
!!CA0/y-2:M1/y7/d/dy6;
!!OW:Rx2/0/d-1 Rx2/1/d-1 Rx2/2/d-1 Rx2/3/d-1;
!!OW:Rx2/4/d-1 Rx2/5/d-1 Rx2/6/d-3000;

[ 本帖最后由 寻梦人 于 2012-12-25 18:05 编辑 ]

寻梦人

假如用在仙剑图里，请把城镇升级脚本删除！

mayicomein

虽然看不懂但是还是要顶。。。而且还要做到沙发上顶。

兽哥哥

很好，为懒人创作条件了。

无心云

哈哈，兽肯定是好这口的
老离不知道喜欢不喜欢。

不过我是要顶一下的

沧海一粟

懒人有福了

fastarrow

我持观望态度。

fastarrow

直觉觉得有BUG。

灰狼王子

这个确实是懒人的福音，记得到中后期几十个城每天过天前都要逐个升级巢穴，至少5分钟，很辛苦的说

灰狼王子

话说要是能区分城镇类型，实现同一类型城镇升级某个兵种的功能就更通用了，比如天使城固定升级5级兵巢穴，泰坦城固定升级4级兵巢穴，不知能否实现。

寻梦人

只要有想法，就一定可以实现！

只是不想固定某个级别，任玩家选择不是很好吗？

寻梦人

关于分城镇触发，要多用8个v变量，就是9个v变量，每个v变量对应一种城堡！

寻梦人

灰狼进来：特意应你要求增加了一个脚本，分9种城镇类型分别设置！

只需设置一次，而且可以随时更改！

贤知有您

请教寻梦人

!?TM1&1000;
!!DO7777/0/7/1:P1;
!?FU7777&x1=1;
!!FU|v7777<1/v7777>7:E;加一个条件限制
!!OW:Ix16/?y1; 检查玩家是否为玩家
!!FU&y1=1:E;             不是玩家则终止
.....

这里!?TM1&1000; 中的 &1000是否已经起到了当前玩家是人类玩家的作用？
为什么后面还要历遍所有玩家，又再检测是否为人类玩家？
还请寻梦指点。

寻梦人

因为不知道人类玩家是哪个颜色啊！

所以一一检测，看看哪个是人类玩家！

方便下面函数调用！

[ 本帖最后由 寻梦人 于 2013-1-3 13:00 编辑 ]

贤知有您

多谢寻梦解答。
TM中255代表了所有玩家。
我认为 &1000 就已经说明当前行动的是人类玩家了，电脑的行动就不会触发了吧？
那么，就应该可以直接检测当前玩家拥有的城镇数量了吧。
不知道以下写法是否妥当。（只是简化一下而已，不用再历遍所有颜色）

!?TM1&1000;
!!FU|v7777<1/v7777>7:E;加一个条件限制
!!OW:W-1/?y-1;         检查当前玩家城镇数量
!!FU&y-1<1:E;            无城镇时终止
!!DO7777/0/y-1/1:P2/x16; 循环调用函数FU7777，自动升级

寻梦人

怎么写都是个人喜好！

只要能够实现预期功能即可！

不管怎么实现，都要知道当前玩家的颜色才好触发函数！

寻梦人

按照你的写法，似乎还是不知道当前玩家的颜色！

所以还要去读取！