提取至官方＃64脚本的【理财术增强II】事件版

fastarrow · 发表于 2010-11-30 14:12:24

就是10级以上专家理财术可以产[wiki]密银[/wiki]的，有人需要么？

ZVSE
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except [wiki]ERM[/wiki]_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
ERMS_ScriptDate=30.11(November).2010
!#VRv2370:S0;             disabled Universal Timer setup and calculations (because already done by Wogify script00.erm)
!#UN:P191/?v2363;       check if Estates Enhanced is enabled in [wiki]WoG[/wiki]ify Options
!#UN:P203/?v2368;       check if Estates I (script48.erm, Arstahd) is enabled
!#UN:P36/?v2369;          check if Mithril (script36.erm, Anders) is enabled
!#VRv2363:C1;
!#VRv2368:C1;
!#VRv2369:C1;
** 全局定时器
!#TM1:S1/999/1/255; triggers every color every day
!#TM2:S1/999/1/255; same but triggers only *after* all calculations from TM1 are done
!#VRv2396:S1;       init v2396 month indicator (starts with month 1)
!#VRv2390:S1;       init v2390 day comparator (c also starts with day 1 value)
!#MCv2391:S@once@;    init macros (= other names) for the seven used universal vars
!#MCv2392:S@day@;
!#MCv2393:S@weekday@;
!#MCv2394:S@AI@;
!#MCv2395:S@color@;
!#MCv2396:S@month@;
!#MCv2388:S@week@;    monthly week count (1,2,3,4,1,2,...), like v2393 is "weekday"
!#MCv2389:S@weeks@; continuing week count (1,2,3,4,5,6,...)
!#MCv2371:S@monday@;    !#VR$monday$:S1; init macros and values for weekdays
!#MCv2372:S@tuesday@; !#VR$tuesday$:S2;
!#MCv2373:S@wednesday@;  !#VR$wednesday$:S3;
!#MCv2374:S@thursday@; !#VR$thursday$:S4;
!#MCv2375:S@friday@;    !#VR$friday$:S5;
!#MCv2376:S@saturday@; !#VR$saturday$:S6;
!#MCv2377:S@sunday@;    !#VR$sunday$:S7;
!#MCv2380:S@red@;       !#VR$red$:S0;    init macros and values for colors
!#MCv2381:S@blue@;    !#VR$blue$:S1;
!#MCv2382:S@tan@;       !#VR$tan$:S2;
!#MCv2383:S@green@;    !#VR$green$:S3;
!#MCv2384:S@orange@;    !#VR$orange$:S4;
!#MCv2385:S@purple@;    !#VR$purple$:S5;
!#MCv2386:S@teal@;    !#VR$teal$:S6;
!#MCv2387:S@pink@;    !#VR$pink$:S7;
!#MCv3333:S@bit@;       !#VRv3333:S3333;
!?TM1&v2370=1;
!!OW:C?v2395;             get current player color (0..7)
!!OW:Iv2395/?v2394;       get current player status (0=human, 1=AI)
!!VRv2393:Sc %7;          set weekday (mon=1..sat=6,sun=0)
!!VRv2393&v2393=0:S7;       set sunday=7 instead of sunday=0
!!VRv2392:Sc;             set current day (comparison with c doesn't work in the next two lines)
!!VRv2391&v2390=v2392:S1; set once-on-that-day flag (only first active color)
!!VRv2391&v2390>v2392:S0; reset that flag (at second active color each day)
!!VRv2390&v2391=1:+1;       inc day comparator (needed for flag)
!!VRv2389&v2391=1:Sc -1 :7 +1; set weeks (cont count)
!!VRv2388&v2393=1/v2391=1:+1; inc  week counter by 1 for each monday
!!VRv2396&v2388=5/v2391=1:+1; inc month counter by 1 for each 5th week
!!VRv2388&v2388=5/v2391=1:S1; reset week counter for each new month
** 幸运值获取函数
!?FU2333;                         in: x1=hero number, out: x2=current luck
!!VRx2:S0;                            init output var x2
!!HEx1:S9/?y1 A2/45/d/?y2 A2/46/d/?y3 A2/47/d/?y4 A2/48/d/?y5 A2/108/d/?y6 R1/?y7 R6/?y8 A2/85/d/?y9 O?y12;
;    Luck  StillEyeDragon  Clover Cards    Ladybird PendCourage  temp cheat  Hourglass (owner)
!!VRy6:*3;                            set 3 bonus for Pendant of Courage
!!VRy8:*33;                         set 33 bonus if "maximum luck cheat" flag is set
!!OW:Wy12/?y10;                      number of towns for hero's owner
!!VRy10:-1;                         town check is 0..max-1 (and not 1..max)
!!DO2332/0/y10/1&y11=0:P?y11/y12;    check for Spirit Guardian (grail) bonus
!!VRx2&y9=0:+y1 +y2 +y3 +y4 +y5 +y6 +y7 +y8 +y11; current luck (x2) if no Hourglass
!!VRx2&y9=1:S0;                      Hourglass negates *all* luck ([wiki]SoD[/wiki] sets 0 battle luck even if cheat active)
!?FU2332;                         check player's towns for a Spirit Guardian
!!VRx1:S0;                            init return value
!!OW:Wx2/x16/?y1;                   get town number (the x16th town in player's list)
!!CA0/y1&y1>-1:T?y2 B3/26;          check if Rampart and Grail built
!!VRx1&1/y2=1:S2;                   set 2 bonus for Spirit Guardian grail structure
**技能点击函数
!?FU2345;
!!VRy1:S0;                            init vars
!!VRy2:S0;                            ..
!!VRy3:S0;                            ..
!!VRx3:S-1;                         .. init skill output var x3 (= -1 if slot empty or no skill slot clicked)
!!VRx4:S-1;                         .. init  area output var x4 (= -1 if slot empty or no skill slot clicked)
!!HEx2:S?y4;                         check number of known skills that are displayed
!!VRy1&x1>78/x1<87:S1;                check skill area (1 if icon clicked)
!!VRy1&x1>86/x1<95:S2;                ..             (2 if name clicked)
!!VRy1&x1>94/x1<103:S3;             ..             (3 if expertise clicked)
!!VRy2&y1=1:Sx1 -78;                calculate skill slot (if icon)
!!VRy2&y1=2:Sx1 -86;                ..                (if name)
!!VRy2&y1=3:Sx1 -94;                ..                (if expertise)
!!HEx2&y1>0:Sy2/?y3/1;
!!VRx3&y1>0:Sy3;                      set output var x3 (skill number)
!!VRx4&y1>0:Sy1;                      set output var x4 (skill area)
!!VRx5&y1>0:Sy2;                      set output var x5 (skill slot)
!!VRx3&y1>0/y2>y4:S-1;                set output vars to none (-1) if empty skill slot (i.e. slot higher than known skills)
!!VRx4&y1>0/y2>y4:S-1;                ..
!!VRx5&y1>0/y2>y4:S-1;                ..
**理财术增强                            (for WoG v3.58f)
!#VRv2333&v2363=1:S100;
!#VRv2334&v2363=1:S0; init lvl 10 msg status
!?TM2&v2363=1;                      daily timer for every color (if script active)
!!UN:B0/?v2369;                      check Mithril status (1=active)
!!OW:H-1/2331/0;                      store current color's number of heroes in v2331
!!DO2343/1/v2331/1:P;                loop through every hero a player has
!?FU2343;                         hero loop function for Estates
!!OW:H-1/2332/x16;                   store x16th hero of that player in v2332
!!IF:V236/1 Wv2332;                   set w var reference to current hero, set flag 236
!!HEv2332:S13/?y1 E?y2/?y3/1 X?y14/?y13/d/d/d/d/d; get Estates expertise y1, hero experience y2 and level y3, hero skill spec (y14=0 and y13=13 if Estates)
!!FU&y1=0/w47=0:E;                   exit if that hero has no Estates and no w47
!!VRy10:S1;                   GOLD full modifier for Expert Estates and in general to avoid division by zero
!!VRy10&y1=2:S2;                      half for Advanced Estates
!!VRy10&y1=1:S4;                      quarter for Basic Estates
!!VRy4&y1>0:Sy2 :10000 *v2333 :y10; calculate gold according to expertise and experience
!!VRy4&y4>2000/y13<>13:S2000;       max of +2000 Gold/day (from lvl 25 on) unless Estates specialist
!!VRy4&y4>5000:S5000;                max of +5000 Gold/day (around lvl 30) even if Estates specialist
!!OW&y1>0:R-1/6/dy4;                give/remove that gold
!!OW&y1>0:R-1/6/?y17;                check current treasure (player's current gold)
!!OW&y1>0/y17<0:R-1/6/0;             no negative treasure allowed
  change w47 state automatically (init w47 for lvl 1..9 or change w47 for ExpEst lvl 10+ or reset unlucky Mithril)
!!VRy11:S0;                         init indicator
*!VRw47&y1=0:S0;                   (if no Estates then reset w47 because hero may have unlearned Estates)
!!VRw47&w47=0/y1>0:R5 +1;             lvl 1..9 inits w47 with random 1..6, meaning +1 (Wood+Ore|Mercury|Sulfur|Crystal|Gem|350 Gold)
*!VRw47&w47<8/y13=13/y14=0:S8;       Estates specialty allows cycling/choosing from the beginning
!!VRw47&w47<8/y13=13/y14=0/w47>0:+8; Estates specialty sets random resource to daily (even for low-level), Expert allows choosing as if lvl10+
!!VRy11&w47<8/y1=3/y3>9:S1;          indicator: no choice yet, Exp Estates, lvl10+
!!VRw47&y11=1/v2369=0:S8; [TESTING] init w47 standard cycling if Mithril script inactive and all conditions met
!!VRw47&y11=1/v2369=1:S15;          init w47 Mithril cycling if Mithril script active and Exp Estates and lvl10+
!!VRw47&w47=16:S15;                   reset w47 Mithril choice unlucky flag (from the day before)
!!VRy5:S41 +y1;                      set correct Estates pic for msg below
!!VRy6:S-1;                         init pic to none
!!VRy6&y1=3/y3>9/v2369=1:S7;          set Mithril pic if Expert Estates and lvl10+ and Mithril active
!!VRy12:S1 +$color$;                get color + 1 (CAREFUL: VR:S$color$ +1 would ignore the +1)
!!FU$bit$:Py12;                      bit conversion, CAREFUL: result is returned in y-100
!!VRy12:Sv2334 &y-100;                check appropriate color for msg status
!!VRz-1:S^^;                         init z-1 [line added on 060912]
!!VRz-1&v2369=1:S^ 选择
秘银的获得依靠[wiki]英雄[/wiki]的幸运值(不幸则每星期给予一些资源)。
高级理财术+英雄10级以上会自动选择获得秘银。^;             Mithril selection line added to lvl 10 msg if Mithril active
!!IF&y11=1/y12=0/1000:Q236/20/y5/y6/0/1^{高级理财术}
每个10级以上的学会理财术的英雄每周将生产指定的资源：
1 木材+矿石每周一(第1天)， 1 水银每周二 (第2天)，
1 硫磺每周三 (第3天)，    1 水晶每周四 (第4天)，
1 宝石每周五 (第5天)，             350金币每周六 (第6天)，
1 秘银每周日 (第7天) 如果秘银激活，另外附加350金币。
左键点击{高级}理财术图标 (英雄资料窗口)选择一种日常资源。
拒绝所有的资源生产顺序将返回自动资源循环生产。%Z-1^; human only msg once hero has reached lvl 10+ and Exp Estates
*!VRv2334&-236:|y-100;                that color won't receive the message any more if Cancel was clicked (if type 2 msgbox above)
!!VRv2334&y11=1/y12=0/1000:|y-100;    that color won't receive the message any more after first display
  prepare resources according to w47 state
!!VRy7:S0;                            init resource var (y7)
!!VRy7&w47>0/w47<8/y3>=$weekday$:Sw47; lvl<10, check for weekday if to give resource type w47 at all that day
!!VRy7&w47=8:S$weekday$;             lvl 10+  cycling, give respective weekday resource
!!VRy7&w47>8/w47<15:Sw47 -8;          lvl 10+  give chosen resource type (w47 -8)
!!FU2333&w47=15:Pv2332/?y-1;          Mithril section: check current luck for that hero
!!VRy8&w47=15:R9;                   .. set daily chance threshold (9)
!!VRy8&w47=15/y-1=0:-1;             .. treat 0 luck as 1 luck (10% base chance)
!!VRy9&y8<y-1:S1;                   .. compare, set (y9=1) if lucky
!!VRy7&w47=15/y9=1:S7;                .. set y7 to Mithril if successful
!!VRy7&w47=15/y9=0/y1>0:S$weekday$; .. set y7 to weekday if unsuccessful but Estates
!!VRw47&w47=15/y9=0:S16;             .. set w47 to 16 if unsuccessful
  give resources according to above conditions
!!OW&y7=1:R-1/0/d1 R-1/2/d1;          give 1 Wood and 1 Ore
!!OW&y7=2:R-1/1/d1;                   give 1 Mercury
!!OW&y7>2/y7<6:R-1/y7/d1;             give 1 Sulphur, Crystal or Gem
!!OW&y7=6:R-1/y7/d350;                give 350 Gold
!!OW&y7=7/v2369=1:R-1/7/d1;          give 1 Mithril if active
!!OW&y7=7/v2369=0:R-1/6/d350;       give 350 Gold if Mithril inactive (weekday cycle reached sunday)
**英雄屏幕点击触发
!?CM2&v2363=1;
!!CM:I?y-1;                         get right-click number (y-1) (79..102 is skill area)
!!CM:S?y-2;                         check left/right-click (=12 left click, =14 right click)
!!FU2345:Py-1/-1/?y-3/?y-4/?y-5;    call skill click function (in: click number and hero number, out: skill (y-3), area (y-4) and slot (y-5))
!!VRy-6|v2368=1/v2360=1:S1;          set "flag" if Estates I (script48) or short skill descriptions (script75) enabled
!!CM&y-6=0/y-1>78/y-1<103/y-3=13:R0;
!!CM&y-6=1/y-1>78/y-1<87/y-3=13:R0; same but for Estates I or short skill descr, then only a click on skill icons will trigger the below msgboxes
!!FU2342&y-6=0/y-3=13:Py-4/y-2;
!!FU2342&y-6=1/y-3=13/y-4=1:Py-4/y-2;
**理财术增强显示函数
!?FU2342;                         display function
; x1 = skill area (= 1 if icon, = 2 if name, = 3 if expertise clicked)
; x2 = click type (= 12 left click, = 14 right click)
!!VRy16&x2=12:S2;                   if left-click  then init y16:=2 (OK/Cancel buttons)
!!VRy16&x2=14:S4;                   if right-click then init y16:=4 (no button)
!!FU&y16=0:E;    BUG COUNTERMEASURE: clicking non-functional-areas after Estates (with disabled std reaction) erroneously gives another msgbox and nasty side effects
!!IF:W-1;                            set w var reference to current hero
!!HE-1:S13/?y1 E?y2/?y3/1 X?y20/?y19/d/d/d/d/d; get Estates expertise (y1), hero experience (y2) and level (y3), skill specialty (y20=0 and y19=13 is Estates)
!!FU&y1=0:E;                         exit if no Estates present
init w47
!!VRw47&w47=0/y3<10:S1 R5;          init w47 with random 1..6 for lvl 1..9 and no init
*!VRw47&w47<8/y3>9:+8;                init w47 with cycling (no lvl 10 msg displayed then)
!!VRw47&w47<8/y1=3/y3>9/v2369=0:S8; init w47 standard cycling if Mithril script inactive and all conditions met
!!VRw47&w47<8/y1=3/y3>9/v2369=1:S15; init w47 Mithril cycling if Mithril script active and Exp Estates and lvl10+
  init weekday names
!!VRz-3&$weekday$=1:S^星期一^;       monday
!!VRz-3&$weekday$=2:S^星期二^;          .
!!VRz-3&$weekday$=3:S^星期三^;          .
!!VRz-3&$weekday$=4:S^星期四^;          .
!!VRz-3&$weekday$=5:S^星期五^;          .
!!VRz-3&$weekday$=6:S^星期六^;          .
!!VRz-3&$weekday$=7:S^星期日^;       sunday
**显示信息
!!VRz-1:S^^;                            init z-1 [line added on 060912]
!!VRy16&w47>0/w47<8/x2=12:S1;          lvl 1..9 left-click has OK button only
!!VRz-1&w47>0/w47<8/y3=1:S^每周一生产附加资源：^;    lvl 1 text
!!VRz-1&w47>0/w47<8/y3>1/y3<7:S^每周的第%Y3天生产附加资源：^;  lvl 2..6 text
!!VRz-1&w47>0/w47<8/y3>6/y3<10:S^每天还有生产附加资源：^; lvl 7..9 text
  lvl 10+ and cycling
!!VRy16&w47=8/x2=12/y1<3:S1;          lvl 10+ cycling left-click Bas/Adv Estates OK button only
!!VRz-1&w47=8/x2=12/y1<3:S^逢[wiki]工作[/wiki]日生产附加资源。
高级理财术将会让你选择资源的类型。
每次%Z-3：^;    lvl 10+ cycling left-click Bas/Adv Estates
!!VRz-1&w47=8/x2=12/y1=3:S^逢工作日生产不同资源。
保持循环？每次%Z-3：^;    lvl 10+ cycling left-click Expert Estates
!!VRz-1&w47=8/x2=14:S^逢工作日还有生产不同资源。
除非左击理财术图标？每次%Z-3：^;       lvl 10+ cycling right-click
!!VRz-1&w47>8/w47<15/x2=12:S^每天保持生产同一种资源？^; lvl 10+ chosen left-click
!!VRz-1&w47>8/w47<15/x2=14:S^选择每天生产的资源。
除非左击理财术图标，
每天：^; lvl 10+ chosen right-click
  lvl 10+ and Mithril chosen
!!FU2333&w47>14:P-1/?y-17;          check current luck of current hero
!!VRy4:Sy-17 *10;                   set daily chance
!!VRy4&y4>100:S100;                   set daily chance 100% max if luck 10+
!!VRy4&y4=0:S10;                      set daily chance 10% if zero luck
!!VRy4&y4<0:S0;                      set daily chance 0% if negative luck
!!VRz-1&w47>14/x2=12:S^每天有%Y4%%的机会
(当前的幸运值： %Y-17)生产秘银
而不是平常的资源。
继续选择秘银？今天你得到：^;       lvl 10+ Mithril chosen left-click
!!VRz-1&w47>14/x2=14:S^每天有%Y4%%的机会
(当前的幸运值： %Y-17)生产秘银
而不是平常的资源。
左键点击修改。今天你得到：^;       lvl 10+ Mithril chosen right-click
**调用资源图片
!!VRy12:S20;                         set first pic as skill pic
!!VRy13:S41 +y1;                      calculate correct Estates pic (according to expertise)
!!VRy14&w47<8:Sw47;                   set resource display for lvl 1..9
!!VRy14|w47=8/w47=16:S$weekday$;    if cycling (=8), or unlucky Mithril (=16), set pic to weekday resource
!!VRy14&w47>8/w47<16:Sw47 -8;       set resource display for lvl 10+ chosen
!!VRy12&y14=1:S0;                   if Wood/Ore then set first pic to Wood instead of Estates
!!VRy13&y14=1:S1;                   .. set Wood amount
!!VRy14&y14=1:S2;                   .. set Ore
!!VRy14&y14=2/y13>1:S1;             set Mercury resource
!!VRy14&y14=7/v2369=0:S6;             set gold resource instead of Mithril if Mithril script disabled (needed for weekday=sunday)
!!VRy15:S1;                         resource amount
!!VRy15&y14=6:S350;                   gold amount 350 instead of 1
**奖励资源资源计算公式
!!VRy5:Sy2 :10000;                   calculate additional gold bonus for display
!!VRy6&y1=1:Sv2333 :4;                set basic bonus factor
!!VRy7&y1=1:S125;                   set basic standard value
!!VRz-2&y1=1:S^初级^;                set basic skill descriptor
!!VRy6&y1=2:Sv2333 :2;                .. adv
!!VRy7&y1=2:S250;                      .. adv
!!VRz-2&y1=2:S^中级^;                .. adv
!!VRy6&y1=3:Sv2333;                   ... exp
!!VRy7&y1=3:S500;                      ... exp
!!VRz-2&y1=3:S^高级^;                ... exp
!!VRy5:*y6;                         set bonus
!!VRy5&y5>2000/y19<>13:S2000;       max of +2000 Gold/day (from lvl 25 on) unless Estates specialist
!!VRy5&y5>5000:S5000;                max of +5000 Gold/day (around lvl 30) even if Estates specialist
!!VRy21:Sy7;                         standard gold bonus
!!VRy7&y19=13/y20=0::20 *y3 +y21;    Estates display incl. specialty +5% per level bonus (y21)
!!VRy22:Sy5;                         display additional gold (given by this script)
!!VRy23:Sy2 :10000 *10;             calculate experience step for additional gold
!!VRy23&y19<>13/y23>200:S200;       display max 200,000 exp step if no Estates specialist
!!VRy23&y19=13/y23>500:S500;          display max 500,000 exp step if Estates specialist
!!VRy5:+y7;                         total gold/day (incl. Estates spec, excl. Estates I)
  if Estates I also active
!!VRy17:S5 *y1;                      check if 5, 10 or 15 gold
!!VRy18:Sy17 *y3;                   set 5/10/15 gold per level (from Estates I)
!!VRy5&v2368=1:+y18;                total if Estates I also active
!!VRz-4&v2368=0:S^)^;                if Estates I inactive
!!VRz-4&v2368=1:S^
+ %Y17每级)          ^;             if Estates I active
**消息显示
!!VRy11:S6 +v2369;                   init upper resource bound (Gold or Mithril if enabled)
!!IF:V236/1;                         init flag 236
!!IF:Q236/y12/y13/y14/y15/y16^{%Z-2 理财术}
拥有%Z-2理财术，这位英雄每天得到{%Y5金币}
(%Y7 + %Y22/%Y23,000 经验%Z-4
%Z-1^; main display
#1: flag
#2: type pic 1 (=20 for secondary skill)
#3: subtype pic 1 (=skill incl expertise, here =41+EstatesExpertise)
#4: type pic 2 (=1..7 for resource, -1 for none)
#5: subtype pic 2 (=amount resource, 350 if gold (resource=6), else 1)
#6: type message  (=1 OK button, =2 OK/Cancel buttons, =4 no button)
!!DO2344/1/y11/1&-236/y1=3/y16=2:P; if Cancel clicked (check flag), loop through resources (1..6 or 1..7 if Mithril allowed)
!!VRw47&-236/y1=3/y16=2:S8;          set w47=8 (cycling) if final resource also rejected
!!VRw47&-236/y1=3/y16=2/v2369=1:S15; set w47=15 (Mithril cycling) if final resource also rejected and Mithril script active
!!VRz-1&-236/y1=3/y16=2/v2369=0:S^^; set empty string if no Mithril
!!VRz-1&-236/y1=3/y16=2/v2369=1:S^ 选择
秘银的获得依靠英雄的幸运值(不幸则每星期给予一些资源)。
高级理财术+英雄10级以上会自动选择获得秘银。^; Mithril selection line added to lvl 10 msg if Mithril active
!!IF&-236/y1=3/y16=2/v2369=1:Q236/20/44/7/0/1^{高级理财术}
每个10级以上的学会理财术的英雄每周将生产指定的资源：
1 木材+矿石每周一(第1天)， 1 水银每周二 (第2天)，
1 硫磺每周三 (第3天)，    1 水晶每周四 (第4天)，
1 宝石每周五 (第5天)，             350金币每周六 (第6天)，
1 秘银每周日 (第7天) 如果秘银激活，另外附加350金币。
左键点击{高级}理财术图标 (英雄资料窗口)选择一种日常资源。
拒绝所有的资源生产顺序将返回自动资源循环生产。%Z-1^; repeat the human only lvl10+ ExpEstMsgbox then
**资源循环函数
!?FU2344;                         resource change loop function
!!VRy12:S20;                         init skill pic
!!VRy13:S44;                         Expert Estates
!!VRy14:Sx16;                         init resource
!!VRy15:S1;                         amount
!!VRy15&x16=6:S350;                   amount of gold
!!VRy12&x16=1:S0;                   Wood pic instead of skill pic
!!VRy13&x16=1:S1;                   amount 1 instead of ExpEst pic
!!VRy14&x16=1:S2;                   Ore pic
!!VRy14&x16=2:S1;                   Mercury pic
!!IF:Q236/y12/y13/y14/y15/2^{高级理财术}
每天英雄应该得到^; selection msgbox for Expert Estates
!!VRw47&236:Sx16 +8;                set respective resource indicator if selected
!!VRx16&236:S10;                      go for exit if selected