矿井加强优化版出错
在359下在大地图右击魔法书查看产量,先卡几秒然后显示完产量后跟着就一堆错误信息;bf;-----------------------
ERM syntax Error.
File: erm
Line: 6719
Reason:
"HE$"-cannot find hero (out of range).
Save all ERM vars to WOGERMLOG.TXT (may take time)?
-----------------------
-----Context-----
O?y3;
!!FU9000&y1=14/y2=1007/y3>-1:P2503/y3; 右键点击金币数量图标
!?FU9000&x1=2503;
!!VRv1451:S-1;
!!VRv1456:C0/0/0/0/0/0/0; v1456-v1462
!!UN:U53/-1/?v1451;
!!DO9000/1/v1451/1&v1451>0:P2504/x2;
!.....
-----------------
是不是和其他的什么脚本冲突了？ dadds 发表于 2013-10-12 23:20
是不是和其他的什么脚本冲突了？
就用359的时候有这问题，用358和ERA的时候就没这情况;bf; 楼主用的是那个版本的矿井脚本呢?
要不把矿井的脚本发上来看看. 作为一个农民，学习是必须的 贤知有您 发表于 2013-10-13 09:08
楼主用的是那个版本的矿井脚本呢?
要不把矿井的脚本发上来看看.
ZVSE
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
ERMS_ScriptDate=29.9(September).2013
**脚本功能**
-矿井加强：根据矿井的驻守为矿井增加产量，公式为：
-金矿：驻守总生命值为增加的产量
-木材和矿石：驻守总生命值除以400为增加的产量
-其他资源：驻守总生命值除以800为增加的产量
-秘银不作改变
**脚本原理**
在访问矿井前与后自动为当前矿井检测兵力，并增减相应变量
**作者：克招 --优化 ashero4
**时间：2013.6.19
**使用变量：v1451~1465
****函数FU9000， x1变量2500-2505
**使用定时器：TM5
********************************************************
*********************矿井访问后*************************
!$OB53&1000;
!!FU9000:P2500;
!?FU9000&x1=2500;
!!VRv1452:C-1/0/-1/-1; v1452 玩家旗帜 v1453总生命 v1454 增加资源 v1455 矿井类型
!!MNv998/v999/v1000:O?v1452/1;
!!MNv998/v999/v1000:R?v1455/1;
!!DO9000/0/6/1:P2501;
!!VRv1454|v1455=0/v1455=2:Sv1453 :400; 木材石头
!!VRv1454|v1455=1/v1455=3/v1455=4/v1455=5:Sv1453 :800; 资源
!!VRv1454&v1455=6:Sv1453; 金币
!!IF&v1454<1/v1453>0:Q1/21/132/1^虽然您已经派兵驻守矿井，但是你安排的部队太少，不能生产额外的资源^;
!!IF&v1454>0/v1453>0:Q1/v1455/v1454/1^派兵驻守}
派兵驻守不仅使你的矿井增加产量，而且他们会为矿井与敌人战斗到最后一刻，目前，此矿井的产量为：^;
!?FU9000&x1=2501; 计算驻守部队生命
!!VRv1:C-1/-1/-1/0;
!!MNv998/v999/v1000:Mx16/?v1/?v2;
!!FU|v1<0/v2<1:E;
!!MA&v1>-1:Pv1/?v3;
!!VRv4&v2>0:Sv3*v2;
!!VRv1453&v4>0:+v4;
**********每天加资源*********
!#TM5:S2/999/1/255;
!?TM5&1000;
!!VRv1451:S-1;
!!UN:U53/-1/?v1451; 取得全地图矿井数
!!DO9000/1/v1451/1&v1451>0:P2506; 加资源
!?FU9000&x1=2506;
!!VRv1452:C-1/0/-1/-1; v1452 玩家旗帜 v1453总生命 v1454 增加资源 v1455 矿井类型
!!VRv1463:C-1/-1/-1; v1463-v1465
!!UN:U53/-1/x16/1463; 取得当前矿井坐标
!!MNv1463/v1464/v1465:O?v1452/1;
!!MNv1463/v1464/v1465:R?v1455/1;
!!FU&v1452<0:E;
!!DO9000/0/6/1:P2505; 计算驻守部队生命
!!VRv1454|v1455=0/v1455=2:Sv1453 :400; 木材石头
!!VRv1454|v1455=1/v1455=3/v1455=4/v1455=5:Sv1453 :800; 资源
!!VRv1454&v1455=6:Sv1453; 金币
!!OW:Rv1452/v1455/dv1454;
****显示加资源的数量*****
!?CM0&1000; 冒险画面右键点击英雄施法图标
!!CM:S?y1 I?y2;
!!FU|y1<>14/y2<>8:E;
!!OW:A-1/?y3;
!!FU&y3<0:E;
!!HEy3:O?y3;
!!FU9000&y1=14/y2=8/y3>-1:P2503/y3; 右键点击施法图标
!!CM:R1;
!!CM:S?y1 I?y2;
!!HE-1:O?y3;
!!FU9000&y1=14/y2=1007/y3>-1:P2503/y3; 右键点击金币数量图标
!?FU9000&x1=2503;
!!VRv1451:S-1;
!!VRv1456:C0/0/0/0/0/0/0; v1456-v1462
!!UN:U53/-1/?v1451;
!!DO9000/1/v1451/1&v1451>0:P2504/x2;
!!VRz80:S^
您的部队在矿井里面辛苦打工，将为您每天增加
%V1456 木材
%V1457 水银
%V1458 矿石
%V1459 硫磺
%V1460 水晶
%V1461 宝石
%V1462 金币
^;
!!IF:D5/80;
!!IF:E1/5;
!?FU9000&x1=2504;
!!VRv1452:C-1/0/-1/-1; v14512 玩家旗帜 v1453总生命 v1454 增加资源 v1455 矿井类型
!!VRv1463:C-1/-1/-1; v1463-v1465
!!UN:U53/-1/x16/1463;
!!MNv1463/v1464/v1465:O?v1452/1;
!!MNv1463/v1464/v1465:R?v1455/1;
!!FU&v1452<>x2:E;
!!DO9000/0/6/1:P2505;
!!VRv1454|v1455=0/v1455=2:Sv1453 :400; 木材石头
!!VRv1454|v1455=1/v1455=3/v1455=4/v1455=5:Sv1453 :800; 资源
!!VRv1454&v1455=6:Sv1453;
!!VRv1456&v1455=0:+v1454; 木材
!!VRv1457&v1455=1:+v1454; 水银
!!VRv1458&v1455=2:+v1454; 石头
!!VRv1459&v1455=3:+v1454; 硫磺
!!VRv1460&v1455=4:+v1454; 水晶
!!VRv1461&v1455=5:+v1454; 宝石
!!VRv1462&v1455=6:+v1454; 金币
!?FU9000&x1=2505; 计算驻守部队生命
!!VRv1:C-1/-1/-1/0;
!!MNv1463/v1464/v1465:Mx16/?v1/?v2;
!!FU|v1<0/v2<1:E;
!!MA&v1>-1:Pv1/?v3;
!!VRv4&v2>0:Sv3*v2;
!!VRv1453&v4>0:+v4;
ZVSE 秘银矿
ERMS_ScriptDate=29.5(May).2006
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
**ERM WoG Option Numbers: 700
*Variables & functions claimed*
*v982-v989: MithrilMine number of players
*v967-v974: MithrilMine occupation day accounts
*FU22550: Set Mithril mine parameters
*FU22551: Set Mithril number
*TM39: Mithril provider
*Initialization
!#UN:P700/?v1;
!#VRv982&v1=1:S0;
!#VRv983&v1=1:S0;
!#VRv984&v1=1:S0;
!#VRv985&v1=1:S0;
!#VRv986&v1=1:S0;
!#VRv987&v1=1:S0;
!#VRv988&v1=1:S0;
!#VRv989&v1=1:S0;
!#VRv967&v1=1:S0;
!#VRv968&v1=1:S0;
!#VRv969&v1=1:S0;
!#VRv970&v1=1:S0;
!#VRv971&v1=1:S0;
!#VRv972&v1=1:S0;
!#VRv973&v1=1:S0;
!#VRv974&v1=1:S0;
!#TM39&v1=1:S1/999/1/255;
!?TM39;
!!UN:P700/?v1;
!!FU&v1=0:E;
!!OW:C?f;
!!VRf:+982;
!!VRg:Svf;
!!OW:C?f;
!!VRf:+967;
!!VRvf:+g;
!!FU22551&vf>=7:Pf;
!?FU22551;
!!VRvf:-7;
!!VRf:-967;
!!OW:Rf/7/?g;
!!VRg:+4;
!!OW:Rf/7/g;
!?OB33/1;
!!UN:P700/?v1;
!!FU&v1=0:E;
!!GRv998/v999/v1000:O?f;
!!OW:C?g;
!!FU22550&f<>g:Pf/g;
!?FU22550;
!!IF:Q1/7/0/1^{Mithril}
You gain control of a Mithril Mine. It will provide you with 4 units of Mithril in every 7 days.^;
!!VRf:S982;
!!VRf&x1<>-1:+x1;
!!VRvf&x1<>-1:-1;
!!VRf:S982;
!!VRf:+x2;
!!VRvf:+1;
358的时候就没问题 gigichart 发表于 2013-10-13 22:33
358的时候就没问题
总觉得这段写得好奇怪
!?CM0&1000; 冒险画面右键点击英雄施法图标
!!CM:S?y1 I?y2;
!!FU|y1<>14/y2<>8:E;
!!OW:A-1/?y3;
!!FU&y3<0:E;
!!HEy3:O?y3;
!!FU9000&y1=14/y2=8/y3>-1:P2503/y3; 右键点击施法图标
!!CM:R1;
!!CM:S?y1 I?y2;
!!HE-1:O?y3;
!!FU9000&y1=14/y2=1007/y3>-1:P2503/y3; 右键点击金币数量图标
试试换成这样
---------------------------------------------------------------------------------
!?CM0&1000; 冒险画面右键点击英雄施法图标
!!CM:S?y1 I?y2;
!!FU|y1<>14/y2<>8:E;
!!OW:A-1/?y3;
!!FU&y3<0:E;
!!HEy3:O?y3;
!!FU9000&y1=14/y2=8/y3>-1:P2503/y3; 右键点击施法图标
!!CM:R1;
!?CM0&1000; 冒险画面右键点击英雄施法图标
!!CM:S?y1 I?y2;
!!FU|y1<>14/y2<>1007:E;
!!OW:A-1/?y3;
!!FU&y3<0:E;
!!HEy3:O?y3;
!!FU9000&y1=14/y2=1007/y3>-1:P2503/y3; 右键点击金币数量图标 贤知有您 发表于 2013-10-14 08:50
总觉得这段写得好奇怪
!?CM0&1000; 冒险画面右键点击英雄施法图标
!!CM:S?y1 I?y2;
没用,换了代码在359下仍然有这情况，只有把359MOD移除才行:shangxin: gigichart 发表于 2013-10-15 04:39
没用,换了代码在359下仍然有这情况，只有把359MOD移除才行
莫非是359MOD某个脚本也有 右击英雄魔法书?
我印象中好像没有啊
页:
[1]
