懒人用的自定义怪物能力ERM

woodmelon

哈哈,突发奇想,写了个[wiki]ERM[/wiki],开始以为很容易,结果一写就是几小时,还频频出错,可能太久没写ERM的缘故.不过最终还是完成了

脚本作用:
1.可以自定义任何生物的攻防伤命速和特技
2.只能在游戏的第一天使用,以后都无法使用
3.大地图中右键点击唤醒/睡眠图标激发

完全适合懒人和对ERM一窍不通者使用
高手用它没多大用处,不过可以很快的改生物能力倒是真的
看此简单,但写出这么个脚本倒花费了不少心思
懒人有福了...
喜欢的话就送钱给我,哈哈哈哈...
大家别把怪物改得太BT了:==:

设置的数目大于1000的话
CPU慢的电脑可能会卡一下,但很快会恢复

代码的最下方有连接下载,对懒人真是适合不过了.


ZVSE
**FU28000-28005
**右键点击睡眠/唤醒按键触发
**只能在游戏开始的第一天有效

!?CM0;
!!VRy-1:Sc0;
!!FU&y-1>1:E;
!!CM:I?y-1 S?y-2;
!!FU28000&y-1=6/y-2=14:P0;  
!!CM:R0;

!?FU28000;
!!VRz1:S^请输入要修改的生物ID
（0～121,123,125,127,129-196）^;
!!VRz2:S^^;
!!VRz3:S^请别输入其它无关文字^;
!!IF:D1/1/3/2////////////;
!!IF:F1/////1;
!!IF:E1/1;
!!VRz10:Sz1;
!!VRz10:H2;
!!FU&-2:E;
!!DO28002/0/196/1:P0;
!!VRz-1&z10<>z4:S^没有找到相关生物ID,再来一次?^;
!!IF&z10<>z4:D5///-1////////////;
!!IF&z10<>z4:F5/////1;
!!IF&z10<>z4:E1/5;
!!FU28000&v1=5/z10<>z4:P0;    输入错误
!!FU28003&z10=z4:P0;          输入正确

*检查ID
!?FU28001;
!!UN:N3/5/x1/0;            z5=name
!!VRz-1:S^你要修改的生物为 %Z5 ,是吗?^;
!!IF:D5///-1////////////;
!!IF:F5/////1;
!!IF:E1/5;
!!FU&v1=5:E;
!!VRz-1:S^继续修改其它生物?^;
!!IF:D5///-1////////////;
!!IF:F5/////1;
!!IF:E1/5;
!!FU28000&v1=5:P0;


*检查输入数
!?FU28002;
!!FU&z10=z4:E;
!!FU&x1=0/x16=122:E;
!!FU&x1=0/x16=124:E;
!!FU&x1=0/x16=126:E;
!!FU&x1=0/x16=128:E;
!!VRz4:S^%X16^;
!!FU28001&z10=z4/x1=0:Px16;
!!VRv2&z10=z4/x1=0:Sx16;           v2=ID
!!VRv4&z10=z4/x1=1:Sx16;

**
!?FU28003;
!!IF:V4/x1;
!!MA&-4:Xv2/?y-1;
!!VRy-1&-4:&4;
!!VRz1&-4:S^修改 %Z5 哪个属性?^;
!!VRz2&-4:S^攻击^;
!!VRz3&-4:S^防御^;
!!VRz4&-4:S^生命^;
!!VRz5&-4:S^最小伤害^;
!!VRz6&-4:S^最大伤害^;
!!VRz7&-4:S^速度^;
!!VRz8&-4:S^^;
!!VRz8&y-1=4/-4:S^箭数目^;
!!VRz9&-4:S^特技^;
!!VRz10&-4:S^取消^;
!!IF&-4:G1/3/256/1/2/3/4/5/6/7/8/9/10;
!!FU&v3=256/-4:E;
!!FU28004&-4/v3<128:P;
!!FU28005&v3=128:P;
!!FU&-4:E;
!!MA&v3=1:Av2/v4;
!!MA&v3=2:Dv2/v4;
!!MA&v3=4:Pv2/v4;
!!MA&v3=8:Mv2/v4;
!!MA&v3=16:Ev2/v4;
!!MA&v3=32:Sv2/v4;
!!MA&v3=64:Nv2/v4;

!?FU28004;
!!VRz1:S^请输入要修改的数值（1～5000）^;
!!VRz2:S^^;
!!VRz3:S^请别输入其它无关文字^;
!!IF:D1/1/3/2////////////;
!!IF:F1/////1;
!!IF:E1/1;
!!VRz10:Sz1;
!!VRz10:H2;
!!FU|-2/v1<>5:E;
!!DO28002/1/5000/1:P1;
!!VRz-1&z10<>z4:S^输入错误!^;
!!IF&z10<>z4:D5///-1////////////;
!!IF&z10<>z4:F5/////0;
!!IF&z10<>z4:E1/5;
!!FU28003&z10<>z4:P0;          输入错误
!!FU28003&z10=z4:P1;           输入正确

!?FU28005;
!!MA:Xv2/?y-1 Xv2/?y-2 Xv2/?y-3 Xv2/?y-4 Xv2/?y-5 Xv2/?y-6 Xv2/?y-7 Xv2/?y-8 Xv2/?y-9;
!!VRy-1:&2;
!!VRy-2:&8;
!!VRy-3:&16;
!!VRy-4:&1024;
!!VRy-5:&16384;
!!VRy-6:&32768;
!!VRy-7:&65536;
!!VRy-8:&262144;
!!VRy-9:&524288;
!!VRz1:S^^;
!!VRz2:S^^;
!!VRz3:S^^;
!!VRz4:S^^;
!!VRz5:S^^;
!!VRz6:S^^;
!!VRz7:S^^;
!!VRz8:S^^;
!!VRz9:S^^;
!!VRz1&y-1=0:S^飞行^;
!!VRz2&y-2=0:S^龙息^;
!!VRz3&y-3=0:S^生存^;
!!VRz4&y-4=0:S^精神免疫^;
!!VRz5&y-5=0:S^火免^;
!!VRz6&y-6=0:S^攻击两次^;
!!VRz7&y-7=0:S^不反击^;
!!VRz8&y-8=0:S^不死系^;
!!VRz9&y-9=0:S^环击^;
!!VRz10:S^请选择[wiki]生物特技[/wiki]^;
!!VRz11:S^取消^;
!!IF:G1/3/256/10/1/2/3/4/5/6/7/8/9/11;
!!FU&v3=512:E;
!!VRy-1&v3=1:S2;
!!VRy-1&v3=2:S8;
!!VRy-1&v3=4:S16;
!!VRy-1&v3=8:S1024;
!!VRy-1&v3=16:S16384;
!!VRy-1&v3=32:S32768;
!!VRy-1&v3=64:S65536;
!!VRy-1&v3=128:S262144;
!!VRy-1&v3=256:S524288;
!!MA:Xv2/dy-1;
!!FU28003:P1;

yunings

发现我是来回捣腾给你＋＃……

zjcadd

佩服
我以后又有福啦（我是浪人）

翼之暹罗

好像和生物周有冲突——当某周是某修改生物的生物周时，那么这个生物的攻防杀伤生命等等数值又会变成修改前的数值+生物周附加数值了。

woodmelon

原帖由 翼之暹罗 于 2006-3-17 21:42 发表
好像和生物周有冲突——当某周是某修改生物的生物周时，那么这个生物的攻防杀伤生命等等数值又会变成修改前的数值+生物周附加数值了。

對Imp無效

查了一下生物之周的[wiki]ERM[/wiki]
應該是第一天記錄了某個生物的攻防，剛好下周是這個生物之周
所以用了之前記錄的屬性+獎勵造成的

可以修正，不過要改動script20.erm中的某些值，算了，不動它們了
使用的話先暫時關閉生物周吧
要不就在第7天時把英雄身上重要的生物扔到城裡就行了（例如天使）
這樣下周就不會是天使周了
生物周好像是在英雄部隊中任選一種生物的

akgod

下不了啊