巫术sorcery技能强化

希望创师

依托官方erm的resistance技能效果反转而来。效果为：
依巫术技能等级，随机提升1-3队低级兵至高级版。比如神怪变灯神等   
简单测试有效，大家帮忙debug啊，谢谢


ZVSE
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_ScriptName=script83
ERMS_ScriptAuthor=Administrator
ERMS_ScriptVersion=1.0.0
ERMS_ScriptDate=4.11(November).2012
ERMS_ScriptERMVersion=2.70
ERMS_ScriptLanguage=中文(中国) or 中文(简体) (native)

*************************************************************************
     Sorcery
*************************************************************************

!?BA0;     [Pre-battle trigger for Sorcery]


!FU661:P;     [set flag 270 to true if a human vs. human network battle (unsupported)]

!!BA:H0/?v900;     [get # of attacking hero]
!!HEv900:B0/?z470;     [get name of that hero]
!!HEv900:R2/?v911;     [get sex of that hero]
!!VRz471&v911=0:Sz103028;     [Strings for hero sex]
!!VRz471&v911=1:Sz103029;
!!HEv900:O?v911;     [get hero owner]
!!OW:Iv911/?v912;     [get AI (1) or human (0)]
!!IF:V5/0;
!!IF&v912=0:V5/1;     [set flag 5 if attacker is human...]
!!BA:H1/?v911;     [get # of defending hero]
!!HEv911&v911>=0:B0/?z-1;     [get name of that hero]
!!VRz-1&v911>=0:+z103056;
!!VRz-1&v911<0:Sz103057;
!!HEv911&v911>=0:O?v912;     [get owner of defender if any]
!!OW&v911>=0:Iv912/?v913;     [get AI/human of defender]
!!IF&v911>=0/v913=0:V5/1;     [set flag 5 if defender is human]

!!HEv900:S25/?v901;     [get Sorcery skill level]
!!VRv911:S7;
!!FU658&v901>=1:P0/1/7;     [call function once per skill level]
!!VRv589:Sv911;     [remember slot changed if any]
!!VRv911:S7;
!!FU658&v901>=2:P0/1/7;
!!VRv588:Sv911;     [remember slot changed if any]
!!VRv911:S7;
!!FU658&v901=3:P0/1/7;
!!VRv587:Sv911;     [remember slot changed if any]
!!BA&v589<7:M0/v589/?v902/?v914;     [get v902 type and v914 qty in slot]
!!BA&v588<7:M0/v588/?v903/?v914;     [get v903 type and v914 qty in slot]
!!BA&v587<7:M0/v587/?v904/?v914;     [get v904 type and v914 qty in slot]
!!VRz472:Sz103030;
!MM&5/v589<7/v588=7:Sz472;
!MM&5/v588<7/v587=7:Sz472;
!MM&5/v587<7:Sz472;

** Alexis Koz
!!VRv911:S0;
!!BA:H1/?v900;     [get # of attacking hero]
!!HEv900&v900>=0:B0/?z470;     [get name of that hero]
!!HEv900&v900>=0:R2/?v911;     [get sex of that hero]
!!VRz471&v911=0:Sz103031;     [Strings for hero sex]
!!VRz471&v911=1:Sz103032;
!!HEv900&v900>=0:O?v911;     [get hero owner]
!!OW&v900>=0:Iv911/?v912;     [get AI (1) or human (0)]
!!IF:V5/0;
!!IF&v900>=0/v912=0:V5/1;     [set flag 5 if attacker is human...]
!!BA:H0/?v911;     [get # of defending hero]
!!HEv911&v911>=0:B0/?z-2;     [get name of that hero]
!!VRz-2&v911>=0:+z103056;
!!VRz-2&v911<0:Sz103057;
!!HEv911:O?v912;     [get owner of defender if any]
!!OW:Iv912/?v913;     [get AI/human of defender]
!!IF&v913=0:V5/1;     [set flag 5 if defender is human]

!!HEv900&v900>=0:S25/?v901;     [get Sorcery skill level]
!!VRv911:S28;
!!FU658&v900>=0/v901>=1:P1/0/28;     [call function once per skill level]
!!VRv489:Sv911;     [remember slot changed if any]
!!VRv911:S28;
!!FU658&v900>=0/v901>=2:P1/0/28;
!!VRv488:Sv911;     [remember slot changed if any]
!!VRv911:S28;
!!FU658&v900>=0/v901=3:P1/0/28;
!!VRv487:Sv911;     [remember slot changed if any]
!!BA&v489<28:M1/v489/?v902/?v914;     [get v902 type and v914 qty in slot]
!!BA&v488<28:M1/v488/?v903/?v914;     [get v903 type and v914 qty in slot]
!!BA&v487<28:M1/v487/?v904/?v914;     [get v904 type and v914 qty in slot]
!!VRz472:Sz103033;
!MM&5/v489<28/v488=28:Sz472;
!MM&5/v488<28/v487=28:Sz472;
!MM&5/v487<28:Sz472;
** Alexis Koz end

** End of pre-battle trigger for sorcery


!?BA1;     [Post-battle trigger for sorcery]


!!VRv901:Sv587;
!!FU660&v587<7:P0/1;     [re-degrade creatures if need be]
!!VRv587:S7;
!!VRv901:Sv588;
!!FU660&v588<7:P0/1;
!!VRv588:S7;
!!VRv901:Sv589;
!!FU660&v589<7:P0/1;
!!VRv589:S7;

** Alexis Koz
!!VRv901:Sv487;
!!FU660&v487<28:P1/0;     [re-upgrade creatures if need be]
!!VRv487:S28;
!!VRv901:Sv488;
!!FU660&v488<28:P1/0;
!!VRv488:S28;
!!VRv901:Sv489;
!!FU660&v489<28:P1/0;
!!VRv489:S28;
** Alexis Koz

** End of post-battle trigger for sorcery


!?FU658;     [Function to upgrade one defending troop stack in battle]

!!VRv902:Sx2 *20 R6;     [random slot # to start search from]
!!DO659/0/6/1:Px1/x2/x3;     [check 7 slots for stack to downgrade]

** End of function to upgrade one defending troop stack in battle


!?FU659;     [Function to check one stack for upgrading]

!!VRv912:Sv902 %7;     [get an actual slot number]
!!VRv912&x2=1: +21;
!!BA:Mx1/v912/?v913/?v914;     [get v913 type and v914 qty in slot]
!!VRv915:S1;     [assume creature is ungraded]
!!VRv915&v913<0:S0;     [treat no creature as a upgraded one]
!!VRv916:Sv913 %2;
!!VRv915&v916=1:S0;     [odd creatures are always upgraded]
!!VRv915&v913>=112/v913<=117:S0;     [elementals and golems]
!!VRv915&v913>=132:S0;     [other neutral creatures]
!!VRv913:+1;     [get type of upgraded version]
!!VRv913&v913=122:S115;     [special cases for elementals]
!!VRv913&v913=124:S113;
!!VRv913&v913=126:S112;
!!VRv913&v913=128:S114;
!!BA&v911=x3/v915=1:Mx1/v912/v913/v914;     [set new upgraded type if we haven't yet]
!!VRv911&v911=x3/v915=1:Sv912;     [note we changed a slot]
!!VRv902:+1;     [next slot]

** End of function to check one stack for downgrading


!?FU660;     [Function to redegrade creatures in defender's slot v901]

!!BA:Mx1/v901/?v913/?v914;     [get v913 type and v914 qty in slot]
!!VRv913:-1;     [usually this gets us Unupgraded version]
!!VRv913&v913=113:S127;     [handle elementals]
!!VRv913&v913=114:S125;
!!VRv913&v913=115:S129;
!!VRv913&v913=116:S123;
!!BA&v913>0/v914>0:Mx1/v901/v913/v914;     [set the old, unupgraded type, if creatures survived]

** End of function to reupgrade creatures in defender's slot v901
-------------------------------------------------------------------------

兽哥哥

这么多行？是直接修改的官方脚本？

兽哥哥

又出丑了，第一行就说了官方脚本我居然华丽的无视了

灰狼王子

我靠~~这个狠了点吧——不过想想原来抵抗术加强的BT之处，也还算平衡吧。
这样资源不足时可以带升级前后差别很大的未升级兵（比如小泰坦、小天使、弓箭手、剑士、小野牛、小吸血鬼、气元素等）出战，战斗时肯定要SL出最牛的升级配置，实战效果一级棒呢

无心云

这个很省钱啊，比理财术强多了去了。

灰狼王子

弱弱的问一下：七级兵能随机升级成8级兵吗？魔幻和女巫是互相升级吗？大妖精升级成圣侏儒后能直接出现护卫吗？单格兵升级后变成双格兵（比如大天使）后会不会出现BUG？升级后经验等级如何判定？保持不变还是按比例折减？九头怪直接升级成血污怪还是地狱九头怪？

灰狼王子

英雄有战术的情况下，是在布阵阶段就已经升级过了还是要等正式开战后？当碰上敌方应加强的抵抗力时，不知会不会有异常情况

兽哥哥

其实现在老离正在写一个更NB的脚本，先卖个关子。

无心云

个人觉得老离是一个典型的闷骚
角落里的山东人

dadds

这个随机提升是这么个随机法？？英雄升级的时候？

希望创师

原帖由 dadds 于 2012-11-4 16:43 发表
这个随机提升是这么个随机法？？英雄升级的时候？

7队里随机升级三队兵，战斗开始前升级，战斗结束后，兵种又回去了。 相当于巫术给生物打了一针兴奋剂吧

希望创师

原帖由 灰狼王子 于 2012-11-4 13:45 发表
弱弱的问一下：七级兵能随机升级成8级兵吗？魔幻和女巫是互相升级吗？大妖精升级成圣侏儒后能直接出现护卫吗？单格兵升级后变成双格兵（比如大天使）后会不会出现BUG？升级后经验等级如何判定？保持不变还是按比例折 ...

仅仅是把生物升级为高级版，不包含wog新生物，不包含八级兵。布阵暂时未测试

dadds

原来是和抵抗术加强相对应的啊，前期有些用，后期都升级了就没效果了吧

希望创师

是的，对升级生物无效。所以相对抵抗术来说不是那么BT。极端情况也就是小天变大天，巨人变泰坦罢了。

抵抗把黑龙变红龙，才是真正bt

dadds

说起抵抗我最惨痛的经历就是玩曙光MOD的时候把敌人的60多头沼泽蜥蜴“降级”为9级兵水平的烈焰龙，S/L了几十次才打了过去，真是无妄之灾

贤知有您

脚本还不错.
只是,抵抗术跟 兵种升降级貌似沾不上边.
不如改为英雄特长吧.呵呵,够新鲜.

无心云

话说英雄特长已经有N个版本了

希望创师

抵抗术确实与兵种升降级沾不上边。所以我写的是巫术啊。巫术是指通过一些神秘的手段，短期内让低级兵获得高级兵的hp和能力等，勉强还是说得通的吧。
007如果有空，帮忙做个孤注一掷能够吸血的erm好吗？上次那个用!!MF 做的使用起来还是有点问题啊

贤知有您

带孤注一掷魔法状态下可以吸血?这么BT啊.
不知道你上次写的是 模拟的还是直接将生物转成吸血鬼形式(攻击后还原)?

如果是我写,我会用模拟来写(动画似而已).一样是用MF触发器.

希望创师

我现在用的是ashero4兄弟写的，孤注一掷后在物理近战前能吸血脚本，可以 使用，但反击不处罚。如果能在攻击、反击时转成吸血鬼形式，配上反戈一击，会很有用。这样两个四级战斗辅助魔法也可以牛一下了。否则四级魔法就看闪电流星复活回城什么的，太单调了啊。

ZVSE

!?MF1&1000;    孤注一掷后近战攻击吸血,造成伤害时触发
!!VRv5100:C-1/-1; v5100-v5101
!!MF:N?v5100 F?v5101;  这里取得所造成的伤害，作为复活的数值
!!VRv5000:C-1/-1/-1/-1/-1/-1; v5000-v5006
!!VRv5007:C-1/-1/-1/-1/-1/-1/-1/-1/-1/-1;  v5007-v5016
!!VRv5017:C-1/-1/-1/-1/-1/-1/-1/-1;  v5017-v5024
!!BG:A?v5000 D?v5001 E?v5002 N?v5003 S?v5004; 造成伤害后用BG取得攻击方和被攻击方的堆栈
!!BG:Q?v5005 H?v5006;
!!BMv5002&v5002>-1:B?v5007 I?v5009 R?v5011 N?v5013 T?v5015 F?v5017 P?v5019 H?v5021 O?v5023;  被攻击方
!!BMv5003&v5003>-1:B?v5008 I?v5010 R?v5012 N?v5014 T?v5016 F?v5018 P?v5020 H?v5022 O?v5024;  攻击方
!!FU&v5000<>6:E;    不是主动近战攻击就退出
!!FU|v5003<0/v5003>41:E;
!!FU|v5002<0/v5002>41:E;
!!FU&v5016>144/v5016<150:E;
!!FU|v5013<1/v5015<0/v5014<1/v5016<0:E;
!!BMv5003:G56/?y1/?y2; 取得攻击堆栈身上的孤注回合数
!!FU&y1<1:E;  回合数小于1就退出吸血脚本
!!DO105/v5003/v5003/1&v5005=0:P30/0/20/v5101;  进攻方的孤注一掷
!!DO105/v5003/v5003/1&v5005=1:P30/21/41/v5101; 防守方的孤注一掷

!?FU105&x1=30;
!!FU|x16<x2/x16>x3:E;
!!BMx16:H?y1 L?y2 N?y3 B?y4 T?y98;
!!FU&y3<1:E;
!!FU&y98>144/y98<146:E;
!!FU&y98>146/y98<150:E;
!!VRy5:Sy1 *y4;
!!VRy6:Sy1 *y3 -y2;
!!FU&y6=y5:E;
!!VRy11:Sx4;
!!VRy7&y11>y1:Sy11 :y1;
!!VRy8&y11>y1:Sy11 %y1;
!!VRy9&y8>0/y11>y1:Sy1 -y8;
!!VRy9&y8=0/y11>y1:Sy1;
!!VRy9&y11<y1:Sy11;
!!VRy10&y9>y2:Sy2 *-1;
!!VRy10&y9<y2:Sy9 *-1;
!!VRy10&y4=1/y11>y1:Sy2 *-1;
!!VRy10&y4=1/y11<y1/y11<y2:Sy11 *-1;
!!VRy10&y4=1/y11<y1/y11>=y2:Sy2 *-1;
!!VRy20:Sy4 -y3;
!!VRy7&y7>y20:Sy20;
!!VRy7&y4=1:S0;
!!BMx16:Ndy7; 此处为吸血复活代码
!!BMx16:Ldy10;
!!UN:N3/23/y98/0;
!!VRz11&y7>0:S^{孤注一掷}使{%Y7 %Z23 起死回生.}^;
!!VRz11&y7=0:S^{孤注一掷}使{%Z23 恢复 %Y9 生命.}^;
!!MM:Sz11;
!!BU:R;

[ 本帖最后由 ashero4 于 2012-10-21 07:27 编辑 ]