关于GB 魔法天尊 ERM 出现的问题
昨天下了个GB关于魔法天尊的ERM,发现攻城的时候用闪电会出问题.放完毁灭之光之后,英雄开始对战场上所有的敌军部队放闪电,可惜打完所有部队之后就会黑屏,接着退出.原因估计是打完部队之后英雄又想用魔法打箭楼从而造成问题.请问这个问题可以解决吗?以下是原ERM的代码:ZVSE
;------------------------------选择新特长--------------------------------------------
!#VRv83:C156/156/156/156; 初始化变量
!#VRz3:S^新英雄特长（by GB）^;
!#VRz4:S^输入拥有该特长的英雄名字:^;
!#VRz5:S^英雄特长为：^;
!#VRz6:S^每级增加己方部队生命的5％^;
!#VRz7:S^每级减少敌方部队生命的2.5％^;
!#VRz8:S^鬼武者:升级后增加鬼部队的攻防血伤速^;
!#VRz9:S^魔法天尊:加强魔法伤害,能学到四系终极魔法^;
!#IF:D6/3/4/5/////////6/7/8/9;
!#IF:E87/6;
!#VRz466&v87>0:Sz1; 将输入的名字保存到z466
!?TM19&1000;
!!DO644/0/155/1:P; 历遍所有英雄
!!VRv85&v85=156:S99; 没有符合名字的英雄,则默认设为跟Mars的设置一样
!!VRv86&v86=156:S57; 大鹏特长改为+生命,地狱火特长改为-生命
!!VRv84&v84=156:S79; 默认为Nagash(黑幕特长),鬼武者
!!VRv83&v83=156:S45; 默认为Solmyr(闪电链特长),魔法天尊
!!HEv83:Y24/1/360/1; 魔法天尊-禁止访问竞技场
!!HEv83:Y7/10/30/1; 魔法天尊-每天+10点魔法
!?FU644;
!!HEx16:B0/?z8; 取名字
!!HEx16:N?y10; 取编号
!!VRv85&z8=z466/v87=1:Sy10; 比较
!!VRv86&z8=z466/v87=2:Sy10;
!!VRv84&z8=z466/v87=3:Sy10;
!!VRv83&z8=z466/v87=4:Sy10;
!!VRz9&z8=z466/v87=1:S^(L)^;
!!VRz9&z8=z466/v87=2:S^(D)^;
!!VRz9&z8=z466/v87=3:S^(G)^;
!!VRz9&z8=z466/v87=4:S^(M)^;
!!VRz9&z8=z466:+z8;
!!HEx16&z8=z466:B0/z9;
;---------------------------战斗开始-------------------------------------------
!?BA0&1000;
!!BA:H0/?v9555; 保存进攻方英雄到v9555
!!BA:H1/?v9560; 防守方hero到v9560
!?BF&1000; 战场生成后
!!DO7041/0/20/1&v9555=v85:P; 小雨
!!DO7041/21/41/1&v9560=v85:P;
!!DO7042/21/41/1&v9555=v86:P; 长C
!!DO7042/0/20/1&v9560=v86:P;
!!DO7055/0/20/1&v9555=v84:P; 鬼武者
!!DO7055/21/41/1&v9560=v84:P;
!!FU7143&v9555=v83:P; 魔法天尊:普通特长启动
!!FU7144&v9560=v83:P;
!!HEv83|v9555=v83/v9560=v83:A2/80/?y9/?y13; 检查土灵球
!!HEv83|v9555=v83/v9560=v83:E?y11/?y23; 检查等级
!!DO7147/0/20/1&v9555=v83/y13>0/y23>=20:P21; 魔法天尊:土之怒
!!DO7147/21/41/1&v9560=v83/y13>0/y23>=20:P0;
!!HEv83&v9555=v83:A2/79/?y9/?y14 A2/81/?y9/?y15 A2/82/?y9/?y16;检查四系灵球
!!FU7150&y13=1/y14=1/y15=1/y16=1:P; 四球齐集,魔神降世
;---------------------------新英雄特长--------------------------------
!?FU7041; rain(寒江夜雨)
!!BMx16:H?y-37;
!!FU&y-37=0:E;
!!VRy-37::20; 每级增加5%的HP
!!VRy-37&y-37=0:S1;
!!HEv85:E?j/?k;
!!VRy-38:Sy-37 *k;
!!BMx16:Hdy-38;
;---------------------------------------------------------------------
!?FU7042; confusionism(长C)
!!BMx16:H?y24;
!!FU&y24=0:E;
!!VRy24::40; 每级减少2.5%的HP
!!VRy24&y24=0:S1;
!!HEv86:E?j/?k;
!!VRy25:Sy24 *k;
!!BMx16:H?y26 T?y27;
!!VRy25&y25>=y26:Sy26 -1;
!!VRy26:-y25;
!!BMx16&y26>0/y27<>156:Hy26;
;---------------------------------------------------------------------
!?FU7055; 鬼武者
!!BMx16:F?y-30;
!!VRy-30:&262144; 判断是否为亡灵部队
!!FU&y-30=0:E;
!!HEv84:E?y21/?y22; 取得鬼武者的等级y22
!!BMx16:Ady22; 按等级直接增加攻,防,伤害
!!BMx16:Ddy22;
!!BMx16:U1/dy22;
!!BMx16:U2/dy22;
!!VRy23&y22<11:S1; 按等级增加1-3点速度
!!VRy23&y22>10/y22<21:S2;
!!VRy23&y22>=21:S3;
!!BMx16:Sdy23;
!!BMx16:H?y-31; 每级增加鬼部队5%的生命
!!VRy-31::20;
!!VRy-31&y-31=0:S1;
!!VRy-32:Sy-31 *y22;
!!BMx16:Hdy-32;
;---------------------------------------------------------------------
;魔法天尊-普通特长
;1.每级增加魔法伤害的5%
;2.每级减少己方部队受到的魔法伤害的2.5%,最低为50%
!?FU7143; 进攻方为魔法天尊
!!HEv83:E?y5/?y6;
!!VRy7:Sy6 *5;
!!VRv7150:Sy7 +100;
!!VRv7151:S100 -y7;
!!VRv7151&v7151<50:S50; 最少受到50%的魔法伤害
!?FU7144; 防守方为魔法天尊
!!HEv83:E?y5/?y6;
!!VRy7:Sy6 *5;
!!VRv7152:Sy7 +100;
!!VRv7153:S100 -y7;
!!VRv7151&v7151<50:S50; 最少受到50%的魔法伤害
** start of magic resist trigger
!?MR0&1000/v9555=v83; 进攻方为魔法天尊
!!BG:A?y-1 E?y2;
!!FU&y-1<>1:E;
!!MR:D?y3;
!!VRy3&y2>20:*v7150 :100;
!!VRy3&y2<21:*v7151 :100;
!!MR:Dy3;
!?MR0&1000/v9560=v83; 防守方为魔法天尊
!!BG:A?y-1 E?y2;
!!FU&y-1<>1:E;
!!MR:D?y3;
!!VRy3&y2<21:*v7152 :100;
!!VRy3&y2>20:*v7153 :100;
!!MR:Dy3;
** end of magic resist trigger
;---------------------气之怒 开始---------------------------------
; "气之怒",须准备气灵球,等级>=10
; 英雄施放闪电时,100%追加毁灭之光,50%几率施放催眠,再引发雷暴.
!?BG0|v9555=v83/v9560=v83; 施放闪电前触发
!!HEv83:E?y11/?v2800; 检查等级
!!HEv83:A2/79/?y9/?y11; 检查气灵球
!!BG:E?v2801 A?v2802 S?v2803 N?v2805 Q?y4; 检查各动作参数
!!BHy4:N?v2804; 检查带领的部队的英雄是否魔法天尊
!!IF&y11>0/v2800>=10/v2802=1/v2803=17/v2804=v83:V440/1; 满足条件则标志为真
*******************************
!?BG1|v9555=v83/v9560=v83; 施放闪电后触发
!!FU|-440/v2801=-1:E; 标志为假或目标不存在则退出
!!BMv2801:N?y43;
!!IF&440/y43<1:V440/0;
!!FU&y43<1:E; 目标部队已被消灭则退出
!!HEv83:I?y90/1; 使用大技不需要耗魔法
!!BG:D?y3; 目标位置
!!HEv83:S15/?y4; 英雄的气系等级
!!BH0:C47/y3/y4/1; +毁灭之光
!!BMv2801:V29 V29;
!!DO7145/21/41/1&v9555=v83:Py4;+全体闪电,作为进攻方时
!!DO7145/0/20/1&v9560=v83:Py4; 作为防守方时
!!BMv2801&v2801>-1:N?y44;
!!VRy-50:S0 T100;
!!BH0&y-50>50/y44>0:C60/y3/y4/1; 50%几率+催眠
!!HEv83:Iy90/1;
!!IF&440:V440/0; 重置标志440
!?FU7145; 全体闪电
!!BMx16:P?y11 N?y12;
!!BH0&y12>0:C17/y11/x1/1; y11=目标位置,x1=技能等级
;---------------------气之怒 结束---------------------------------
;---------------------火之怒 开始---------------------------------
;"火之怒",须准备火灵球,等级>=15
; 己方部队反击时,各25%几率失明和疯狂对方.
; 敌人一支部队被消灭后,将被转化为火元素,受我方控制,等HP转化.
!?BG0|v9555=v83/v9560=v83; 部队反击前触发
!!HEv83:A2/81/?y9/?y12; 检查火灵球
!!FU|y12<>1/v2801=-1:E;
!!BMv2801:R?v2806;
!!BMv2801:I?y4;
!!BHy4:N?y6;
*!IF:M^v2801=%V2801,v2806=%V2806,y4=%Y4,y6=%Y6^;
!!IF&y12>0/v2800>=15/v2802=6/y6=v83:V441/1; 满足条件则标志为真
!?BG1|v9555=v83/v9560=v83;
!!FU|-441/v2801=-1:E; 标志为假则退出
!!BMv2805:N?y42 P?y43;
!!FU7146&y42<1:Py43; 被攻击部队死亡则召唤火元素
!!IF&441/y42<1:V441/0; 重置标志441
!!FU&y42<1:E;
!!BMv2801:R?y28; 被攻击部队的反击次数
!!VRy-51:S0 T100; 基于系统时间产生0-100的随机数
!!BMv2805&y-51<25/y28<v2806:V6; 失明效果(分开写是为避免魔法延迟)
!!BMv2805&y-51<25/y28<v2806:M62/3/1; 25%几率+失明
!!BMv2805&y-51>75/y28<v2806:V35;
!!BMv2805&y-51>75/y28<v2806:M59/3/1; 25%几率+疯狂
!!IF&441:V441/0; 重置标志441
!?FU7146;
!!BMv2805:T?y6 B?y7; v2800为被攻击部队的堆栈号
!!MA:Py6/?y8; 被消灭部队的数量和生命
!!VRy9:Sy8 *y7 :35; 总生命除35(火元素的生命值)=召唤数量
;防止堆栈溢出,BU应该会自动检查
!!BMv2805:V9 V57 V11; 出场效果,地狱火+地雷
!!BU&y9>0:S114/y9/x1/0/-1/1; 数量至少为一则召唤火元素出来
;---------------------火之怒 结束---------------------------------
;---------------------土之怒 开始---------------------------------
;"土之怒",须准备土灵球,等级>=20
; 战斗前己方获得护盾,石肤,敌人受减速,悲伤,各持续八和四回合.
; 施放雷鸣爆弹时,在目标周围制造流沙结界,50%几率石化该部队.
!?FU7147;
!!BMx16:M27/8/2 M46/8/2; +护盾,石肤
!!BMx1:M54/4/2 M50/4/2; +减速,悲伤
!!VRx1:+1;
!?BG0|v9555=v83/v9560=v83; 施放爆裂前触发
!!HEv83:A2/80/?y9/?y13; 检查土灵球
!!IF&y13>0/v2800>=20/v2802=1/v2803=18/v2804=v83:V442/1; 满足条件则标志为真
!?BG1|v9555=v83/v9560=v83;
!!FU&-442:E; 标志为假则退出
!!HEv83:I?y90/1; 使用大技不需要耗魔法
!!BMv2801:N?y64;
!!VRy-52:S0 T100; 基于系统时间产生0-100的随机数
!!BMv2801&y-52>50/y64>0:V67;
!!BMv2801&y-52>50/y64>0:M70/3/0; 50%几率+石化
!!BG:D?y16; 目标位置
!!FU7148&v9555=v83:Py16/0; 流沙结界
!!FU7148&v9560=v83:Py16/21;
!!HEv83:Iy90/1; 使用大技不需要耗魔法
!!IF&442:V442/0; 重置标志442
!?FU7148;
!!VRy-80:Sx1 :17 +1; 由怪物位置得出所处行数y-80
!!VRy-81:S0; 奇偶行的位置修正数
!!VRy-82:S0;
!!VRy-81|y-80=1/y-80=3/y-80=5/y-80=7/y-80=9/y-80=11:S1;
!!VRy-82|y-80=2/y-80=4/y-80=6/y-80=8/y-80=10:S1;
!!VRy20:Sx1 +1; 得出目标周围的六个位置坐标
!!VRy21:Sx1 +16 +y-81;
!!VRy22:Sx1 +17 +y-81;
!!VRy23:Sx1 -1;
!!VRy24:Sx1 -16 -y-82;
!!VRy25:Sx1 -17 -y-82;
!!BMx2:Q0/y20/0; 在周围六个位置施放流沙
!!BMx2:Q0/y21/0;
!!BMx2:Q0/y22/0;
!!BMx2:Q0/y23/0;
!!BMx2:Q0/y24/0;
!!BMx2:Q0/y25/1;
;---------------------土之怒 结束--------------------------------- ;---------------------水之怒 开始---------------------------------
;"水之怒",须准备水灵球,等级>=25
; 己方部队射击时,10%几率把对方转化为镜像体.
; 战斗胜利后,把经验的10%转换为移动力,最高为2000点
!?BG0|v9555=v83/v9560=v83; 部队攻击前触发
!!HEv83:A2/82/?y9/?y14; 检查水灵球
!!IF&y14>0/v2800>=25/v2802=7/v2804=v83:V443/1; 满足条件则标志为真
!?BG1|v9555=v83/v9560=v83;
!!FU|-443/v2801=-1:E; 标志为假则退出
!!BMv2801:N?y43;
!!IF&443/y43<1:V443/0;
!!FU&y43<1:E; 部队已被消灭则退出
!!VRy-54:S0 T100; 基于系统时间产生0-100的随机数
!!BMv2801&y-54>90:V81 V80; 虚弱+必杀效果
!!BMv2801&y-54>90:F?y11; 读取怪物标志
!!VRy11&y-54>90:|12582912; +镜像体标志
!!BMv2801&y-54>90:Fy11; 重写
!!BU&y-54>90:R; 刷新屏幕
!!IF&443:V443/0; 重置标志443
******************************
!?BA0&1000;
!!HEv83&v9555=v83:E?v9549; 战斗前的经验
!!HEv83&v9560=v83:E?v9551;
!?BA1&1000;
!!BA:H0/?y60; 保存进攻方英雄到v9555
!!BA:H1/?y61; 防守方hero到v9560
!!HEy60&y60=v83:E?v9550;
!!HEy61&y61=v83:E?v9552;
!!VRy14:S0;
!!HEv83|y60=v83/y61=v83:A2/82/?y9/?y14; 检查水灵球
!!FU7149&y14=1/y60=v83/v2800>=25:Pv9550/v9549;经验转化为移动力
!!FU7149&y14=1/y61=v83/v2800>=25:Pv9552/v9551;
!!FU7151&444:P; 神之怒重置
!!IF&444:V444/0;
!?FU7149; 10%经验值转化移动力
!!VRy88:Sx1 -x2;
!!VRy88::10;
!!VRy88&y88>1000:S1000; 最高限制为1000点
*!IF:M^add %Y88^;
!!HEv83&y88>0:Wdy88;
;---------------------水之怒 结束---------------------------------
;---------------------神之怒 开始---------------------------------
;"神之怒",须装备四系灵球.等级>=30,只在作为进攻方时有效.
; 取消所有部队的魔法抗性,相当于毁灭之球
; 禁止对方英雄施放魔法.
; 屏蔽禁魔球的作用.
; 战斗时,英雄施放魔法将不消耗魔法点.
!?FU7150; 战斗前触发"神之怒"效果
!!HEv83:E?y1/?y2;
!!FU&y2<30:E; 检查等级
!!HEv83:A2/93/?y40/?y41; 是否已经有毁灭之球
!!HEv83&y41<>1:A-3; 没有则删掉投石车
!!HEv83&y41<>1:A1/93/16; 装备毁灭之球
!!HEv9560&v9560>-1:A2/126/?y40/?y41; 检查敌英雄是否有禁魔球
!!HEv9560&v9560>-1/y41=1:A-126; 有则删掉
!!HEv9560&v9560>-1/y41=1:A126; 把球扔到背囊里
!!IF:V444/1; 四球齐集标志
!!HEv83:I?v2808; 魔法天尊的魔法点
!?FU7151; 战斗后删掉毁灭球
!!HEv83:A2/3/?y40/?y41;
!!FU&y40=1:E;
!!HEv83:A3/93/1/1;
!!HEv83:A4/3;
!?BG0&v9555=v83; 战斗中
!!BG&v2804=v9560/v2802=1/444:A0; 电脑英雄想施放魔法则禁止
!?BG1&v9555=v83; 魔法天尊施放魔法后
!!BM0&v2802=1/v2804=v83/444:V63; 火墙效果
!!HEv83&v2802=1/v2804=v83/444:Iv2808/1; 保持魔法值不变
;---------------------神之怒 结束---------------------------------
;--------------------灵球购买触发---------------------------------
;这个是要写的,不然我辛辛苦苦写的新特长就没法发挥了,嘿嘿.
;它会在魔法天尊升到特定的级别时触发,提问是否购买相应的灵球,机会只有一次.
;升到10,15,20,25级可购买的分别为气,火,土,水灵球,
;气灵球=10000金,火20000,土30000,水40000;
*?HLv83&v83>-1; 竟然不能用变量作触发参数,FT..
!?HL-1;
!!HE-1:N?y83;
!!FU&y83<>v83:E; 不是魔法天尊则退出
!!HEv83&v83>-1:E?y70/?y71;获得级别
!!FU7152&y71=10:P79/10000;10级时学气之怒,买气灵球
!!FU7152&y71=15:P81/20000;15,火
!!FU7152&y71=20:P80/30000;20,土
!!FU7152&y71=25:P82/40000;25,水
!!IF&y71=30:M^You become a archmage and learn "Raging God"^;
!?FU7152;
!!HEv83&v83>-1:B0/?z9; 英雄名字
!!VRz10&x1=79:S^Raging Air^; 终极魔法名字
!!VRz10&x1=81:S^Raging Fire^;
!!VRz10&x1=80:S^Raging Earth^;
!!VRz10&x1=82:S^Raging Water^;
;提问是否购买灵球
!!IF:Q4/8/x1/6/x2/2^%Z9 learn the magic
"-=%Z10=-".
Buy This Artifact?^;
!!FU&-4:E;
!!HEv83&v83>-1:O?y10;
!!OW:Ry10/6/?y11;
!!IF&y11<x2:M^Show Me The Money.^; 检查现金
!!FU&y11<x2:E;
!!VRy11:-x2;
!!OW:Ry10/6/y11; 扣钱
!!HEv83&v83>-1:A4/x1; 获得宝物
;------------------------------END-------------------------------- 看代码中全体闪电的代码没有错误，判断和条件都对。楼主是每次都遇到这种情况吗？还是偶尔出现？另外，出现这种情况前是否添加了其他脚本（就是说使用这个脚本后是否又添加了额外脚本）？因为某些玩家的自编脚本如果书写不够规范，容易与其他脚本冲突，造成游戏黑屏退出，所以，出现这种状况要排查原因不是那么容易的。 我只用了这一个脚本和另外一个宠物全技能全宝物的脚本,其它的都是官方脚本.每次都是这样.请问别的人有没这种问题?不知是别的人没这种问题还是没人有闪电攻城.(今天又下了个生灵之戒）
今天发现了新问题.有一次用闪电并没有打所有的人.很奇怪的有一个人没打(并不是被挡,是根本没打).可惜只出了一次,不知为何.真奇怪.
[ 本帖最后由 kidlau 于 2007-4-3 12:42 编辑 ] 看楼主的描述，应该属于游戏的随机Bug，我这边游戏一切正常，使用魔法天尊ERM测试没有发现楼主描述的现象（未添加任何非官方脚本） 我用魔法天尊的时候从来没碰到过黑屏情况
页:
[1]
