塔南特长优化版

异界行者 · 发表于 2011-7-27 12:29:46

在 骷髅召唤师 和 寻梦人 两位大大所作的脚本基础上进行了优化。
优化如下：
塔南多了后勤特长，并且如果塔南变成另一个英雄（就是把原来的塔南名字改掉，另一个英雄名字改成塔南）那么特长将对新英雄有效，原来的就无效了。
塔南的头像自动会改变成一个常规英雄没有用到的头像。如果塔南发生变化，那么头像会还原，新塔南将会换成那个头像。
全兵种特长算法稍微修改：原来是先乘以5%或2%的，这样有个缺点就是，低级兵永远只能获得1点增幅，高级兵才能享受正常加成。修改后则是先乘以等级再乘以5%或2%，这样所有兵都正常加成了。
另外一些细节修改，比如塔南特长特技图标修改，英雄传记修改。不过这些修改我并没有设置还原，因为感觉没有必要，如果你要常常改英雄名字，那么其实只要头像别乱了就行了。

PS：席德·堪培多尔就是我的马甲
ZVSE
!#VRz466:S^塔南^;
!#VRv84:S-1;
;---------------------------后勤--------------
!#TM99:S1/999/1/255;
!?TM99&1000;
!!HEv84&v84<>-1:L4/v84; 头像还原
!!VRv84:S-1;
!!DO644/0/155/1:P; 历遍所有英雄
!?FU644;
!!HEx16:B0/?z8; 取名字
!!HEx16:N?y10; 取编号
!!VRv84&z8=z466:Sy10;
!?PI;
!?TM99&1000;
!!HEv84&v84>-1:E?y1/?y2 S2/?y3;
!!VRy4&y3=0:S0;
!!VRy4&y3=1:S200;
!!VRy4&y3=2:S400;
!!VRy4&y3=3:S600;
!!VRy5:Sy2 *10 *y3 *y4;
!!VRy5::100;
!!HEv84&v84>-1:Wdy5;
;*********杂项设置*********
!?TM99&1000;
!!VRz9:S^塔南被祖先们认为没有资格进入天堂，他在这片土地上游荡以寻找对他以前罪恶的补偿。他是一个不朽的英雄，一个永恒的守护者，但是他自己一直困扰着他是否能够弥补他年轻时所犯下的涛天大错。
{额外特长}：每升1级，部队生命最大值+5%，攻、防、伤+2%；速度每5级+1，最大+11。敌人生命值与伤害值根据英雄等级每级降低1%，速度根据其本身速度而降低，速度越快降低越多。后勤有5%的等级加成。^;
!!HEv84&v84>-1:L1^hps002sh.PCX^; 改变小头像
!!HEv84&v84>-1:L2^hpl002sh.PCX^; 改变大头像
!!HEv84&v84>-1:R2/0; 性别男
!!HEv84&v84>-1:B1/z9;
!!UN&v84>-1:G2/v84/3/356; 特技图标
;******添加辅助技能**********************
!?TM99&1000;
!!DO645/0/27/1:P; 遍历所有辅助技能
!?FU645;
!!HEv84:Sx16/?y-27;
!!HEv84&x16<>4/x16<>12/y-27=0:Sx16/1; 排除外交术和招魂术，若无技能则添加。
*********脚本制作：骷髅召唤师，寻梦人*************************
*********效果：塔南全兵种特长***************
;---------------------------战斗开始-------------------------------------------
!?BA0&1000;
!!VRz7:S^^;
!!VRz8:S^^;
!!BA:H0/?v9555; 保存进攻方英雄到v9555
!!BA:H1/?v9560; 防守方hero到v9560
!!HEv9555:B0/?z7;
!!HEv9560&v9560>-1:B0/?z8;
!?BF&1000; 战场生成后
!!DO7055/0/20/1&z7=z466:Pv9555;本方数据
!!DO7055/21/41/1&z8=z466:Pv9560;
!!DO7056/21/41/1&z7=z466:P; 敌方数据
!!DO7056/0/20/1&z8=z466:P;
;---------------------------新英雄特长--------------------------------
!?FU7055; 己方触发
!!HEx1:E?y21/?v85; 取得英雄的等级v85
!!BMx16:T?y-30;
!!BMx16:H?y-31; 每级增加部队5%的生命
!!VRy-31: *v85;
!!VRy-32:Sy-31 :20;
!!VRy-32&y-32=0:S1;
!!BMx16:Hdy-32;
!!BMx16:A?y-33; 每级增加部队2%的攻击
!!VRy-33: *v85;
!!VRy-34:Sy-33:50;
!!VRy-34&y-34=0:S1;
!!BMx16:Ady-34;
!!BMx16:D?y-35; 每级增加部队2%的防御
!!VRy-35: *v85;
!!VRy-36:Sy-35:50;
!!VRy-36&y-36=0:S1;
!!BMx16:Ddy-36;
!!BMx16:U1/?y-37; 每级增加部队2%的最低伤害
!!VRy-37: *v85;
!!VRy-38:Sy-37:50;
!!VRy-38&y-38=0:S1;
!!BMx16:U1/dy-38;
!!BMx16:U2/?y-39; 每级增加部队2%的最高伤害
!!VRy-39: *v85;
!!VRy-40:Sy-39:50;
!!VRy-40&y-40=0:S1;
!!BMx16:U2/dy-40;
!!VRy23&v85<11:S0; 按等级增加1-11点速度
!!VRy23&v85<6:S1;
!!VRy23&v85>5/v85<11:S2;
!!VRy23&v85>10/v85<16:S3;
!!VRy23&v85>15/v85<21:S4;
!!VRy23&v85>20/v85<26:S5;
!!VRy23&v85>25/v85<31:S6;
!!VRy23&v85>30/v85<36:S7;
!!VRy23&v85>35/v85<41:S8;
!!VRy23&v85>40/v85<46:S9;
!!VRy23&v85>45/v85<51:S10;
!!VRy23&v85>50/v85<56:S11;
!!BMx16:Sdy23;
;********************************************
!?FU7056; 敌方触发
!!BMx16:S?y32;
!!FU&y32=0:E;
!!VRy33&y32<8:S-2; 根据敌方怪物速度减少其速度
!!VRy33&y32>7/y32<15:S-3;
!!VRy33&y32>14/y32<20:S-4;
!!VRy33&y32>=20:S-5;
!!BMx16:Sdy33;
!!VRy28:Sv85 :100;
!!BMx16:H?y-41; 每级降低部队1%的生命
!!VRy-42:Sy-41 *v85 :-100;
!!VRy-42&y-42=0:S-1;
!!VRy-42&y-41=1:S0;
!!BMx16:Hdy-42;
!!BMx16&y28>=1:HS1;
!!BMx16:U1/?y24; 每级降低部队1%的最低伤害
!!VRy24: *v85;
!!VRy25:Sy24 :-100;
!!VRy25&y25=0:S-1;
!!BMx16:U1/dy25;
!!BMx16&y28>=1:U1/S0;
!!BMx16:U2/?y26; 每级降低部队1%的最高伤害
!!VRy26: *v85;
!!VRy27:Sy26 :-100;
!!VRy27&y27=0:S-1;
!!BMx16:U2/dy27;
!!BMx16&y28>=1:U2/S0;

[ 本帖最后由异界行者于 2011-7-30 13:41 编辑 ]