这段统率力脚本还是有bug，哪位有更新的版本呢？
目前守城的统率值不能正常计算，现发出脚本内容如下，这个脚本很有意思，请大家帮助完善哦~ZVSE
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.10.5.945
ERMS_ScriptDate=24.1(January).2016
** Command Points version 0.2
** by Timothy Pulver
** script122.erm
** Temporary script number: script96.erm
** Last Updated: June 21, 2006
** Previously Updated: June 12, 2006
** This script limits the number of troops that a single hero can take into
** battle. The main goal is to require players to spread out their army,
** rather than using the tried-and-true (but somewhat boring) "superhero"
** strategy.
** Higher level heroes *will* be able to command more troops, but the limits
** make it necessary to diversify if you wish to field a larger army.
** Each hero can command up to 2000 plus 3000 Command Points (3000 gold) worth
** of troops per hero level in battle. Exceeding this results in the excess
** troops departing.
** A towns without a defending hero or Fort can send 5,000 Command Points of
** troops into battle. If the town has a Fort, it can sent 10,000 points, a
** Citadel, 15,000 points, and a Castle, 20,000 points. If the town has a
** defending hero, the Fort/Citadel/Castle bonus is added to the defending
** hero's Command Point total.
** Neutral armies and towns have no Command Point limits.
** To see the active hero's Command Point limit and total Command Points of the
** hero's army at any time, right-click on the Sleep/Wake button. To see the
** Command Points for a town garrison or garrison hero, right-click on the
** garrison hero slot in the town screen.
** Leadership reduces the Command Point value of troops by 10% per level of
** Leadership (i.e., 10%/20%/30%) for troops affected by morale only.
** In other words, Undead and Elementals don't get this reduction bonus.
** Necromancy reduces the Command Point value of Undead troops in the same way
** as Leadership (i.e., 10%/20%/30% for Undead troops only).
** Air/Earth/Fire/Water Magic reduce the Command Point values of Elementals of
** the same element by 10%/20%/30%, e.g., Advanced Fire Magic reduces the
** Command Point cost of Fire and Energy Elementals by 20%.
** Diplomacy increases a hero's Command Points by 150/300/500 per level.
--------------------------------------------------------------------------------
** ERM Option Number: 322
** Flags and Variables: local/temporary only
** Functions: FU317-FU321
--------------------------------------------------------------------------------
!#UN:P322/1;
!?CM0&999;
!!UN:P322/=1; !!FU&-1:E;
!!CM:I?y-1;
!!FU&y-1<>6:E;
!!OW:A-1/?y-1;
!!FU317&y-1>=0:Py-1/0/0;
!!CM:R0;
--------------------------------------------------------------------------------
!?CM1&999;
!!UN:P322/=1; !!FU&-1:E;
!!CM:I?y-1 S?y-2;
!!FU|y-1<>123/y-2<>14:E;
!!CA-1:H0/?y-1;
!!IF:V1/0;
!!CA-1:B3/9;
!!VRy-27&1:S3;
!!CA-1&-1:B3/8;
!!VRy-27&1/y-27=0:S2;
!!CA-1&-1:B3/7;
!!VRy-27&1/y-27=0:S1;
!!FU317&y-1>=0:Py-1/0/y-27/0;
!!FU317&y-1<0:Py-1/0/y-27/1;
!!CM:R0;
--------------------------------------------------------------------------------
!?FU317;
!!HEx1&x4=0:Ed/?y1;
!!HEx1&x4=0:S6/?y2 S12/?y3 S15/?y4 S17/?y5 S14/?y6 S16/?y7 S4/?y8;
!!VRy9&x4=0:S2500 *y1 +2500; ***每级增加3000点统率值
!!VRy9&x3=0/x4=1:S5000;
!!VRy9&x3=1:+10000;
!!VRy9&x3=2:+15000;
!!VRy9&x3=3:+20000;
!!VRy10&y8=1:S100 *y1;
!!VRy10&y8=2:S200 *y1;
!!VRy10&y8=3:S300 *y1;
!!VRy11:Sy9 +y10;
!!VRy12:S10 -y2;
!!VRy13:S10 -y3;
!!VRy14:S10 -y4;
!!VRy15:S10 -y5;
!!VRy16:S10 -y6;
!!VRy17:S10 -y7;
!!VRy-2:S0;
!!DO318/0/6/1&x4=0:Px1/y12/y13/y14/y15/y16/y17/0/0/0;
!!DO318/0/6/1&x4=1:Px1/y12/y13/y14/y15/y16/y17/0/1/0;
!!HEx1&x4=0:B0/?z5 R2/?y18;
!!CA-1&x4=1:N?z5;
!!VRz6&y18=0:S^他的^;
!!VRz6&y18=1:S^她的^;
!!VRz6&x4=1:S^这^;
!!VRz7&y18=0:S^他^;
!!VRz7&y18=1:S^她^;
!!VRz7&x4=1:S^%Z5^;
!!VRz9&y18=0:S^他的^;
!!VRz9&y18=1:S^她的^;
!!VRz9&x4=1:S^它的^;
!!VRz10:S^带领^;
!!VRz10&x4=1:S^发送^;
!!VRy19&y11>=y-2:Sy11 -y-2;
!!VRy19&y11<y-2:Sy-2 -y11;
!!VRz8&x2=0/y11=y-2:S^（战斗时%Z7无法统率更多部队了。）^;
!!VRz8&x2=0/y11>y-2:S^（%Z7的剩余统率值还有%Y19点，部队仍可进行扩充。）^;
!!VRz8&x2=0/y11<y-2:S^（现有兵力已超出%Z5的统率值%Y19点。）^;
!!VRz1&x2=0:S^统率值：%Y11点。^;
!!VRz2&x2=0:S^%Z5的最大统率值为%Y11点（招募价格）：初始2500点，每级增加2500点。^;
!!VRz3&x2=0:S^部队总统率值：%Y-2点。^;
!!VRz4&x2=0:S^%Z5的统率值须达到%Y-2点方可带领全员参战。^;
!!UN&x2=0:A68/9/1 A68/10/2 A12/9/3 A12/10/4;
!!IF&x2=0:Q1/8/68/8/12/1^{统率值：}
%Z5的最大统率值为%Y11点。
统率值达到%Y-2点可带领%Z6部队全员作战。
%Z8。^;
!!UN&x2=0:A68/9/0 A68/10/0 A12/9/0 A12/10/0;
!!FU|x2=0/y11>=y-2:E;
!!VRy-5:S-1;
!!VRe-1:Sy19 :y-2;
!!DO318/0/6/1:Px1/y12/y13/y14/y15/y16/y17/1/0/x4;
!!VRy-2:S0;
!!DO318/0/6/1:Px1/y12/y13/y14/y15/y16/y17/0/0/x4;
!!FU|y11>=y-2/y-5<0:E;
!!VRy-6:Sy-2 -y11;
!!HEx1&x4=0:C0/y-10/?y21/?y22;
!!CAy-17/y-18/y-19&x4=1:M2/y-10/?y21/?y22;
!!VRy23:Sy21 *y22;
!!VRy24:R1/y23;
!!DO319/0/1/0:Px1/y12/y13/y14/y15/y16/y17/x4;
--------------------------------------------------------------------------------
!?FU318;
!!HEx1&x9=0/x10=0:C0/x16/?y1/?y2;
!!CAy-17/y-18/y-19&x9=0/x10=1:M2/x16/?y1/?y2;
!!CA-1&x9=1:M2/x16/?y1/?y2;
!!VRy10:S-20 -x16;
!!VRyy10&yy10<0:Sy2;
!!VRy11:S-50 -x16;
!!VRyy11&yy11<0:Sy1;
!!FU|y1<0/y2<1:E;
!!MA:Cy1/6/?y3 Xy1/?y4;
!!VRy5:Sy3 *y2;
!!VRy6:Sy4;
!!VRy6:&16;
!!VRy5&y6=16:*x2 :10;
!!VRy6:Sy4;
!!VRy6:&262144;
!!VRy5&y6=262144:*x3 :10;
!!VRy5|y1=112/y1=127:*x4 :10;
!!VRy5|y1=113/y1=125:*x5 :10;
!!VRy5|y1=114/y1=129:*x6 :10;
!!VRy5|y1=115/y1=123:*x7 :10;
!!VRy-2&x8=0:+y5;
!!FU&x8=0:E;
!!VRe1:Sy5 *e-1;
!!VRe2:Sy5 :y2;
!!VRy7:Se1 :e2;
!!VRy7&y7>y2:Sy2;
!!VRy8:Sy7 *-1;
!!HEx1&x10=0:C0/x16/d/dy8;
!!CAy-17/y-18/y-19&x10=1:M2/x16/d/dy8;
!!FU&y7=y2:E;
!!VRy-5:+1;
!!VRy9:S-10 -y-5;
!!VRyy9:Sx16;
--------------------------------------------------------------------------------
!?FU319;
!!VRy11:S0 Ry-5;
!!VRy12:S-10 -y11;
!!VRy13:Syy12;
!!HEx1&x8=0:C0/y13/?y1/?y2;
!!CAy-17/y-18/y-19&x8=1:M2/y13/?y1/?y2;
!!FU|y1<0/y2<1:E;
!!MA:Cy1/6/?y3 Xy1/?y4;
!!VRy5:Sy3 *y2;
!!VRy6:Sy4;
!!VRy6:&16;
!!VRy5&y6=16:*x2 :10;
!!VRy6:Sy4;
!!VRy6:&262144;
!!VRy5&y6=262144:*x3 :10;
!!VRy5|y1=112/y1=127:*x4 :10;
!!VRy5|y1=113/y1=125:*x5 :10;
!!VRy5|y1=114/y1=129:*x6 :10;
!!VRy5|y1=115/y1=123:*x7 :10;
!!VRe1:Sy5 :y2;
!!HEx1&x8=0:C0/y13/d/d-1;
!!CAy-17/y-18/y-19&x8=1:M2/y13/d/d-1;
!!VRy-6:-e1;
!!VRx16&y-6<=0:S999;
--------------------------------------------------------------------------------
!?BA52;
!!UN:P322/=1; !!FU&-1:E;
!!BA:H0/?y-3 H1/?y-4;
!!DO321/20/56/1:P;
!!FU317&y-3>=0:Py-3/1/0/0;
!!VRy-7:S-1;
!!DO320/0/6/1&y-3>=0:Py-3;
!!IF&y-7>=0/y-3>=0:Ny-30/y-40/y-31/y-41/y-32/y-42/y-33/y-43/y-34/y-44/y-35/y-45/y-36/y-46/-1/-1;
!!IF&y-7>=0/y-3>=0:N^{无法参战的散兵游勇}
%Z5的统率值不足，无法参战的部队变成了散兵游勇四散溃逃！（在战略界面右键单击睡眠/唤醒按钮可查看统率值。）^;
!!DO321/20/56/1:P;
!!BA:P?y-17/?y-18/?y-19;
!!BA:S?y-8;
!!OBy-17/y-18/y-19:T?y-9;
!!CAy-17/y-18/y-19&y-9=98:O?y-28;
!!FU&y-4<0/y-9<>98:E;
!!FU317&y-4>=0:Py-4/1/y-8/0;
!!FU317&y-4=-2/y-9=98/y-28>=0:Py-4/1/y-8/1;
!!VRy-7:S-1;
!!DO320/0/6/1&y-4>=0:Py-4/0;
!!DO320/0/6/1&y-4=-2/y-9=98/y-28>=0:Py-4/1;
!!IF&y-7>=0:Ny-30/y-40/y-31/y-41/y-32/y-42/y-33/y-43/y-34/y-44/y-35/y-45/y-36/y-46/-1/-1;
!!IF&y-7>=0:N^{无法参战的散兵游勇}
%Z5的统率值不足，无法参战的部队变成了散兵游勇四散溃逃！（在战略界面右键单击睡眠/唤醒按钮可查看统率值。）^;
--------------------------------------------------------------------------------
!?FU320;
!!HEx1&x2=0:C0/x16/?y1/?y2;
!!CAy-17/y-18/y-19&x2=1:M2/x16/?y1/?y2;
!!VRy3:S-20 -x16;
!!VRy4:Syy3 -y2;
!!VRy7:S-50 -x16;
!!FU|y4<1/yy7<0:E;
!!VRy-7:+1;
!!VRy5:S-30 -y-7;
!!VRyy5:S21;
!!VRy6:S-40 -y-7;
!!VRyy6:Sy4 *65536 +yy7;
--------------------------------------------------------------------------------
!?FU321;
!!VRy1:Sx16 *-1;
!!VRyy1:S-1;
--------------------------------------------------------------------------------
页:
[1]
