论坛 › ERM公会 | ERM Guild › 超级学者erm(1楼变态版+27楼普通版)

沧海一粟 发表于 2012-5-14 19:57:21

超级学者erm(1楼变态版+27楼普通版)

唉，众口难调，为省辛苦操劳还得多挨口侏笔伐之痛，遂利用半夜加班之余，对此erm再作一次更新。   更新后此erm将在不增加任何变量和函数的基础上将功能一分为二，按理也不会其它erm发生冲突，但两个版本彼此并不兼容：   1楼为变态版本，玩家可以通过访问地图中任一学者，自主通过选择学习自己所要的功能，但限定不超过学者本身的功能权限，学习技能时受8个技能槽等的限制，学习魔法时受魔法书等的限制，且不能从学者身上学习飞行及次元门；   27楼为通用版本，玩家可以在访问地图中任一学者前，得知学者传授的功能，并自由选择是否学习，限制条件同原学者的一切限制。

-------------------------------------------------------------------------变态版本代码如下：-------------------------------------------------------------------------
ZVSE

_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
;ERMS_说明：可自主选择学习技能的学者。
;ERMS_变量：FU48(x1=-999~-994)，v47v48v49。
;ERMS_制作：沧海一粟。

!?OB81;
!!FU48:P-999;

!?FU48&x1=-999/1000;
!!VRv47:C0/0/0;
!!OBv998/v999/v1000:R;
!!HE-1:B0/?z-1;
!!VRz1:S^在一片空地上你遇见一位学者“咳咳，%Z-1，
受WOG中央ERM务院肚子疼委员的派遣，我可以让你自主地选择想要学习的技能。”你的选择是：^;
!!VRz2:S^增加基本技能^;
!!VRz3:S^增加辅助技能^;
!!VRz4:S^增加一种魔法^;
!!VRz5:S^我什么都不干^;
!!IF:G1/7/1/1/2/3/4/5;
!!VRy2:S0;
!!VRy2:Sv7;
!!VRv7:S0;
!!OBv998/v999/v1000&y2=8:S;
!!FU&y2=8:E;
!!SCv998/v999/v1000&y2=1:T0;
!!FU48&y2=1:P-998;
!!SCv998/v999/v1000&y2=2:T1;
!!FU48&y2=2:P-997;
!!SCv998/v999/v1000&y2=4:T2;
!!FU48&y2=4:P-996;

!?FU48&x1=-998;
!!VRz3:S^请输入你想要增加的四围代码：
〖0攻击1防御2力量3知识〗^;
!!VRz4:S^如果输入字母或者空白则默认为0^;
!!VRz5:S^^;
!!IF:D2/3/4/5;
!!IF:E1/2;
!!OBv998/v999/v1000&v1=-1:S;
!!FU&v1=-1:E;
!!VRy4:Vz1;
!!IF|y4<0/y4>3:M^无效输入，再犯错小心送你去劳教。^;
!!OBv998/v999/v1000|y4<0/y4>3:S;
!!FU|y4<0/y4>3:E;
!!SCv998/v999/v1000:Py4;

!?FU48&x1=-997;
!!VRz3:S^请输入你想拥有的技能代码：
〖0寻路1箭术2后勤3侦查4外交5航海6领导7智慧8 神秘9幸运10弹道
11鹰眼12招魂13理财14火系15气系16水系17土系18学术19战术
20驽车21学习22进攻23防御24智力25魔力26抗魔27急救〗^;
!!VRz4:S^如果输入字母或者空白则默认为0^;
!!VRz5:S^^;
!!IF:D2/3/4/5;
!!IF:E1/2;
!!OBv998/v999/v1000&v1=-1:S;
!!FU&v1=-1:E;
!!VRy4:Vz1;
!!IF|y4>27/y4<0:M^无效输入，再犯错小心送你去劳教。^;
!!OBv998/v999/v1000|y4>27/y4<0:S;
!!FU|y4>27/y4<0:E;
!!HE-1:Sy4/?y5;
!!UN:N4/-6/y4/1;
!!IF&y5>=3:M^做人别太贪心，你已经拥有高级%Z-6技能。^;
!!OBv998/v999/v1000&y5>=3:S;
!!FU&y5>=3:E;
!!DO48/0/27/1:P-995/-1;
!!DO48/1/8/1:P-994/-1/y4;
!!IF&v47>7/v48>7:M^做人别太贪心，你已经拥有8个高级技能。^;
!!OBv998/v999/v1000&v47>7/v48>7:S;
!!FU&v47>7/v48>7:E;
!!IF&v47<8/v49>7:M^做人别太贪心，你的8个技能已经全满了。^;
!!OBv998/v999/v1000&v47<8/v49>7:S;
!!FU&v47<8/v49>7:E;
!!SCv998/v999/v1000:Sy4;

!?FU48&x1=-995;
!!HEx2:Sx16/?x4;
!!FU&x4<3:E;
!!VRv47:+1;

!?FU48&x1=-994;
!!HEx2:Sx16/?x4/1;
!!FU|x4>27/x4<0:E;
!!VRv48:+1;
!!FU&x4=x3:E;
!!VRv49:+1;

!?FU48&x1=-996;
!!HE-1:A2/0/d/?y3;
!!IF&y3<1:M^你好像还没有魔法书，没资格进行魔法学习。^;
!!OBv998/v999/v1000&y3<1:S;
!!FU&y3<1:E;
!!VRz3:S^请输入你想拥有的魔法编号（不能学习飞行及次元门）：
〖0召船1毁船 2透视 3观地4伪装5观天6飞行7凌波8次元9回城10流沙
11地雷12力盾13火墙14地震15魔箭16寒冰17闪电18雷鸣19连闪20冰环
21火球22烈焰23火雨24死波25圣唱26末日27土盾28气盾29火盾30御气
31御火32御水33御土34抗魔35驱魔36魔镜37疗伤38复活39聚灵40牺牲
41祝福42恶咒43嗜血44百中45虚弱46石肤47毁灭48祈祷49欢欣50悲痛
51幸运52厄运53加速54迟缓55屠龙56孤注57神雷58反戈59丧心60蛊惑
61失忆62盲眼63瞬移64驱障65镜像66召火67召土68召水69召气〗^;
!!VRz4:S^如果输入字母或者空白则默认为0^;
!!VRz5:S^^;
!!IF:D2/3/4/5;
!!IF:E1/2;
!!OBv998/v999/v1000&v1=-1:S;
!!FU&v1=-1:E;
!!VRy4:Vz1;
!!IF|y4<0/y4>69:M^无效输入，再犯错小心送你去劳教。^;
!!OBv998/v999/v1000|y4<0/y4>69:S;
!!FU|y4<0/y4>69:E;
!!IF&y4=6:M^禁止学习飞行奇术魔法。^;
!!IF&y4=8:M^不能学习异次元之门魔法。^;
!!OBv998/v999/v1000|y4=6/y4=8:S;
!!FU|y4=6/y4=8:E;
!!UN:N1/-4/y4/1;
!!HE-1:My4/?y5;
!!IF&y5=1:M^做人别太贪心，你已经学会了%Z-4魔法。^;
!!OBv998/v999/v1000&y5=1:S;
!!FU&y5=1:E;
*!SCv998/v999/v1000:Ly4; ～唉，直接实现写烦了，换个写法。
!!IF:Q1/9/y4/1^在一片空地上你遇见一位学者，他答应在离开之前教你一些东西。^;
!!OBv998/v999/v1000:S;
!!HE-1:My4/1;
!!VRz-9:S^pickup06.82M^;
!!SN:Pz-9;
!!UN:Ov998/v999/v1000;
*********************************************************

[ 本帖最后由 沧海一粟 于 2012-5-28 17:54 编辑 ]

兽哥哥 发表于 2012-5-14 20:02:24

这个还是自娱自乐好点。

才玩的小菜鸟 发表于 2012-5-14 20:03:54

;balu; 沧海兄是要逆天么？？！！

无心云 发表于 2012-5-14 20:08:06

哇，这样的学者真是N奔大了

其实肚子疼委员长好像只是说想增加一个可以选择不学的选项，想不到沧海师一出手就是逆天学者了，大拿就是大拿;oweojs;

沧海一粟 发表于 2012-5-14 20:10:20

原帖由 无心云 于 2012-5-14 20:08 发表 http://bbs.h3wog.com/images/common/back.gif
哇，这样的学者真是N奔大了

其实肚子疼委员长好像只是说想增加一个可以选择不学的选项，想不到沧海师一出手就是逆天学者了，大拿就是大拿;oweojs;

;quq; 原来要求才这样的，我还以为......要强制学者出辅助技能害我白白用了3个V变量。

songfx 发表于 2012-5-14 20:22:31

就是，你这也太周到了，比kfc的收银员还婆婆妈妈 。

renlinfeng 发表于 2012-5-14 20:22:44

:buxie: 感觉如果能放在TE里的话

dadds 发表于 2012-5-14 20:30:10

随意自选？沧海大师果然是BT中的战斗机;han;

[ 本帖最后由 dadds 于 2012-5-14 20:31 编辑 ]

兽哥哥 发表于 2012-5-14 20:34:49

原帖由 renlinfeng 于 2012-5-14 20:22 发表 http://www.h3wog.com/images/common/back.gif
:buxie: 感觉如果能放在TE里的话 呵呵，放TE里面，TE就毁了;aieol;

希望创师 发表于 2012-5-14 20:36:08

沧海的这个erm太bt了吧，和预想大不一样啊;ekow;

沧海一粟 发表于 2012-5-14 20:39:24

好吧，好吧，喝酒回来晚上写个不太变态的。;kl;

水手 发表于 2012-5-14 21:01:33

回复 11# 的帖子

真是好心没好报啊。

dadds 发表于 2012-5-14 21:13:32

回复 12# 的帖子

汗;bf; 也没那么严重啦

兽哥哥 发表于 2012-5-14 21:19:00

回复 13# 的帖子

人外有人，山外有山啊

53lm2 发表于 2012-5-14 21:21:38

;ekow;
没什么意思的说...

贤知有您 发表于 2012-5-14 22:24:57

哈哈哈.是我说要改动学者可以学习任何奖励的.
这个强大,正合我意.

无心云 发表于 2012-5-14 22:26:53

嘿嘿，果然是萝卜白菜各有所爱

沧海没有白辛苦;oweojs;

灰狼王子 发表于 2012-5-14 22:59:13

这个绝对给力啊，超级学者集成了战术学院、魔法学院和女巫小屋的功能与一体;oweojs; 不想太BT的话，设置成一次性的就行了。

灰狼王子 发表于 2012-5-14 23:00:06

还有就是这个仅限于己方，要是给电脑学个什么逆天的魔法或者技能就悲催了，尤其在BT地图里。

沧海一粟 发表于 2012-5-14 23:28:19

原帖由 灰狼王子 于 2012-5-14 23:00 发表 http://bbs.h3wog.com/images/common/back.gif
还有就是这个仅限于己方，要是给电脑学个什么逆天的魔法或者技能就悲催了，尤其在BT地图里。

经代码限定和测试，确实是只限玩家触发。但有点太变态了，理解错误，哈哈！
都是我的错啊;hx;

查看完整版本: 超级学者erm(1楼变态版+27楼普通版)