请高手帮写个ERM，英雄对本族1-8级生物均有加成。
体现一下种族特色，省得万年都是那几个英雄出场不知道哪有高手有闲 不能出这么空泛的求助的.别人看到都不想理了.
楼主你得出个方案啊,谁知道你到底想要怎样的效果. 贤大出现，太荣兴了，我对数字不太敏感，容我先去算算，看能不能搞个相对合理的方案出来。 贤知有您 发表于 2015-9-16 21:20
不能出这么空泛的求助的.别人看到都不想理了.
楼主你得出个方案啊,谁知道你到底想要怎样的效果.
以我的水平，只能搞这么个方案了
英雄对本族所有生物
生命 1级加5%，每2级加1% 以20%为上限
攻防 [（英雄等级 / 怪物等级）X5]%+怪物等级
伤害 1级加1 ，每5级加1 以怪物最小伤害为上限
速度 固定加1
本帖最后由 贤知有您 于 2015-9-17 10:27 编辑
攻防 [（英雄等级 / 怪物等级）X5]%+怪物等级
最后的+怪物等级是什么意思.
怪物等级是作为百分比还是数值?
生命 1级加5%，每2级加1% 以20%为上限
对于低级生物,如果计算是0,不增加吗?还是至少为1.
贤知有您 发表于 2015-9-17 10:24
攻防 [（英雄等级 / 怪物等级）X5]%+怪物等级
最后的+怪物等级是什么意思.
1.加攻防：前面的公式就是原版H3的加成方式，但这样15的6级兵特才攻防各加2，所以在这个基础上再加上一个怪物等级数的攻击力。
2.生命值至少加1，小数的处理采用进位法吧，如大于1小于2时，按2算。 本帖最后由 贤知有您 于 2015-9-17 21:01 编辑
郭磊 发表于 2015-9-17 14:37
1.加攻防：前面的公式就是原版H3的加成方式，但这样15的6级兵特才攻防各加2，所以在这个基础上再加上一个 ...
ERM的语法上,基本都是小数按退位的,也就是截尾后的整数.
因为ERM的整型除法就是这么个处理.
攻防 [（英雄等级 / 怪物等级）X5]%+怪物等级15级的英雄,6级兵. 那么 15/6=2,再乘以5也就是10%.假设生物有20攻击,才是20*10%=2吧.如果再加等级,也就是+8攻击了.
楼主有没有想过,如果再英雄刚好特长生物,那么这个生物岂不是更BT了.
代码纯粹手写,未测试过,楼主先试试看效果.
ZVSE
!?BF&1000;
!!BA:H0/?y1;
!!if&y1>-1:;
!!HEy1:Ed/?y11/1 B2/?y12;
!!VRy12::2;
!!DO2718281/0/20/1:Py1/y11/y12;
!!en:;
!!BA:H1/?y2;
!!if&y2>-1:;
!!HEy2:Ed/?y21/1 B2/?y22;
!!VRy22::2;
!!DO2718281/21/41/1:Py2/y21/y22;
!!en:;
!?FU2718281;
*x1=HERO,x2=HERO_LEVEL,x3=TOWN_TYPE
*生命 1级加5%，每2级加1% 以20%为上限 (至少1?)
*攻防 [（英雄等级 / 怪物等级）X5]%+怪物等级
*伤害 1级加1 ，每5级加1 以怪物最小伤害为上限
*速度 固定加1
!!BMx16:T?y1 N?y2;
!!FU|y1<0/y2<1:E;
!!MA:Oy1/?y3;
!!FU&y3<>x3:E;
!!MA:Ay1/?y11 Dy1/?y12 My1/?y13 Ey1/?y14 Py1/?y15 Ly1/?y16;[攻/防/伤Min/伤Max/命/级]
!!VRy16:+1;
!!BMx16:A?y21 D?y22 U1/?y23 U2/?y24 H?y25;
*攻击/防御*
!!VRy9:Sx2:y16*5*y11:100+y16;[攻击]
!!VRy10:Sx2:y16*5*y12:100+y16;[防御]
!!BMx16:Ady9 Ddy10;
*伤害*
!!VRy10:Sx2-1:5+1;
!!VRy10&y10>y13:Sy13;[上限是最少伤害]
!!BMx16:U1/dy10 U2/dy10;
*生命*
!!VRy10:Sx2 -1 :2 +5;
!!VRy10&y10>20:S20;
!!VRy9:Sy15 *y10 :100;
!!VRy9&y9<1:S1;[增加生命,至少1]
!!BMx16:Hdy9;
*速度*
!!BMx16:Sd1; 贤知有您 发表于 2015-9-17 21:07
代码纯粹手写,未测试过,楼主先试试看效果.
感谢贤大，在单位只能简单进游戏看一下，效果都实现了:deyi:
兵种特确实是变态了，小伊一级木弓速度8，生命18……
页:
[1]
