小黑脚本出世，希望有地图作者能早日用上该脚本（V1.00修正版）

克招 · 发表于 2012-6-7 06:49:53

前有小白辟天立地登场，后有小黑稀里糊涂出世，小白脚本作为可成长生物风靡一时，给大家带来无数欢乐。今天东施效颦，放出小黑脚本，希望能传承经典，给大家带来更多欢乐。

小黑就是暗黑龙，在游戏中名字不变，属性不变，只增加特性，特性如下：

1、“死神之眼”，效果为：每次攻击有10%~50%的几率触发，扣除生物血量为小黑的总血量，并再额外死亡X个，X为小黑的数量。
2、攻返、恐惧。
3、复活：每回合开始，如有受伤，恢复满生命值，每次恢复或复活增加1%~11%的生物各项属性，战后属性保留（每场战斗最大增幅为30%）。
4、暗黑怒吼：每回合可以放弃进攻机会，施放大祈祷和大复活，复活兵种的血量为小黑的总血量（只有存活的兵种才能接受大复活）。[使用方法：轮到小黑行动时右击施法图标]
5、强弩之末：杀死你的怪物立即死亡。

其实这些技能设计都是有思路的，那么就简单地分析一下各个特技：
1、死神之眼：死亡凝视的增强版，不仅对高级生物有杀伤力，对低级生物杀伤力更大。
2、攻返、恐惧：暗黑龙的招牌技能了，没变，但是把不反击删掉了，为什么呢？为了配合技能3，哈哈，自己看。
3、复活：这个才是小黑的主技能，只要受伤，每回合恢复满生命值，然后增加属性，属性战后保留。所以就把不反击删掉了，就是要让你反击，就是要自虐，小黑表示，我是神级自虐狂~~~~
4、暗黑怒吼：施放大祈祷和大复活，大祈祷不用说了，最强的辅助魔法，大复活更是让所有参战的己方生物增加小黑自身的血量，这意味着直接把小黑复制了7份。这可是顶级的奶妈啊，使得它成为了敌方首要攻击目标，无非又给它带来复活+加属性的机会。
5、强弩之末：很恶心的一个技能，死了还要拉你垫背，不过小黑不同小白，死了就真死了，复活不了了，因为魔免，所以，呵呵，这个技能用来看的而已。

地图作者该如何使用这个脚本？
首先把脚本放进地图中，这个就不用说了。然后小黑应该和小白一样，只能有一个，如果太多了，杀伤力太强了，而且就可以使用分出一个小黑来骗反击，以施放强弩之末爆对面的海量生物这种很无耻的手段，不过一切随地图作者的愿意。然后小黑不能作为一追二追，这个可以模仿小白版的一追二追脚本进行修改。

版本号：V1.00 Beta
____________________________________________________________
版本号：V1.00 正式版
更新：完善所有错误的BUG———————————————————————————————————
版本号：V1.00 修正版
更新：修正一个疏忽的小BUG
最后更新时间：2012.6.19
作者：克招

[ 本帖最后由克招于 2012-6-19 06:40 编辑 ]

克招 · 发表于 2012-6-7 06:50:11

脚本代码：

ZVSE
ERMS_ScriptName=小黑（暗黑龙）
ERMS_ScriptAuthor=克招
ERMS_ScriptVersion=1.00 beta
ERMS_ScriptDate=14.6(June).2012
ERMS_ScriptERMVersion=2.70
ERMS_ScriptLanguage=中文(简体，中国) or 中文(简体) (native)
ERMS_ScriptUsedVariables=v9130~v9140
ERMS_ScriptUsedFunctions=FU6305~FU6307
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
脚本名称：小黑（暗黑龙）
作者：克招_黑椒
版本号：v1.00 修正版
生物特性：
1、“死神之眼”，效果为：每次攻击有10%~50%的几率触发，扣除生物血量为小黑的总血量，并再额外死亡X个，X为小黑的数量。
2、攻返、恐惧。
3、复活：每回合开始，如有受伤，恢复满生命值，每次恢复或复活增加1%~11%的生物各项属性，战后属性保留（每场战斗最大增幅为30%）。
4、暗黑怒吼：每回合可以放弃进攻机会，施放大祈祷和大复活，复活兵种的血量为小黑的总血量（只有存活的兵种才能接受大复活）。[使用方法：轮到小黑行动时右击施法图标]
5、强弩之末：杀死你的怪物立即死亡。
**********怪物描述更改*******
!#VRz877:S^魔免、攻返、恐惧、{死神之眼}、复活、{暗黑怒吼}、{强弩之末}。^;
!#UN:G1/155/2/877;
**********1、死神之眼********
!#EA155:B6/1/69/37/10/14/18/22/26/30/34/38/42/46/50;
**主动攻击触发
!?BG0; 动作前触发
!!BG:A?y1; 获取动作为y1
!!FU&y1<>6:E; 动作不为攻击则退出
!!BG:N?y2; 获取当前怪物堆栈为y2
!!BMy2:T?y3; 获取当前怪物编号为y3
!!FU&y3<>155:E; 当前怪物不为暗黑龙则退出
!!VRy4:Sy2 +1;
!!VRy4:*-1; 将堆栈编号置为负数
!!EAy4:E?y5/6/d/d; 获取堆栈经验值
!!EA155:L?y6; 获取暗黑龙的满经验值
!!VRy6::10; 将满经验值除以10
!!VRy5::y6; 将y5除以y6获得暗黑龙当前经验等级
!!VRy6:Sy5; y5赋值给y6
!!VRy7&y6=0:S10;
!!VRy7&y6=1:S14;
!!VRy7&y6=2:S18;
!!VRy7&y6=3:S22;
!!VRy7&y6=4:S26;
!!VRy7&y6=5:S30;
!!VRy7&y6=6:S34;
!!VRy7&y6=7:S38;
!!VRy7&y6=8:S42;
!!VRy7&y6=9:S46;
!!VRy7&y6=10:S50;
*设置触发比例给y7
!!VRy8:S0 R99; y8随机0~99
!!FU&y8>y7:E; 若y8>y7则退出
!!VRv9136:S1; 放置几率成功的标志
!!BG:E?v9137; 获得打向目的的堆栈
!!BG:N?v9138; 获取暗黑龙的堆栈
!?BG1;
!!FU&v9136<>1:E; 如果几率失效则退出
!!VRv9136:S0; 重置标志
!!VRy10:Sv9137; 获得打向目的的堆栈
!!BMy10:N?y1; 获取怪物数量
!!FU&y1<1:E; 怪物数量小于1则退出
!!VRy2:Sv9138; 获取暗黑龙的堆栈
!!BMy2:N?y11; 获取暗黑龙的数量
!!BMy2:H?y12; 获取暗黑龙的生命值
!!BMy2:L?y2; 获取暗黑龙受到的伤害
!!VRy3:Sy12 -y2; 计算暗黑龙的当前生命值
!!VRy11:-1;
!!VRy12:*y11;
!!VRy12:+y3;
*获取暗黑龙的总血量
!!BMy10:T?y13; 获取目标堆栈的怪物类型
!!BMy10:H?y14; 获取目标堆栈的血量
!!VRy15:Sy14 *y11; 目标将要死亡位数为小黑的数量
!!VRy12:+y15; 目标堆栈所收到的总伤害
!!VRy16:Sy12 :y14; 目标堆栈所死亡的数量
!!BMy10:N?y17; 获取目标堆栈的数量
!!VRy16&y17<y16:Sy17; 如果目标堆栈数量少于伤害死亡的数量，则伤亡显示为目标堆栈的全部
!!BMy10:V80; 播放堆栈的魔法
!!BMy10:Ky12; 目标堆栈受到伤害
!!BU:R; 重画屏幕
!!VRz-1:S^受到暗黑龙的“死神之眼”的影响，%Y16个生物死亡了！^; 伤亡报告
!!BU:Mz-1; 显示伤亡报告
**反击触发
!?BG0; 动作前触发
!!BG:A?y1; 获取动作类型为y1
!!FU&y1<>6:E; 不为攻击则退出
!!BG:E?y2; 获取目标堆栈为y2
!!BMy2:T?y3; 获取y2堆栈的怪物类型为y3
!!FU&y3<>155:E; 不为暗黑龙则退出
!!BMy2:R?y4; 获取暗黑龙可反击次数
!!FU&y4=<0:E; 若不可反击则退出
!!VRy4:Sy2 +1;
!!VRy4:*-1; 将堆栈编号置为负数
!!EAy4:E?y5/6/d/d; 获取堆栈经验值
!!EA155:L?y6; 获取暗黑龙的满经验值为y6
!!VRy6::10; 将满经验值除以10
!!VRy5::y6; 将y5除以y6获得暗黑龙当前经验等级
!!VRy6:Sy5; 将y5赋值给y6
!!VRy7&y6=0:S10;
!!VRy7&y6=1:S14;
!!VRy7&y6=2:S18;
!!VRy7&y6=3:S22;
!!VRy7&y6=4:S26;
!!VRy7&y6=5:S30;
!!VRy7&y6=6:S34;
!!VRy7&y6=7:S38;
!!VRy7&y6=8:S42;
!!VRy7&y6=9:S46;
!!VRy7&y6=10:S50;
*设置触发比例给y7
!!VRy8:S0 R99; y8随机0~99
!!FU&y8>y7:E; 若y8>y7则退出
!!VRv9136:S1; 放置几率成功的标志
!!BG:N?v9137; 获得攻击者的堆栈
!!BG:E?v9138; 获取暗黑龙的堆栈
!?BG1;
!!FU&v9136<>1:E; 如果几率失效则退出
!!VRv9136:S0; 重置标志
!!VRy10:Sv9137; 获得攻击者的堆栈
!!VRy2:Sv9138; 获取暗黑龙的堆栈
!!BMy2:N?y11; 获取暗黑龙的数量
!!FU&y11<1:E; 若暗黑龙全部死亡则退出
!!BMy2:H?y12; 获取暗黑龙的生命值
!!BMy2:L?y2; 获取暗黑龙受到的伤害
!!VRy3:Sy12 -y2; 计算暗黑龙的当前生命值
!!VRy11:-1;
!!VRy12:*y11;
!!VRy12:+y3;
*获取暗黑龙的总血量
!!BMy10:T?y13; 获取目标堆栈的怪物类型
!!BMy10:H?y14; 获取目标堆栈的血量
!!VRy15:Sy14 *y11; 目标将要死亡位数为小黑的数量
!!VRy12:+y15; 目标堆栈所收到的总伤害
!!VRy16:Sy12 :y14; 目标堆栈所死亡的数量
!!BMy10:N?y17; 获取目标堆栈的数量
!!VRy16&y17<y16:Sy17; 如果目标堆栈数量少于伤害死亡的数量，则伤亡显示为目标堆栈的全部
!!BMy10:V80; 播放堆栈的魔法
!!BMy10:Ky12; 目标堆栈受到伤害
!!BU:R; 重画屏幕
!!VRz-1:S^受到暗黑龙的“死神之眼”的影响，%Y16个生物死亡了！^; 伤亡报告
!!BU:Mz-1; 显示伤亡报告
************2、攻返，恐惧*********
!#MA:X155/1 X155/d2 X155/d8 X155/d16 X155/d128 X155/d2147483648;
!#EA155:B7/1/102/98/1/1/1/1/1/1/1/1/1/1/1;
!#EA155:B8/1/70/37/10/15/20/25/30/35/40/45/50/55/60;
************3、复活与加成***************
**每回合加满生命值
!?BA0;
!!MA:A155/?y1;
!!MA:D155/?y2;
!!MA:P155/?y3;
!!MA:S155/?y4;
!!MA:M155/?y5;
!!MA:E155/?y6;
!!VRv9130:Sy1 :2 +y1;
!!VRv9131:Sy2 :2 +y2;
!!VRv9132:Sy3 :2 +y3;
!!VRv9133:Sy4 :2 +y4;
!!VRv9134:Sy5 :2 +y5;
!!VRv9135:Sy6 :2 +y6;
!?BR; 每回合开始触发
!!DO6305/0/41/1:P; 进入循环函数1
!?FU6305; 函数1
!!BMx16:T?y1; 获取怪物类型
!!FU&y1<>155:E; 若不为暗黑龙则退出
!!BMx16:N?y2; 检查生物数量
!!FU&y2<1:E; 若暗黑龙不存活则退出
!!BMx16:L?y3; 检查暗黑龙是否受伤
!!FU&y3<1:E; 若暗黑龙未受伤则退出
!!BMx16:V4; 播放动画
!!BMx16:L0; 将暗黑龙生命值回复满
!!VRz-1:S^暗黑龙的生命值全部恢复了，并且属性大幅提高了。^; 设置文本
!!BU:Mz-1; 显示文本
!!FU6306:Px16; 进入函数2并将堆栈数赋给x1
!?FU6306; 函数2
!!VRy1:Sx1 +1;
!!VRy1:*-1; 将x1赋给y1并置为负数
!!EAy1:E?y2/6/d/d; 获取暗黑龙经验值为y2
!!EA155:L?y3; 获取暗黑龙的满经验值
!!VRy3::10; 将满经验值除以10
!!VRy2::y3; 将y2除以y3获得暗黑龙当前经验等级
!!VRy3:Sy2; y2赋值给y3
!!VRy3:+1; 将y3+1获得增长比例
!!MA:A155/?y4;
!!MA:D155/?y5;
!!MA:P155/?y6;
!!MA:S155/?y7;
!!MA:M155/?y8;
!!MA:E155/?y9;
!!VRy10:Sy4 *y3 :100;
!!VRy10&y10<1:S1;
!!VRy11:Sy5 *y3 :100;
!!VRy11&y11<1:S1;
!!VRy12:Sy6 *y3 :100;
!!VRy12&y12<1:S1;
!!VRy13:Sy7 *y3 :100;
!!VRy13&y13<1:S1;
!!VRy14:Sy8 *y3 :100;
!!VRy14&y14<1:S1;
!!VRy15:Sy9 *y3 :100;
!!VRy15&y15<1:S1;
*增长值计算
!!VRy16:Sy10 +y4;
!!VRy17:Sy11 +y5;
!!VRy18:Sy12 +y6;
!!VRy19:Sy13 +y7;
!!VRy20:Sy14 +y8;
!!VRy21:Sy15 +y9;
*限额计算
!!MA&y16<v9130:A155/dy10;
!!MA&y17<v9131:D155/dy11;
!!MA&y18<v9132:P155/dy12;
!!MA&y19<v9133:S155/dy13;
!!MA&y20<v9134:M155/dy14;
!!MA&y21<v9135:E155/dy15;
*属性增加
**************4、暗黑怒吼******************
!?CM4; 战场点击触发
!!CM:F?y1; 获取点击类型
!!FU&y1<>512:E; 不为右键则退出
!!CM:I?y2; 获取点击位置
!!FU&y2<>2008:E; 不为施法图标则退出
!!BG:N?y3; 获取当前堆栈
!!BMy3:T?y4; 获取堆栈怪物类型
!!FU&y4<>155:E; 不为暗黑龙则退出
!!CM:R0; 禁用标准反应
!!IF:Q2^{暗黑怒吼}
你是否要放弃攻击而施放暗黑怒吼，施放暗黑怒吼将提高我方部队的能力并增加生命值。^; 询问对话框
!!FU&-2:E; 否，则退出
!!VRy5&y3<21:S0; 若暗黑龙为进攻方所有，则y5=0
!!VRy5&y3>20:S21; 若暗黑龙为防守方所有，则y5=21
!!VRy6:Sy5 +20; y5赋值给y6并增加20
!!BMy3:Fd67108864; 设置暗黑龙为已行动
!!BMy3:H?y7; 获取暗黑龙当前生命值
!!MA:P155/?y8; 获取暗黑龙初始生命值
!!BMy3:N?y9; 获取暗黑龙数量
!!VRy9:-1; 当前数量减1
!!VRy10:Sy9 *y8 +y7; 计算总生命值
!!BM:C48/1/3/3/0; 施放大祈祷
!!VRz-1:S^暗黑龙施放了{暗黑怒吼}^; 设置文本
!!BU:Mz-1; 显示文本
!!DO6307/y5/y6/1:Py10; 进入循环函数3（施法）
!?FU6307; 函数3
!!VRy2:Sx1; y2设置为增加生命值的数量
!!BMx16:H?y3; 检查堆栈生命值
!!BMx16:L?y4; 检查堆栈已损失生命
!!BMx16:N?y11; 获取堆栈的当前数量
!!BMx16:B?y6; 获取怪物初始数量
!!BMx16&y2=<y4:L0; 恢复生命值
!!VRy8&y3>0:Sy2 :y3; 将总恢复点数y2赋给y8并除以堆栈当前生命值y3（结果为可复活的生物数）
!!VRy8:+1; 将可复活生物数y8加1得到最终的可复活生物数
!!VRy12:Sy11 +y8; 将堆栈当前数量y11赋给y12并加上可复活生物数y8（结果为理论最终复活数量）
!!BMx16&y2>y4/y12<=y6:Ny12; 若理论复活数量小于实际复活数量则复活y12个生物
!!BMx16&y2>y4/y12>y6:Ny6; 若理论复活数量大于实际复活数量则将堆栈还原为初始数量
!!BMx16&y2>y4:L0; 恢复生命值
!!BU:R; 重画屏幕
**************5、强弩之末***********************
!#VRv9139:S-1; 设置初始值
!?BG0; 动作前触发
!!BG:A?y3; 获取动作类型
!!FU&y3<>6:E; 不为攻击则退出
!!BG:E?y1; 获取目标堆栈为y1
!!BMy1:T?y2; 获取怪物类型为y2
!!FU&y2<>155:E; 不为暗黑龙则退出
!!BG:N?y5; 获取攻击方堆栈
!!VRv9139:Sy5; 将攻击方堆栈赋值给v9139
!!VRv9140:Sy1; 将目标堆栈赋值给v9140
*被动杀死
!?BG0; 动作前触发
!!BG:A?y3; 获取动作类型
!!FU&y3<>6:E; 不为攻击则退出
!!BG:N?y1; 获取攻击方堆栈为y1
!!BMy1:T?y2; 获取怪物类型为y2
!!FU&y2<>155:E; 不为暗黑龙则退出
!!BG:E?y5; 获取目标堆栈
!!VRv9139:Sy5; 将目标堆栈赋值给v9139
!!VRv9140:Sy1; 将攻击方堆栈赋值给v9140
*反击杀死
!?BG1; 动作后触发
!!FU&v9139<0:E; 若无堆栈则退出
!!VRy5:Sv9139; 将v9139赋值给y5
!!VRy1:Sv9140; 将v9140赋值给y1
!!VRv9139:S-1; 将v9139归为-1
!!BMy1:N?y4; 获取暗黑龙是否存活
!!FU&y4>0:E; 依然存活或不存在则退出
!!BMy5:V15; 播放动画
!!BMy5:K9999999999999999; 造成杀伤
!!BU:R; 重画屏幕
!!VRz-1:S^暗黑龙死亡前施放了{强弩之末}，杀死它的怪物全部死亡了。^; 设置文本
!!BU:Mz-1; 显示文本
*实际作用
*********end*********
made by:Kezhao24

复制代码

[ 本帖最后由克招于 2012-6-19 06:41 编辑 ]

克招 · 发表于 2012-6-7 06:55:06

第一次写脚本把每句都标注释的，是因为太生疏了，怕自己都不记得，以前从来都不写注释的。

学习ERM的童鞋也可以把脚本下下来研究，我擅长的是计算，看我这个脚本和之前的脚本就知道了，要学ERM算法的话，可以参考下，要学战斗类型脚本写法的话，可以看看。不过本人技术不高，仅作参考。
等有空我会放出小黑的战斗视频给各位观赏。